New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zsbc.F90 @ 10111

Last change on this file since 10111 was 10111, checked in by cetlod, 6 years ago

v4.0 : bugfix to better estimate the coastal release of iron in PISCES

  • Property svn:keywords set to Id
File size: 28.1 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC ::   ln_dust      !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC ::   ln_solub     !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC ::   ln_river     !: boolean for river input of nutrients
26   LOGICAL , PUBLIC ::   ln_ndepo     !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC ::   ln_ironsed   !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC ::   ln_hydrofe   !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC ::   ln_ironice   !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC ::   sedfeinput   !: Coastal release of Iron
31   REAL(wp), PUBLIC ::   dustsolub    !: Solubility of the dust
32   REAL(wp), PUBLIC ::   mfrac        !: Mineral Content of the dust
33   REAL(wp), PUBLIC ::   icefeinput   !: Iron concentration in sea ice
34   REAL(wp), PUBLIC ::   wdust        !: Sinking speed of the dust
35   REAL(wp), PUBLIC ::   nitrfix      !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC ::   diazolight   !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC ::   concfediaz   !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)         ::   hratio       !: Fe:3He ratio assumed for vent iron supply
39   REAL(wp)         ::   distcoast    !: Distance off the coast for Iron from sediments
40   REAL(wp), PUBLIC ::   fep_rats     !: Fep/Fer ratio from sed  sources
41   REAL(wp), PUBLIC ::   fep_rath     !: Fep/Fer ratio from hydro sources
42   REAL(wp), PUBLIC ::   lgw_rath     !: Weak ligand ratio from hydro sources
43
44   LOGICAL , PUBLIC ::   ll_sbc
45   LOGICAL          ::   ll_solub
46
47   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
48   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
49   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
50   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
51   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
52   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
53   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
54   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
55
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub     ! structure of input dust
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river     ! structure of input riverdic
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
62
63   INTEGER , PARAMETER ::   nbtimes = 365                          ! maximum number of times record in a file
64   INTEGER             ::   ntimes_dust, ntimes_riv, ntimes_ndep   ! number of time steps in a file
65   INTEGER             ::   ntimes_solub, ntimes_hydro             ! number of time steps in a file
66
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   dust  , solub    !: dust fields
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdic, rivalk   !: river input fields
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdin, rivdip   !: river input fields
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdon, rivdop   !: river input fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdoc           !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdsi           !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nitdep           !: atmospheric N deposition
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ironsed          !: Coastal supply of iron
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   hydrofe          !: Hydrothermal vent supply of iron
76
77   REAL(wp), PUBLIC ::   rivalkinput, rivdicinput, nitdepinput, sumdepsi
78   REAL(wp), PUBLIC ::   rivdininput, rivdipinput, rivdsiinput
79
80   !! * Substitutions
81#  include "vectopt_loop_substitute.h90"
82   !!----------------------------------------------------------------------
83   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
84   !! $Id$
85   !! Software governed by the CeCILL license (see ./LICENSE)
86   !!----------------------------------------------------------------------
87CONTAINS
88
89   SUBROUTINE p4z_sbc( kt )
90      !!----------------------------------------------------------------------
91      !!                  ***  routine p4z_sbc  ***
92      !!
93      !! ** purpose :   read and interpolate the external sources of nutrients
94      !!
95      !! ** method  :   read the files and interpolate the appropriate variables
96      !!
97      !! ** input   :   external netcdf files
98      !!
99      !!----------------------------------------------------------------------
100      INTEGER, INTENT(in) ::   kt   ! ocean time step
101      !
102      INTEGER  ::   ji, jj 
103      REAL(wp) ::   zcoef, zyyss
104      !!---------------------------------------------------------------------
105      !
106      IF( ln_timing )   CALL timing_start('p4z_sbc')
107      !
108      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
109      IF( ln_dust ) THEN
110         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
111            CALL fld_read( kt, 1, sf_dust )
112            IF( nn_ice_tr == -1 .AND. .NOT.ln_ironice ) THEN   ;   dust(:,:) = sf_dust(1)%fnow(:,:,1)
113            ELSE                                               ;   dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.-fr_i(:,:) )
114            ENDIF
115         ENDIF
116      ENDIF
117      !
118      IF( ll_solub ) THEN
119         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
120            CALL fld_read( kt, 1, sf_solub )
121            solub(:,:) = sf_solub(1)%fnow(:,:,1)
122         ENDIF
123      ENDIF
124
125      ! N/P and Si releases due to coastal rivers
126      ! Compute river at nit000 or only if there is more than 1 time record in river file
127      ! -----------------------------------------
128      IF( ln_river ) THEN
129         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
130            CALL fld_read( kt, 1, sf_river )
131            IF( ln_p4z ) THEN
132               DO jj = 1, jpj
133                  DO ji = 1, jpi
134                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
135                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
136                        &              * 1.E3        / ( 12. * zcoef + rtrn )
137                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
138                        &              * 1.E3         / ( 12. * zcoef + rtrn )
139                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
140                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
141                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
142                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
143                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
144                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
145                  END DO
146               END DO
147            ELSE    !  ln_p5z
148               DO jj = 1, jpj
149                  DO ji = 1, jpi
150                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
151                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
152                        &              * 1.E3        / ( 12. * zcoef + rtrn )
153                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) ) &
154                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
155                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) ) &
156                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
157                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) ) &
158                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
159                     rivdoc(ji,jj) = ( sf_river(jr_doc)%fnow(ji,jj,1) ) &
160                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
161                     rivdon(ji,jj) = ( sf_river(jr_don)%fnow(ji,jj,1) ) &
162                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
163                     rivdop(ji,jj) = ( sf_river(jr_dop)%fnow(ji,jj,1) ) &
164                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
165                  END DO
166               END DO
167            ENDIF
168         ENDIF
169      ENDIF
170
171      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
172      IF( ln_ndepo ) THEN
173         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
174             zcoef = rno3 * 14E6 * ryyss
175             CALL fld_read( kt, 1, sf_ndepo )
176             nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
177         ENDIF
178         IF( .NOT.ln_linssh ) THEN
179           zcoef = rno3 * 14E6 * ryyss
180           nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
181         ENDIF
182      ENDIF
183      !
184      IF( ln_timing )  CALL timing_stop('p4z_sbc')
185      !
186   END SUBROUTINE p4z_sbc
187
188
189   SUBROUTINE p4z_sbc_init
190      !!----------------------------------------------------------------------
191      !!                  ***  routine p4z_sbc_init  ***
192      !!
193      !! ** purpose :   initialization of the external sources of nutrients
194      !!
195      !! ** method  :   read the files and compute the budget
196      !!                called at the first timestep (nittrc000)
197      !!
198      !! ** input   :   external netcdf files
199      !!
200      !!----------------------------------------------------------------------
201      INTEGER  :: ji, jj, jk, jm, ifpr
202      INTEGER  :: ii0, ii1, ij0, ij1
203      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
204      INTEGER  :: ierr, ierr1, ierr2, ierr3
205      INTEGER  :: ios                 ! Local integer output status for namelist read
206      INTEGER  :: ik50                !  last level where depth less than 50 m
207      INTEGER  :: isrow             ! index for ORCA1 starting row
208      REAL(wp) :: zexpide, zdenitide, zmaskt, zsurfc, zsurfp,ze3t, ze3t2, zcslp
209      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
210      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
211      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
212      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
213      !
214      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
215      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
216      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
217      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
218      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
219      !!
220      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
221        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
222        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
223        &                sedfeinput, distcoast, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, &
224        &                hratio, fep_rats, fep_rath, lgw_rath
225      !!----------------------------------------------------------------------
226      !
227      IF(lwp) THEN
228         WRITE(numout,*)
229         WRITE(numout,*) 'p4z_sbc_init : initialization of the external sources of nutrients '
230         WRITE(numout,*) '~~~~~~~~~~~~ '
231      ENDIF
232      !                            !* set file information
233      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
234      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
235901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
236      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
237      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
238902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
239      IF(lwm) WRITE ( numonp, nampissbc )
240
241      IF(lwp) THEN
242         WRITE(numout,*) '   Namelist : nampissbc '
243         WRITE(numout,*) '      dust input from the atmosphere           ln_dust     = ', ln_dust
244         WRITE(numout,*) '      Variable solubility of iron input        ln_solub    = ', ln_solub
245         WRITE(numout,*) '      river input of nutrients                 ln_river    = ', ln_river
246         WRITE(numout,*) '      atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
247         WRITE(numout,*) '      Fe input from sediments                  ln_ironsed  = ', ln_ironsed
248         WRITE(numout,*) '      Fe input from seaice                     ln_ironice  = ', ln_ironice
249         WRITE(numout,*) '      fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
250         WRITE(numout,*) '      coastal release of iron                  sedfeinput  = ', sedfeinput
251         WRITE(numout,*) '      distance off the coast                   distcoast   = ', distcoast
252         WRITE(numout,*) '      solubility of the dust                   dustsolub   = ', dustsolub
253         WRITE(numout,*) '      Mineral Fe content of the dust           mfrac       = ', mfrac
254         WRITE(numout,*) '      Iron concentration in sea ice            icefeinput  = ', icefeinput
255         WRITE(numout,*) '      sinking speed of the dust                wdust       = ', wdust
256         WRITE(numout,*) '      nitrogen fixation rate                   nitrfix     = ', nitrfix
257         WRITE(numout,*) '      nitrogen fixation sensitivty to light    diazolight  = ', diazolight
258         WRITE(numout,*) '      Fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
259         WRITE(numout,*) '      Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
260         IF( ln_ligand ) THEN
261            WRITE(numout,*) '      Fep/Fer ratio from sed sources            fep_rats   = ', fep_rats
262            WRITE(numout,*) '      Fep/Fer ratio from sed hydro sources      fep_rath   = ', fep_rath
263            WRITE(numout,*) '      Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
264         ENDIF
265      END IF
266
267      IF( nn_ice_tr >= 0 .AND. ln_ironice ) THEN
268         IF(lwp) THEN
269            WRITE(numout,*) '   ==>>>   ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
270            WRITE(numout,*) '           Specify your sea ice iron concentration in nampisice instead '
271            WRITE(numout,*) '           ln_ironice is forced to .FALSE. '
272         ENDIF
273         ln_ironice = .FALSE.
274      ENDIF
275
276      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN   ;   ll_sbc = .TRUE.
277      ELSE                                             ;   ll_sbc = .FALSE.
278      ENDIF
279
280      IF( ln_dust .AND. ln_solub ) THEN                ;   ll_solub = .TRUE.
281      ELSE                                             ;   ll_solub = .FALSE.
282      ENDIF
283
284      ! set the number of level over which river runoffs are applied
285      ! online configuration : computed in sbcrnf
286      IF( l_offline ) THEN
287        nk_rnf(:,:) = 1
288        h_rnf (:,:) = gdept_n(:,:,1)
289      ENDIF
290
291      ! dust input from the atmosphere
292      ! ------------------------------
293      IF( ln_dust ) THEN 
294         !
295         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
296         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
297         !
298         ALLOCATE( dust(jpi,jpj) )    ! allocation
299         !
300         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
301         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
302         !
303         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
304                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
305         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
306         !
307         IF( Agrif_Root() ) THEN   !  Only on the master grid
308            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
309            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
310            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
311            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
312            DO jm = 1, ntimes_dust
313               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
314            END DO
315            CALL iom_close( numdust )
316            ztimes_dust = 1._wp / REAL(ntimes_dust, wp) 
317            sumdepsi = 0.e0
318            DO jm = 1, ntimes_dust
319               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
320            END DO
321            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
322            DEALLOCATE( zdust)
323         ENDIF
324      ELSE
325         sumdepsi  = 0._wp
326      END IF
327
328      ! Solubility of dust deposition of iron
329      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
330      ! -----------------------------------------------------------------
331      IF( ll_solub ) THEN
332         !
333         IF(lwp) WRITE(numout,*)
334         IF(lwp) WRITE(numout,*) '   ==>>>   ll_solub=T , initialize variable solubility of Fe '
335         !
336         ALLOCATE( solub(jpi,jpj) )    ! allocation
337         !
338         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
339         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
340         !
341         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
342                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
343         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
344         ! get number of record in file
345         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
346         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
347         CALL iom_close( numsolub )
348      ENDIF
349
350      ! nutrient input from rivers
351      ! --------------------------
352      IF( ln_river ) THEN
353         !
354         slf_river(jr_dic) = sn_riverdic   ;   slf_river(jr_doc) = sn_riverdoc   ;   slf_river(jr_din) = sn_riverdin 
355         slf_river(jr_don) = sn_riverdon   ;   slf_river(jr_dip) = sn_riverdip   ;   slf_river(jr_dop) = sn_riverdop
356         slf_river(jr_dsi) = sn_riverdsi 
357         !
358         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
359         IF( ln_p5z )  ALLOCATE( rivdon(jpi,jpj), rivdop(jpi,jpj), rivdoc(jpi,jpj) )
360         !
361         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )    !* allocate and fill sf_river (forcing structure) with sn_river_
362         rivinput(:) = 0._wp
363
364         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
365         !
366         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
367         DO ifpr = 1, jpriv
368                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
369            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
370         END DO
371         IF( Agrif_Root() ) THEN   !  Only on the master grid
372            ! Get total input rivers ; need to compute total river supply in a year
373            DO ifpr = 1, jpriv
374               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
375               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
376               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
377               DO jm = 1, ntimes_riv
378                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
379               END DO
380               CALL iom_close( numriv )
381               ztimes_riv = 1._wp / REAL(ntimes_riv, wp) 
382               DO jm = 1, ntimes_riv
383                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
384               END DO
385               DEALLOCATE( zriver)
386            END DO
387            ! N/P and Si releases due to coastal rivers
388            ! -----------------------------------------
389            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
390            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
391            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
392            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
393            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
394            !
395         ENDIF
396      ELSE
397         rivdicinput = 0._wp
398         rivdininput = 0._wp
399         rivdipinput = 0._wp
400         rivdsiinput = 0._wp
401         rivalkinput = 0._wp
402      END IF 
403      ! nutrient input from dust
404      ! ------------------------
405      IF( ln_ndepo ) THEN
406         !
407         IF(lwp) WRITE(numout,*)
408         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ndepo=T , initialize the nutrient input by dust from NetCDF file'
409         !
410         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
411         !
412         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
413         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
414         !
415         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
416                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
417         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
418         !
419         IF( Agrif_Root() ) THEN   !  Only on the master grid
420            ! Get total input dust ; need to compute total atmospheric supply of N in a year
421            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
422            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
423            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
424            DO jm = 1, ntimes_ndep
425               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
426            END DO
427            CALL iom_close( numdepo )
428            ztimes_ndep = 1._wp / REAL(ntimes_ndep, wp) 
429            nitdepinput = 0._wp
430            DO jm = 1, ntimes_ndep
431              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
432            ENDDO
433            nitdepinput = nitdepinput / rno3 / 14E6 
434            DEALLOCATE( zndepo)
435         ENDIF
436      ELSE
437         nitdepinput = 0._wp
438      ENDIF
439
440      ! coastal and island masks
441      ! ------------------------
442      IF( ln_ironsed ) THEN     
443         !
444         IF(lwp) WRITE(numout,*)
445         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ironsed=T , computation of an island mask to enhance coastal supply of iron'
446         !
447         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
448         !
449         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
450         ALLOCATE( zcmask(jpi,jpj,jpk) )
451         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
452         CALL iom_close( numiron )
453         !
454         ik50 = 5        !  last level where depth less than 50 m
455         DO jk = jpkm1, 1, -1
456            IF( gdept_1d(jk) > 50. )   ik50 = jk - 1
457         END DO
458         IF(lwp) WRITE(numout,*)
459         IF(lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
460         DO jk = 1, ik50
461            DO jj = 2, jpjm1
462               DO ji = fs_2, fs_jpim1
463                  ze3t   = e3t_0(ji,jj,jk)
464                  zsurfc =  e1u(ji,jj) * ( 1. - umask(ji  ,jj  ,jk) )   &
465                          + e1u(ji,jj) * ( 1. - umask(ji-1,jj  ,jk) )   &
466                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj  ,jk) )   &
467                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj-1,jk) )
468                  zsurfp = zsurfc * ze3t / e1e2t(ji,jj)
469                  ! estimation of the coastal slope : 5 km off the coast
470                  ze3t2 = ze3t * ze3t
471                  zcslp = SQRT( ( distcoast*distcoast + ze3t2 ) / ze3t2 )
472                  !
473                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) + zcslp * zsurfp
474               END DO
475            END DO
476         END DO
477         !
478         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
479         !
480         DO jk = 1, jpk
481            DO jj = 1, jpj
482               DO ji = 1, jpi
483                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
484                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
485                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
486               END DO
487            END DO
488         END DO
489         ! Coastal supply of iron
490         ! -------------------------
491         ironsed(:,:,jpk) = 0._wp
492         DO jk = 1, jpkm1
493            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
494         END DO
495         DEALLOCATE( zcmask)
496      ENDIF
497      !
498      ! Iron from Hydrothermal vents
499      ! ------------------------
500      IF( ln_hydrofe ) THEN
501         !
502         IF(lwp) WRITE(numout,*)
503         IF(lwp) WRITE(numout,*) '   ==>>>   ln_hydrofe=T , Input of iron from hydrothermal vents'
504         !
505         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
506         !
507         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
508         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
509         CALL iom_close( numhydro )
510         !
511         DO jk = 1, jpk
512            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
513         ENDDO
514         !
515      ENDIF
516      !
517      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
518      !
519      IF(lwp) THEN
520         WRITE(numout,*)
521         WRITE(numout,*) '    Total input of elements from river supply'
522         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
523         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
524         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1    ,' TgSi/yr'
525         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
526         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12         ,' Teq/yr'
527         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12     ,' TgC/yr'
528         WRITE(numout,*) 
529         WRITE(numout,*) '    Total input of elements from atmospheric supply'
530         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
531         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
532         WRITE(numout,*) 
533      ENDIF
534      !
535   END SUBROUTINE p4z_sbc_init
536
537   !!======================================================================
538END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.