New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zsink.F90 @ 10375

Last change on this file since 10375 was 10375, checked in by aumont, 5 years ago

Create generic routines for vertical sinking of particles

  • Property svn:keywords set to Id
File size: 10.6 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!----------------------------------------------------------------------
11   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
12   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
13   !!   p4z_sink_alloc :  Allocate sinking speed variables
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE trcsink         !  General routine to compute sedimentation
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21   USE lib_mpp
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_sink         ! called in p4zbio.F90
27   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
28   PUBLIC   p4z_sink_alloc
29
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
31   !                                                          !  (different meanings depending on the parameterization)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingn, sinking2n  !: POC sinking fluxes
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingp, sinking2p  !: POC sinking fluxes
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfep      !: Fep sinking fluxes
38
39   INTEGER  :: ik100
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   !!----------------------------------------------------------------------
49   !!   'standard sinking parameterisation'                  ???
50   !!----------------------------------------------------------------------
51
52   SUBROUTINE p4z_sink ( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_sink  ***
55      !!
56      !! ** Purpose :   Compute vertical flux of particulate matter due to
57      !!                gravitational sinking
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) :: kt, knt
62      INTEGER  ::   ji, jj, jk
63      CHARACTER (len=25) :: charout
64      REAL(wp) :: zmax, zfact
65      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
66      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zw2d
67      !!---------------------------------------------------------------------
68      !
69      IF( ln_timing )   CALL timing_start('p4z_sink')
70
71      ! Initialization of some global variables
72      ! ---------------------------------------
73      prodpoc(:,:,:) = 0.
74      conspoc(:,:,:) = 0.
75      prodgoc(:,:,:) = 0.
76      consgoc(:,:,:) = 0.
77
78      !
79      !    Sinking speeds of detritus is increased with depth as shown
80      !    by data and from the coagulation theory
81      !    -----------------------------------------------------------
82      DO jk = 1, jpkm1
83         DO jj = 1, jpj
84            DO ji = 1,jpi
85               zmax  = MAX( heup_01(ji,jj), hmld(ji,jj) )
86               zfact = MAX( 0., gdepw_n(ji,jj,jk+1) - zmax ) / wsbio2scale
87               wsbio4(ji,jj,jk) = wsbio2 + MAX(0., ( wsbio2max - wsbio2 )) * zfact
88            END DO
89         END DO
90      END DO
91
92      ! limit the values of the sinking speeds to avoid numerical instabilities 
93      wsbio3(:,:,:) = wsbio
94
95      !
96      !  Initializa to zero all the sinking arrays
97      !   -----------------------------------------
98      sinking (:,:,:) = 0.e0
99      sinking2(:,:,:) = 0.e0
100      sinkcal (:,:,:) = 0.e0
101      sinkfer (:,:,:) = 0.e0
102      sinksil (:,:,:) = 0.e0
103      sinkfer2(:,:,:) = 0.e0
104
105      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
106      !   -----------------------------------------------------
107      CALL trc_sink( kt, wsbio3, sinking , jppoc, rfact2 )
108      CALL trc_sink( kt, wsbio3, sinkfer , jpsfe, rfact2 )
109      CALL trc_sink( kt, wsbio4, sinking2, jpgoc, rfact2 )
110      CALL trc_sink( kt, wsbio4, sinkfer2, jpbfe, rfact2 )
111      CALL trc_sink( kt, wsbio4, sinksil , jpgsi, rfact2 )
112      CALL trc_sink( kt, wsbio4, sinkcal , jpcal, rfact2 )
113
114      IF( ln_p5z ) THEN
115         sinkingn (:,:,:) = 0.e0
116         sinking2n(:,:,:) = 0.e0
117         sinkingp (:,:,:) = 0.e0
118         sinking2p(:,:,:) = 0.e0
119
120         !   Compute the sedimentation term using p4zsink2 for all the sinking particles
121         !   -----------------------------------------------------
122         CALL trc_sink( kt, wsbio3, sinkingn , jppon, rfact2 )
123         CALL trc_sink( kt, wsbio3, sinkingp , jppop, rfact2 )
124         CALL trc_sink( kt, wsbio4, sinking2n, jpgon, rfact2 )
125         CALL trc_sink( kt, wsbio4, sinking2p, jpgop, rfact2 )
126      ENDIF
127
128      IF( ln_ligand ) THEN
129         wsfep (:,:,:) = wfep
130         !
131         sinkfep(:,:,:) = 0.e0
132         CALL trc_sink( kt, wsfep, sinkfep , jpfep, rfact2 )
133      ENDIF
134
135     ! Total carbon export per year
136     IF( iom_use( "tcexp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
137        &   t_oce_co2_exp = glob_sum( ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * e1e2t(:,:) * tmask(:,:,1) )
138     !
139     IF( lk_iomput ) THEN
140       IF( knt == nrdttrc ) THEN
141          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
142          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
143          !
144          IF( iom_use( "EPC100" ) )  THEN
145              zw2d(:,:) = ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of carbon at 100m
146              CALL iom_put( "EPC100"  , zw2d )
147          ENDIF
148          IF( iom_use( "EPFE100" ) )  THEN
149              zw2d(:,:) = ( sinkfer(:,:,ik100) + sinkfer2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of iron at 100m
150              CALL iom_put( "EPFE100"  , zw2d )
151          ENDIF
152          IF( iom_use( "EPCAL100" ) )  THEN
153              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
154              CALL iom_put( "EPCAL100"  , zw2d )
155          ENDIF
156          IF( iom_use( "EPSI100" ) )  THEN
157              zw2d(:,:) =  sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
158              CALL iom_put( "EPSI100"  , zw2d )
159          ENDIF
160          IF( iom_use( "EXPC" ) )  THEN
161              zw3d(:,:,:) = ( sinking(:,:,:) + sinking2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of carbon in the water column
162              CALL iom_put( "EXPC"  , zw3d )
163          ENDIF
164          IF( iom_use( "EXPFE" ) )  THEN
165              zw3d(:,:,:) = ( sinkfer(:,:,:) + sinkfer2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of iron
166              CALL iom_put( "EXPFE"  , zw3d )
167          ENDIF
168          IF( iom_use( "EXPCAL" ) )  THEN
169              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
170              CALL iom_put( "EXPCAL"  , zw3d )
171          ENDIF
172          IF( iom_use( "EXPSI" ) )  THEN
173              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
174              CALL iom_put( "EXPSI"  , zw3d )
175          ENDIF
176          IF( iom_use( "tcexp" ) )  CALL iom_put( "tcexp" , t_oce_co2_exp * zfact )   ! molC/s
177          !
178          DEALLOCATE( zw2d, zw3d )
179        ENDIF
180      ENDIF
181      !
182      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
183         WRITE(charout, FMT="('sink')")
184         CALL prt_ctl_trc_info(charout)
185         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
186      ENDIF
187      !
188      IF( ln_timing )   CALL timing_stop('p4z_sink')
189      !
190   END SUBROUTINE p4z_sink
191
192
193   SUBROUTINE p4z_sink_init
194      !!----------------------------------------------------------------------
195      !!                  ***  ROUTINE p4z_sink_init  ***
196      !!----------------------------------------------------------------------
197      INTEGER :: jk
198      !!----------------------------------------------------------------------
199      !
200      ik100 = 10        !  last level where depth less than 100 m
201      DO jk = jpkm1, 1, -1
202         IF( gdept_1d(jk) > 100. )  ik100 = jk - 1
203      END DO
204      IF (lwp) WRITE(numout,*)
205      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
206      IF (lwp) WRITE(numout,*)
207      !
208      t_oce_co2_exp = 0._wp
209      !
210   END SUBROUTINE p4z_sink_init
211
212   INTEGER FUNCTION p4z_sink_alloc()
213      !!----------------------------------------------------------------------
214      !!                     ***  ROUTINE p4z_sink_alloc  ***
215      !!----------------------------------------------------------------------
216      INTEGER :: ierr(3)
217      !!----------------------------------------------------------------------
218      !
219      ierr(:) = 0
220      !
221      ALLOCATE( sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                    ,     &               
222         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                    ,     &               
223         &      sinkfer2(jpi,jpj,jpk)                                           ,     &               
224         &      sinkfer(jpi,jpj,jpk)                                            , STAT=ierr(1) )               
225         !
226      IF( ln_ligand ) ALLOCATE( sinkfep(jpi,jpj,jpk)                            , STAT=ierr(2) ) 
227         
228      IF( ln_p5z    ) ALLOCATE( sinkingn(jpi,jpj,jpk), sinking2n(jpi,jpj,jpk)   ,     &
229         &                      sinkingp(jpi,jpj,jpk), sinking2p(jpi,jpj,jpk)   , STAT=ierr(3) )
230      !
231      p4z_sink_alloc = MAXVAL( ierr )
232      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
233      !
234   END FUNCTION p4z_sink_alloc
235   
236   !!======================================================================
237END MODULE p4zsink
Note: See TracBrowser for help on using the repository browser.