New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zmicro.F90 @ 12232

Last change on this file since 12232 was 12232, checked in by cetlod, 4 years ago

trunk : bugfixes on grazing diagnostics, see ticket #2260

  • Property svn:keywords set to Id
File size: 14.2 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro      : Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init : Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zlim          ! Co-limitations
17   USE p4zprod         ! production
18   USE iom             ! I/O manager
19   USE prtctl_trc      ! print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   REAL(wp), PUBLIC ::   part        !: part of calcite not dissolved in microzoo guts
28   REAL(wp), PUBLIC ::   xprefc      !: microzoo preference for POC
29   REAL(wp), PUBLIC ::   xprefn      !: microzoo preference for nanophyto
30   REAL(wp), PUBLIC ::   xprefd      !: microzoo preference for diatoms
31   REAL(wp), PUBLIC ::   xthreshdia  !: diatoms feeding threshold for microzooplankton
32   REAL(wp), PUBLIC ::   xthreshphy  !: nanophyto threshold for microzooplankton
33   REAL(wp), PUBLIC ::   xthreshpoc  !: poc threshold for microzooplankton
34   REAL(wp), PUBLIC ::   xthresh     !: feeding threshold for microzooplankton
35   REAL(wp), PUBLIC ::   resrat      !: exsudation rate of microzooplankton
36   REAL(wp), PUBLIC ::   mzrat       !: microzooplankton mortality rate
37   REAL(wp), PUBLIC ::   grazrat     !: maximal microzoo grazing rate
38   REAL(wp), PUBLIC ::   xkgraz      !: Half-saturation constant of assimilation
39   REAL(wp), PUBLIC ::   unass       !: Non-assimilated part of food
40   REAL(wp), PUBLIC ::   sigma1      !: Fraction of microzoo excretion as DOM
41   REAL(wp), PUBLIC ::   epsher      !: growth efficiency for grazing 1
42   REAL(wp), PUBLIC ::   epshermin   !: minimum growth efficiency for grazing 1
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_micro( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_micro  ***
54      !!
55      !! ** Purpose :   Compute the sources/sinks for microzooplankton
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt    ! ocean time step
60      INTEGER, INTENT(in) ::   knt   ! ???
61      !
62      INTEGER  :: ji, jj, jk
63      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
64      REAL(wp) :: zgraze  , zdenom, zdenom2
65      REAL(wp) :: zfact   , zfood, zfoodlim, zbeta
66      REAL(wp) :: zepsherf, zepshert, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
67      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
68      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
69      REAL(wp) :: zgrazp, zgrazm, zgrazsd
70      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
71      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo, zzligprod
72      CHARACTER (len=25) :: charout
73      !!---------------------------------------------------------------------
74      !
75      IF( ln_timing )   CALL timing_start('p4z_micro')
76      !
77      DO jk = 1, jpkm1
78         DO jj = 1, jpj
79            DO ji = 1, jpi
80               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
81               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
82
83               !  Respiration rates of both zooplankton
84               !  -------------------------------------
85               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
86                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
87
88               !  Zooplankton mortality. A square function has been selected with
89               !  no real reason except that it seems to be more stable and may mimic predation.
90               !  ---------------------------------------------------------------
91               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
92
93               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
94               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
95               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
96               
97               !     Microzooplankton grazing
98               !     ------------------------
99               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi
100               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
101               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
102               zdenom2   = zdenom / ( zfood + rtrn )
103               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
104
105               zgrazp    = zgraze  * xprefn * zcompaph  * zdenom2 
106               zgrazm    = zgraze  * xprefc * zcompapoc * zdenom2 
107               zgrazsd   = zgraze  * xprefd * zcompadi  * zdenom2 
108
109               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
110               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
111               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
112               !
113               zgraztotc = zgrazp  + zgrazm  + zgrazsd 
114               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
115               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
116
117               ! Grazing by microzooplankton
118               zgrazing(ji,jj,jk) = zgraztotc
119
120               !    Various remineralization and excretion terms
121               !    --------------------------------------------
122               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn )
123               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn )
124               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
125               zbeta     = MAX(0., (epsher - epshermin) )
126               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
127               zepsherv  = zepsherf * zepshert 
128
129               zgrafer   = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
130               zgrarem   = zgraztotc * ( 1. - zepsherv - unass )
131               zgrapoc   = zgraztotc * unass
132
133               !  Update of the TRA arrays
134               !  ------------------------
135               zgrarsig  = zgrarem * sigma1
136               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
137               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
138               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
139               !
140               IF( ln_ligand ) THEN
141                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
142                  zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
143               ENDIF
144               !
145               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
146               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
147               zfezoo(ji,jj,jk)    = zgrafer
148               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
149               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + zgrapoc
150               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
151               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
152               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
153               !   Update the arrays TRA which contain the biological sources and sinks
154               !   --------------------------------------------------------------------
155               zmortz = ztortz + zrespz
156               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztotc 
157               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
158               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
159               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
160               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
161               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
162               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
163               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
164               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
165               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
166               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
167               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
168               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
169               !
170               ! calcite production
171               zprcaca = xfracal(ji,jj,jk) * zgrazp
172               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
173               !
174               zprcaca = part * zprcaca
175               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
176               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
177               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
178            END DO
179         END DO
180      END DO
181      !
182      IF( lk_iomput .AND. knt == nrdttrc ) THEN
183         zgrazing(:,:,jpk) = 0._wp
184         zfezoo  (:,:,jpk) = 0._wp
185         CALL iom_put( "GRAZ1", zgrazing(:,:,:) * 1.e+3       * rfact2r * tmask(:,:,:) )  !   Total grazing of phyto by zooplankton
186         CALL iom_put( "FEZOO", zfezoo  (:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
187         IF( ln_ligand )  THEN
188            zzligprod(:,:,jpk) = 0._wp
189            CALL iom_put( "LPRODZ", zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)  )
190         ENDIF
191      ENDIF
192      !
193      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
194         WRITE(charout, FMT="('micro')")
195         CALL prt_ctl_trc_info(charout)
196         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
197      ENDIF
198      !
199      IF( ln_timing )   CALL timing_stop('p4z_micro')
200      !
201   END SUBROUTINE p4z_micro
202
203
204   SUBROUTINE p4z_micro_init
205      !!----------------------------------------------------------------------
206      !!                  ***  ROUTINE p4z_micro_init  ***
207      !!
208      !! ** Purpose :   Initialization of microzooplankton parameters
209      !!
210      !! ** Method  :   Read the nampiszoo namelist and check the parameters
211      !!                called at the first timestep (nittrc000)
212      !!
213      !! ** input   :   Namelist nampiszoo
214      !!
215      !!----------------------------------------------------------------------
216      INTEGER ::   ios   ! Local integer
217      !
218      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, &
219         &                xprefd,  xthreshdia,  xthreshphy,  xthreshpoc, &
220         &                xthresh, xkgraz, epsher, epshermin, sigma1, unass
221      !!----------------------------------------------------------------------
222      !
223      IF(lwp) THEN
224         WRITE(numout,*) 
225         WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
226         WRITE(numout,*) '~~~~~~~~~~~~~~'
227      ENDIF
228      !
229      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
230      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
231901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' )
232      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
233      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
234902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' )
235      IF(lwm) WRITE( numonp, namp4zzoo )
236      !
237      IF(lwp) THEN                         ! control print
238         WRITE(numout,*) '   Namelist : namp4zzoo'
239         WRITE(numout,*) '      part of calcite not dissolved in microzoo guts  part        =', part
240         WRITE(numout,*) '      microzoo preference for POC                     xprefc      =', xprefc
241         WRITE(numout,*) '      microzoo preference for nano                    xprefn      =', xprefn
242         WRITE(numout,*) '      microzoo preference for diatoms                 xprefd      =', xprefd
243         WRITE(numout,*) '      diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
244         WRITE(numout,*) '      nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
245         WRITE(numout,*) '      poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
246         WRITE(numout,*) '      feeding threshold for microzooplankton          xthresh     =', xthresh
247         WRITE(numout,*) '      exsudation rate of microzooplankton             resrat      =', resrat
248         WRITE(numout,*) '      microzooplankton mortality rate                 mzrat       =', mzrat
249         WRITE(numout,*) '      maximal microzoo grazing rate                   grazrat     =', grazrat
250         WRITE(numout,*) '      non assimilated fraction of P by microzoo       unass       =', unass
251         WRITE(numout,*) '      Efficicency of microzoo growth                  epsher      =', epsher
252         WRITE(numout,*) '      Minimum efficicency of microzoo growth          epshermin   =', epshermin
253         WRITE(numout,*) '      Fraction of microzoo excretion as DOM           sigma1      =', sigma1
254         WRITE(numout,*) '      half sturation constant for grazing 1           xkgraz      =', xkgraz
255      ENDIF
256      !
257   END SUBROUTINE p4z_micro_init
258
259   !!======================================================================
260END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.