New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/trunk/tests/STATION_ASF/MY_SRC – NEMO

source: NEMO/trunk/tests/STATION_ASF/MY_SRC/icesbc.F90 @ 14072

Last change on this file since 14072 was 14072, checked in by laurent, 3 years ago

Merging branch "2020/dev_r13648_ASINTER-04_laurent_bulk_ice", ticket #2369
File size: 17.8 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb, ONLY : rn_alb_oce         ! sea-ice: albedo !#LB
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29   USE fldread        !!GS: needed by agrif
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC ice_sbc_tau   ! called by icestp.F90
35   PUBLIC ice_sbc_flx   ! called by icestp.F90
36   PUBLIC ice_sbc_init  ! called by icestp.F90
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
42   !! $Id: icesbc.F90 13472 2020-09-16 13:05:19Z smasson $
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
48      !!-------------------------------------------------------------------
49      !!                  ***  ROUTINE ice_sbc_tau  ***
50      !!
51      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
52      !!
53      !! ** Action  : It provides the following fields:
54      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
55      !!-------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
57      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
58      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
59      !!
60      INTEGER  ::   ji, jj                 ! dummy loop index
61      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice
62      !!-------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('ice_sbc')
65      !
66      IF( kt == nit000 .AND. lwp ) THEN
67         WRITE(numout,*)
68         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
69         WRITE(numout,*)'~~~~~~~~~~~~~~~'
70      ENDIF
71      !
72      SELECT CASE( ksbc )
73         !
74      CASE( jp_usr     )
75         CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
76         !
77      CASE( jp_blk     )
78         CALL blk_ice_1( sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1),   &
79            &                                      theta_air_zt(:,:), q_air_zt(:,:),   &   ! #LB: known from "sbc_oce" module...
80            &                                      sf(jp_slp )%fnow(:,:,1), u_ice, v_ice, tm_su    ,   &   ! inputs
81            &                                      putaui = utau_ice, pvtaui = vtau_ice            )       ! outputs
82         !        CASE( jp_abl     )    utau_ice & vtau_ice are computed in ablmod
83      CASE( jp_purecpl )
84         CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
85      END SELECT
86      !
87      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
88         CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
89         DO_2D( 0, 0, 0, 0 )
90         utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
91         vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
92         END_2D
93         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1.0_wp, vtau_ice, 'V', -1.0_wp )
94      ENDIF
95      !
96      IF( ln_timing )   CALL timing_stop('ice_sbc')
97      !
98   END SUBROUTINE ice_sbc_tau
99
100
101   SUBROUTINE ice_sbc_flx( kt, ksbc )
102      !!-------------------------------------------------------------------
103      !!                  ***  ROUTINE ice_sbc_flx  ***
104      !!
105      !! ** Purpose : provide surface boundary condition for sea ice (flux)
106      !!
107      !! ** Action  : It provides the following fields used in sea ice model:
108      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
109      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
110      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
111      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
112      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
113      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
114      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
115      !!            + some fields that are not used outside this module:
116      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
117      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
118      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
119      !!                alb_ice                                  = albedo above sea ice
120      !!-------------------------------------------------------------------
121      INTEGER, INTENT(in) ::   kt     ! ocean time step
122      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
123      !
124      INTEGER  ::   ji, jj, jl      ! dummy loop index
125      REAL(wp) ::   zmiss_val       ! missing value retrieved from xios
126      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zalb, zmsk00      ! 2D workspace
127      !!--------------------------------------------------------------------
128      !
129      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
130
131      IF( kt == nit000 .AND. lwp ) THEN
132         WRITE(numout,*)
133         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
134         WRITE(numout,*)'~~~~~~~~~~~~~~~'
135      ENDIF
136
137      ! get missing value from xml
138      CALL iom_miss_val( "icetemp", zmiss_val )
139
140      ! --- ice albedo --- !
141      !#LB:CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice )
142
143      !
144      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
145         !
146      CASE( jp_usr )              !--- user defined formulation
147         CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
148         !
149      CASE( jp_blk, jp_abl )  !--- bulk formulation & ABL formulation
150         CALL blk_ice_2    ( t_su, h_s, h_i, alb_ice, &
151            &                theta_air_zt(:,:), q_air_zt(:,:),    &   ! #LB: known from "sbc_oce" module...
152            &                sf(jp_slp)%fnow(:,:,1), sf(jp_qlw)%fnow(:,:,1), &
153            &                sf(jp_prec)%fnow(:,:,1), sf(jp_snow)%fnow(:,:,1) )
154         !
155         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
156         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
157         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
158         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
159            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
160      CASE ( jp_purecpl )         !--- coupled formulation
161         CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
162         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
163      END SELECT
164
165      !--- output ice albedo and surface albedo ---!
166      IF( iom_use('icealb') .OR. iom_use('albedo') ) THEN
167
168         ALLOCATE( zalb(jpi,jpj), zmsk00(jpi,jpj) )
169
170         WHERE( at_i_b < 1.e-03 )
171            zmsk00(:,:) = 0._wp
172            zalb  (:,:) = rn_alb_oce
173         ELSEWHERE
174            zmsk00(:,:) = 1._wp
175            zalb  (:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
176         END WHERE
177         ! ice albedo
178         CALL iom_put( 'icealb' , zalb * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) )
179         ! ice+ocean albedo
180         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
181         CALL iom_put( 'albedo' , zalb )
182
183         DEALLOCATE( zalb, zmsk00 )
184
185      ENDIF
186      !
187      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
188      !
189   END SUBROUTINE ice_sbc_flx
190
191
192   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
193      !!-------------------------------------------------------------------
194      !!                  ***  ROUTINE ice_flx_dist  ***
195      !!
196      !! ** Purpose :   update the ice surface boundary condition by averaging
197      !!              and/or redistributing fluxes on ice categories
198      !!
199      !! ** Method  :   average then redistribute
200      !!
201      !! ** Action  :   depends on k_flxdist
202      !!                = -1  Do nothing (needs N(cat) fluxes)
203      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
204      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
205      !!                                                 using T-ice and albedo sensitivity
206      !!                =  2  Redistribute a single flux over categories
207      !!-------------------------------------------------------------------
208      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
209      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
210      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
211      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
212      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
213      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
214      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
215      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
216      !
217      INTEGER  ::   jl      ! dummy loop index
218      !
219      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
220      !
221      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
222      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
223      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
224      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
225      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
226      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
227      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
228      !!----------------------------------------------------------------------
229      !
230      WHERE ( at_i (:,:) > 0._wp )
231         z1_at_i(:,:) = 1._wp / at_i (:,:)
232      ELSEWHERE
233         z1_at_i(:,:) = 0._wp
234      END WHERE
235
236      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
237         !
238      CASE( 0 , 1 )
239         !
240         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) )
241         !
242         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
243         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
244         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
245         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
246         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
247         DO jl = 1, jpl
248            pqns_ice  (:,:,jl) = z_qns_m (:,:)
249            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
250            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
251            pevap_ice (:,:,jl) = z_evap_m(:,:)
252            pdevap_ice(:,:,jl) = z_devap_m(:,:)
253         END DO
254         !
255         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m )
256         !
257      END SELECT
258      !
259      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
260         !
261      CASE( 1 , 2 )
262         !
263         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) )
264         !
265         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
266         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
267         DO jl = 1, jpl
268            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
269            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
270            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
271         END DO
272         !
273         DEALLOCATE( zalb_m, ztem_m )
274         !
275      END SELECT
276      !
277   END SUBROUTINE ice_flx_dist
278
279
280   SUBROUTINE ice_sbc_init
281      !!-------------------------------------------------------------------
282      !!                  ***  ROUTINE ice_sbc_init  ***
283      !!
284      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
285      !!
286      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
287      !!              parameter values called at the first timestep (nit000)
288      !!
289      !! ** input   :   Namelist namsbc
290      !!-------------------------------------------------------------------
291      INTEGER ::   ios, ioptio   ! Local integer
292      !!
293      NAMELIST/namsbc/ rn_cio, nn_snwfra, rn_snwblow, nn_flxdist, ln_cndflx, ln_cndemulate, nn_qtrice
294      !!-------------------------------------------------------------------
295      !
296      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
297901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
298      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
299902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
300      IF(lwm) WRITE( numoni, namsbc )
301      !
302      IF(lwp) THEN                     ! control print
303         WRITE(numout,*)
304         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
305         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
306         WRITE(numout,*) '   Namelist namsbc:'
307         WRITE(numout,*) '      drag coefficient for oceanic stress                       rn_cio        = ', rn_cio
308         WRITE(numout,*) '      fraction of ice covered by snow (options 0,1,2)           nn_snwfra     = ', nn_snwfra
309         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall            rn_snwblow    = ', rn_snwblow
310         WRITE(numout,*) '      Multicategory heat flux formulation                       nn_flxdist    = ', nn_flxdist
311         WRITE(numout,*) '      Use conduction flux as surface condition                  ln_cndflx     = ', ln_cndflx
312         WRITE(numout,*) '         emulate conduction flux                                ln_cndemulate = ', ln_cndemulate
313         WRITE(numout,*) '      solar flux transmitted thru the surface scattering layer  nn_qtrice     = ', nn_qtrice
314         WRITE(numout,*) '         = 0  Grenfell and Maykut 1977'
315         WRITE(numout,*) '         = 1  Lebrun 2019'
316      ENDIF
317      !
318      IF(lwp) WRITE(numout,*)
319      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
320      CASE( -1  )
321         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
322      CASE(  0  )
323         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
324      CASE(  1  )
325         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
326         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
327      CASE(  2  )
328         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
329         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
330      CASE DEFAULT
331         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
332      END SELECT
333      !
334   END SUBROUTINE ice_sbc_init
335
336#else
337   !!----------------------------------------------------------------------
338   !!   Default option :         Empty module         NO SI3 sea-ice model
339   !!----------------------------------------------------------------------
340#endif
341
342   !!======================================================================
343END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.