New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
usrdef_istate.F90 in NEMO/trunk/tests/VORTEX/MY_SRC – NEMO

source: NEMO/trunk/tests/VORTEX/MY_SRC/usrdef_istate.F90 @ 14433

Last change on this file since 14433 was 14433, checked in by smasson, 3 years ago

trunk: merge dev_r14312_MPI_Interface into the trunk, #2598
  • Property svn:keywords set to Id
File size: 7.2 KB
Line 
1MODULE usrdef_istate
2   !!======================================================================
3   !!                     ***  MODULE usrdef_istate   ***
4   !!
5   !!                      ===  VORTEX configuration  ===
6   !!
7   !! User defined : set the initial state of a user configuration
8   !!======================================================================
9   !! History :  NEMO ! 2017-11  (J. Chanut) Original code
10   !!                 ! 2020-11  (S. Techene, G. Madec) separate tsuv from ssh
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!  usr_def_istate : initial state in Temperature and salinity
15   !!----------------------------------------------------------------------
16   USE par_oce        ! ocean space and time domain
17   USE dom_oce , ONLY : glamt, gphit, glamu, gphiu, glamv, gphiv 
18   USE phycst         ! physical constants
19   USE eosbn2  , ONLY : rn_a0
20   !
21   USE in_out_manager ! I/O manager
22   USE lib_mpp        ! MPP library
23   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
24   !   
25   USE usrdef_nam, ONLY : rn_ppgphi0  ! Reference latitude   
26   
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   usr_def_istate       ! called by istate.F90
31   PUBLIC   usr_def_istate_ssh   ! called by domqco.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41 
42   SUBROUTINE usr_def_istate( pdept, ptmask, pts, pu, pv )
43      !!----------------------------------------------------------------------
44      !!                   ***  ROUTINE usr_def_istate  ***
45      !!
46      !! ** Purpose :   Initialization of the dynamics and tracers
47      !!                Here VORTEX configuration
48      !!
49      !! ** Method  :   Set a gaussian anomaly of pressure and associated
50      !!                geostrophic velocities
51      !!----------------------------------------------------------------------
52      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pdept   ! depth of t-point               [m]
53      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   ptmask  ! t-point ocean mask             [m]
54      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pts     ! T & S fields      [Celsius ; g/kg]
55      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pu      ! i-component of the velocity  [m/s]
56      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pv      ! j-component of the velocity  [m/s]
57      !
58      INTEGER  :: ji, jj, jk  ! dummy loop indices
59      REAL(wp) :: zx, zy, zP0, zumax, zlambda, zn2, zf0, zH, zrho1, za, zf
60      REAL(wp) :: zdt, zdu, zdv
61      !!----------------------------------------------------------------------
62      !
63      IF(lwp) WRITE(numout,*)
64      IF(lwp) WRITE(numout,*) 'usr_def_istate : VORTEX configuration, analytical definition of initial state'
65      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~   '
66      !
67      !
68      !
69      zf0   = 2._wp * omega * SIN( rad * rn_ppgphi0 )
70      zumax = 1._wp * SIGN(1._wp, zf0) ! Here Anticyclonic: set zumax=-1 for cyclonic
71      zlambda = SQRT(2._wp)*60.e3      ! Horizontal scale in meters
72      zn2 = 3.e-3**2
73      zH = 0.5_wp * 5000._wp
74      !
75      zP0 = rho0 * zf0 * zumax * zlambda * SQRT(EXP(1._wp)/2._wp)
76      !
77      ! temperature:         
78      DO_2D( 1, 1, 1, 1 )
79         zx = glamt(ji,jj) * 1.e3
80         zy = gphit(ji,jj) * 1.e3
81         DO jk=1,jpk
82            zdt =  pdept(ji,jj,jk) 
83            zrho1 = rho0 * (1._wp + zn2*zdt/grav)
84            IF (zdt < zH) THEN
85               zrho1 = zrho1 - zP0 * (1._wp-EXP(zdt-zH)) &
86                  & * EXP(-(zx**2+zy**2)/zlambda**2) / (grav*(zH -1._wp + EXP(-zH)));
87            ENDIF
88            pts(ji,jj,jk,jp_tem) = (20._wp + (rho0-zrho1) / rn_a0 ) * ptmask(ji,jj,jk)
89         END DO
90      END_2D
91      !
92      ! salinity: 
93      pts(:,:,:,jp_sal) = 35._wp * ptmask(:,:,:) 
94      !
95      ! velocities:
96      za = 2._wp * zP0 / (zf0 * rho0 * zlambda**2)
97      DO_2D( 0, 0, 0, 0 )
98         zx = glamu(ji,jj) * 1.e3
99         zy = gphiu(ji,jj) * 1.e3
100         DO jk=1, jpk
101            zdu = 0.5_wp * (pdept(ji  ,jj,jk) + pdept(ji+1,jj,jk))
102            IF (zdu < zH) THEN
103               zf = (zH-1._wp-zdu+EXP(zdu-zH)) / (zH-1._wp+EXP(-zH))
104               pu(ji,jj,jk) = (za * zf * zy * EXP(-(zx**2+zy**2)/zlambda**2)) * ptmask(ji,jj,jk) * ptmask(ji+1,jj,jk)
105            ELSE
106               pu(ji,jj,jk) = 0._wp
107            ENDIF
108         END DO
109      END_2D
110      !
111      DO_2D( 0, 0, 0, 0 )
112         zx = glamv(ji,jj) * 1.e3
113         zy = gphiv(ji,jj) * 1.e3
114         DO jk=1, jpk
115            zdv = 0.5_wp * (pdept(ji  ,jj,jk) + pdept(ji,jj+1,jk))
116            IF (zdv < zH) THEN
117               zf = (zH-1._wp-zdv+EXP(zdv-zH)) / (zH-1._wp+EXP(-zH))
118               pv(ji,jj,jk) = -(za * zf * zx * EXP(-(zx**2+zy**2)/zlambda**2)) * ptmask(ji,jj,jk) * ptmask(ji,jj+1,jk)
119            ELSE
120               pv(ji,jj,jk) = 0._wp
121            ENDIF
122         END DO
123      END_2D
124      !
125      CALL lbc_lnk( 'usrdef_istate', pu, 'U', -1., pv, 'V', -1. )
126      !   
127   END SUBROUTINE usr_def_istate
128
129
130   SUBROUTINE usr_def_istate_ssh( ptmask, pssh )
131      !!----------------------------------------------------------------------
132      !!                   ***  ROUTINE usr_def_istate  ***
133      !!
134      !! ** Purpose :   Initialization of ssh
135      !!                Here VORTEX configuration
136      !!
137      !! ** Method  :   Set ssh according to a gaussian anomaly of pressure and associated
138      !!                geostrophic velocities
139      !!----------------------------------------------------------------------
140      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   ptmask  ! t-point ocean mask   [m]
141      REAL(wp), DIMENSION(jpi,jpj)         , INTENT(  out) ::   pssh    ! sea-surface height   [m]
142      !
143      INTEGER  :: ji, jj ! dummy loop indices
144      REAL(wp) :: zx, zy, zP0, zumax, zlambda, zf0, zH, zrho1, za
145      !!----------------------------------------------------------------------
146      !
147      IF(lwp) WRITE(numout,*)
148      IF(lwp) WRITE(numout,*) 'usr_def_istate_ssh : VORTEX configuration, analytical definition of initial state'
149      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~   '
150      !
151      !
152      !
153      zf0   = 2._wp * omega * SIN( rad * rn_ppgphi0 )
154      zumax = 1._wp * SIGN(1._wp, zf0) ! Here Anticyclonic: set zumax=-1 for cyclonic
155      zlambda = SQRT(2._wp)*60.e3      ! Horizontal scale in meters
156      zH = 0.5_wp * 5000._wp
157      !
158      zP0 = rho0 * zf0 * zumax * zlambda * SQRT(EXP(1._wp)/2._wp)
159      !
160      ! Sea level:
161      za = -zP0 * (1._wp-EXP(-zH)) / (grav*(zH-1._wp + EXP(-zH)))
162      DO_2D( 1, 1, 1, 1 )
163         zx = glamt(ji,jj) * 1.e3
164         zy = gphit(ji,jj) * 1.e3
165         zrho1 = rho0 + za * EXP(-(zx**2+zy**2)/zlambda**2)
166         pssh(ji,jj) = zP0 * EXP(-(zx**2+zy**2)/zlambda**2)/(zrho1*grav) * ptmask(ji,jj,1)
167      END_2D
168     
169   END SUBROUTINE usr_def_istate_ssh
170
171   !!======================================================================
172END MODULE usrdef_istate
Note: See TracBrowser for help on using the repository browser.