New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcrst.F90 in NEMO/trunk/src/TOP – NEMO

source: NEMO/trunk/src/TOP/trcrst.F90 @ 12165

Last change on this file since 12165 was 11536, checked in by smasson, 5 years ago

trunk: merge dev_r10984_HPC-13 into the trunk

  • Property svn:keywords set to Id
File size: 16.1 KB
Line 
1MODULE trcrst
2   !!======================================================================
3   !!                         ***  MODULE trcrst  ***
4   !! TOP :   Manage the passive tracer restart
5   !!======================================================================
6   !! History :    -   !  1991-03  ()  original code
7   !!             1.0  !  2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!              -   !  2005-10 (C. Ethe) print control
9   !!             2.0  !  2005-10 (C. Ethe, G. Madec) revised architecture
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   trc_rst        : Restart for passive tracer
17   !!   trc_rst_opn    : open  restart file
18   !!   trc_rst_read   : read  restart file
19   !!   trc_rst_wri    : write restart file
20   !!----------------------------------------------------------------------
21   USE oce_trc
22   USE trc
23   USE iom
24   USE daymod
25   USE lib_mpp
26   
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_rst_opn       ! called by ???
31   PUBLIC   trc_rst_read      ! called by ???
32   PUBLIC   trc_rst_wri       ! called by ???
33   PUBLIC   trc_rst_cal
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41   
42   SUBROUTINE trc_rst_opn( kt )
43      !!----------------------------------------------------------------------
44      !!                    ***  trc_rst_opn  ***
45      !!
46      !! ** purpose  :   output of sea-trc variable in a netcdf file
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT(in) ::   kt       ! number of iteration
49      !
50      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step define as a character
51      CHARACTER(LEN=50)   ::   clname   ! trc output restart file name
52      CHARACTER(LEN=256)  ::   clpath   ! full path to ocean output restart file
53      !!----------------------------------------------------------------------
54      !
55      IF( l_offline ) THEN
56         IF( kt == nittrc000 ) THEN
57            lrst_trc = .FALSE.
58            IF( ln_rst_list ) THEN
59               nrst_lst = 1
60               nitrst = nn_stocklist( nrst_lst )
61            ELSE
62               nitrst = nitend
63            ENDIF
64         ENDIF
65
66         IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN
67            ! we use kt - 1 and not kt - nittrc000 to keep the same periodicity from the beginning of the experiment
68            nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
69            IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
70         ENDIF
71      ELSE
72         IF( kt == nittrc000 ) lrst_trc = .FALSE.
73      ENDIF
74
75      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
76
77      ! to get better performances with NetCDF format:
78      ! we open and define the tracer restart file one tracer time step before writing the data (-> at nitrst - 2*nn_dttrc + 1)
79      ! except if we write tracer restart files every tracer time step or if a tracer restart file was writen at nitend - 2*nn_dttrc + 1
80      IF( kt == nitrst - 2*nn_dttrc .OR. nn_stock == nn_dttrc .OR. ( kt == nitend - nn_dttrc .AND. .NOT. lrst_trc ) ) THEN
81         ! beware of the format used to write kt (default is i8.8, that should be large enough)
82         IF( nitrst > 1.0e9 ) THEN   ;   WRITE(clkt,*       ) nitrst
83         ELSE                        ;   WRITE(clkt,'(i8.8)') nitrst
84         ENDIF
85         ! create the file
86         IF(lwp) WRITE(numout,*)
87         clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_trcrst_out)
88         clpath = TRIM(cn_trcrst_outdir)
89         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
90         IF(lwp) WRITE(numout,*) &
91             '             open trc restart.output NetCDF file: ',TRIM(clpath)//clname
92         CALL iom_open( TRIM(clpath)//TRIM(clname), numrtw, ldwrt = .TRUE. )
93         lrst_trc = .TRUE.
94      ENDIF
95      !
96   END SUBROUTINE trc_rst_opn
97
98   SUBROUTINE trc_rst_read
99      !!----------------------------------------------------------------------
100      !!                    ***  trc_rst_opn  ***
101      !!
102      !! ** purpose  :   read passive tracer fields in restart files
103      !!----------------------------------------------------------------------
104      INTEGER  ::  jn     
105
106      !!----------------------------------------------------------------------
107      !
108      IF(lwp) WRITE(numout,*)
109      IF(lwp) WRITE(numout,*) 'trc_rst_read : read data in the TOP restart file'
110      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
111
112      ! READ prognostic variables and computes diagnostic variable
113      DO jn = 1, jptra
114         CALL iom_get( numrtr, jpdom_autoglo, 'TRN'//ctrcnm(jn), trn(:,:,:,jn) )
115      END DO
116
117      DO jn = 1, jptra
118         CALL iom_get( numrtr, jpdom_autoglo, 'TRB'//ctrcnm(jn), trb(:,:,:,jn) )
119      END DO
120      !
121      CALL iom_delay_rst( 'READ', 'TOP', numrtr )   ! read only TOP delayed global communication variables
122     
123   END SUBROUTINE trc_rst_read
124
125   SUBROUTINE trc_rst_wri( kt )
126      !!----------------------------------------------------------------------
127      !!                    ***  trc_rst_wri  ***
128      !!
129      !! ** purpose  :   write passive tracer fields in restart files
130      !!----------------------------------------------------------------------
131      INTEGER, INTENT( in ) ::   kt    ! ocean time-step index
132      !!
133      INTEGER  :: jn
134      !!----------------------------------------------------------------------
135      !
136      CALL iom_rstput( kt, nitrst, numrtw, 'rdttrc1', rdttrc )   ! passive tracer time step
137      ! prognostic variables
138      ! --------------------
139      DO jn = 1, jptra
140         CALL iom_rstput( kt, nitrst, numrtw, 'TRN'//ctrcnm(jn), trn(:,:,:,jn) )
141      END DO
142
143      DO jn = 1, jptra
144         CALL iom_rstput( kt, nitrst, numrtw, 'TRB'//ctrcnm(jn), trb(:,:,:,jn) )
145      END DO
146      !
147      CALL iom_delay_rst( 'WRITE', 'TOP', numrtw )   ! save only TOP delayed global communication variables
148   
149      IF( kt == nitrst ) THEN
150          CALL trc_rst_stat            ! statistics
151          CALL iom_close( numrtw )     ! close the restart file (only at last time step)
152#if ! defined key_trdmxl_trc
153          lrst_trc = .FALSE.
154#endif
155          IF( l_offline .AND. ln_rst_list ) THEN
156             nrst_lst = nrst_lst + 1
157             nitrst = nn_stocklist( nrst_lst )
158          ENDIF
159      ENDIF
160      !
161   END SUBROUTINE trc_rst_wri 
162
163
164   SUBROUTINE trc_rst_cal( kt, cdrw )
165      !!---------------------------------------------------------------------
166      !!                   ***  ROUTINE trc_rst_cal  ***
167      !!
168      !!  ** Purpose : Read or write calendar in restart file:
169      !!
170      !!  WRITE(READ) mode:
171      !!       kt        : number of time step since the begining of the experiment at the
172      !!                   end of the current(previous) run
173      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
174      !!                   end of the current(previous) run (REAL -> keep fractions of day)
175      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
176      !!
177      !!   According to namelist parameter nrstdt,
178      !!       nn_rsttr = 0  no control on the date (nittrc000 is  arbitrary).
179      !!       nn_rsttr = 1  we verify that nittrc000 is equal to the last
180      !!                   time step of previous run + 1.
181      !!       In both those options, the  exact duration of the experiment
182      !!       since the beginning (cumulated duration of all previous restart runs)
183      !!       is not stored in the restart and is assumed to be (nittrc000-1)*rdt.
184      !!       This is valid is the time step has remained constant.
185      !!
186      !!       nn_rsttr = 2  the duration of the experiment in days (adatrj)
187      !!                    has been stored in the restart file.
188      !!----------------------------------------------------------------------
189      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
190      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
191      !
192      LOGICAL  ::  llok
193      REAL(wp) ::  zrdttrc1, zkt, zndastp, zdayfrac, ksecs, ktime
194      INTEGER  ::   ihour, iminute
195
196      ! Time domain : restart
197      ! ---------------------
198
199      IF( TRIM(cdrw) == 'READ' ) THEN
200
201         IF(lwp) WRITE(numout,*)
202         IF(lwp) WRITE(numout,*) 'trc_rst_cal : read the TOP restart file for calendar'
203         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
204
205         IF( ln_rsttr ) THEN
206            CALL iom_open( TRIM(cn_trcrst_indir)//'/'//cn_trcrst_in, numrtr )
207            CALL iom_get ( numrtr, 'kt', zkt )   ! last time-step of previous run
208
209            IF(lwp) THEN
210               WRITE(numout,*) ' *** Info read in restart : '
211               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
212               WRITE(numout,*) ' *** restart option'
213               SELECT CASE ( nn_rsttr )
214               CASE ( 0 )   ;   WRITE(numout,*) ' nn_rsttr = 0 : no control of nittrc000'
215               CASE ( 1 )   ;   WRITE(numout,*) ' nn_rsttr = 1 : no control the date at nittrc000 (use ndate0 read in the namelist)'
216               CASE ( 2 )   ;   WRITE(numout,*) ' nn_rsttr = 2 : calendar parameters read in restart'
217               END SELECT
218               WRITE(numout,*)
219            ENDIF
220            ! Control of date
221            IF( nittrc000  - NINT( zkt ) /= nn_dttrc .AND.  nn_rsttr /= 0 )                                  &
222               &   CALL ctl_stop( ' ===>>>> : problem with nittrc000 for the restart',                 &
223               &                  ' verify the restart file or rerun with nn_rsttr = 0 (namelist)' )
224         ENDIF
225         !
226         IF( l_offline ) THEN   
227            !                                          ! set the date in offline mode
228            IF( ln_rsttr .AND. nn_rsttr == 2 ) THEN
229               CALL iom_get( numrtr, 'ndastp', zndastp )
230               ndastp = NINT( zndastp )
231               CALL iom_get( numrtr, 'adatrj', adatrj  )
232               CALL iom_get( numrtr, 'ntime' , ktime   )
233               nn_time0=INT(ktime)
234               ! calculate start time in hours and minutes
235               zdayfrac=adatrj-INT(adatrj)
236               ksecs = NINT(zdayfrac*86400)            ! Nearest second to catch rounding errors in adatrj             
237               ihour = INT(ksecs/3600)
238               iminute = ksecs/60-ihour*60
239               
240               ! Add to nn_time0
241               nhour   =   nn_time0 / 100
242               nminute = ( nn_time0 - nhour * 100 )
243               nminute=nminute+iminute
244               
245               IF( nminute >= 60 ) THEN
246                  nminute=nminute-60
247                  nhour=nhour+1
248               ENDIF
249               nhour=nhour+ihour
250               IF( nhour >= 24 ) THEN
251                  nhour=nhour-24
252                  adatrj=adatrj+1
253               ENDIF           
254               nn_time0 = nhour * 100 + nminute
255               adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated           
256             ELSE
257               ! parameters corresponding to nit000 - 1 (as we start the step
258               ! loop with a call to day)
259               ndastp = ndate0 - 1       ! ndate0 read in the namelist in dom_nam
260               nhour   =   nn_time0 / 100
261               nminute = ( nn_time0 - nhour * 100 )
262               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
263               adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
264               ! note this is wrong if time step has changed during run
265            ENDIF
266            IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
267            !
268            IF(lwp) THEN
269              WRITE(numout,*) ' *** Info used values : '
270              WRITE(numout,*) '   date ndastp                                      : ', ndastp
271              WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
272              WRITE(numout,*) '   nn_time0                                         : ', nn_time0
273              WRITE(numout,*)
274            ENDIF
275            !
276            IF( ln_rsttr )  THEN   ;    neuler = 1
277            ELSE                   ;    neuler = 0
278            ENDIF
279            !
280            CALL day_init          ! compute calendar
281            !
282         ENDIF
283         !
284      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
285         !
286         IF(  kt == nitrst ) THEN
287            IF(lwp) WRITE(numout,*)
288            IF(lwp) WRITE(numout,*) 'trc_wri : write the TOP restart file (NetCDF) at it= ', kt, ' date= ', ndastp
289            IF(lwp) WRITE(numout,*) '~~~~~~~'
290         ENDIF
291         CALL iom_rstput( kt, nitrst, numrtw, 'kt'     , REAL( kt    , wp) )   ! time-step
292         CALL iom_rstput( kt, nitrst, numrtw, 'ndastp' , REAL( ndastp, wp) )   ! date
293         CALL iom_rstput( kt, nitrst, numrtw, 'adatrj' , adatrj            )   ! number of elapsed days since
294         !                                                                     ! the begining of the run [s]
295         CALL iom_rstput( kt, nitrst, numrtw, 'ntime'  , REAL( nn_time0, wp)) ! time
296      ENDIF
297
298   END SUBROUTINE trc_rst_cal
299
300
301   SUBROUTINE trc_rst_stat
302      !!----------------------------------------------------------------------
303      !!                    ***  trc_rst_stat  ***
304      !!
305      !! ** purpose  :   Compute tracers statistics
306      !!----------------------------------------------------------------------
307      INTEGER  :: jk, jn
308      REAL(wp) :: ztraf, zmin, zmax, zmean, zdrift
309      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zvol
310      !!----------------------------------------------------------------------
311
312      IF( lwp ) THEN
313         WRITE(numout,*) 
314         WRITE(numout,*) '           ----TRACER STAT----             '
315         WRITE(numout,*) 
316      ENDIF
317      !
318      DO jk = 1, jpk
319         zvol(:,:,jk) = e1e2t(:,:) * e3t_a(:,:,jk) * tmask(:,:,jk)
320      END DO
321      !
322      DO jn = 1, jptra
323         ztraf = glob_sum( 'trcrst', trn(:,:,:,jn) * zvol(:,:,:) )
324         zmin  = MINVAL( trn(:,:,:,jn), mask= ((tmask*SPREAD(tmask_i,DIM=3,NCOPIES=jpk).NE.0.)) )
325         zmax  = MAXVAL( trn(:,:,:,jn), mask= ((tmask*SPREAD(tmask_i,DIM=3,NCOPIES=jpk).NE.0.)) )
326         IF( lk_mpp ) THEN
327            CALL mpp_min( 'trcrst', zmin )      ! min over the global domain
328            CALL mpp_max( 'trcrst', zmax )      ! max over the global domain
329         END IF
330         zmean  = ztraf / areatot
331         zdrift = ( ( ztraf - trai(jn) ) / ( trai(jn) + 1.e-12 )  ) * 100._wp
332         IF(lwp) WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), zmean, zmin, zmax, zdrift
333      END DO
334      IF(lwp) WRITE(numout,*) 
3359000  FORMAT(' tracer nb :',i2,'    name :',a10,'    mean :',e18.10,'    min :',e18.10, &
336      &      '    max :',e18.10,'    drift :',e18.10, ' %')
337      !
338   END SUBROUTINE trc_rst_stat
339
340#else
341   !!----------------------------------------------------------------------
342   !!  Dummy module :                                     No passive tracer
343   !!----------------------------------------------------------------------
344CONTAINS
345   SUBROUTINE trc_rst_read                      ! Empty routines
346   END SUBROUTINE trc_rst_read
347   SUBROUTINE trc_rst_wri( kt )
348      INTEGER, INTENT ( in ) :: kt
349      WRITE(*,*) 'trc_rst_wri: You should not have seen this print! error?', kt
350   END SUBROUTINE trc_rst_wri   
351#endif
352
353   !!----------------------------------------------------------------------
354   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
355   !! $Id$
356   !! Software governed by the CeCILL license (see ./LICENSE)
357   !!======================================================================
358END MODULE trcrst
Note: See TracBrowser for help on using the repository browser.