New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in NEMO/trunk/src/TOP – NEMO

source: NEMO/trunk/src/TOP/trcstp.F90 @ 10351

Last change on this file since 10351 was 10068, checked in by nicolasmartin, 6 years ago

First part of modifications to have a common default header : fix typos and SVN keywords properties

  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp       : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc        ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp         ! passive tracers transport
16   USE trcsms         ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trcsub         !
20   USE trdtrc_oce
21   USE trdmxl_trc
22   !
23   USE prtctl_trc     ! Print control for debbuging
24   USE iom            !
25   USE in_out_manager !
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_stp    ! called by step
31
32   LOGICAL  ::   llnew                   ! ???
33   REAL(wp) ::   rdt_sampl               ! ???
34   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
35   REAL(wp) ::   rsecfst, rseclast       ! ???
36   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
37
38   !!----------------------------------------------------------------------
39   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE trc_stp( kt )
46      !!-------------------------------------------------------------------
47      !!                     ***  ROUTINE trc_stp  ***
48      !!                     
49      !! ** Purpose :   Time loop of opa for passive tracer
50      !!
51      !! ** Method  :   Compute the passive tracers trends
52      !!                Update the passive tracers
53      !!-------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
55      !
56      INTEGER ::   jk, jn   ! dummy loop indices
57      REAL(wp)::   ztrai    ! local scalar
58      CHARACTER (len=25) ::   charout   !
59      !!-------------------------------------------------------------------
60      !
61      IF( ln_timing )   CALL timing_start('trc_stp')
62      !
63      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
64         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
65      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
66         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
67      ENDIF
68      !
69      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
70      !
71      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
72         DO jk = 1, jpk
73            cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
74         END DO
75         areatot         = glob_sum( cvol(:,:,:) )
76      ENDIF
77      !
78      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
79      !   
80      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
81      !   
82      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
83         !
84         IF(ln_ctl) THEN
85            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
86            CALL prt_ctl_trc_info(charout)
87         ENDIF
88         !
89         tra(:,:,:,:) = 0.e0
90         !
91                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
92         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
93                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
94                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
95                                   CALL trc_trp      ( kt )       ! transport of passive tracers
96         IF( kt == nittrc000 ) THEN
97            CALL iom_close( numrtr )       ! close input tracer restart file
98            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
99         ENDIF
100         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
101         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
102         !
103         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
104         !
105      ENDIF
106      !
107      ztrai = 0._wp                                                   !  content of all tracers
108      DO jn = 1, jptra
109         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
110      END DO
111      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1129300  FORMAT(i10,D23.16)
113      !
114      IF( ln_timing )   CALL timing_stop('trc_stp')
115      !
116   END SUBROUTINE trc_stp
117
118
119   SUBROUTINE trc_mean_qsr( kt )
120      !!----------------------------------------------------------------------
121      !!             ***  ROUTINE trc_mean_qsr  ***
122      !!
123      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
124      !!               of diurnal cycle
125      !!
126      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
127      !!              is greater than 1 hour ) and then, compute the  mean with
128      !!              a moving average over 24 hours.
129      !!              In coupled mode, the sampling is done at every coupling frequency
130      !!----------------------------------------------------------------------
131      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
132      !
133      INTEGER  ::   jn   ! dummy loop indices
134      REAL(wp) ::   zkt, zrec     ! local scalars
135      CHARACTER(len=1) ::   cl1   ! 1 character
136      CHARACTER(len=2) ::   cl2   ! 2 characters
137      !!----------------------------------------------------------------------
138      !
139      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
140      !
141      IF( kt == nittrc000 ) THEN
142         IF( ln_cpl )  THEN 
143            rdt_sampl = rday / ncpl_qsr_freq
144            nb_rec_per_day = ncpl_qsr_freq
145         ELSE 
146            rdt_sampl = MAX( 3600., rdttrc )
147            nb_rec_per_day = INT( rday / rdt_sampl )
148         ENDIF
149         !
150         IF(lwp) THEN
151            WRITE(numout,*) 
152            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
153            WRITE(numout,*) 
154         ENDIF
155         !
156         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
157         !
158         !                                            !* Restart: read in restart file
159         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
160           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
161           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
162           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
163
164            CALL iom_get( numrtr, 'ktdcy', zkt ) 
165            rsecfst = INT( zkt ) * rdttrc
166            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
167            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
168            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
169            IF( INT( zrec ) == nb_rec_per_day ) THEN
170               DO jn = 1, nb_rec_per_day 
171                  IF( jn <= 9 )  THEN
172                    WRITE(cl1,'(i1)') jn
173                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
174                  ELSE
175                    WRITE(cl2,'(i2.2)') jn
176                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
177                  ENDIF
178              END DO
179            ELSE
180               DO jn = 1, nb_rec_per_day
181                  qsr_arr(:,:,jn) = qsr_mean(:,:)
182               ENDDO
183            ENDIF
184         ELSE                                         !* no restart: set from nit000 values
185            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
186            rsecfst  = kt * rdttrc
187            !
188            qsr_mean(:,:) = qsr(:,:)
189            DO jn = 1, nb_rec_per_day
190               qsr_arr(:,:,jn) = qsr_mean(:,:)
191            END DO
192         ENDIF
193         !
194      ENDIF
195      !
196      rseclast = kt * rdttrc
197      !
198      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
199      IF( llnew ) THEN
200          ktdcy = kt
201          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
202             &                      ' time = ', rseclast/3600.,'hours '
203          rsecfst = rseclast
204          DO jn = 1, nb_rec_per_day - 1
205             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
206          ENDDO
207          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
208          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
209      ENDIF
210      !
211      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
212         IF(lwp) WRITE(numout,*)
213         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
214         IF(lwp) WRITE(numout,*) '~~~~~~~'
215         zkt  = REAL( ktdcy, wp )
216         zrec = REAL( nb_rec_per_day, wp )
217         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
218         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
219          DO jn = 1, nb_rec_per_day 
220             IF( jn <= 9 )  THEN
221               WRITE(cl1,'(i1)') jn
222               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
223             ELSE
224               WRITE(cl2,'(i2.2)') jn
225               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
226             ENDIF
227         END DO
228         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
229      ENDIF
230      !
231      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
232      !
233   END SUBROUTINE trc_mean_qsr
234
235#else
236   !!----------------------------------------------------------------------
237   !!   Default key                                     NO passive tracers
238   !!----------------------------------------------------------------------
239CONTAINS
240   SUBROUTINE trc_stp( kt )        ! Empty routine
241      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
242   END SUBROUTINE trc_stp
243#endif
244
245   !!======================================================================
246END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.