New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zsed.F90 @ 10222

Last change on this file since 10222 was 10127, checked in by cetlod, 6 years ago

Bugfix to allow the use of on-the-fly interpolation for PISCES ancillary data, see ticket #2003
  • Property svn:keywords set to Id
File size: 24.7 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zice          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sed 
26   PUBLIC   p4z_sed_alloc
27 
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
30   REAL(wp) :: r1_rday                  !: inverse of rday
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE p4z_sed( kt, knt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE p4z_sed  ***
42      !!
43      !! ** Purpose :   Compute loss of organic matter in the sediments. This
44      !!              is by no way a sediment model. The loss is simply
45      !!              computed to balance the inout from rivers and dust
46      !!
47      !! ** Method  : - ???
48      !!---------------------------------------------------------------------
49      !
50      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
51      INTEGER  ::  ji, jj, jk, ikt
52      REAL(wp) ::  zrivalk, zrivsil, zrivno3
53      REAL(wp) ::  zwflux, zfminus, zfplus
54      REAL(wp) ::  zlim, zfact, zfactcal
55      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
56      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
57      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
58      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
59      REAL(wp) ::  xdiano3, xdianh4
60      REAL(wp) ::  zwssfep
61      !
62      CHARACTER (len=25) :: charout
63      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff, zwork
64      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4, zwscal
65      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
66      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zsidep, zwsfep, zironice
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )  CALL timing_start('p4z_sed')
72      !
73      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
74      !
75      ! Allocate temporary workspace
76      IF( ln_p5z )    ALLOCATE( ztrpo4(jpi,jpj,jpk), ztrdop(jpi,jpj,jpk) )
77      IF( ln_ligand ) ALLOCATE( zwsfep(jpi,jpj) )
78
79
80      zdenit2d(:,:) = 0.e0
81      zbureff (:,:) = 0.e0
82      zwork   (:,:) = 0.e0
83      zsedsi  (:,:) = 0.e0
84      zsedcal (:,:) = 0.e0
85      zsedc   (:,:) = 0.e0
86
87
88      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
89      ! ----------------------------------------------------
90      IF( ln_ironice ) THEN 
91         !                                             
92         ALLOCATE( zironice(jpi,jpj) )
93         !                                             
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96               zdep    = rfact2 / e3t_n(ji,jj,1)
97               zwflux  = fmmflx(ji,jj) / 1000._wp
98               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
99               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
100               zironice(ji,jj) =  zfplus + zfminus
101            END DO
102         END DO
103         !
104         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) 
105         !
106         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
107            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
108         !
109         DEALLOCATE( zironice )
110         !                                             
111      ENDIF
112
113      ! Add the external input of nutrients from dust deposition
114      ! ----------------------------------------------------------
115      IF( ln_dust ) THEN
116         !                                             
117         ALLOCATE( zsidep(jpi,jpj), zpdep(jpi,jpj,jpk), zirondep(jpi,jpj,jpk) )
118         !                                              ! Iron and Si deposition at the surface
119         IF( ln_solub ) THEN
120            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
121         ELSE
122            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
123         ENDIF
124         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1 
125         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r 
126         !                                              ! Iron solubilization of particles in the water column
127         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
128         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
129         DO jk = 2, jpkm1
130            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
131            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
132         END DO
133         !                                              ! Iron solubilization of particles in the water column
134         tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep  (:,:)
135         DO jk = 1, jpkm1
136            tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zpdep   (:,:,jk)
137            tra(:,:,jk,jpfer) = tra(:,:,jk,jpfer) + zirondep(:,:,jk) 
138         ENDDO
139         !
140         IF( lk_iomput ) THEN
141            IF( knt == nrdttrc ) THEN
142                IF( iom_use( "Irondep" ) )   &
143                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
144                IF( iom_use( "pdust" ) )   &
145                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
146            ENDIF
147         ENDIF
148         DEALLOCATE( zsidep, zpdep, zirondep )
149         !                                             
150      ENDIF
151     
152      ! Add the external input of nutrients from river
153      ! ----------------------------------------------------------
154      IF( ln_river ) THEN
155         DO jj = 1, jpj
156            DO ji = 1, jpi
157               DO jk = 1, nk_rnf(ji,jj)
158                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
159                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
160                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
161                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
162                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
163                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
164               ENDDO
165            ENDDO
166         ENDDO
167         IF( ln_p5z ) THEN
168            DO jj = 1, jpj
169               DO ji = 1, jpi
170                  DO jk = 1, nk_rnf(ji,jj)
171                     tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2
172                     tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2
173                     tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + rivdoc(ji,jj) * rfact2
174                  ENDDO
175               ENDDO
176            ENDDO
177         ENDIF
178      ENDIF
179     
180      ! Add the external input of nutrients from nitrogen deposition
181      ! ----------------------------------------------------------
182      IF( ln_ndepo ) THEN
183         tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2
184         tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
185      ENDIF
186
187      ! Add the external input of iron from sediment mobilization
188      ! ------------------------------------------------------
189      IF( ln_ironsed ) THEN
190                         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
191         IF( ln_ligand ) tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( ironsed(:,:,:) * fep_rats ) * rfact2
192         !
193         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
194            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
195      ENDIF
196
197      ! Add the external input of iron from hydrothermal vents
198      ! ------------------------------------------------------
199      IF( ln_hydrofe ) THEN
200            tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
201         IF( ln_ligand ) THEN
202            tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( hydrofe(:,:,:) * fep_rath ) * rfact2
203            tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
204         ENDIF
205         !
206         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
207            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
208      ENDIF
209
210      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
211      ! --------------------------------------------------------------------
212      DO jj = 1, jpj
213         DO ji = 1, jpi
214            ikt  = mbkt(ji,jj)
215            zdep = e3t_n(ji,jj,ikt) / xstep
216            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
217            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
218            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
219         END DO
220      END DO
221      !
222      IF( ln_ligand ) THEN
223         DO jj = 1, jpj
224            DO ji = 1, jpi
225               ikt  = mbkt(ji,jj)
226               zdep = e3t_n(ji,jj,ikt) / xstep
227               zwsfep(ji,jj)  = MIN( 0.99 * zdep, wsfep(ji,jj,ikt)  )
228            END DO
229         ENDDO
230      ENDIF
231
232      IF( .NOT.lk_sed ) THEN
233         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
234         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
235         ! -------------------------------------------------------
236         DO jj = 1, jpj
237            DO ji = 1, jpi
238              IF( tmask(ji,jj,1) == 1 ) THEN
239                 ikt = mbkt(ji,jj)
240                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
241                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
242                 zflx  = LOG10( MAX( 1E-3, zflx ) )
243                 zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
244                 zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
245                 zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
246                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
247                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
248                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
249                   !
250                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
251                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
252                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
253              ENDIF
254            END DO
255         END DO 
256         !
257      ENDIF
258
259      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
260      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
261      ! ------------------------------------------------------
262      IF( .NOT.lk_sed )  zrivsil = 1._wp - sedsilfrac
263
264      DO jj = 1, jpj
265         DO ji = 1, jpi
266            ikt  = mbkt(ji,jj)
267            zdep = xstep / e3t_n(ji,jj,ikt) 
268            zwsc = zwscal (ji,jj) * zdep
269            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
270            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
271            !
272            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
273            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
274         END DO
275      END DO
276      !
277      IF( .NOT.lk_sed ) THEN
278         DO jj = 1, jpj
279            DO ji = 1, jpi
280               ikt  = mbkt(ji,jj)
281               zdep = xstep / e3t_n(ji,jj,ikt) 
282               zwsc = zwscal (ji,jj) * zdep
283               zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
284               zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
285               tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
286               !
287               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
288               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
289               zrivalk  = sedcalfrac * zfactcal
290               tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
291               tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
292               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t_n(ji,jj,ikt) 
293               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t_n(ji,jj,ikt) 
294            END DO
295         END DO
296      ENDIF
297      !
298      DO jj = 1, jpj
299         DO ji = 1, jpi
300            ikt  = mbkt(ji,jj)
301            zdep = xstep / e3t_n(ji,jj,ikt) 
302            zws4 = zwsbio4(ji,jj) * zdep
303            zws3 = zwsbio3(ji,jj) * zdep
304            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
305            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
306            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
307            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
308         END DO
309      END DO
310      !
311      IF( ln_ligand ) THEN
312         DO jj = 1, jpj
313            DO ji = 1, jpi
314               ikt     = mbkt(ji,jj)
315               zdep    = xstep / e3t_n(ji,jj,ikt) 
316               zwssfep = zwsfep(ji,jj) * zdep
317               tra(ji,jj,ikt,jpfep) = tra(ji,jj,ikt,jpfep) - trb(ji,jj,ikt,jpfep) * zwssfep
318            END DO
319         END DO
320      ENDIF
321      !
322      IF( ln_p5z ) THEN
323         DO jj = 1, jpj
324            DO ji = 1, jpi
325               ikt  = mbkt(ji,jj)
326               zdep = xstep / e3t_n(ji,jj,ikt) 
327               zws4 = zwsbio4(ji,jj) * zdep
328               zws3 = zwsbio3(ji,jj) * zdep
329               tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
330               tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
331               tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
332               tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
333            END DO
334         END DO
335      ENDIF
336
337      IF( .NOT.lk_sed ) THEN
338         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
339         ! denitrification in the sediments. Not very clever, but simpliest option.
340         DO jj = 1, jpj
341            DO ji = 1, jpi
342               ikt  = mbkt(ji,jj)
343               zdep = xstep / e3t_n(ji,jj,ikt) 
344               zws4 = zwsbio4(ji,jj) * zdep
345               zws3 = zwsbio3(ji,jj) * zdep
346               zrivno3 = 1. - zbureff(ji,jj)
347               zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
348               zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
349               z1pdenit = zwstpoc * zrivno3 - zpdenit
350               zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
351               tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit
352               tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit
353               tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit
354               tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * zpdenit
355               tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
356               tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
357               tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit 
358               sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
359               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t_n(ji,jj,ikt)
360               IF( ln_p5z ) THEN
361                  zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
362                  zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
363                  tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
364                  tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
365               ENDIF
366            END DO
367         END DO
368       ENDIF
369
370
371      ! Nitrogen fixation process
372      ! Small source iron from particulate inorganic iron
373      !-----------------------------------
374      DO jk = 1, jpkm1
375         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
376         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
377      ENDDO
378      IF( ln_p4z ) THEN
379         DO jk = 1, jpkm1
380            DO jj = 1, jpj
381               DO ji = 1, jpi
382                  !                      ! Potential nitrogen fixation dependant on temperature and iron
383                  zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
384                  IF( zlim <= 0.2 )   zlim = 0.01
385                  zfact = zlim * rfact2
386
387                  ztrfer  = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
388                  ztrpo4s = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
389                  nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) &
390                    &                *  zfact * MIN( ztrfer, ztrpo4s ) * zlight(ji,jj,jk)
391               END DO
392            END DO
393         END DO
394      ELSE       ! p5z
395         DO jk = 1, jpkm1
396            DO jj = 1, jpj
397               DO ji = 1, jpi
398                  !                      ! Potential nitrogen fixation dependant on temperature and iron
399                  ztemp = tsn(ji,jj,jk,jp_tem)
400                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
401                  !       Potential nitrogen fixation dependant on temperature and iron
402                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
403                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
404                  zlim = ( 1.- xdiano3 - xdianh4 )
405                  IF( zlim <= 0.1 )   zlim = 0.01
406                  zfact = zlim * rfact2
407                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
408                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
409                  ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
410                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
411                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
412               END DO
413            END DO
414         END DO
415      ENDIF
416
417      ! Nitrogen change due to nitrogen fixation
418      ! ----------------------------------------
419      IF( ln_p4z ) THEN
420         DO jk = 1, jpkm1
421            DO jj = 1, jpj
422               DO ji = 1, jpi
423                  zfact = nitrpot(ji,jj,jk) * nitrfix
424                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
425                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
426                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
427                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
428                  &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
429                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
430              END DO
431            END DO
432         END DO
433      ELSE    ! p5z
434         DO jk = 1, jpkm1
435            DO jj = 1, jpj
436               DO ji = 1, jpi
437                  zfact = nitrpot(ji,jj,jk) * nitrfix
438                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
439                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
440                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
441                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
442                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
443                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
444                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
445                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
446                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
447                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
448                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
449                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
450                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
451                  tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
452                  tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
453                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
454                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
455                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
456                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
457                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
458              END DO
459            END DO
460         END DO
461         !
462      ENDIF
463
464      IF( lk_iomput ) THEN
465         IF( knt == nrdttrc ) THEN
466            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
467            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
468            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
469               zwork(:,:) = 0.
470               DO jk = 1, jpkm1
471                 zwork(:,:) = zwork(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t_n(:,:,jk) * tmask(:,:,jk)
472               ENDDO
473               CALL iom_put( "INTNFIX" , zwork ) 
474            ENDIF
475            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
476            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
477            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
478            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
479         ENDIF
480      ENDIF
481      !
482      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
483         WRITE(charout, fmt="('sed ')")
484         CALL prt_ctl_trc_info(charout)
485         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
486      ENDIF
487      !
488      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
489      IF( ln_ligand ) DEALLOCATE( zwsfep )
490      !
491      IF( ln_timing )  CALL timing_stop('p4z_sed')
492      !
493   END SUBROUTINE p4z_sed
494
495
496   INTEGER FUNCTION p4z_sed_alloc()
497      !!----------------------------------------------------------------------
498      !!                     ***  ROUTINE p4z_sed_alloc  ***
499      !!----------------------------------------------------------------------
500      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
501      !
502      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
503      !
504   END FUNCTION p4z_sed_alloc
505
506   !!======================================================================
507END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.