New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zrem.F90 @ 10069

Last change on this file since 10069 was 10069, checked in by nicolasmartin, 6 years ago

Fix mistakes of previous commit on SVN keywords property

  • Property svn:keywords set to Id
File size: 17.7 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zice
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC
32   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON
33   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP
34   REAL(wp), PUBLIC ::   xremik     !: remineralisation rate of POC
35   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
36   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of POC
37   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of POC
38   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
39   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
40   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacteria Fe/C
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_rem( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_rem  ***
54      !!
55      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
60      !
61      INTEGER  ::   ji, jj, jk
62      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
63      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
64      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
65      REAL(wp) ::   zammonic, zoxyrem
66      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
67      CHARACTER (len=25) :: charout
68      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
71      !!---------------------------------------------------------------------
72      !
73      IF( ln_timing )   CALL timing_start('p4z_rem')
74      !
75      ! Initialisation of arrys
76      zdepprod(:,:,:) = 1._wp
77      ztempbac(:,:)   = 0._wp
78      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
79      zfacsi(:,:,:)   = xsilab
80
81      ! Computation of the mean phytoplankton concentration as
82      ! a crude estimate of the bacterial biomass
83      ! this parameterization has been deduced from a model version
84      ! that was modeling explicitely bacteria
85      ! -------------------------------------------------------
86      DO jk = 1, jpkm1
87         DO jj = 1, jpj
88            DO ji = 1, jpi
89               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
90               IF( gdept_n(ji,jj,jk) < zdep ) THEN
91                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
92                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
93               ELSE
94                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
95                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
96                  zdepprod(ji,jj,jk) = zdepmin**0.273
97               ENDIF
98            END DO
99         END DO
100      END DO
101
102      IF( ln_p4z ) THEN
103         DO jk = 1, jpkm1
104            DO jj = 1, jpj
105               DO ji = 1, jpi
106                  ! DOC ammonification. Depends on depth, phytoplankton biomass
107                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
108                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
109                  zremik = MAX( zremik, 2.74e-4 * xstep )
110                  ! Ammonification in oxic waters with oxygen consumption
111                  ! -----------------------------------------------------
112                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
113                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
114                  ! Ammonification in suboxic waters with denitrification
115                  ! -------------------------------------------------------
116                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
117                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
118                  zoxyrem           = zammonic *        nitrfac2(ji,jj,jk)
119                  !
120                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
121                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
122                  zoxyrem           = MAX( 0.e0, zoxyrem  )
123
124                  !
125                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
126                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
127                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
128                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyrem
129                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
130                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
131                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyrem    &
132                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
133               END DO
134            END DO
135         END DO
136      ELSE
137         DO jk = 1, jpkm1
138            DO jj = 1, jpj
139               DO ji = 1, jpi
140                  ! DOC ammonification. Depends on depth, phytoplankton biomass
141                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
142                  ! -----------------------------------------------------------------
143                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
144                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
145
146                  zremikc = xremikc * zremik
147                  zremikn = xremikn / xremikc
148                  zremikp = xremikp / xremikc
149
150                  ! Ammonification in oxic waters with oxygen consumption
151                  ! -----------------------------------------------------
152                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
153                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
154                  zolimi(ji,jj,jk) = zolimic
155                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
156                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
157
158                  ! Ammonification in suboxic waters with denitrification
159                  ! -------------------------------------------------------
160                  zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
161                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
162                  denitr(ji,jj,jk) = MAX( 0.e0, denitr(ji,jj,jk) )
163                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
164                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
165
166                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
167                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
168                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
169                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk)
170                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
171                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
172                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
173                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk)
174                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
175               END DO
176            END DO
177         END DO
178         !
179      ENDIF
180
181
182      DO jk = 1, jpkm1
183         DO jj = 1, jpj
184            DO ji = 1, jpi
185               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
186               ! below 2 umol/L. Inhibited at strong light
187               ! ----------------------------------------------------------
188               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
189               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
190               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
191               ! Update of the tracers trends
192               ! ----------------------------
193               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
194               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
195               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
196               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
197            END DO
198         END DO
199      END DO
200
201       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
202         WRITE(charout, FMT="('rem1')")
203         CALL prt_ctl_trc_info(charout)
204         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
205       ENDIF
206
207      DO jk = 1, jpkm1
208         DO jj = 1, jpj
209            DO ji = 1, jpi
210
211               ! Bacterial uptake of iron. No iron is available in DOC. So
212               ! Bacteries are obliged to take up iron from the water. Some
213               ! studies (especially at Papa) have shown this uptake to be significant
214               ! ----------------------------------------------------------
215               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
216                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
217                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
218               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
219               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
220               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
221            END DO
222         END DO
223      END DO
224
225       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
226         WRITE(charout, FMT="('rem2')")
227         CALL prt_ctl_trc_info(charout)
228         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
229       ENDIF
230
231      ! Initialization of the array which contains the labile fraction
232      ! of bSi. Set to a constant in the upper ocean
233      ! ---------------------------------------------------------------
234
235      DO jk = 1, jpkm1
236         DO jj = 1, jpj
237            DO ji = 1, jpi
238               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
239               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
240               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
241               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
242               ! Remineralization rate of BSi depedant on T and saturation
243               ! ---------------------------------------------------------
244               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
245                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
246                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
247                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
248                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
249                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
250               ENDIF
251               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
252               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
253               !
254               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
255               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
256               !
257            END DO
258         END DO
259      END DO
260
261      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
262         WRITE(charout, FMT="('rem3')")
263         CALL prt_ctl_trc_info(charout)
264         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
265       ENDIF
266
267      IF( knt == nrdttrc ) THEN
268          ALLOCATE( zw3d(jpi,jpj,jpk) )
269          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
270          !
271          IF( iom_use( "REMIN" ) )  THEN
272              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
273              CALL iom_put( "REMIN"  , zw3d )
274          ENDIF
275          IF( iom_use( "DENIT" ) )  THEN
276              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
277              CALL iom_put( "DENIT"  , zw3d )
278          ENDIF
279          !
280          DEALLOCATE( zw3d )
281       ENDIF
282      !
283      IF( ln_timing )   CALL timing_stop('p4z_rem')
284      !
285   END SUBROUTINE p4z_rem
286
287
288   SUBROUTINE p4z_rem_init
289      !!----------------------------------------------------------------------
290      !!                  ***  ROUTINE p4z_rem_init  ***
291      !!
292      !! ** Purpose :   Initialization of remineralization parameters
293      !!
294      !! ** Method  :   Read the nampisrem namelist and check the parameters
295      !!      called at the first timestep
296      !!
297      !! ** input   :   Namelist nampisrem
298      !!
299      !!----------------------------------------------------------------------
300      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
301         &                xremikc, xremikn, xremikp
302      INTEGER :: ios                 ! Local integer output status for namelist read
303      !!----------------------------------------------------------------------
304      !
305      IF(lwp) THEN
306         WRITE(numout,*)
307         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
308         WRITE(numout,*) '~~~~~~~~~~~~'
309      ENDIF
310      !
311      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
312      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
313901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
314      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
315      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
316902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
317      IF(lwm) WRITE( numonp, nampisrem )
318
319      IF(lwp) THEN                         ! control print
320         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
321         IF( ln_p4z ) THEN
322            WRITE(numout,*) '      remineralization rate of DOC              xremik    =', xremik
323         ELSE
324            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
325            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
326            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
327         ENDIF
328         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
329         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
330         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
331         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
332         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
333         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
334      ENDIF
335      !
336      denitr(:,:,:) = 0._wp
337      !
338   END SUBROUTINE p4z_rem_init
339
340
341   INTEGER FUNCTION p4z_rem_alloc()
342      !!----------------------------------------------------------------------
343      !!                     ***  ROUTINE p4z_rem_alloc  ***
344      !!----------------------------------------------------------------------
345      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
346      !
347      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
348      !
349   END FUNCTION p4z_rem_alloc
350
351   !!======================================================================
352END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.