source: NEMO/trunk/src/TOP/TRP/trcdmp.F90 @ 10213

Last change on this file since 10213 was 10213, checked in by aumont, 2 years ago

corrects bugs described in Tickets 2144 and 2145

  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE trcdmp
2   !!======================================================================
3   !!                       ***  MODULE  trcdmp  ***
4   !! Ocean physics: internal restoring trend on passive tracers
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (O. Marti, G. Madec)  Original code
7   !!                 !  1996-01  (G. Madec) statement function for e3
8   !!                 !  1997-05  (H. Loukos)  adapted for passive tracers
9   !!    NEMO    9.0  !  2004-03  (C. Ethe)    free form + modules
10   !!            3.2  !  2007-02  (C. Deltel)  Diagnose ML trends for passive tracers
11   !!            3.3  !  2010-06  (C. Ethe, G. Madec) merge TRA-TRC
12   !!----------------------------------------------------------------------
13#if  defined key_top 
14   !!----------------------------------------------------------------------
15   !!   trc_dmp      : update the tracer trend with the internal damping
16   !!   trc_dmp_init : initialization, namlist read, parameters control
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and tracers variables
19   USE trc             ! ocean passive tracers variables
20   USE trcdta
21   USE tradmp
22   USE trdtra
23   USE trd_oce
24   !
25   USE iom
26   USE prtctl_trc      ! Print control for debbuging
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC trc_dmp     
32   PUBLIC trc_dmp_clo   
33   PUBLIC trc_dmp_alloc 
34   PUBLIC trc_dmp_ini   
35
36   INTEGER            , PUBLIC ::   nn_zdmp_tr    !: = 0/1/2 flag for damping in the mixed layer
37   CHARACTER(LEN=200) , PUBLIC ::   cn_resto_tr   !: File containing restoration coefficient
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   restotr   ! restoring coeff. on tracers (s-1)
40
41   INTEGER, PARAMETER         ::   npncts = 8       ! number of closed sea
42   INTEGER, DIMENSION(npncts) ::   nctsi1, nctsj1   ! south-west closed sea limits (i,j)
43   INTEGER, DIMENSION(npncts) ::   nctsi2, nctsj2   ! north-east closed sea limits (i,j)
44
45   !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   INTEGER FUNCTION trc_dmp_alloc()
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE trc_dmp_alloc  ***
57      !!----------------------------------------------------------------------
58      ALLOCATE( restotr(jpi,jpj,jpk) , STAT=trc_dmp_alloc )
59      !
60      IF( trc_dmp_alloc /= 0 )   CALL ctl_warn('trc_dmp_alloc: failed to allocate array')
61      !
62   END FUNCTION trc_dmp_alloc
63
64
65   SUBROUTINE trc_dmp( kt )
66      !!----------------------------------------------------------------------
67      !!                   ***  ROUTINE trc_dmp  ***
68      !!                 
69      !! ** Purpose :   Compute the passive tracer trend due to a newtonian damping
70      !!      of the tracer field towards given data field and add it to the
71      !!      general tracer trends.
72      !!
73      !! ** Method  :   Newtonian damping towards trdta computed
74      !!      and add to the general tracer trends:
75      !!                     trn = tra + restotr * (trdta - trb)
76      !!         The trend is computed either throughout the water column
77      !!      (nlmdmptr=0) or in area of weak vertical mixing (nlmdmptr=1) or
78      !!      below the well mixed layer (nlmdmptr=2)
79      !!
80      !! ** Action  : - update the tracer trends tra with the newtonian
81      !!                damping trends.
82      !!              - save the trends ('key_trdmxl_trc')
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      !
86      INTEGER ::   ji, jj, jk, jn, jl   ! dummy loop indices
87      CHARACTER (len=22) ::   charout
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrcdta   ! 3D  workspace
90      !!----------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('trc_dmp')
93      !
94      IF( l_trdtrc )   ALLOCATE( ztrtrd(jpi,jpj,jpk) )   ! temporary save of trends
95      !
96      IF( nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
97         !
98         ALLOCATE( ztrcdta(jpi,jpj,jpk) )    ! Memory allocation
99         !                                                          ! ===========
100         DO jn = 1, jptra                                           ! tracer loop
101            !                                                       ! ===========
102            IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)    ! save trends
103            !
104            IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
105               !
106               jl = n_trc_index(jn) 
107               CALL trc_dta( kt, sf_trcdta(jl), rf_trfac(jl), ztrcdta )   ! read tracer data at nit000
108               !
109               SELECT CASE ( nn_zdmp_tr )
110               !
111               CASE( 0 )                !==  newtonian damping throughout the water column  ==!
112                  DO jk = 1, jpkm1
113                     DO jj = 2, jpjm1
114                        DO ji = fs_2, fs_jpim1   ! vector opt.
115                           tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
116                        END DO
117                     END DO
118                  END DO
119                  !
120               CASE ( 1 )                !==  no damping in the turbocline (avt > 5 cm2/s)  ==!
121                  DO jk = 1, jpkm1
122                     DO jj = 2, jpjm1
123                        DO ji = fs_2, fs_jpim1   ! vector opt.
124                           IF( avs(ji,jj,jk) <= 5.e-4_wp )  THEN
125                              tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
126                           ENDIF
127                        END DO
128                     END DO
129                  END DO
130                  !
131               CASE ( 2 )               !==  no damping in the mixed layer   ==!
132                  DO jk = 1, jpkm1
133                     DO jj = 2, jpjm1
134                        DO ji = fs_2, fs_jpim1   ! vector opt.
135                           IF( gdept_n(ji,jj,jk) >= hmlp (ji,jj) ) THEN
136                              tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
137                           END IF
138                        END DO
139                     END DO
140                  END DO
141                 
142               END SELECT
143               !
144            ENDIF
145            !
146            IF( l_trdtrc ) THEN
147               ztrtrd(:,:,:) = tra(:,:,:,jn) -  ztrtrd(:,:,:)
148               CALL trd_tra( kt, 'TRC', jn, jptra_dmp, ztrtrd )
149            END IF
150            !                                                       ! ===========
151         END DO                                                     ! tracer loop
152         !                                                          ! ===========
153         DEALLOCATE( ztrcdta )
154      ENDIF
155      !
156      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
157      !                                          ! print mean trends (used for debugging)
158      IF( ln_ctl ) THEN
159         WRITE(charout, FMT="('dmp ')")
160         CALL prt_ctl_trc_info(charout)
161         CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
162      ENDIF
163      !
164      IF( ln_timing )   CALL timing_stop('trc_dmp')
165      !
166   END SUBROUTINE trc_dmp
167
168
169   SUBROUTINE trc_dmp_ini
170      !!----------------------------------------------------------------------
171      !!                  ***  ROUTINE trc_dmp_ini  ***
172      !!
173      !! ** Purpose :   Initialization for the newtonian damping
174      !!
175      !! ** Method  :   read the nammbf namelist and check the parameters
176      !!              called by trc_dmp at the first timestep (nittrc000)
177      !!----------------------------------------------------------------------
178      INTEGER ::   ios, imask  ! local integers
179      !!
180      NAMELIST/namtrc_dmp/ nn_zdmp_tr , cn_resto_tr
181      !!----------------------------------------------------------------------
182      !
183      REWIND( numnat_ref )              ! Namelist namtrc_dmp in reference namelist : Passive tracers newtonian damping
184      READ  ( numnat_ref, namtrc_dmp, IOSTAT = ios, ERR = 909)
185909   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_dmp in reference namelist', lwp )
186      REWIND( numnat_cfg )              ! Namelist namtrc_dmp in configuration namelist : Passive tracers newtonian damping
187      READ  ( numnat_cfg, namtrc_dmp, IOSTAT = ios, ERR = 910)
188910   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_dmp in configuration namelist', lwp )
189      IF(lwm) WRITE ( numont, namtrc_dmp )
190
191      IF(lwp) THEN                       ! Namelist print
192         WRITE(numout,*)
193         WRITE(numout,*) 'trc_dmp : Passive tracers newtonian damping'
194         WRITE(numout,*) '~~~~~~~'
195         WRITE(numout,*) '   Namelist namtrc_dmp : set damping parameter'
196         WRITE(numout,*) '      mixed layer damping option     nn_zdmp_tr  = ', nn_zdmp_tr, '(zoom: forced to 0)'
197         WRITE(numout,*) '      Restoration coeff file         cn_resto_tr = ', cn_resto_tr
198      ENDIF
199      !                          ! Allocate arrays
200      IF( trc_dmp_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trc_dmp_ini: unable to allocate arrays' )
201      !
202      SELECT CASE ( nn_zdmp_tr )
203      CASE ( 0 )   ;   IF(lwp) WRITE(numout,*) '      ===>>   tracer damping throughout the water column'
204      CASE ( 1 )   ;   IF(lwp) WRITE(numout,*) '      ===>>   no tracer damping in the turbocline (avt > 5 cm2/s)'
205      CASE ( 2 )   ;   IF(lwp) WRITE(numout,*) '      ===>>   no tracer damping in the mixed layer'
206      CASE DEFAULT
207         WRITE(ctmp1,*) 'bad flag value for nn_zdmp_tr = ', nn_zdmp_tr
208         CALL ctl_stop(ctmp1)
209      END SELECT
210
211      IF( .NOT.lk_c1d ) THEN
212         IF( .NOT.ln_tradmp )   &
213            &   CALL ctl_stop( 'passive tracer damping need ln_tradmp to compute damping coef.' )
214         !
215         !                          ! Read damping coefficients from file
216         !Read in mask from file
217         CALL iom_open ( cn_resto_tr, imask)
218         CALL iom_get  ( imask, jpdom_autoglo, 'resto', restotr)
219         CALL iom_close( imask )
220         !
221      ENDIF
222      !
223   END SUBROUTINE trc_dmp_ini
224
225
226   SUBROUTINE trc_dmp_clo( kt )
227      !!---------------------------------------------------------------------
228      !!                  ***  ROUTINE trc_dmp_clo  ***
229      !!
230      !! ** Purpose :   Closed sea domain initialization
231      !!
232      !! ** Method  :   if a closed sea is located only in a model grid point
233      !!                we restore to initial data
234      !!
235      !! ** Action  :   nctsi1(), nctsj1() : south-west closed sea limits (i,j)
236      !!                nctsi2(), nctsj2() : north-east Closed sea limits (i,j)
237      !!----------------------------------------------------------------------
238      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
239      !
240      INTEGER :: ji , jj, jk, jn, jl, jc                    ! dummy loop indicesa
241      INTEGER :: isrow                                      ! local index
242      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrcdta       ! 3D  workspace
243      !!----------------------------------------------------------------------
244
245      IF( kt == nit000 ) THEN
246         ! initial values
247         nctsi1(:) = 1  ;  nctsi2(:) = 1
248         nctsj1(:) = 1  ;  nctsj2(:) = 1
249
250         ! set the closed seas (in data domain indices)
251         ! -------------------
252
253         IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA") THEN
254            !
255            SELECT CASE ( nn_cfg )
256            !                                           ! =======================
257            CASE ( 1 )                                  ! eORCA_R1 configuration
258            !                                           ! =======================
259            isrow = 332 - jpjglo
260            !
261            nctsi1(1)   = 333  ; nctsj1(1)   = 243 - isrow   ! Caspian Sea
262            nctsi2(1)   = 342  ; nctsj2(1)   = 274 - isrow
263            !                                       
264            nctsi1(2)   = 198  ; nctsj1(2)   = 258 - isrow   ! Lake Superior
265            nctsi2(2)   = 204  ; nctsj2(2)   = 262 - isrow
266            !                                         
267            nctsi1(3)   = 201  ; nctsj1(3)   = 250 - isrow   ! Lake Michigan
268            nctsi2(3)   = 203  ; nctsj2(3)   = 256 - isrow
269            !                                       
270            nctsi1(4)   = 204  ; nctsj1(4)   = 252 - isrow   ! Lake Huron
271            nctsi2(4)   = 209  ; nctsj2(4)   = 256 - isrow
272            !                                       
273            nctsi1(5)   = 206  ; nctsj1(5)   = 249 - isrow   ! Lake Erie
274            nctsi2(5)   = 209  ; nctsj2(5)   = 251 - isrow
275            !                                       
276            nctsi1(6)   = 210  ; nctsj1(6)   = 252 - isrow   ! Lake Ontario
277            nctsi2(6)   = 212  ; nctsj2(6)   = 252 - isrow
278            !                                       
279            nctsi1(7)   = 321  ; nctsj1(7)   = 180 - isrow   ! Victoria Lake
280            nctsi2(7)   = 322  ; nctsj2(7)   = 189 - isrow
281            !                                       
282            nctsi1(8)   = 297  ; nctsj1(8)   = 270 - isrow   ! Baltic Sea
283            nctsi2(8)   = 308  ; nctsj2(8)   = 293 - isrow
284            !                                       
285            !                                           ! =======================
286            CASE ( 2 )                                  !  ORCA_R2 configuration
287               !                                        ! =======================
288               !                                     
289               nctsi1(1)   =  11  ;  nctsj1(1)   = 103       ! Caspian Sea
290               nctsi2(1)   =  17  ;  nctsj2(1)   = 112
291               !                                     
292               nctsi1(2)   =  97  ;  nctsj1(2)   = 107       ! Great North American Lakes
293               nctsi2(2)   = 103  ;  nctsj2(2)   = 111
294               !                                     
295               nctsi1(3)   = 174  ;  nctsj1(3)   = 107       ! Black Sea 1 : west part of the Black Sea
296               nctsi2(3)   = 181  ;  nctsj2(3)   = 112
297              !                                     
298               nctsi1(4)   =   2  ;  nctsj1(4)   = 107      ! Black Sea 2 : est part of the Black Sea
299               nctsi2(4)   =   6  ;  nctsj2(4)   = 112
300               !                                     
301               nctsi1(5)   =  145 ;  nctsj1(5)   = 116       ! Baltic Sea
302               nctsi2(5)   =  150 ;  nctsj2(5)   = 126
303               !                                        ! =======================
304            CASE ( 4 )                                  !  ORCA_R4 configuration
305               !                                        ! =======================
306               !                                   
307               nctsi1(1)   =  4  ;  nctsj1(1)   = 53         ! Caspian Sea
308               nctsi2(1)   =  4  ;  nctsj2(1)   = 56
309               !                                   
310               nctsi1(2)   = 49  ;  nctsj1(2)   = 55         ! Great North American Lakes
311               nctsi2(2)   = 51  ;  nctsj2(2)   = 56
312               !                                   
313               nctsi1(3)   = 88  ;  nctsj1(3)   = 55         ! Black Sea
314               nctsi2(3)   = 91  ;  nctsj2(3)   = 56
315               !                                   
316               nctsi1(4)   = 75  ;  nctsj1(4)   = 59         ! Baltic Sea
317               nctsi2(4)   = 76  ;  nctsj2(4)   = 61
318               !                                        ! =======================
319            CASE ( 025 )                                ! ORCA_R025 configuration
320               !                                        ! =======================
321               !                                   
322               nctsi1(1)   = 1330 ; nctsj1(1)   = 645        ! Caspian + Aral sea
323               nctsi2(1)   = 1400 ; nctsj2(1)   = 795
324               !                                   
325               nctsi1(2)   = 1284 ; nctsj1(2)   = 722        ! Azov Sea
326               nctsi2(2)   = 1304 ; nctsj2(2)   = 747
327               !
328            END SELECT
329            !
330         ENDIF
331         !
332         ! convert the position in local domain indices
333         ! --------------------------------------------
334         DO jc = 1, npncts
335            nctsi1(jc)   = mi0( nctsi1(jc) )
336            nctsj1(jc)   = mj0( nctsj1(jc) )
337            !
338            nctsi2(jc)   = mi1( nctsi2(jc) )
339            nctsj2(jc)   = mj1( nctsj2(jc) )
340         END DO
341         !
342      ENDIF
343
344      ! Restore close seas values to initial data
345      IF( ln_trcdta .AND. nb_trcdta > 0 )  THEN   ! Initialisation of tracer from a file that may also be used for damping
346         !
347         IF(lwp)  WRITE(numout,*)
348         IF(lwp)  WRITE(numout,*) ' trc_dmp_clo : Restoring of nutrients on close seas at time-step kt = ', kt
349         IF(lwp)  WRITE(numout,*)
350         !
351         ALLOCATE( ztrcdta(jpi,jpj,jpk) )   ! Memory allocation
352         !
353         DO jn = 1, jptra
354            IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
355                jl = n_trc_index(jn)
356                CALL trc_dta( kt, sf_trcdta(jl), rf_trfac(jl), ztrcdta )   ! read tracer data at nit000
357                DO jc = 1, npncts
358                   DO jk = 1, jpkm1
359                      DO jj = nctsj1(jc), nctsj2(jc)
360                         DO ji = nctsi1(jc), nctsi2(jc)
361                            trn(ji,jj,jk,jn) = ztrcdta(ji,jj,jk)
362                            trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn)
363                         END DO
364                      END DO
365                   END DO
366                END DO
367             ENDIF
368          END DO
369          DEALLOCATE( ztrcdta )
370      ENDIF
371      !
372   END SUBROUTINE trc_dmp_clo
373 
374#else
375   !!----------------------------------------------------------------------
376   !!  Dummy module :                                     No passive tracer
377   !!----------------------------------------------------------------------
378CONTAINS
379   SUBROUTINE trc_dmp( kt )        ! Empty routine
380      INTEGER, INTENT(in) :: kt
381      WRITE(*,*) 'trc_dmp: You should not have seen this print! error?', kt
382   END SUBROUTINE trc_dmp
383#endif
384
385   !!======================================================================
386END MODULE trcdmp
Note: See TracBrowser for help on using the repository browser.