New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcbc.F90 in NEMO/trunk/src/TOP – NEMO

source: NEMO/trunk/src/TOP/trcbc.F90 @ 11536

Last change on this file since 11536 was 11536, checked in by smasson, 5 years ago

trunk: merge dev_r10984_HPC-13 into the trunk

  • Property svn:keywords set to Id
File size: 23.3 KB
Line 
1MODULE trcbc
2   !!======================================================================
3   !!                     ***  MODULE  trcbc  ***
4   !! TOP :  module for passive tracer boundary conditions
5   !!=====================================================================
6   !! History :  3.5 !  2014 (M. Vichi, T. Lovato)  Original
7   !!            3.6 !  2015 (T . Lovato) Revision and BDY support
8   !!            4.0 !  2016 (T . Lovato) Include application of sbc and cbc
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP model
13   !!----------------------------------------------------------------------
14   !!   trc_bc       :  Apply tracer Boundary Conditions
15   !!----------------------------------------------------------------------
16   USE par_trc       !  passive tracers parameters
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE iom           !  I/O manager
20   USE lib_mpp       !  MPP library
21   USE fldread       !  read input fields
22   USE bdy_oce,  ONLY: ln_bdy, nb_bdy , idx_bdy, ln_coords_file, rn_time_dmp, rn_time_dmp_out
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_bc         ! called in trcstp.F90 or within TOP modules
28   PUBLIC   trc_bc_ini     ! called in trcini.F90
29
30   INTEGER  , SAVE, PUBLIC                             :: nb_trcobc    ! number of tracers with open BC
31   INTEGER  , SAVE, PUBLIC                             :: nb_trcsbc    ! number of tracers with surface BC
32   INTEGER  , SAVE, PUBLIC                             :: nb_trccbc    ! number of tracers with coastal BC
33   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indobc ! index of tracer with OBC data
34   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indsbc ! index of tracer with SBC data
35   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indcbc ! index of tracer with CBC data
36   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trsfac    ! multiplicative factor for SBC tracer values
37   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcsbc    ! structure of data input SBC (file informations, fields read)
38   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trcfac    ! multiplicative factor for CBC tracer values
39   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trccbc    ! structure of data input CBC (file informations, fields read)
40   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trofac    ! multiplicative factor for OBCtracer values
41#if defined key_agrif
42   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcobc    ! structure of data input OBC (file informations, fields read)
43#else
44   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET  :: sf_trcobc
45#endif
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_bc_ini( ntrc )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trc_bc_ini  ***
59      !!                   
60      !! ** Purpose :   initialisation of passive tracer BC data
61      !!
62      !! ** Method  : - Read namtsd namelist
63      !!              - allocates passive tracer BC data structure
64      !!----------------------------------------------------------------------
65      INTEGER,INTENT(in) :: ntrc                           ! number of tracers
66      !
67      INTEGER            :: jl, jn , ib, ibd, ii, ij, ik   ! dummy loop indices
68      INTEGER            :: ierr0, ierr1, ierr2, ierr3     ! temporary integers
69      INTEGER            :: ios                            ! Local integer output status for namelist read
70      INTEGER            :: nblen, igrd                    ! support arrays for BDY
71      CHARACTER(len=100) :: clndta, clntrc
72      !
73      CHARACTER(len=100) :: cn_dir_sbc, cn_dir_cbc, cn_dir_obc
74      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i  ! local array of namelist informations on the fields to read
75      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcobc    ! open
76      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcsbc    ! surface
77      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trccbc    ! coastal
78      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trofac    ! multiplicative factor for tracer values
79      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trsfac    ! multiplicative factor for tracer values
80      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trcfac    ! multiplicative factor for tracer values
81      !!
82      NAMELIST/namtrc_bc/ cn_dir_obc, sn_trcobc, rn_trofac, cn_dir_sbc, sn_trcsbc, rn_trsfac, & 
83                        & cn_dir_cbc, sn_trccbc, rn_trcfac, ln_rnf_ctl, rn_bc_time
84      NAMELIST/namtrc_bdy/ cn_trc_dflt, cn_trc, nn_trcdmp_bdy
85      !!----------------------------------------------------------------------
86      !
87      IF( lwp ) THEN
88         WRITE(numout,*)
89         WRITE(numout,*) 'trc_bc_ini : Tracers Boundary Conditions (BC)'
90         WRITE(numout,*) '~~~~~~~~~~~ '
91      ENDIF
92      !  Initialisation and local array allocation
93      ierr0 = 0   ;   ierr1 = 0   ;   ierr2 = 0   ;   ierr3 = 0 
94      ALLOCATE( slf_i(ntrc), STAT=ierr0 )
95      IF( ierr0 > 0 ) THEN
96         CALL ctl_stop( 'trc_bc_ini: unable to allocate local slf_i' )   ;   RETURN
97      ENDIF
98
99      ! Compute the number of tracers to be initialised with open, surface and boundary data
100      ALLOCATE( n_trc_indobc(ntrc), STAT=ierr0 )
101      IF( ierr0 > 0 ) THEN
102         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indobc' )   ;   RETURN
103      ENDIF
104      nb_trcobc       = 0
105      n_trc_indobc(:) = 0
106      !
107      ALLOCATE( n_trc_indsbc(ntrc), STAT=ierr0 )
108      IF( ierr0 > 0 ) THEN
109         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indsbc' )   ;   RETURN
110      ENDIF
111      nb_trcsbc       = 0
112      n_trc_indsbc(:) = 0
113      !
114      ALLOCATE( n_trc_indcbc(ntrc), STAT=ierr0 )
115      IF( ierr0 > 0 ) THEN
116         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indcbc' )   ;   RETURN
117      ENDIF
118      nb_trccbc       = 0
119      n_trc_indcbc(:) = 0
120      !
121      ! Read Boundary Conditions Namelists
122      REWIND( numnat_ref )              ! Namelist namtrc_bc in reference namelist : Passive tracer data structure
123      READ  ( numnat_ref, namtrc_bc, IOSTAT = ios, ERR = 901)
124901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bc in reference namelist' )
125      REWIND( numnat_cfg )              ! Namelist namtrc_bc in configuration namelist : Passive tracer data structure
126      READ  ( numnat_cfg, namtrc_bc, IOSTAT = ios, ERR = 902 )
127902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bc in configuration namelist' )
128      IF(lwm) WRITE ( numont, namtrc_bc )
129
130      IF ( ln_bdy ) THEN
131         REWIND( numnat_ref )              ! Namelist namtrc_bdy in reference namelist : Passive tracer data structure
132         READ  ( numnat_ref, namtrc_bdy, IOSTAT = ios, ERR = 903)
133903      IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bdy in reference namelist' )
134         ! make sur that all elements of the namelist variables have a default definition from namelist_ref
135         cn_trc     (2:jp_bdy) = cn_trc     (1)
136         cn_trc_dflt(2:jp_bdy) = cn_trc_dflt(1)
137         REWIND( numnat_cfg )              ! Namelist namtrc_bdy in configuration namelist : Passive tracer data structure
138         READ  ( numnat_cfg, namtrc_bdy, IOSTAT = ios, ERR = 904 )
139904      IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bdy in configuration namelist' )
140         IF(lwm) WRITE ( numont, namtrc_bdy )
141     
142         ! setup up preliminary informations for BDY structure
143         DO jn = 1, ntrc
144            DO ib = 1, nb_bdy
145               ! Set type of obc in BDY data structure (around here we may plug user override of obc type from nml)
146               IF ( ln_trc_obc(jn) ) THEN   ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc     (ib) )
147               ELSE                         ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc_dflt(ib) )
148               ENDIF
149               ! set damping use in BDY data structure
150               trcdta_bdy(jn,ib)%dmp = .false.
151               IF(nn_trcdmp_bdy(ib) == 1 .AND. ln_trc_obc(jn) )   trcdta_bdy(jn,ib)%dmp = .true.
152               IF(nn_trcdmp_bdy(ib) == 2                      )   trcdta_bdy(jn,ib)%dmp = .true.
153               IF(trcdta_bdy(jn,ib)%cn_obc == 'frs' .AND. nn_trcdmp_bdy(ib) /= 0 )  &
154                   & CALL ctl_stop( 'trc_bc_ini: Use FRS OR relaxation' )
155               IF(  .NOT.( 0 < nn_trcdmp_bdy(ib)  .AND.  nn_trcdmp_bdy(ib) <= 2 )  )   &
156                   & CALL ctl_stop( 'trc_bc_ini: Not a valid option for nn_trcdmp_bdy. Allowed: 0,1,2.' )
157            END DO
158         END DO
159      ELSE
160         ! Force all tracers OBC to false if bdy not used
161         ln_trc_obc = .false.
162      ENDIF
163
164      ! compose BC data indexes
165      DO jn = 1, ntrc
166         IF( ln_trc_obc(jn) ) THEN
167             nb_trcobc       = nb_trcobc + 1   ;   n_trc_indobc(jn) = nb_trcobc
168         ENDIF
169         IF( ln_trc_sbc(jn) ) THEN
170             nb_trcsbc       = nb_trcsbc + 1   ;   n_trc_indsbc(jn) = nb_trcsbc
171         ENDIF
172         IF( ln_trc_cbc(jn) ) THEN
173             nb_trccbc       = nb_trccbc + 1   ;   n_trc_indcbc(jn) = nb_trccbc
174         ENDIF
175      END DO
176
177      ! Print summmary of Boundary Conditions
178      IF( lwp ) THEN
179         WRITE(numout,*)
180         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with SURFACE BCs data:', nb_trcsbc
181         IF ( nb_trcsbc > 0 ) THEN
182            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
183            DO jn = 1, ntrc
184               IF ( ln_trc_sbc(jn) ) WRITE(numout,9001) jn, TRIM( sn_trcsbc(jn)%clvar ), 'SBC', rn_trsfac(jn)
185            END DO
186         ENDIF
187         WRITE(numout,'(2a)') '   SURFACE BC data repository : ', TRIM(cn_dir_sbc)
188         !
189         WRITE(numout,*)
190         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with COASTAL BCs data:', nb_trccbc
191         IF( nb_trccbc > 0 ) THEN
192            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
193            DO jn = 1, ntrc
194               IF ( ln_trc_cbc(jn) ) WRITE(numout, 9001) jn, TRIM( sn_trccbc(jn)%clvar ), 'CBC', rn_trcfac(jn)
195            END DO
196         ENDIF
197         WRITE(numout,'(2a)') '   COASTAL BC data repository : ', TRIM(cn_dir_cbc)
198         IF( .NOT.ln_rnf .OR. .NOT.ln_linssh )   ln_rnf_ctl = .FALSE.
199         IF( ln_rnf_ctl )  WRITE(numout,'(a)') &
200              &            ' -> Remove runoff dilution effect on tracers with absent river load (ln_rnf_ctl = .TRUE.)'
201         WRITE(numout,*)
202         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with OPEN BCs data:', nb_trcobc
203
204         IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
205            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact.   OBC Settings'
206            DO jn = 1, ntrc
207               IF (       ln_trc_obc(jn) )  WRITE(numout, 9001) jn, TRIM( sn_trcobc(jn)%clvar ), 'OBC', rn_trofac(jn), &
208                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
209               IF ( .NOT. ln_trc_obc(jn) )  WRITE(numout, 9002) jn, 'Set data to IC and use default condition'       , &
210                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
211            END DO
212            WRITE(numout,*) ' '
213            DO ib = 1, nb_bdy
214               IF(nn_trcdmp_bdy(ib) == 0) WRITE(numout,9003) '   Boundary ', ib, &
215                  &                                          ' -> NO damping of tracers'
216               IF(nn_trcdmp_bdy(ib) == 1) WRITE(numout,9003) '   Boundary ', ib, &
217                  &                                          ' -> damping ONLY for tracers with external data provided'
218               IF(nn_trcdmp_bdy(ib) == 2) WRITE(numout,9003) '   Boundary ', ib, &
219                  &                                          ' -> damping of ALL tracers'
220               IF(nn_trcdmp_bdy(ib) >  0) THEN
221                   WRITE(numout,9003) '     USE damping parameters from nambdy for boundary ', ib,' : '
222                   WRITE(numout,'(a,f10.2,a)') '     - Inflow damping time scale  : ',rn_time_dmp    (ib),' days'
223                   WRITE(numout,'(a,f10.2,a)') '     - Outflow damping time scale : ',rn_time_dmp_out(ib),' days'
224               ENDIF
225            END DO
226         ENDIF
227         !
228         WRITE(numout,'(2a)') '   OPEN BC data repository : ', TRIM(cn_dir_obc)
229      ENDIF
2309001  FORMAT(2x,i5, 3x, a15, 3x, a5, 6x, e11.3, 4x, 10a13)
2319002  FORMAT(2x,i5, 3x, a41, 3x, 10a13)
2329003  FORMAT(a, i5, a)
233      !
234      !
235      ! OPEN Lateral boundary conditions
236      IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
237         ALLOCATE ( sf_trcobc(nb_trcobc), rf_trofac(nb_trcobc), STAT=ierr1 )
238         IF( ierr1 > 0 ) THEN
239            CALL ctl_stop( 'trc_bc_ini: unable to allocate sf_trcobc structure' )   ;   RETURN
240         ENDIF
241         !
242         igrd = 1                       ! Everything is at T-points here
243         !
244         DO jn = 1, ntrc
245            DO ib = 1, nb_bdy
246               !
247               nblen = idx_bdy(ib)%nblen(igrd)
248               !
249               IF( ln_trc_obc(jn) ) THEN     !* Initialise from external data *!
250                  jl = n_trc_indobc(jn)
251                  slf_i(jl)    = sn_trcobc(jn)
252                  rf_trofac(jl) = rn_trofac(jn)
253                                                ALLOCATE( sf_trcobc(jl)%fnow(nblen,1,jpk)   , STAT=ierr2 )
254                  IF( sn_trcobc(jn)%ln_tint )   ALLOCATE( sf_trcobc(jl)%fdta(nblen,1,jpk,2) , STAT=ierr3 )
255                  IF( ierr2 + ierr3 > 0 ) THEN
256                    CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer OBC data arrays' )   ;   RETURN
257                  ENDIF
258                  trcdta_bdy(jn,ib)%trc => sf_trcobc(jl)%fnow(:,1,:)
259                  trcdta_bdy(jn,ib)%rn_fac = rf_trofac(jl)
260               ELSE                          !* Initialise obc arrays from initial conditions *!
261                  ALLOCATE ( trcdta_bdy(jn,ib)%trc(nblen,jpk) )
262                  DO ibd = 1, nblen
263                     DO ik = 1, jpkm1
264                        ii = idx_bdy(ib)%nbi(ibd,igrd)
265                        ij = idx_bdy(ib)%nbj(ibd,igrd)
266                        trcdta_bdy(jn,ib)%trc(ibd,ik) = trn(ii,ij,ik,jn) * tmask(ii,ij,ik)
267                     END DO
268                  END DO
269                  trcdta_bdy(jn,ib)%rn_fac = 1._wp
270               ENDIF
271            END DO
272         END DO
273         !
274         CALL fld_fill( sf_trcobc, slf_i, cn_dir_obc, 'trc_bc_ini', 'Passive tracer OBC data', 'namtrc_bc' )
275         DO jn = 1, ntrc   ! define imap pointer, must be done after the call to fld_fill
276            DO ib = 1, nb_bdy
277               IF( ln_trc_obc(jn) ) THEN     !* Initialise from external data *!
278                  jl = n_trc_indobc(jn)
279                  sf_trcobc(jl)%imap => idx_bdy(ib)%nbmap(1:idx_bdy(ib)%nblen(igrd),igrd)
280               ENDIF
281            END DO
282         END DO
283         !
284      ENDIF
285
286      ! SURFACE Boundary conditions
287      IF( nb_trcsbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
288         ALLOCATE( sf_trcsbc(nb_trcsbc), rf_trsfac(nb_trcsbc), STAT=ierr1 )
289         IF( ierr1 > 0 ) THEN
290            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trcsbc structure' )   ;   RETURN
291         ENDIF
292         !
293         DO jn = 1, ntrc
294            IF( ln_trc_sbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
295               jl = n_trc_indsbc(jn)
296               slf_i(jl)    = sn_trcsbc(jn)
297               rf_trsfac(jl) = rn_trsfac(jn)
298                                            ALLOCATE( sf_trcsbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
299               IF( sn_trcsbc(jn)%ln_tint )  ALLOCATE( sf_trcsbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
300               IF( ierr2 + ierr3 > 0 ) THEN
301                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer SBC data arrays' )   ;   RETURN
302               ENDIF
303            ENDIF
304            !   
305         END DO
306         !                         ! fill sf_trcsbc with slf_i and control print
307         CALL fld_fill( sf_trcsbc, slf_i, cn_dir_sbc, 'trc_bc_ini', 'Passive tracer SBC data', 'namtrc_bc' )
308         !
309      ENDIF
310      !
311      ! COSTAL Boundary conditions
312      IF( nb_trccbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
313         ALLOCATE( sf_trccbc(nb_trccbc), rf_trcfac(nb_trccbc), STAT=ierr1 )
314         IF( ierr1 > 0 ) THEN
315            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trccbc structure' )   ;   RETURN
316         ENDIF
317         !
318         DO jn = 1, ntrc
319            IF( ln_trc_cbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
320               jl = n_trc_indcbc(jn)
321               slf_i(jl)    = sn_trccbc(jn)
322               rf_trcfac(jl) = rn_trcfac(jn)
323                                            ALLOCATE( sf_trccbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
324               IF( sn_trccbc(jn)%ln_tint )  ALLOCATE( sf_trccbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
325               IF( ierr2 + ierr3 > 0 ) THEN
326                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer CBC data arrays' )   ;   RETURN
327               ENDIF
328            ENDIF
329            !   
330         END DO
331         !                         ! fill sf_trccbc with slf_i and control print
332         CALL fld_fill( sf_trccbc, slf_i, cn_dir_cbc, 'trc_bc_ini', 'Passive tracer CBC data', 'namtrc_bc' )
333         !
334      ENDIF
335      !
336      DEALLOCATE( slf_i )          ! deallocate local field structure
337      !
338   END SUBROUTINE trc_bc_ini
339
340
341   SUBROUTINE trc_bc(kt, jit)
342      !!----------------------------------------------------------------------
343      !!                   ***  ROUTINE trc_bc  ***
344      !!
345      !! ** Purpose :  Apply Boundary Conditions data to tracers
346      !!
347      !! ** Method  :  1) Read BC inputs and update data structures using fldread
348      !!               2) Apply Boundary Conditions to tracers
349      !!----------------------------------------------------------------------
350      USE fldread
351      !!     
352      INTEGER, INTENT(in)           ::   kt    ! ocean time-step index
353      INTEGER, INTENT(in), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
354      !!
355      INTEGER  :: ji, jj, jk, jn, jl             ! Loop index
356      REAL(wp) :: zfact, zrnf
357      !!---------------------------------------------------------------------
358      !
359      IF( ln_timing )   CALL timing_start('trc_bc')
360
361      IF( kt == nit000 .AND. lwp) THEN
362         WRITE(numout,*)
363         WRITE(numout,*) 'trc_bc : Surface boundary conditions for passive tracers.'
364         WRITE(numout,*) '~~~~~~~ '
365      ENDIF
366
367      ! 1. Update Boundary conditions data
368      IF( PRESENT(jit) ) THEN 
369         !
370         ! OPEN boundary conditions (use kt_offset=+1 as they are applied at the end of the step)
371         IF( nb_trcobc > 0 ) THEN
372           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
373           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, kit=jit, kt_offset=+1)
374         ENDIF
375         !
376         ! SURFACE boundary conditions
377         IF( nb_trcsbc > 0 ) THEN
378           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
379           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc, kit=jit)
380         ENDIF
381         !
382         ! COASTAL boundary conditions
383         IF( nb_trccbc > 0 ) THEN
384           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
385           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc, kit=jit)
386         ENDIF
387         !
388      ELSE
389         !
390         ! OPEN boundary conditions (use kt_offset=+1 as they are applied at the end of the step)
391         IF( nb_trcobc > 0 ) THEN
392           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
393           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, kt_offset=+1)
394         ENDIF
395         !
396         ! SURFACE boundary conditions
397         IF( nb_trcsbc > 0 ) THEN
398           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
399           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc )
400         ENDIF
401         !
402         ! COASTAL boundary conditions
403         IF( nb_trccbc > 0 ) THEN
404           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
405           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc )
406         ENDIF
407         !
408      ENDIF
409
410      ! 2. Apply Boundary conditions data
411      !
412      DO jn = 1 , jptra
413         !
414         ! Remove river dilution for tracers with absent river load
415         IF( ln_rnf_ctl .AND. .NOT.ln_trc_cbc(jn) ) THEN
416            DO jj = 2, jpj
417               DO ji = fs_2, fs_jpim1
418                  DO jk = 1, nk_rnf(ji,jj)
419                     zrnf = (rnf(ji,jj) + rnf_b(ji,jj)) * 0.5_wp * r1_rau0 / h_rnf(ji,jj)
420                     tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)  + (trn(ji,jj,jk,jn) * zrnf)
421                  END DO
422               END DO
423            END DO
424         ENDIF
425         !
426         ! OPEN boundary conditions: trcbdy is called in trcnxt !
427         !
428         ! SURFACE boundary conditions
429         IF( ln_trc_sbc(jn) ) THEN
430            jl = n_trc_indsbc(jn)
431            DO jj = 2, jpj
432               DO ji = fs_2, fs_jpim1   ! vector opt.
433                  zfact = 1. / ( e3t_n(ji,jj,1) * rn_bc_time )
434                  tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + rf_trsfac(jl) * sf_trcsbc(jl)%fnow(ji,jj,1) * zfact
435               END DO
436            END DO
437         ENDIF
438         !
439         ! COASTAL boundary conditions
440         IF( ln_rnf .AND. ln_trc_cbc(jn) ) THEN
441            jl = n_trc_indcbc(jn)
442            DO jj = 2, jpj
443               DO ji = fs_2, fs_jpim1   ! vector opt.
444                  DO jk = 1, nk_rnf(ji,jj)
445                     zfact = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_bc_time ) 
446                     tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zfact
447                  END DO
448               END DO
449            END DO
450         ENDIF
451         !                                                       ! ===========
452      END DO                                                     ! tracer loop
453      !                                                          ! ===========
454      IF( ln_timing )   CALL timing_stop('trc_bc')
455      !
456   END SUBROUTINE trc_bc
457
458#else
459   !!----------------------------------------------------------------------
460   !!   Dummy module                              NO 3D passive tracer data
461   !!----------------------------------------------------------------------
462CONTAINS
463   SUBROUTINE trc_bc_ini( ntrc )        ! Empty routine
464      INTEGER,INTENT(IN) :: ntrc                           ! number of tracers
465      WRITE(*,*) 'trc_bc_ini: You should not have seen this print! error?', kt
466   END SUBROUTINE trc_bc_ini
467   SUBROUTINE trc_bc( kt )        ! Empty routine
468      WRITE(*,*) 'trc_bc: You should not have seen this print! error?', kt
469   END SUBROUTINE trc_bc
470#endif
471
472   !!======================================================================
473END MODULE trcbc
Note: See TracBrowser for help on using the repository browser.