New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/2011/DEV_r2739_STFC_dCSE/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2011/DEV_r2739_STFC_dCSE/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 3837

Last change on this file since 3837 was 3837, checked in by trackstand2, 11 years ago

Merge of finiss

  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35   USE trc_oce, ONLY : lk_offline ! offline flag
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   day        ! called by step.F90
41   PUBLIC   day_init   ! called by istate.F90
42
43   INTEGER ::   nsecd, nsecd05, ndt, ndt05
44
45   !! * Control permutation of array indices
46#  include "dom_oce_ftrans.h90"
47
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE day_init
56      !!----------------------------------------------------------------------
57      !!                   ***  ROUTINE day_init  ***
58      !!
59      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
60      !!                because day will be called at the beginning of step
61      !!
62      !! ** Action  : - nyear        : current year
63      !!              - nmonth       : current month of the year nyear
64      !!              - nday         : current day of the month nmonth
65      !!              - nday_year    : current day of the year nyear
66      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
67      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
68      !!              - nsec_day     : current time step counted in second since 00h of the current day
69      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
70      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
71      !!----------------------------------------------------------------------
72      INTEGER  ::   inbday, idweek
73      REAL(wp) ::   zjul
74      !!----------------------------------------------------------------------
75
76      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
77      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
78      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
79      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
80      nsecd   = NINT(rday           )
81      nsecd05 = NINT(0.5 * rday     )
82      ndt     = NINT(      rdttra(1))
83      ndt05   = NINT(0.5 * rdttra(1))
84
85      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' ) 
86
87      ! set the calandar from ndastp (read in restart file and namelist)
88
89      nyear   =   ndastp / 10000
90      nmonth  = ( ndastp - (nyear * 10000) ) / 100
91      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
92
93      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
94      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
95      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
96
97      nsec1jan000 = 0
98      CALL day_mth
99     
100      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
101         nmonth = nmonth - 1 
102         nday = nmonth_len(nmonth)
103      ENDIF
104      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
105         nmonth = 12
106         nyear = nyear - 1
107         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
108         IF( nleapy == 1 )   CALL day_mth
109      ENDIF
110     
111      ! day since january 1st
112      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
113
114      !compute number of days between last monday and today     
115      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
116      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day 
117      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day 
118
119      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
120      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
121      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
122      nsec_week  = idweek    * nsecd - ndt05
123      nsec_day   =             nsecd - ndt05
124
125      ! control print
126      IF(lwp) WRITE(numout,"(' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',i6,'/',i2,'/',i2,'  nsec_day:',i6,'  nsec_week:',I)") nyear, nmonth, nday, nsec_day, nsec_week
127
128      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
129      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
130      CALL day( nit000 )
131
132   END SUBROUTINE day_init
133
134
135   SUBROUTINE day_mth
136      !!----------------------------------------------------------------------
137      !!                   ***  ROUTINE day_init  ***
138      !!
139      !! ** Purpose :   calendar values related to the months
140      !!
141      !! ** Action  : - nmonth_len    : length in days of the months of the current year
142      !!              - nyear_len     : length in days of the previous/current year
143      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
144      !!              - nmonth_end    : second since the beginning of the year and the end of the months
145      !!----------------------------------------------------------------------
146      INTEGER  ::   jm               ! dummy loop indice
147      !!----------------------------------------------------------------------
148
149      ! length of the month of the current year (from nleapy, read in namelist)
150      IF ( nleapy < 2 ) THEN
151         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
152         nyear_len(:) = 365
153         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
154            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
155               nyear_len(0) = 366
156            ENDIF
157            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
158               nmonth_len(2) = 29
159               nyear_len(1) = 366
160            ENDIF
161         ENDIF
162      ELSE
163         nmonth_len(:) = nleapy   ! all months with nleapy days per year
164         nyear_len(:) = 12 * nleapy
165      ENDIF
166
167      ! half month in second since the begining of the year:
168      ! time since Jan 1st   0     1     2    ...    11    12    13
169      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
170      !                 <---> <---> <--->  ...  <---> <---> <--->       
171      ! month number      0     1     2    ...    11    12    13
172      !
173      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
174      nmonth_half(0) = - nsecd05 * nmonth_len(0)
175      DO jm = 1, 13
176         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
177      END DO
178
179      nmonth_end(0) = 0
180      DO jm = 1, 13
181         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
182      END DO
183      !           
184   END SUBROUTINE
185
186
187   SUBROUTINE day( kt )
188      !!----------------------------------------------------------------------
189      !!                      ***  ROUTINE day  ***
190      !!
191      !! ** Purpose :   Compute the date with a day iteration IF necessary.
192      !!
193      !! ** Method  : - ???
194      !!
195      !! ** Action  : - nyear     : current year
196      !!              - nmonth    : current month of the year nyear
197      !!              - nday      : current day of the month nmonth
198      !!              - nday_year : current day of the year nyear
199      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
200      !!              - adatrj    : date in days since the beginning of the run
201      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
202      !!----------------------------------------------------------------------     
203      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
204      !
205      CHARACTER (len=25) ::   charout
206      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
207      !!----------------------------------------------------------------------
208      zprec = 0.1 / rday
209      !                                                 ! New time-step
210      nsec_year  = nsec_year  + ndt 
211      nsec_month = nsec_month + ndt                 
212      nsec_week  = nsec_week  + ndt
213      nsec_day   = nsec_day   + ndt               
214      adatrj  = adatrj  + rdttra(1) / rday
215      fjulday = fjulday + rdttra(1) / rday
216      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
217      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
218     
219      IF( nsec_day > nsecd ) THEN                       ! New day
220         !
221         nday      = nday + 1
222         nday_year = nday_year + 1
223         nsec_day  = ndt05
224         !
225         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
226            nday   = 1
227            nmonth = nmonth + 1
228            nsec_month = ndt05
229            IF( nmonth == 13 ) THEN                     ! New year
230               nyear     = nyear + 1
231               nmonth    = 1
232               nday_year = 1
233               nsec_year = ndt05
234               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
235               IF( nleapy == 1 )   CALL day_mth
236            ENDIF
237         ENDIF
238         !
239         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
240         !
241         !compute first day of the year in julian days
242         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
243         !
244         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
245              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
246         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
247              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
248      ENDIF
249
250      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
251     
252      IF(ln_ctl) THEN
253         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
254         CALL prt_ctl_info(charout)
255      ENDIF
256
257      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
258      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
259      !
260   END SUBROUTINE day
261
262
263   SUBROUTINE day_rst( kt, cdrw )
264      !!---------------------------------------------------------------------
265      !!                   ***  ROUTINE ts_rst  ***
266      !!
267      !!  ** Purpose : Read or write calendar in restart file:
268      !!
269      !!  WRITE(READ) mode:
270      !!       kt        : number of time step since the begining of the experiment at the
271      !!                   end of the current(previous) run
272      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
273      !!                   end of the current(previous) run (REAL -> keep fractions of day)
274      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
275      !!
276      !!   According to namelist parameter nrstdt,
277      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
278      !!       nrstdt = 1  we verify that nit000 is equal to the last
279      !!                   time step of previous run + 1.
280      !!       In both those options, the  exact duration of the experiment
281      !!       since the beginning (cumulated duration of all previous restart runs)
282      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
283      !!       This is valid is the time step has remained constant.
284      !!
285      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
286      !!                    has been stored in the restart file.
287      !!----------------------------------------------------------------------
288      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
289      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
290      !
291      REAL(wp) ::   zkt, zndastp
292      !!----------------------------------------------------------------------
293     
294      IF( TRIM(cdrw) == 'READ' ) THEN
295
296         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
297            ! Get Calendar informations
298            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
299            IF(lwp) THEN
300               WRITE(numout,*) ' *** Info read in restart : '
301               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
302               WRITE(numout,*) ' *** restart option'
303               SELECT CASE ( nrstdt )
304               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
305               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
306               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
307               END SELECT
308               WRITE(numout,*)
309            ENDIF
310            ! Control of date
311            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
312                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
313                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
314            ! define ndastp and adatrj
315            IF ( nrstdt == 2 ) THEN 
316               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
317               CALL iom_get( numror, 'ndastp', zndastp )
318               ndastp = NINT( zndastp )
319               CALL iom_get( numror, 'adatrj', adatrj  )
320            ELSE 
321               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
322               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
323               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
324               ! note this is wrong if time step has changed during run
325            ENDIF
326         ELSE
327            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
328            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
329            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
330         ENDIF
331         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
332         !
333         IF(lwp) THEN
334            WRITE(numout,*) ' *** Info used values : '
335            WRITE(numout,*) '   date ndastp                                      : ', ndastp
336            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
337            WRITE(numout,*)
338         ENDIF
339         !
340      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
341         !
342         IF( kt == nitrst ) THEN
343            IF(lwp) WRITE(numout,*)
344            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
345            IF(lwp) WRITE(numout,*) '~~~~~~~'         
346         ENDIF
347         ! calendar control
348         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
349         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
350         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
351         !                                                                     ! the begining of the run [s]
352      ENDIF
353      !
354   END SUBROUTINE day_rst
355
356   !!======================================================================
357END MODULE daymod
Note: See TracBrowser for help on using the repository browser.