source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zsbc.F90 @ 10425

Last change on this file since 10425 was 10425, checked in by smasson, 20 months ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 26.6 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC ::   ln_dust      !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC ::   ln_solub     !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC ::   ln_river     !: boolean for river input of nutrients
26   LOGICAL , PUBLIC ::   ln_ndepo     !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC ::   ln_ironsed   !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC ::   ln_hydrofe   !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC ::   ln_ironice   !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC ::   sedfeinput   !: Coastal release of Iron
31   REAL(wp), PUBLIC ::   dustsolub    !: Solubility of the dust
32   REAL(wp), PUBLIC ::   mfrac        !: Mineral Content of the dust
33   REAL(wp), PUBLIC ::   icefeinput   !: Iron concentration in sea ice
34   REAL(wp), PUBLIC ::   wdust        !: Sinking speed of the dust
35   REAL(wp), PUBLIC ::   nitrfix      !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC ::   diazolight   !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC ::   concfediaz   !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)         ::   hratio       !: Fe:3He ratio assumed for vent iron supply
39   REAL(wp)         ::   distcoast    !: Distance off the coast for Iron from sediments
40   REAL(wp), PUBLIC ::   lgw_rath     !: Weak ligand ratio from hydro sources
41
42   LOGICAL , PUBLIC ::   ll_sbc
43   LOGICAL          ::   ll_solub
44
45   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
46   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
47   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
48   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
49   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
50   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
51   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
52   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub     ! structure of input dust
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river     ! structure of input riverdic
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
60
61   INTEGER , PARAMETER ::   nbtimes = 365                          ! maximum number of times record in a file
62   INTEGER             ::   ntimes_dust, ntimes_riv, ntimes_ndep   ! number of time steps in a file
63   INTEGER             ::   ntimes_solub, ntimes_hydro             ! number of time steps in a file
64
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   dust  , solub    !: dust fields
66   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdic, rivalk   !: river input fields
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdin, rivdip   !: river input fields
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdon, rivdop   !: river input fields
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdoc           !: river input fields
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rivdsi           !: river input fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nitdep           !: atmospheric N deposition
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ironsed          !: Coastal supply of iron
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   hydrofe          !: Hydrothermal vent supply of iron
74
75   REAL(wp), PUBLIC :: sedsilfrac, sedcalfrac
76   REAL(wp), PUBLIC :: rivalkinput, rivdicinput
77   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
78
79   !! * Substitutions
80#  include "vectopt_loop_substitute.h90"
81   !!----------------------------------------------------------------------
82   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
83   !! $Id$
84   !! Software governed by the CeCILL license (see ./LICENSE)
85   !!----------------------------------------------------------------------
86CONTAINS
87
88   SUBROUTINE p4z_sbc( kt )
89      !!----------------------------------------------------------------------
90      !!                  ***  routine p4z_sbc  ***
91      !!
92      !! ** purpose :   read and interpolate the external sources of nutrients
93      !!
94      !! ** method  :   read the files and interpolate the appropriate variables
95      !!
96      !! ** input   :   external netcdf files
97      !!
98      !!----------------------------------------------------------------------
99      INTEGER, INTENT(in) ::   kt   ! ocean time step
100      !
101      INTEGER  ::   ji, jj 
102      REAL(wp) ::   zcoef, zyyss
103      !!---------------------------------------------------------------------
104      !
105      IF( ln_timing )   CALL timing_start('p4z_sbc')
106      !
107      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
108      IF( ln_dust ) THEN
109         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
110            CALL fld_read( kt, 1, sf_dust )
111            IF( nn_ice_tr == -1 .AND. .NOT.ln_ironice ) THEN   ;   dust(:,:) = MAX( rtrn, sf_dust(1)%fnow(:,:,1) )
112            ELSE                                               ;   dust(:,:) = MAX( rtrn, sf_dust(1)%fnow(:,:,1) * ( 1.-fr_i(:,:) ) )
113            ENDIF
114         ENDIF
115      ENDIF
116      !
117      IF( ll_solub ) THEN
118         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
119            CALL fld_read( kt, 1, sf_solub )
120            solub(:,:) = sf_solub(1)%fnow(:,:,1)
121         ENDIF
122      ENDIF
123
124      ! N/P and Si releases due to coastal rivers
125      ! Compute river at nit000 or only if there is more than 1 time record in river file
126      ! -----------------------------------------
127      IF( ln_river ) THEN
128         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
129            CALL fld_read( kt, 1, sf_river )
130            IF( ln_p4z ) THEN
131               DO jj = 1, jpj
132                  DO ji = 1, jpi
133                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
134                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)  &
135                        &              * 1.E3        / ( 12. * zcoef + rtrn )
136                     rivdic(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)  &
137                        &              * 1.E3         / ( 12. * zcoef + rtrn )
138                     rivdin(ji,jj) =   sf_river(jr_din)%fnow(ji,jj,1)  &
139                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
140                     rivdip(ji,jj) =   sf_river(jr_dip)%fnow(ji,jj,1)  &
141                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
142                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)  &
143                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
144                     rivdoc(ji,jj) =   sf_river(jr_doc)%fnow(ji,jj,1)  &
145                        &              * 1.E3        / ( 12. * zcoef + rtrn ) 
146                  END DO
147               END DO
148            ELSE    !  ln_p5z
149               DO jj = 1, jpj
150                  DO ji = 1, jpi
151                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
152                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
153                        &              * 1.E3        / ( 12. * zcoef + rtrn )
154                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) ) &
155                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
156                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) ) &
157                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
158                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) ) &
159                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
160                     rivdon(ji,jj) = ( sf_river(jr_don)%fnow(ji,jj,1) ) &
161                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
162                     rivdop(ji,jj) = ( sf_river(jr_dop)%fnow(ji,jj,1) ) &
163                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
164                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)  &
165                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
166                     rivdoc(ji,jj) =   sf_river(jr_doc)%fnow(ji,jj,1)  &
167                        &              * 1.E3        / ( 12. * zcoef + rtrn )
168                  END DO
169               END DO
170            ENDIF
171         ENDIF
172      ENDIF
173
174      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
175      IF( ln_ndepo ) THEN
176         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
177             zcoef = rno3 * 14E6 * ryyss
178             CALL fld_read( kt, 1, sf_ndepo )
179             nitdep(:,:) = MAX( rtrn, sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) )
180         ENDIF
181         IF( .NOT.ln_linssh ) THEN
182           zcoef = rno3 * 14E6 * ryyss
183           nitdep(:,:) = MAX( rtrn, sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) )
184         ENDIF
185      ENDIF
186      !
187      IF( ln_timing )  CALL timing_stop('p4z_sbc')
188      !
189   END SUBROUTINE p4z_sbc
190
191
192   SUBROUTINE p4z_sbc_init
193      !!----------------------------------------------------------------------
194      !!                  ***  routine p4z_sbc_init  ***
195      !!
196      !! ** purpose :   initialization of the external sources of nutrients
197      !!
198      !! ** method  :   read the files and compute the budget
199      !!                called at the first timestep (nittrc000)
200      !!
201      !! ** input   :   external netcdf files
202      !!
203      !!----------------------------------------------------------------------
204      INTEGER  :: ji, jj, jk, jm, ifpr
205      INTEGER  :: ii0, ii1, ij0, ij1
206      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
207      INTEGER  :: ierr, ierr1, ierr2, ierr3
208      INTEGER  :: ios                 ! Local integer output status for namelist read
209      INTEGER  :: ik50                !  last level where depth less than 50 m
210      INTEGER  :: isrow             ! index for ORCA1 starting row
211      REAL(wp) :: zexpide, zdenitide, zmaskt, zsurfc, zsurfp,ze3t, ze3t2, zcslp
212      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
213      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
214      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
215      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zriver, zcmask
216      !
217      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
218      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
219      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
220      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
221      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
222      !!
223      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
224        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
225        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
226        &                sedfeinput, distcoast, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, &
227        &                hratio, lgw_rath
228      !!----------------------------------------------------------------------
229      !
230      IF(lwp) THEN
231         WRITE(numout,*)
232         WRITE(numout,*) 'p4z_sbc_init : initialization of the external sources of nutrients '
233         WRITE(numout,*) '~~~~~~~~~~~~ '
234      ENDIF
235      !                            !* set file information
236      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
237      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
238901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
239      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
240      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
241902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
242      IF(lwm) WRITE ( numonp, nampissbc )
243
244      IF(lwp) THEN
245         WRITE(numout,*) '   Namelist : nampissbc '
246         WRITE(numout,*) '      dust input from the atmosphere           ln_dust     = ', ln_dust
247         WRITE(numout,*) '      Variable solubility of iron input        ln_solub    = ', ln_solub
248         WRITE(numout,*) '      river input of nutrients                 ln_river    = ', ln_river
249         WRITE(numout,*) '      atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
250         WRITE(numout,*) '      Fe input from sediments                  ln_ironsed  = ', ln_ironsed
251         WRITE(numout,*) '      Fe input from seaice                     ln_ironice  = ', ln_ironice
252         WRITE(numout,*) '      fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
253         WRITE(numout,*) '      coastal release of iron                  sedfeinput  = ', sedfeinput
254         WRITE(numout,*) '      distance off the coast                   distcoast   = ', distcoast
255         WRITE(numout,*) '      solubility of the dust                   dustsolub   = ', dustsolub
256         WRITE(numout,*) '      Mineral Fe content of the dust           mfrac       = ', mfrac
257         WRITE(numout,*) '      Iron concentration in sea ice            icefeinput  = ', icefeinput
258         WRITE(numout,*) '      sinking speed of the dust                wdust       = ', wdust
259         WRITE(numout,*) '      nitrogen fixation rate                   nitrfix     = ', nitrfix
260         WRITE(numout,*) '      nitrogen fixation sensitivty to light    diazolight  = ', diazolight
261         WRITE(numout,*) '      Fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
262         WRITE(numout,*) '      Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
263         IF( ln_ligand ) THEN
264            WRITE(numout,*) '      Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
265         ENDIF
266      END IF
267
268      IF( nn_ice_tr >= 0 .AND. ln_ironice ) THEN
269         IF(lwp) THEN
270            WRITE(numout,*) '   ==>>>   ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
271            WRITE(numout,*) '           Specify your sea ice iron concentration in nampisice instead '
272            WRITE(numout,*) '           ln_ironice is forced to .FALSE. '
273         ENDIF
274         ln_ironice = .FALSE.
275      ENDIF
276
277      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN   ;   ll_sbc = .TRUE.
278      ELSE                                             ;   ll_sbc = .FALSE.
279      ENDIF
280
281      IF( ln_dust .AND. ln_solub ) THEN                ;   ll_solub = .TRUE.
282      ELSE                                             ;   ll_solub = .FALSE.
283      ENDIF
284
285      ! set the number of level over which river runoffs are applied
286      ! online configuration : computed in sbcrnf
287      IF( l_offline ) THEN
288        nk_rnf(:,:) = 1
289        h_rnf (:,:) = gdept_n(:,:,1)
290      ENDIF
291
292      ! dust input from the atmosphere
293      ! ------------------------------
294      IF( ln_dust ) THEN 
295         !
296         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
297         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
298         !
299         ALLOCATE( dust(jpi,jpj) )    ! allocation
300         !
301         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
302         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
303         !
304         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
305                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
306         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
307         !
308         IF( Agrif_Root() ) THEN   !  Only on the master grid
309            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
310            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
311            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
312         END IF
313      END IF
314
315      ! Solubility of dust deposition of iron
316      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
317      ! -----------------------------------------------------------------
318      IF( ll_solub ) THEN
319         !
320         IF(lwp) WRITE(numout,*)
321         IF(lwp) WRITE(numout,*) '   ==>>>   ll_solub=T , initialize variable solubility of Fe '
322         !
323         ALLOCATE( solub(jpi,jpj) )    ! allocation
324         !
325         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
326         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
327         !
328         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
329                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
330         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
331         ! get number of record in file
332         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
333         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
334         CALL iom_close( numsolub )
335      ENDIF
336
337      ! nutrient input from rivers
338      ! --------------------------
339      IF( ln_river ) THEN
340         !
341         slf_river(jr_dic) = sn_riverdic   ;   slf_river(jr_doc) = sn_riverdoc   ;   slf_river(jr_din) = sn_riverdin 
342         slf_river(jr_don) = sn_riverdon   ;   slf_river(jr_dip) = sn_riverdip   ;   slf_river(jr_dop) = sn_riverdop
343         slf_river(jr_dsi) = sn_riverdsi 
344         !
345         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj), rivdoc(jpi,jpj) ) 
346         IF( ln_p5z )  ALLOCATE( rivdon(jpi,jpj), rivdop(jpi,jpj) )
347         !
348         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )    !* allocate and fill sf_river (forcing structure) with sn_river_
349         rivinput(:) = 0._wp
350
351         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
352         !
353         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
354         DO ifpr = 1, jpriv
355                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
356            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
357         END DO
358         IF( Agrif_Root() ) THEN   !  Only on the master grid
359            ! Get total input rivers ; need to compute total river supply in a year
360            DO ifpr = 1, jpriv
361               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
362               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
363               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
364               DO jm = 1, ntimes_riv
365                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
366               END DO
367               CALL iom_close( numriv )
368               ztimes_riv = 1._wp / REAL(ntimes_riv, wp) 
369               DO jm = 1, ntimes_riv
370                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( 'p4zsbc', zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
371               END DO
372               DEALLOCATE( zriver)
373            END DO
374            ! N/P and Si releases due to coastal rivers
375            ! -----------------------------------------
376            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
377            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
378            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
379            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
380            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
381            !
382         ENDIF
383      ELSE
384         rivdicinput = 0._wp
385         rivdininput = 0._wp
386         rivdipinput = 0._wp
387         rivdsiinput = 0._wp
388         rivalkinput = 0._wp
389      END IF 
390      ! nutrient input from dust
391      ! ------------------------
392      IF( ln_ndepo ) THEN
393         !
394         IF(lwp) WRITE(numout,*)
395         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ndepo=T , initialize the nutrient input by dust from NetCDF file'
396         !
397         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
398         !
399         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
400         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
401         !
402         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
403                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
404         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
405         !
406         IF( Agrif_Root() ) THEN   !  Only on the master grid
407            ! Get total input dust ; need to compute total atmospheric supply of N in a year
408            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
409            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
410         ENDIF
411      ENDIF
412
413      ! coastal and island masks
414      ! ------------------------
415      IF( ln_ironsed ) THEN     
416         !
417         IF(lwp) WRITE(numout,*)
418         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ironsed=T , computation of an island mask to enhance coastal supply of iron'
419         !
420         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
421         !
422         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
423         ALLOCATE( zcmask(jpi,jpj,jpk) )
424         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
425         CALL iom_close( numiron )
426         !
427         ik50 = 5        !  last level where depth less than 50 m
428         DO jk = jpkm1, 1, -1
429            IF( gdept_1d(jk) > 50. )   ik50 = jk - 1
430         END DO
431         IF(lwp) WRITE(numout,*)
432         IF(lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
433         DO jk = 1, ik50
434            DO jj = 2, jpjm1
435               DO ji = fs_2, fs_jpim1
436                  ze3t   = e3t_0(ji,jj,jk)
437                  zsurfc =  e1u(ji,jj) * ( 1. - umask(ji  ,jj  ,jk) )   &
438                          + e1u(ji,jj) * ( 1. - umask(ji-1,jj  ,jk) )   &
439                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj  ,jk) )   &
440                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj-1,jk) )
441                  zsurfp = zsurfc * ze3t / e1e2t(ji,jj)
442                  ! estimation of the coastal slope : 5 km off the coast
443                  ze3t2 = ze3t * ze3t
444                  zcslp = SQRT( ( distcoast*distcoast + ze3t2 ) / ze3t2 )
445                  !
446                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) + zcslp * zsurfp
447               END DO
448            END DO
449         END DO
450         !
451         CALL lbc_lnk( 'p4zsbc', zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
452         !
453         DO jk = 1, jpk
454            DO jj = 1, jpj
455               DO ji = 1, jpi
456                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
457                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
458                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
459               END DO
460            END DO
461         END DO
462         ! Coastal supply of iron
463         ! -------------------------
464         ironsed(:,:,jpk) = 0._wp
465         DO jk = 1, jpkm1
466            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
467         END DO
468         DEALLOCATE( zcmask)
469      ENDIF
470      !
471      ! Iron from Hydrothermal vents
472      ! ------------------------
473      IF( ln_hydrofe ) THEN
474         !
475         IF(lwp) WRITE(numout,*)
476         IF(lwp) WRITE(numout,*) '   ==>>>   ln_hydrofe=T , Input of iron from hydrothermal vents'
477         !
478         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
479         !
480         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
481         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
482         CALL iom_close( numhydro )
483         !
484         DO jk = 1, jpk
485            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
486         ENDDO
487         !
488      ENDIF
489      !
490      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
491      !
492      IF(lwp) THEN
493         WRITE(numout,*)
494         WRITE(numout,*) '    Total input of elements from river supply'
495         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
496         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
497         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1    ,' TgSi/yr'
498         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
499         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12         ,' Teq/yr'
500         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12     ,' TgC/yr'
501         WRITE(numout,*) 
502      ENDIF
503      !
504      sedsilfrac = 0.03     ! percentage of silica loss in the sediments
505      sedcalfrac = 0.6      ! percentage of calcite loss in the sediments
506      !
507   END SUBROUTINE p4z_sbc_init
508
509   !!======================================================================
510END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.