New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in branches/2011/DEV_r2739_STFC_dCSE/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2011/DEV_r2739_STFC_dCSE/NEMOGCM/NEMO/OPA_SRC/DOM/domzgr.F90 @ 4400

Last change on this file since 4400 was 4400, checked in by trackstand2, 10 years ago

Replace jpk with jpkf in bound_exch_generic. Turn on test timing of exchanges
  • Property svn:keywords set to Id
File size: 87.4 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean initialization : domain initialization
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   dom_zgr          : defined the ocean vertical coordinate system
21   !!       zgr_bat      : bathymetry fields (levels and meters)
22   !!       zgr_bat_zoom : modify the bathymetry field if zoom domain
23   !!       zgr_bat_ctl  : check the bathymetry files
24   !!       zgr_bot_level: deepest ocean level for t-, u, and v-points
25   !!       zgr_z        : reference z-coordinate
26   !!       zgr_zco      : z-coordinate
27   !!       zgr_zps      : z-coordinate with partial steps
28   !!       zgr_sco      : s-coordinate
29   !!       fssig        : sigma coordinate non-dimensional function
30   !!       dfssig       : derivative of the sigma coordinate function    !!gm  (currently missing!)
31   !!---------------------------------------------------------------------
32   USE oce               ! ocean variables
33   USE dom_oce           ! ocean domain
34   USE closea            ! closed seas
35   USE c1d               ! 1D vertical configuration
36   USE in_out_manager    ! I/O manager
37   USE iom               ! I/O library
38   USE lbclnk            ! ocean lateral boundary conditions (or mpp link)
39   USE lib_mpp           ! distributed memory computing library
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   dom_zgr        ! called by dom_init.F90
45   PUBLIC   zgr_z, zgr_bat, zgr_zco, zgr_zps ! called by nemogcm::recursive_partition
46   PUBLIC   fssig1         ! called by partition_mod::smooth_bathy
47
48   !                                       !!* Namelist namzgr_sco *
49   REAL(wp) ::   rn_sbot_min =  300._wp     ! minimum depth of s-bottom surface (>0) (m)
50   REAL(wp) ::   rn_sbot_max = 5250._wp     ! maximum depth of s-bottom surface (= ocean depth) (>0) (m)
51   REAL(wp) ::   rn_theta    =    6.00_wp   ! surface control parameter (0<=rn_theta<=20)
52   REAL(wp) ::   rn_thetb    =    0.75_wp   ! bottom control parameter  (0<=rn_thetb<= 1)
53   REAL(wp) ::   rn_rmax     =    0.15_wp   ! maximum cut-off r-value allowed (0<rn_rmax<1)
54   LOGICAL  ::   ln_s_sigma  = .false.      ! use hybrid s-sigma -coordinate & stretching function fssig1 (ln_sco=T)
55   REAL(wp) ::   rn_bb       =    0.80_wp   ! stretching parameter for song and haidvogel stretching
56   !                                        ! ( rn_bb=0; top only, rn_bb =1; top and bottom)
57   REAL(wp) ::   rn_hc       =  150._wp     ! Critical depth for s-sigma coordinates
58   PUBLIC rn_sbot_min, rn_sbot_max, rn_theta, rn_thetb, rn_rmax, &
59          ln_s_sigma, rn_bb, rn_hc
60   PUBLIC ln_zco, ln_zps, ln_sco
61
62   !! * Control permutation of array indices
63#  include "oce_ftrans.h90"
64#  include "dom_oce_ftrans.h90"
65
66  !! * Substitutions
67#  include "domzgr_substitute.h90"
68#  include "vectopt_loop_substitute.h90"
69
70   NAMELIST/namzgr/ ln_zco, ln_zps, ln_sco
71   NAMELIST/namzgr_sco/ rn_sbot_max, rn_sbot_min, rn_theta, rn_thetb, &
72                        rn_rmax, ln_s_sigma, rn_bb, rn_hc
73   PUBLIC namzgr, namzgr_sco
74   !!----------------------------------------------------------------------
75   !! NEMO/OPA 3.3.1 , NEMO Consortium (2011)
76   !! $Id$
77   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
78   !!----------------------------------------------------------------------
79CONTAINS       
80
81   SUBROUTINE dom_zgr
82      !!----------------------------------------------------------------------
83      !!                ***  ROUTINE dom_zgr  ***
84      !!                   
85      !! ** Purpose :  set the depth of model levels and the resulting
86      !!      vertical scale factors.
87      !!
88      !! ** Method  : - reference 1D vertical coordinate (gdep._0, e3._0)
89      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
90      !!              - vertical coordinate (gdep., e3.) depending on the
91      !!                coordinate chosen :
92      !!                   ln_zco=T   z-coordinate   
93      !!                   ln_zps=T   z-coordinate with partial steps
94      !!                   ln_zco=T   s-coordinate
95      !!
96      !! ** Action  :   define gdep., e3., mbathy and bathy
97      !!----------------------------------------------------------------------
98      INTEGER ::   ioptio = 0   ! temporary integer
99      !
100      !NAMELIST/namzgr/ ln_zco, ln_zps, ln_sco
101      !!----------------------------------------------------------------------
102
103      REWIND( numnam )                 ! Read Namelist namzgr : vertical coordinate
104      READ  ( numnam, namzgr )
105
106      IF(lwp) THEN                     ! Control print
107         WRITE(numout,*)
108         WRITE(numout,*) 'dom_zgr : vertical coordinate'
109         WRITE(numout,*) '~~~~~~~'
110         WRITE(numout,*) '          Namelist namzgr : set vertical coordinate'
111         WRITE(numout,*) '             z-coordinate - full steps      ln_zco = ', ln_zco
112         WRITE(numout,*) '             z-coordinate - partial steps   ln_zps = ', ln_zps
113         WRITE(numout,*) '             s- or hybrid z-s-coordinate    ln_sco = ', ln_sco
114      ENDIF
115
116      ioptio = 0                       ! Check Vertical coordinate options
117      IF( ln_zco ) ioptio = ioptio + 1
118      IF( ln_zps ) ioptio = ioptio + 1
119      IF( ln_sco ) ioptio = ioptio + 1
120      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
121      !
122      ! Build the vertical coordinate system
123      ! ------------------------------------
124                          CALL zgr_z            ! Reference z-coordinate system (always called)
125                          CALL zgr_bat          ! Bathymetry fields (levels and meters)
126      IF( ln_zco      )   CALL zgr_zco          ! z-coordinate
127      IF( ln_zps      )   CALL zgr_zps          ! Partial step z-coordinate
128      IF( ln_sco      )   CALL zgr_sco          ! s-coordinate or hybrid z-s coordinate
129      !
130      ! final adjustment of mbathy & check
131      ! -----------------------------------
132      IF( lzoom       )   CALL zgr_bat_zoom     ! correct mbathy in case of zoom subdomain
133      IF( .NOT.lk_c1d )   CALL zgr_bat_ctl      ! check bathymetry (mbathy) and suppress isoated ocean points
134                          CALL zgr_bot_level    ! deepest ocean level for t-, u- and v-points
135      !
136      !
137
138      IF( nprint == 1 .AND. lwp )   THEN
139         WRITE(numout,*) ' MIN val mbathy ', MINVAL( mbathy(:,:) ), ' MAX ', MAXVAL( mbathy(:,:) )
140         WRITE(numout,*) ' MIN val depth t ', MINVAL( fsdept(:,:,:) ),   &
141            &                   ' w ',   MINVAL( fsdepw(:,:,:) ), '3w ', MINVAL( fsde3w(:,:,:) )
142         WRITE(numout,*) ' MIN val e3    t ', MINVAL( fse3t(:,:,:) ), ' f ', MINVAL( fse3f(:,:,:) ),  &
143            &                   ' u ',   MINVAL( fse3u(:,:,:) ), ' u ', MINVAL( fse3v(:,:,:) ),  &
144            &                   ' uw',   MINVAL( fse3uw(:,:,:)), ' vw', MINVAL( fse3vw(:,:,:)),   &
145            &                   ' w ',   MINVAL( fse3w(:,:,:) )
146
147         WRITE(numout,*) ' MAX val depth t ', MAXVAL( fsdept(:,:,:) ),   &
148            &                   ' w ',   MAXVAL( fsdepw(:,:,:) ), '3w ', MAXVAL( fsde3w(:,:,:) )
149         WRITE(numout,*) ' MAX val e3    t ', MAXVAL( fse3t(:,:,:) ), ' f ', MAXVAL( fse3f(:,:,:) ),  &
150            &                   ' u ',   MAXVAL( fse3u(:,:,:) ), ' u ', MAXVAL( fse3v(:,:,:) ),  &
151            &                   ' uw',   MAXVAL( fse3uw(:,:,:)), ' vw', MAXVAL( fse3vw(:,:,:)),   &
152            &                   ' w ',   MAXVAL( fse3w(:,:,:) )
153      ENDIF
154      !
155   END SUBROUTINE dom_zgr
156
157
158   SUBROUTINE zgr_z
159      !!----------------------------------------------------------------------
160      !!                   ***  ROUTINE zgr_z  ***
161      !!                   
162      !! ** Purpose :   set the depth of model levels and the resulting
163      !!      vertical scale factors.
164      !!
165      !! ** Method  :   z-coordinate system (use in all type of coordinate)
166      !!        The depth of model levels is defined from an analytical
167      !!      function the derivative of which gives the scale factors.
168      !!        both depth and scale factors only depend on k (1d arrays).
169      !!              w-level: gdepw_0  = fsdep(k)
170      !!                       e3w_0(k) = dk(fsdep)(k)     = fse3(k)
171      !!              t-level: gdept_0  = fsdep(k+0.5)
172      !!                       e3t_0(k) = dk(fsdep)(k+0.5) = fse3(k+0.5)
173      !!
174      !! ** Action  : - gdept_0, gdepw_0 : depth of T- and W-point (m)
175      !!              - e3t_0  , e3w_0   : scale factors at T- and W-levels (m)
176      !!
177      !! Reference : Marti, Madec & Delecluse, 1992, JGR, 97, No8, 12,763-12,766.
178      !!----------------------------------------------------------------------
179      INTEGER  ::   jk                     ! dummy loop indices
180      REAL(wp) ::   zt, zw                 ! temporary scalars
181      REAL(wp) ::   zsur, za0, za1, zkth   ! Values set from parameters in
182      REAL(wp) ::   zacr, zdzmin, zhmax    ! par_CONFIG_Rxx.h90
183      REAL(wp) ::   zrefdep                ! depth of the reference level (~10m)
184      REAL(wp) ::   za2, zkth2, zacr2      ! Values for optional double tanh function set from parameters
185      !!----------------------------------------------------------------------
186
187      ! Set variables from parameters
188      ! ------------------------------
189       zkth = ppkth       ;   zacr = ppacr
190       zdzmin = ppdzmin   ;   zhmax = pphmax
191       zkth2 = ppkth2     ;   zacr2 = ppacr2   ! optional (ldbletanh=T) double tanh parameters
192
193      ! If ppa1 and ppa0 and ppsur are et to pp_to_be_computed
194      !  za0, za1, zsur are computed from ppdzmin , pphmax, ppkth, ppacr
195      IF(   ppa1  == pp_to_be_computed  .AND.  &
196         &  ppa0  == pp_to_be_computed  .AND.  &
197         &  ppsur == pp_to_be_computed           ) THEN
198         !
199         za1  = (  ppdzmin - pphmax / FLOAT(jpkm1)  )                                                      &
200            & / ( TANH((1-ppkth)/ppacr) - ppacr/FLOAT(jpk-1) * (  LOG( COSH( (jpk - ppkth) / ppacr) )      &
201            &                                                   - LOG( COSH( ( 1  - ppkth) / ppacr) )  )  )
202         za0  = ppdzmin - za1 *              TANH( (1-ppkth) / ppacr )
203         zsur =   - za0 - za1 * ppacr * LOG( COSH( (1-ppkth) / ppacr )  )
204      ELSE
205         za1 = ppa1 ;       za0 = ppa0 ;          zsur = ppsur
206         za2 = ppa2                            ! optional (ldbletanh=T) double tanh parameter
207      ENDIF
208
209      IF(lwp) THEN                         ! Parameter print
210         WRITE(numout,*)
211         WRITE(numout,*) '    zgr_z   : Reference vertical z-coordinates'
212         WRITE(numout,*) '    ~~~~~~~'
213         IF(  ppkth == 0._wp ) THEN             
214              WRITE(numout,*) '            Uniform grid with ',jpk-1,' layers'
215              WRITE(numout,*) '            Total depth    :', zhmax
216              WRITE(numout,*) '            Layer thickness:', zhmax/(jpk-1)
217         ELSE
218            IF( ppa1 == 0._wp .AND. ppa0 == 0._wp .AND. ppsur == 0._wp ) THEN
219               WRITE(numout,*) '         zsur, za0, za1 computed from '
220               WRITE(numout,*) '                 zdzmin = ', zdzmin
221               WRITE(numout,*) '                 zhmax  = ', zhmax
222            ENDIF
223            WRITE(numout,*) '           Value of coefficients for vertical mesh:'
224            WRITE(numout,*) '                 zsur = ', zsur
225            WRITE(numout,*) '                 za0  = ', za0
226            WRITE(numout,*) '                 za1  = ', za1
227            WRITE(numout,*) '                 zkth = ', zkth
228            WRITE(numout,*) '                 zacr = ', zacr
229            IF( ldbletanh ) THEN
230               WRITE(numout,*) ' (Double tanh    za2  = ', za2
231               WRITE(numout,*) '  parameters)    zkth2= ', zkth2
232               WRITE(numout,*) '                 zacr2= ', zacr2
233            ENDIF
234         ENDIF
235      ENDIF
236
237
238      ! Reference z-coordinate (depth - scale factor at T- and W-points)
239      ! ======================
240      IF( ppkth == 0._wp ) THEN            !  uniform vertical grid       
241         za1 = zhmax / FLOAT(jpk-1) 
242         DO jk = 1, jpk
243            zw = FLOAT( jk )
244            zt = FLOAT( jk ) + 0.5_wp
245            gdepw_0(jk) = ( zw - 1 ) * za1
246            gdept_0(jk) = ( zt - 1 ) * za1
247            e3w_0  (jk) =  za1
248            e3t_0  (jk) =  za1
249         END DO
250      ELSE                                ! Madec & Imbard 1996 function
251         IF( .NOT. ldbletanh ) THEN
252            DO jk = 1, jpk
253               zw = REAL( jk , wp )
254               zt = REAL( jk , wp ) + 0.5_wp
255               gdepw_0(jk) = ( zsur + za0 * zw + za1 * zacr * LOG ( COSH( (zw-zkth) / zacr ) )  )
256               gdept_0(jk) = ( zsur + za0 * zt + za1 * zacr * LOG ( COSH( (zt-zkth) / zacr ) )  )
257               e3w_0  (jk) =          za0      + za1        * TANH(       (zw-zkth) / zacr   )
258               e3t_0  (jk) =          za0      + za1        * TANH(       (zt-zkth) / zacr   )
259            END DO
260         ELSE
261            DO jk = 1, jpk
262               zw = FLOAT( jk )
263               zt = FLOAT( jk ) + 0.5_wp
264               ! Double tanh function
265               gdepw_0(jk) = ( zsur + za0 * zw + za1 * zacr * LOG ( COSH( (zw-zkth ) / zacr  ) )    &
266                  &                            + za2 * zacr2* LOG ( COSH( (zw-zkth2) / zacr2 ) )  )
267               gdept_0(jk) = ( zsur + za0 * zt + za1 * zacr * LOG ( COSH( (zt-zkth ) / zacr  ) )    &
268                  &                            + za2 * zacr2* LOG ( COSH( (zt-zkth2) / zacr2 ) )  )
269               e3w_0  (jk) =          za0      + za1        * TANH(       (zw-zkth ) / zacr  )    &
270                  &                            + za2        * TANH(       (zw-zkth2) / zacr2 )
271               e3t_0  (jk) =          za0      + za1        * TANH(       (zt-zkth ) / zacr  )    &
272                  &                            + za2        * TANH(       (zt-zkth2) / zacr2 )
273            END DO
274         ENDIF
275         gdepw_0(1) = 0._wp                    ! force first w-level to be exactly at zero
276      ENDIF
277
278!!gm BUG in s-coordinate this does not work!
279      ! deepest/shallowest W level Above/Below ~10m
280      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_0 )                    ! ref. depth with tolerance (10% of minimum layer thickness)
281      nlb10 = MINLOC( gdepw_0, mask = gdepw_0 > zrefdep, dim = 1 )   ! shallowest W level Below ~10m
282      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
283!!gm end bug
284
285      IF(lwp) THEN                        ! control print
286         WRITE(numout,*)
287         WRITE(numout,*) '              Reference z-coordinate depth and scale factors:'
288         WRITE(numout, "(9x,' level   gdept    gdepw     e3t      e3w  ')" )
289         WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, gdept_0(jk), gdepw_0(jk), e3t_0(jk), e3w_0(jk), jk = 1, jpk )
290      ENDIF
291      DO jk = 1, jpk                      ! control positivity
292         IF( e3w_0  (jk) <= 0._wp .OR. e3t_0  (jk) <= 0._wp )   CALL ctl_stop( 'dom:zgr_z: e3w or e3t =< 0 '    )
293         IF( gdepw_0(jk) <  0._wp .OR. gdept_0(jk) <  0._wp )   CALL ctl_stop( 'dom:zgr_z: gdepw or gdept < 0 ' )
294      END DO
295      !
296   END SUBROUTINE zgr_z
297
298
299   SUBROUTINE zgr_bat(global_domain)
300      !!----------------------------------------------------------------------
301      !!                    ***  ROUTINE zgr_bat  ***
302      !!
303      !! ** Purpose :   set bathymetry both in levels and meters
304      !!
305      !! ** Method  :   read or define mbathy and bathy arrays
306      !!       * level bathymetry:
307      !!      The ocean basin geometry is given by a two-dimensional array,
308      !!      mbathy, which is defined as follow :
309      !!            mbathy(ji,jj) = 1, ..., jpk-1, the number of ocean level
310      !!                              at t-point (ji,jj).
311      !!                            = 0  over the continental t-point.
312      !!      The array mbathy is checked to verified its consistency with
313      !!      model option. in particular:
314      !!            mbathy must have at least 1 land grid-points (mbathy<=0)
315      !!                  along closed boundary.
316      !!            mbathy must be cyclic IF jperio=1.
317      !!            mbathy must be lower or equal to jpk-1.
318      !!            isolated ocean grid points are suppressed from mbathy
319      !!                  since they are only connected to remaining
320      !!                  ocean through vertical diffusion.
321      !!      ntopo=-1 :   rectangular channel or bassin with a bump
322      !!      ntopo= 0 :   flat rectangular channel or basin
323      !!      ntopo= 1 :   mbathy is read in 'bathy_level.nc' NetCDF file
324      !!                   bathy  is read in 'bathy_meter.nc' NetCDF file
325      !!
326      !! ** Action  : - mbathy: level bathymetry (in level index)
327      !!              - bathy : meter bathymetry (in meters)
328      !!----------------------------------------------------------------------
329      LOGICAL, OPTIONAL, INTENT(in) :: global_domain ! Whether dealing with
330                                                     ! whole domain (T) or a
331                                                     ! sub-domain after domain
332                                                     ! decomposition
333      ! Locals
334      INTEGER  ::   ji, jj, jl, jk            ! dummy loop indices
335      INTEGER  ::   inum                      ! temporary logical unit
336      INTEGER  ::   ii_bump, ij_bump, ih      ! bump center position
337      INTEGER  ::   ii0, ii1, ij0, ij1, ik    ! local indices
338      REAL(wp) ::   r_bump , h_bump , h_oce   ! bump characteristics
339      REAL(wp) ::   zi, zj, zh, zhmin         ! local scalars
340      INTEGER , DIMENSION(jpidta,jpjdta) ::   idta   ! global domain integer data
341      REAL(wp), DIMENSION(jpidta,jpjdta) ::   zdta   ! global domain scalar data
342      LOGICAL  ::   is_global 
343      !!----------------------------------------------------------------------
344
345      IF(lwp) WRITE(numout,*)
346      IF(lwp) WRITE(numout,*) '    zgr_bat : defines level and meter bathymetry'
347      IF(lwp) WRITE(numout,*) '    ~~~~~~~'
348
349      ! Set local flag to signal whether we're dealing with the global domain
350      ! (pre decomposition) or a local part of it. Required by the
351      ! recursive k-section partitioning.
352      is_global = .FALSE.
353      IF( PRESENT(global_domain) )THEN
354         IF( global_domain ) is_global = .TRUE.
355      END IF
356
357      !                                               ! ================== !
358      IF( ntopo == 0 .OR. ntopo == -1 ) THEN          !   defined by hand  !
359         !                                            ! ================== !
360         !                                            ! global domain level and meter bathymetry (idta,zdta)
361         !
362         IF( ntopo == 0 ) THEN                        ! flat basin
363            IF(lwp) WRITE(numout,*)
364            IF(lwp) WRITE(numout,*) '         bathymetry field: flat basin'
365            idta(:,:) = jpkm1                            ! before last level
366            zdta(:,:) = gdepw_0(jpk)                     ! last w-point depth
367            h_oce     = gdepw_0(jpk)
368         ELSE                                         ! bump centered in the basin
369            IF(lwp) WRITE(numout,*)
370            IF(lwp) WRITE(numout,*) '         bathymetry field: flat basin with a bump'
371            ii_bump = jpidta / 2                           ! i-index of the bump center
372            ij_bump = jpjdta / 2                           ! j-index of the bump center
373            r_bump  = 0.165*MIN(jpidta,jpjdta)             ! bump radius (grid cells)       
374            h_bump  =  3000._wp                            ! bump height (meters)
375            h_oce   = gdepw_0(jpk)                         ! background ocean depth (meters)
376            IF(lwp) WRITE(numout,*) '            bump characteristics: '
377            IF(lwp) WRITE(numout,*) '               bump center (i,j)   = ', ii_bump, ij_bump
378            IF(lwp) WRITE(numout,*) '               bump height         = ', h_bump , ' meters'
379            IF(lwp) WRITE(numout,*) '               bump radius         = ', r_bump , ' cells'
380            IF(lwp) WRITE(numout,*) '            background ocean depth = ', h_oce  , ' meters'
381            !                                       
382            DO jj = 1, jpjdta                              ! zdta :
383               DO ji = 1, jpidta
384                  !zi = FLOAT( ji - ii_bump ) * ppe1_m / r_bump
385                  !zj = FLOAT( jj - ij_bump ) * ppe2_m / r_bump
386                  zi = FLOAT( ji - ii_bump ) / r_bump
387                  zj = FLOAT( jj - ij_bump ) / r_bump
388                  zdta(ji,jj) = h_oce - h_bump * EXP( -( zi*zi + zj*zj ) )
389               END DO
390            END DO
391            !                                              ! idta :
392            IF( ln_sco ) THEN                                   ! s-coordinate (zsc       ): idta()=jpk
393               idta(:,:) = jpkm1
394            ELSE                                                ! z-coordinate (zco or zps): step-like topography
395               idta(:,:) = jpkm1
396               DO jk = 1, jpkm1
397                  WHERE( gdept_0(jk) < zdta(:,:) .AND. zdta(:,:) <= gdept_0(jk+1) )   idta(:,:) = jk
398               END DO
399            ENDIF
400         ENDIF
401         !                                            ! set GLOBAL boundary conditions
402         !                                            ! Caution : idta on the global domain: use of jperio, not nperio
403         IF( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 ) THEN
404            idta( :    , 1    ) = -1                ;      zdta( :    , 1    ) = -1._wp
405            idta( :    ,jpjdta) =  0                ;      zdta( :    ,jpjdta) =  0._wp
406         ELSEIF( jperio == 2 ) THEN
407            idta( :    , 1    ) = idta( : ,  3  )   ;      zdta( :    , 1    ) = zdta( : ,  3  )
408            idta( :    ,jpjdta) = 0                 ;      zdta( :    ,jpjdta) =  0._wp
409            idta( 1    , :    ) = 0                 ;      zdta( 1    , :    ) =  0._wp
410            idta(jpidta, :    ) = 0                 ;      zdta(jpidta, :    ) =  0._wp
411         ELSE
412            ih = 0                                  ;      zh = 0._wp
413            IF( ln_sco )   ih = jpkm1               ;      IF( ln_sco )   zh = h_oce
414            idta( :    , 1    ) = ih                ;      zdta( :    , 1    ) =  zh
415            idta( :    ,jpjdta) = ih                ;      zdta( :    ,jpjdta) =  zh
416            idta( 1    , :    ) = ih                ;      zdta( 1    , :    ) =  zh
417            idta(jpidta, :    ) = ih                ;      zdta(jpidta, :    ) =  zh
418         ENDIF
419
420         !                                            ! local domain level and meter bathymetries (mbathy,bathy)
421         mbathy(:,:) = 0                                   ! set to zero extra halo points
422         bathy (:,:) = 0._wp                               ! (require for mpp case)
423#if defined key_mpp_rkpart
424         DO jj = nldj, nlcj                                   ! interior values
425            DO ji = nldi, nlci
426#else
427         DO jj = 1, nlcj                                   ! interior values
428            DO ji = 1, nlci
429#endif
430               mbathy(ji,jj) = idta( mig(ji), mjg(jj) )
431               bathy (ji,jj) = zdta( mig(ji), mjg(jj) )
432            END DO
433         END DO
434         !
435         !                                            ! ================ !
436      ELSEIF( ntopo == 1 ) THEN                       !   read in file   ! (over the local domain)
437         !                                            ! ================ !
438         !
439         IF( ln_zco )   THEN                          ! zco : read level bathymetry
440            CALL iom_open ( 'bathy_level.nc', inum ) 
441            IF(is_global)THEN
442               CALL iom_get ( inum, jpdom_unknown, 'Bathymetry' , bathy, &
443                              kstart=(/jpizoom,jpjzoom/),                &
444                              kcount=(/jpiglo,jpjglo/) )
445            ELSE
446               CALL iom_get  ( inum, jpdom_data, 'Bathy_level', bathy )
447            END IF
448
449            CALL iom_close( inum )
450            mbathy(:,:) = INT( bathy(:,:) )
451            !                                                ! =====================
452            IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN    ! ORCA R2 configuration
453               !                                             ! =====================
454               IF( nn_cla == 0 ) THEN
455                  ii0 = 140   ;   ii1 = 140                  ! Gibraltar Strait open
456                  ij0 = 102   ;   ij1 = 102                  ! (Thomson, Ocean Modelling, 1995)
457                  DO ji = mi0(ii0), mi1(ii1)
458                     DO jj = mj0(ij0), mj1(ij1)
459                        mbathy(ji,jj) = 15
460                     END DO
461                  END DO
462                  IF(lwp) WRITE(numout,*)
463                  IF(lwp) WRITE(numout,*) '      orca_r2: Gibraltar strait open at i=',ii0,' j=',ij0
464                  !
465                  ii0 = 160   ;   ii1 = 160                  ! Bab el mandeb Strait open
466                  ij0 = 88    ;   ij1 = 88                   ! (Thomson, Ocean Modelling, 1995)
467                  DO ji = mi0(ii0), mi1(ii1)
468                     DO jj = mj0(ij0), mj1(ij1)
469                        mbathy(ji,jj) = 12
470                     END DO
471                  END DO
472                  IF(lwp) WRITE(numout,*)
473                  IF(lwp) WRITE(numout,*) '      orca_r2: Bab el Mandeb strait open at i=',ii0,' j=',ij0
474               ENDIF
475               !
476            ENDIF
477            !
478         ENDIF
479         IF( ln_zps .OR. ln_sco )   THEN              ! zps or sco : read meter bathymetry
480            CALL iom_open ( 'bathy_meter.nc', inum ) 
481            IF(is_global)THEN
482               CALL iom_get ( inum, jpdom_unknown, 'Bathymetry' , bathy, &
483                              kstart=(/jpizoom,jpjzoom/),                &
484                              kcount=(/jpiglo,jpjglo/) )
485            ELSE
486               CALL iom_get  ( inum, jpdom_data, 'Bathymetry', bathy )
487            END IF
488            CALL iom_close( inum )
489            !                                                ! =====================
490            IF( cp_cfg == "orca" .AND. jp_cfg == 1 ) THEN    ! ORCA R1 configuration
491               ii0 = 142   ;   ii1 = 142                     ! =====================
492               ij0 =  51   ;   ij1 =  53                     
493               DO ji = mi0(ii0), mi1(ii1)                    ! Close Halmera Strait
494                  DO jj = mj0(ij0), mj1(ij1)
495                     bathy(ji,jj) = 0._wp
496                  END DO
497               END DO
498               IF(lwp) WRITE(numout,*)
499               IF(lwp) WRITE(numout,*) '      orca_r1: Halmera strait closed at i=',ii0,' j=',ij0,'->',ij1
500            ENDIF
501            !                                                ! =====================
502            IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN    ! ORCA R2 configuration
503               !                                             ! =====================
504              IF( nn_cla == 0 ) THEN
505                 ii0 = 140   ;   ii1 = 140                   ! Gibraltar Strait open
506                 ij0 = 102   ;   ij1 = 102                   ! (Thomson, Ocean Modelling, 1995)
507                 DO ji = mi0(ii0), mi1(ii1)
508                    DO jj = mj0(ij0), mj1(ij1)
509                       bathy(ji,jj) = 284._wp
510                    END DO
511                 END DO
512                 IF(lwp) WRITE(numout,*)
513                 IF(lwp) WRITE(numout,*) '      orca_r2: Gibraltar strait open at i=',ii0,' j=',ij0
514                 !
515                 ii0 = 160   ;   ii1 = 160                   ! Bab el mandeb Strait open
516                 ij0 = 88    ;   ij1 = 88                    ! (Thomson, Ocean Modelling, 1995)
517                 DO ji = mi0(ii0), mi1(ii1)
518                    DO jj = mj0(ij0), mj1(ij1)
519                       bathy(ji,jj) = 137._wp
520                    END DO
521                 END DO
522                 IF(lwp) WRITE(numout,*)
523                 IF(lwp) WRITE(numout,*) '             orca_r2: Bab el Mandeb strait open at i=',ii0,' j=',ij0
524              ENDIF
525              !
526           ENDIF
527            !
528        ENDIF
529         !                                            ! =============== !
530      ELSE                                            !      error      !
531         !                                            ! =============== !
532         WRITE(ctmp1,*) 'parameter , ntopo = ', ntopo
533         CALL ctl_stop( '    zgr_bat : '//trim(ctmp1) )
534      ENDIF
535      !
536      !                                               ! =========================== !
537      IF( nclosea == 0 ) THEN                         !   NO closed seas or lakes   !
538         DO jl = 1, jpncs                             ! =========================== !
539            DO jj = ncsj1(jl), ncsj2(jl)
540               DO ji = ncsi1(jl), ncsi2(jl)
541                  mbathy(ji,jj) = 0                   ! suppress closed seas and lakes from bathymetry
542                  bathy (ji,jj) = 0._wp               
543               END DO
544            END DO
545         END DO
546      ENDIF
547      !
548      !                                               ! =========================== !
549      !                                               !     set a minimum depth     !
550      !                                               ! =========================== !
551      IF ( .not. ln_sco ) THEN
552         IF( rn_hmin < 0._wp ) THEN    ;   ik = - INT( rn_hmin )                                      ! from a nb of level
553         ELSE                          ;   ik = MINLOC( gdepw_0, mask = gdepw_0 > rn_hmin, dim = 1 )  ! from a depth
554         ENDIF
555         zhmin = gdepw_0(ik+1)                                                         ! minimum depth = ik+1 w-levels
556         WHERE( bathy(:,:) <= 0._wp )   ;   bathy(:,:) = 0._wp                         ! min=0     over the lands
557         ELSEWHERE                      ;   bathy(:,:) = MAX(  zhmin , bathy(:,:)  )   ! min=zhmin over the oceans
558         END WHERE
559         IF(lwp) write(numout,*) 'Minimum ocean depth: ', zhmin, ' minimum number of ocean levels : ', ik
560      ENDIF
561      !
562   END SUBROUTINE zgr_bat
563
564
565   SUBROUTINE zgr_bat_zoom
566      !!----------------------------------------------------------------------
567      !!                    ***  ROUTINE zgr_bat_zoom  ***
568      !!
569      !! ** Purpose : - Close zoom domain boundary if necessary
570      !!              - Suppress Med Sea from ORCA R2 and R05 arctic zoom
571      !!
572      !! ** Method  :
573      !!
574      !! ** Action  : - update mbathy: level bathymetry (in level index)
575      !!----------------------------------------------------------------------
576      INTEGER ::   ii0, ii1, ij0, ij1   ! temporary integers
577      !!----------------------------------------------------------------------
578      !
579      IF(lwp) WRITE(numout,*)
580      IF(lwp) WRITE(numout,*) '    zgr_bat_zoom : modify the level bathymetry for zoom domain'
581      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~'
582      !
583      ! Zoom domain
584      ! ===========
585      !
586      ! Forced closed boundary if required
587      IF( lzoom_s )   mbathy(  : , mj0(jpjzoom):mj1(jpjzoom) )      = 0
588      IF( lzoom_w )   mbathy(      mi0(jpizoom):mi1(jpizoom) , :  ) = 0
589      IF( lzoom_e )   mbathy(      mi0(jpiglo+jpizoom-1):mi1(jpiglo+jpizoom-1) , :  ) = 0
590      IF( lzoom_n )   mbathy(  : , mj0(jpjglo+jpjzoom-1):mj1(jpjglo+jpjzoom-1) )      = 0
591      !
592      ! Configuration specific domain modifications
593      ! (here, ORCA arctic configuration: suppress Med Sea)
594      IF( cp_cfg == "orca" .AND. lzoom_arct ) THEN
595         SELECT CASE ( jp_cfg )
596         !                                        ! =======================
597         CASE ( 2 )                               !  ORCA_R2 configuration
598            !                                     ! =======================
599            IF(lwp) WRITE(numout,*) '                   ORCA R2 arctic zoom: suppress the Med Sea'
600            ii0 = 141   ;   ii1 = 162      ! Sea box i,j indices
601            ij0 =  98   ;   ij1 = 110
602            !                                     ! =======================
603         CASE ( 05 )                              !  ORCA_R05 configuration
604            !                                     ! =======================
605            IF(lwp) WRITE(numout,*) '                   ORCA R05 arctic zoom: suppress the Med Sea'
606            ii0 = 563   ;   ii1 = 642      ! zero over the Med Sea boxe
607            ij0 = 314   ;   ij1 = 370 
608         END SELECT
609         !
610         mbathy( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0   ! zero over the Med Sea boxe
611         !
612      ENDIF
613      !
614   END SUBROUTINE zgr_bat_zoom
615
616
617   SUBROUTINE zgr_bat_ctl
618      !!----------------------------------------------------------------------
619      !!                    ***  ROUTINE zgr_bat_ctl  ***
620      !!
621      !! ** Purpose :   check the bathymetry in levels
622      !!
623      !! ** Method  :   The array mbathy is checked to verified its consistency
624      !!      with the model options. in particular:
625      !!            mbathy must have at least 1 land grid-points (mbathy<=0)
626      !!                  along closed boundary.
627      !!            mbathy must be cyclic IF jperio=1.
628      !!            mbathy must be lower or equal to jpk-1.
629      !!            isolated ocean grid points are suppressed from mbathy
630      !!                  since they are only connected to remaining
631      !!                  ocean through vertical diffusion.
632      !!      C A U T I O N : mbathy will be modified during the initializa-
633      !!      tion phase to become the number of non-zero w-levels of a water
634      !!      column, with a minimum value of 1.
635      !!
636      !! ** Action  : - update mbathy: level bathymetry (in level index)
637      !!              - update bathy : meter bathymetry (in meters)
638      !!----------------------------------------------------------------------
639      USE mapcomm_mod, ONLY:   trimmed, nidx,eidx,sidx,widx
640      USE wrk_nemo,    ONLY:   wrk_in_use, wrk_not_released
641      USE wrk_nemo,    ONLY:   zbathy => wrk_2d_1
642      !!
643      INTEGER ::   ji, jj, jl                    ! dummy loop indices
644      INTEGER ::   icompt, ibtest, ikmax         ! temporary integers
645      !!----------------------------------------------------------------------
646
647      IF( wrk_in_use(2, 1) ) THEN
648         CALL ctl_stop('zgr_bat_ctl: requested workspace array unavailable')   ;   RETURN
649      ENDIF
650
651      IF(lwp) WRITE(numout,*)
652      IF(lwp) WRITE(numout,*) '    zgr_bat_ctl : check the bathymetry'
653      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
654
655      !                                          ! Suppress isolated ocean grid points
656      IF(lwp) WRITE(numout,*)
657      IF(lwp) WRITE(numout,*)'                   suppress isolated ocean grid points'
658      IF(lwp) WRITE(numout,*)'                   -----------------------------------'
659      icompt = 0
660      DO jl = 1, 2
661         IF( nperio == 1 .OR. nperio  ==  4 .OR. nperio  ==  6 ) THEN
662            mbathy( 1 ,:) = mbathy(jpim1,:)           ! local domain is cyclic east-west
663            mbathy(jpi,:) = mbathy(  2  ,:)
664         ENDIF
665         DO jj = 2, jpjm1
666            DO ji = 2, jpim1
667               ibtest = MAX(  mbathy(ji-1,jj), mbathy(ji+1,jj),   &
668                  &           mbathy(ji,jj-1), mbathy(ji,jj+1)  )
669               IF( ibtest < mbathy(ji,jj) ) THEN
670                  IF(lwp) WRITE(numout,*) ' the number of ocean level at ',   &
671                     &   'grid-point (i,j) =  ',ji,jj,' is changed from ', mbathy(ji,jj),' to ', ibtest
672                  mbathy(ji,jj) = ibtest
673                  icompt = icompt + 1
674               ENDIF
675            END DO
676         END DO
677      END DO
678      IF( icompt == 0 ) THEN
679         IF(lwp) WRITE(numout,*)'     no isolated ocean grid points'
680      ELSE
681         IF(lwp) WRITE(numout,*)'    ',icompt,' ocean grid points suppressed'
682      ENDIF
683
684      IF( lk_mpp ) THEN
685         zbathy(:,:) = FLOAT( mbathy(:,:) )
686         CALL lbc_lnk( zbathy, 'T', 1._wp )
687         mbathy(:,:) = INT( zbathy(:,:) )
688      ENDIF
689
690      !                                          ! East-west cyclic boundary conditions
691      IF( nperio == 0 ) THEN
692         IF(lwp) WRITE(numout,*) ' mbathy set to 0 along east and west boundary: nperio = ', nperio
693         IF( lk_mpp ) THEN
694            IF( (nbondi == -1 .OR. nbondi == 2) .AND. (.NOT. trimmed(widx,narea) ) ) THEN
695               IF( jperio /= 1 )   mbathy(1,:) = 0
696            ENDIF
697            IF( (nbondi == 1 .OR. nbondi == 2) .AND. (.NOT. trimmed(eidx,narea) ) ) THEN
698               IF( jperio /= 1 )   mbathy(nlci,:) = 0
699            ENDIF
700         ELSE
701            IF( ln_zco .OR. ln_zps ) THEN
702               mbathy( 1 ,:) = 0
703               mbathy(jpi,:) = 0
704            ELSE
705               mbathy( 1 ,:) = jpkm1
706               mbathy(jpi,:) = jpkm1
707            ENDIF
708         ENDIF
709      ELSEIF( nperio == 1 .OR. nperio == 4 .OR. nperio ==  6 ) THEN
710         IF(lwp) WRITE(numout,*)' east-west cyclic boundary conditions on mbathy: nperio = ', nperio
711         mbathy( 1 ,:) = mbathy(jpim1,:)
712         mbathy(jpi,:) = mbathy(  2  ,:)
713      ELSEIF( nperio == 2 ) THEN
714         IF(lwp) WRITE(numout,*) '   equatorial boundary conditions on mbathy: nperio = ', nperio
715      ELSE
716         IF(lwp) WRITE(numout,*) '    e r r o r'
717         IF(lwp) WRITE(numout,*) '    parameter , nperio = ', nperio
718         !         STOP 'dom_mba'
719      ENDIF
720
721      !  Boundary condition on mbathy
722      IF( .NOT.lk_mpp ) THEN 
723!!gm     !!bug ???  think about it !
724         !   ... mono- or macro-tasking: T-point, >0, 2D array, no slab
725         zbathy(:,:) = FLOAT( mbathy(:,:) )
726         CALL lbc_lnk( zbathy, 'T', 1._wp )
727         mbathy(:,:) = INT( zbathy(:,:) )
728      ENDIF
729
730      ! Number of ocean level inferior or equal to jpkm1
731      ikmax = 0
732      DO jj = 1, jpj
733         DO ji = 1, jpi
734            ikmax = MAX( ikmax, mbathy(ji,jj) )
735         END DO
736      END DO
737!!gm  !!! test to do:   ikmax = MAX( mbathy(:,:) )   ???
738      IF( ikmax > jpkm1 ) THEN
739         IF(lwp) WRITE(numout,*) ' maximum number of ocean level = ', ikmax,' >  jpk-1'
740         IF(lwp) WRITE(numout,*) ' change jpk to ',ikmax+1,' to use the exact ead bathymetry'
741      ELSE IF( ikmax < jpkm1 ) THEN
742         IF(lwp) WRITE(numout,*) ' maximum number of ocean level = ', ikmax,' < jpk-1' 
743         IF(lwp) WRITE(numout,*) ' you can decrease jpk to ', ikmax+1
744      ENDIF
745
746      IF( lwp .AND. nprint == 1 ) THEN      ! control print
747         WRITE(numout,*)
748         WRITE(numout,*) ' bathymetric field :   number of non-zero T-levels '
749         WRITE(numout,*) ' ------------------'
750         CALL prihin( mbathy, jpi, jpj, 1, jpi, 1, 1, jpj, 1, 3, numout )
751         WRITE(numout,*)
752      ENDIF
753      !
754      IF( wrk_not_released(2, 1) )   CALL ctl_stop('zgr_bat_ctl: failed to release workspace array')
755      !
756   END SUBROUTINE zgr_bat_ctl
757
758
759   SUBROUTINE zgr_bot_level
760      !!----------------------------------------------------------------------
761      !!                    ***  ROUTINE zgr_bot_level  ***
762      !!
763      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
764      !!
765      !! ** Method  :   computes from mbathy with a minimum value of 1 over land
766      !!
767      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
768      !!                                     ocean level at t-, u- & v-points
769      !!                                     (min value = 1 over land)
770      !!----------------------------------------------------------------------
771      !USE arpdebugging, ONLY: dump_array
772      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
773      USE wrk_nemo, ONLY:   zmbk => wrk_2d_1
774      USE par_oce,  ONLY: jpkf, jpkfm1
775      !!
776      INTEGER ::   ji, jj   ! dummy loop indices
777      !!----------------------------------------------------------------------
778      !
779      IF( wrk_in_use(2, 1) ) THEN
780         CALL ctl_stop('zgr_bot_level: requested 2D workspace unavailable')   ;   RETURN
781      ENDIF
782      !
783      IF(lwp) WRITE(numout,*)
784      IF(lwp) WRITE(numout,*) '    zgr_bot_level : ocean bottom k-index of T-, U-, V- and W-levels '
785      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~'
786      !
787      !CALL dump_array(0, 'mbathy', mbathy, withHalos=.TRUE.)
788
789      mbkt(:,:) = MAX( mbathy(:,:) , 1 )    ! bottom k-index of T-level (=1 over land)
790      !                                     ! bottom k-index of W-level = mbkt+1
791      DO jj = 1, jpjm1                      ! bottom k-index of u- (v-) level
792         DO ji = 1, jpim1
793            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
794            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
795         END DO
796      END DO
797      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
798      zmbk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk(zmbk,'U',1.)   ;   mbku  (:,:) = MAX( INT( zmbk(:,:) ), 1 )
799      zmbk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk(zmbk,'V',1.)   ;   mbkv  (:,:) = MAX( INT( zmbk(:,:) ), 1 )
800      !
801      ! Compute and store the deepest bottom level of any grid-type at each grid point
802      ! For use in removing data below ocean floor from compute loops
803      mbkmax(:,:) = MAX(mbkt(:,:)+1, mbku(:,:), mbkv(:,:))
804      jpkf = MAXVAL( mbkmax(:,:) )
805      jpkfm1 = jpkf - 1
806      WRITE(*,*) narea,': ARPDBG: shallowest pt and jpkf = ', MINVAL(mbkmax(:,:)), jpkf
807
808      !
809      IF( wrk_not_released(2, 1) )   CALL ctl_stop('zgr_bot_level: failed to release workspace array')
810      !
811   END SUBROUTINE zgr_bot_level
812
813
814   SUBROUTINE zgr_zco
815      !!----------------------------------------------------------------------
816      !!                  ***  ROUTINE zgr_zco  ***
817      !!
818      !! ** Purpose :   define the z-coordinate system
819      !!
820      !! ** Method  :   set 3D coord. arrays to reference 1D array
821      !!----------------------------------------------------------------------
822#if defined key_z_first
823      INTEGER  ::   ji, jj   ! Dummy loop indices
824#else
825      INTEGER  ::   jk
826#endif
827      !!----------------------------------------------------------------------
828      !
829#if defined key_z_first
830      DO jj = 1, jpj
831         DO ji = 1, jpi
832            fsdept(ji,jj,:) = gdept_0(:)
833            fsdepw(ji,jj,:) = gdepw_0(:)
834            fsde3w(ji,jj,:) = gdepw_0(:)
835            fse3t (ji,jj,:) = e3t_0(:)
836            fse3u (ji,jj,:) = e3t_0(:)
837            fse3v (ji,jj,:) = e3t_0(:)
838            fse3f (ji,jj,:) = e3t_0(:)
839            fse3w (ji,jj,:) = e3w_0(:)
840            fse3uw(ji,jj,:) = e3w_0(:)
841            fse3vw(ji,jj,:) = e3w_0(:)
842         END DO
843      END DO
844#else
845      DO jk = 1, jpk
846         fsdept(:,:,jk) = gdept_0(jk)
847         fsdepw(:,:,jk) = gdepw_0(jk)
848         fsde3w(:,:,jk) = gdepw_0(jk)
849         fse3t (:,:,jk) = e3t_0(jk)
850         fse3u (:,:,jk) = e3t_0(jk)
851         fse3v (:,:,jk) = e3t_0(jk)
852         fse3f (:,:,jk) = e3t_0(jk)
853         fse3w (:,:,jk) = e3w_0(jk)
854         fse3uw(:,:,jk) = e3w_0(jk)
855         fse3vw(:,:,jk) = e3w_0(jk)
856      END DO
857#endif
858      !
859   END SUBROUTINE zgr_zco
860
861
862   SUBROUTINE zgr_zps(pre_domain_decomp)
863      !!----------------------------------------------------------------------
864      !!                  ***  ROUTINE zgr_zps  ***
865      !!                     
866      !! ** Purpose :   the depth and vertical scale factor in partial step
867      !!      z-coordinate case
868      !!
869      !! ** Method  :   Partial steps : computes the 3D vertical scale factors
870      !!      of T-, U-, V-, W-, UW-, VW and F-points that are associated with
871      !!      a partial step representation of bottom topography.
872      !!
873      !!        The reference depth of model levels is defined from an analytical
874      !!      function the derivative of which gives the reference vertical
875      !!      scale factors.
876      !!        From  depth and scale factors reference, we compute there new value
877      !!      with partial steps  on 3d arrays ( i, j, k ).
878      !!
879      !!              w-level: gdepw(i,j,k)  = fsdep(k)
880      !!                       e3w(i,j,k) = dk(fsdep)(k)     = fse3(i,j,k)
881      !!              t-level: gdept(i,j,k)  = fsdep(k+0.5)
882      !!                       e3t(i,j,k) = dk(fsdep)(k+0.5) = fse3(i,j,k+0.5)
883      !!
884      !!        With the help of the bathymetric file ( bathymetry_depth_ORCA_R2.nc),
885      !!      we find the mbathy index of the depth at each grid point.
886      !!      This leads us to three cases:
887      !!
888      !!              - bathy = 0 => mbathy = 0
889      !!              - 1 < mbathy < jpkm1   
890      !!              - bathy > gdepw(jpk) => mbathy = jpkm1 
891      !!
892      !!        Then, for each case, we find the new depth at t- and w- levels
893      !!      and the new vertical scale factors at t-, u-, v-, w-, uw-, vw-
894      !!      and f-points.
895      !!
896      !!        This routine is given as an example, it must be modified
897      !!      following the user s desiderata. nevertheless, the output as
898      !!      well as the way to compute the model levels and scale factors
899      !!      must be respected in order to insure second order accuracy
900      !!      schemes.
901      !!
902      !!         c a u t i o n : gdept_0, gdepw_0 and e3._0 are positives
903      !!         - - - - - - -   gdept, gdepw and e3. are positives
904      !!     
905      !!  Reference :   Pacanowsky & Gnanadesikan 1997, Mon. Wea. Rev., 126, 3248-3270.
906      !!----------------------------------------------------------------------
907      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
908      USE wrk_nemo, ONLY:   zprt => wrk_3d_1
909      !! DCSE_NEMO: wrk_3d_1 renamed, need additional directive
910!FTRANS zprt :I :I :z
911      LOGICAL, INTENT(in), OPTIONAL :: pre_domain_decomp
912      !!
913      INTEGER  ::   ji, jj, jk       ! dummy loop indices
914      INTEGER  ::   ik, it           ! temporary integers
915      LOGICAL  ::   ll_print         ! Allow  control print for debugging
916      REAL(wp) ::   ze3tp , ze3wp    ! Last ocean level thickness at T- and W-points
917      REAL(wp) ::   zdepwp, zdepth   ! Ajusted ocean depth to avoid too small e3t
918      REAL(wp) ::   zmax             ! Maximum depth
919      REAL(wp) ::   zdiff            ! temporary scalar
920      REAL(wp) ::   zrefdep          ! temporary scalar
921      !!---------------------------------------------------------------------
922      !
923      IF( wrk_in_use(3, 1) ) THEN
924         CALL ctl_stop('zgr_zps: requested workspace unavailable.')   ;   RETURN
925      ENDIF
926
927      IF(lwp) WRITE(numout,*)
928      IF(lwp) WRITE(numout,*) '    zgr_zps : z-coordinate with partial steps'
929      IF(lwp) WRITE(numout,*) '    ~~~~~~~ '
930      IF(lwp) WRITE(numout,*) '              mbathy is recomputed : bathy_level file is NOT used'
931
932      ll_print = .FALSE.                   ! Local variable for debugging
933     
934      IF(lwp .AND. ll_print) THEN          ! control print of the ocean depth
935         WRITE(numout,*)
936         WRITE(numout,*) 'dom_zgr_zps:  bathy (in hundred of meters)'
937         CALL prihre( bathy, jpi, jpj, 1,jpi, 1, 1, jpj, 1, 1.e-2, numout )
938      ENDIF
939
940
941      ! bathymetry in level (from bathy_meter)
942      ! ===================
943      zmax = gdepw_0(jpk) + e3t_0(jpk)          ! maximum depth (i.e. the last ocean level thickness <= 2*e3t_0(jpkm1) )
944      bathy(:,:) = MIN( zmax ,  bathy(:,:) )    ! bounded value of bathy (min already set at the end of zgr_bat)
945      WHERE( bathy(:,:) == 0._wp )   ;   mbathy(:,:) = 0       ! land  : set mbathy to 0
946      ELSEWHERE                     ;   mbathy(:,:) = jpkm1   ! ocean : initialize mbathy to the max ocean level
947      END WHERE
948
949      ! Compute mbathy for ocean points (i.e. the number of ocean levels)
950      ! find the number of ocean levels such that the last level thickness
951      ! is larger than the minimum of e3zps_min and e3zps_rat * e3t_0 (where
952      ! e3t_0 is the reference level thickness
953      DO jk = jpkm1, 1, -1
954         zdepth = gdepw_0(jk) + MIN( e3zps_min, e3t_0(jk)*e3zps_rat )
955         WHERE( 0._wp < bathy(:,:) .AND. bathy(:,:) <= zdepth )   mbathy(:,:) = jk-1
956      END DO
957
958      ! If we've been called before domain decomposition then we only want to compute
959      ! mbathy and the return.
960      IF( PRESENT(pre_domain_decomp) )THEN
961         IF( pre_domain_decomp )RETURN
962      ENDIF
963
964      ! Scale factors and depth at T- and W-points
965#if defined key_z_first
966      DO jj = 1, jpj
967         DO ji = 1, jpi                     ! intitialization to the reference z-coordinate
968            gdept(ji,jj,:) = gdept_0(:)
969            gdepw(ji,jj,:) = gdepw_0(:)
970            e3t  (ji,jj,:) = e3t_0  (:)
971            e3w  (ji,jj,:) = e3w_0  (:)
972         END DO
973      END DO
974#else
975      DO jk = 1, jpk                        ! intitialization to the reference z-coordinate
976         gdept(:,:,jk) = gdept_0(jk)
977         gdepw(:,:,jk) = gdepw_0(jk)
978         e3t  (:,:,jk) = e3t_0  (jk)
979         e3w  (:,:,jk) = e3w_0  (jk)
980      END DO
981#endif
982      !
983      DO jj = 1, jpj
984         DO ji = 1, jpi
985            ik = mbathy(ji,jj)
986            IF( ik > 0 ) THEN               ! ocean point only
987               ! max ocean level case
988               IF( ik == jpkm1 ) THEN
989                  zdepwp = bathy(ji,jj)
990                  ze3tp  = bathy(ji,jj) - gdepw_0(ik)
991                  ze3wp = 0.5_wp * e3w_0(ik) * ( 1._wp + ( ze3tp/e3t_0(ik) ) )
992                  e3t(ji,jj,ik  ) = ze3tp
993                  e3t(ji,jj,ik+1) = ze3tp
994                  e3w(ji,jj,ik  ) = ze3wp
995                  e3w(ji,jj,ik+1) = ze3tp
996                  gdepw(ji,jj,ik+1) = zdepwp
997                  gdept(ji,jj,ik  ) = gdept_0(ik-1) + ze3wp
998                  gdept(ji,jj,ik+1) = gdept(ji,jj,ik) + ze3tp
999                  !
1000               ELSE                         ! standard case
1001                  IF( bathy(ji,jj) <= gdepw_0(ik+1) ) THEN   ;   gdepw(ji,jj,ik+1) = bathy(ji,jj)
1002                  ELSE                                       ;   gdepw(ji,jj,ik+1) = gdepw_0(ik+1)
1003                  ENDIF
1004!gm Bug?  check the gdepw_0
1005                  !       ... on ik
1006                  gdept(ji,jj,ik) = gdepw_0(ik) + ( gdepw  (ji,jj,ik+1) - gdepw_0(ik) )   &
1007                     &                          * ((gdept_0(      ik  ) - gdepw_0(ik) )   &
1008                     &                          / ( gdepw_0(      ik+1) - gdepw_0(ik) ))
1009                  e3t  (ji,jj,ik) = e3t_0  (ik) * ( gdepw  (ji,jj,ik+1) - gdepw_0(ik) )   & 
1010                     &                          / ( gdepw_0(      ik+1) - gdepw_0(ik) ) 
1011                  e3w  (ji,jj,ik) = 0.5_wp * ( gdepw(ji,jj,ik+1) + gdepw_0(ik+1) - 2._wp * gdepw_0(ik) )   &
1012                     &                     * ( e3w_0(ik) / ( gdepw_0(ik+1) - gdepw_0(ik) ) )
1013                  !       ... on ik+1
1014                  e3w  (ji,jj,ik+1) = e3t  (ji,jj,ik)
1015                  e3t  (ji,jj,ik+1) = e3t  (ji,jj,ik)
1016                  gdept(ji,jj,ik+1) = gdept(ji,jj,ik) + e3t(ji,jj,ik)
1017               ENDIF
1018            ENDIF
1019         END DO
1020      END DO
1021      !
1022      it = 0
1023      DO jj = 1, jpj
1024         DO ji = 1, jpi
1025            ik = mbathy(ji,jj)
1026            IF( ik > 0 ) THEN               ! ocean point only
1027               e3tp (ji,jj) = e3t(ji,jj,ik  )
1028               e3wp (ji,jj) = e3w(ji,jj,ik  )
1029               ! test
1030               zdiff= gdepw(ji,jj,ik+1) - gdept(ji,jj,ik  )
1031               IF( zdiff <= 0._wp .AND. lwp ) THEN
1032                  it = it + 1
1033                  WRITE(numout,*) ' it      = ', it, ' ik      = ', ik, ' (i,j) = ', ji, jj
1034                  WRITE(numout,*) ' bathy = ', bathy(ji,jj)
1035                  WRITE(numout,*) ' gdept = ', gdept(ji,jj,ik), ' gdepw = ', gdepw(ji,jj,ik+1), ' zdiff = ', zdiff
1036                  WRITE(numout,*) ' e3tp  = ', e3t  (ji,jj,ik), ' e3wp  = ', e3w  (ji,jj,ik  )
1037               ENDIF
1038            ENDIF
1039         END DO
1040      END DO
1041
1042      ! Scale factors and depth at U-, V-, UW and VW-points
1043#if defined key_z_first
1044      DO jj = 1, jpj                        ! initialisation to z-scale factors
1045         DO ji = 1, jpi
1046            e3u (ji,jj,:) = e3t_0(:)
1047            e3v (ji,jj,:) = e3t_0(:)
1048            e3uw(ji,jj,:) = e3w_0(:)
1049            e3vw(ji,jj,:) = e3w_0(:)
1050         END DO
1051      END DO
1052#else
1053      DO jk = 1, jpk                        ! initialisation to z-scale factors
1054         e3u (:,:,jk) = e3t_0(jk)
1055         e3v (:,:,jk) = e3t_0(jk)
1056         e3uw(:,:,jk) = e3w_0(jk)
1057         e3vw(:,:,jk) = e3w_0(jk)
1058      END DO
1059#endif
1060#if defined key_z_first
1061      DO jj = 1, jpjm1
1062         DO ji = 1, jpim1
1063            DO jk = 1, jpk        ! Computed as the minimum of neighbouring scale factors
1064#else
1065      DO jk = 1,jpk               ! Computed as the minimum of neighbouring scale factors
1066         DO jj = 1, jpjm1
1067            DO ji = 1, fs_jpim1   ! vector opt.
1068#endif
1069               e3u (ji,jj,jk) = MIN( e3t(ji,jj,jk), e3t(ji+1,jj,jk) )
1070               e3v (ji,jj,jk) = MIN( e3t(ji,jj,jk), e3t(ji,jj+1,jk) )
1071               e3uw(ji,jj,jk) = MIN( e3w(ji,jj,jk), e3w(ji+1,jj,jk) )
1072               e3vw(ji,jj,jk) = MIN( e3w(ji,jj,jk), e3w(ji,jj+1,jk) )
1073            END DO
1074         END DO
1075      END DO
1076      CALL lbc_lnk( e3u , 'U', 1._wp )   ;   CALL lbc_lnk( e3uw, 'U', 1._wp )   ! lateral boundary conditions
1077      CALL lbc_lnk( e3v , 'V', 1._wp )   ;   CALL lbc_lnk( e3vw, 'V', 1._wp )
1078      !
1079      DO jk = 1, jpk                        ! set to z-scale factor if zero (i.e. along closed boundaries)
1080         WHERE( e3u (:,:,jk) == 0._wp )   e3u (:,:,jk) = e3t_0(jk)
1081         WHERE( e3v (:,:,jk) == 0._wp )   e3v (:,:,jk) = e3t_0(jk)
1082         WHERE( e3uw(:,:,jk) == 0._wp )   e3uw(:,:,jk) = e3w_0(jk)
1083         WHERE( e3vw(:,:,jk) == 0._wp )   e3vw(:,:,jk) = e3w_0(jk)
1084      END DO
1085     
1086      ! Scale factor at F-point
1087#if defined key_z_first
1088      DO jj = 1, jpj
1089         DO ji = 1, jpi                     ! initialisation to z-scale factors
1090            e3f(ji,jj,:) = e3t_0(:)
1091         END DO
1092      END DO
1093      DO jj = 1, jpjm1
1094         DO ji = 1, jpim1                   ! NO vector opt.
1095            DO jk = 1, jpk                  ! Computed as the minimum of neighbooring V-scale factors
1096               e3f(ji,jj,jk) = MIN( e3v(ji,jj,jk), e3v(ji+1,jj,jk) )
1097            END DO
1098         END DO
1099      END DO
1100#else
1101      DO jk = 1, jpk                        ! initialisation to z-scale factors
1102         e3f(:,:,jk) = e3t_0(jk)
1103      END DO
1104      DO jk = 1, jpk                        ! Computed as the minimum of neighbooring V-scale factors
1105         DO jj = 1, jpjm1
1106            DO ji = 1, fs_jpim1   ! vector opt.
1107               e3f(ji,jj,jk) = MIN( e3v(ji,jj,jk), e3v(ji+1,jj,jk) )
1108            END DO
1109         END DO
1110      END DO
1111#endif
1112      CALL lbc_lnk( e3f, 'F', 1._wp )       ! Lateral boundary conditions
1113      !
1114      DO jk = 1, jpk                        ! set to z-scale factor if zero (i.e. along closed boundaries)
1115         WHERE( e3f(:,:,jk) == 0._wp )   e3f(:,:,jk) = e3t_0(jk)
1116      END DO
1117!!gm  bug ? :  must be a do loop with mj0,mj1
1118      !
1119      e3t(:,mj0(1),:) = e3t(:,mj0(2),:)     ! we duplicate factor scales for jj = 1 and jj = 2
1120      e3w(:,mj0(1),:) = e3w(:,mj0(2),:) 
1121      e3u(:,mj0(1),:) = e3u(:,mj0(2),:) 
1122      e3v(:,mj0(1),:) = e3v(:,mj0(2),:) 
1123      e3f(:,mj0(1),:) = e3f(:,mj0(2),:) 
1124
1125      ! Control of the sign
1126      IF( MINVAL( e3t  (:,:,:) ) <= 0._wp )   CALL ctl_stop( '    zgr_zps :   e r r o r   e3t   <= 0' )
1127      IF( MINVAL( e3w  (:,:,:) ) <= 0._wp )   CALL ctl_stop( '    zgr_zps :   e r r o r   e3w   <= 0' )
1128      IF( MINVAL( gdept(:,:,:) ) <  0._wp )   CALL ctl_stop( '    zgr_zps :   e r r o r   gdepw <  0' )
1129      IF( MINVAL( gdepw(:,:,:) ) <  0._wp )   CALL ctl_stop( '    zgr_zps :   e r r o r   gdepw <  0' )
1130     
1131      ! Compute gdep3w (vertical sum of e3w)
1132      gdep3w(:,:,1) = 0.5_wp * e3w(:,:,1)
1133      DO jk = 2, jpk
1134         gdep3w(:,:,jk) = gdep3w(:,:,jk-1) + e3w(:,:,jk) 
1135      END DO
1136       
1137      !                                               ! ================= !
1138      IF(lwp .AND. ll_print) THEN                     !   Control print   !
1139         !                                            ! ================= !
1140         DO jj = 1,jpj
1141            DO ji = 1, jpi
1142               ik = MAX( mbathy(ji,jj), 1 )
1143               zprt(ji,jj,1) = e3t   (ji,jj,ik)
1144               zprt(ji,jj,2) = e3w   (ji,jj,ik)
1145               zprt(ji,jj,3) = e3u   (ji,jj,ik)
1146               zprt(ji,jj,4) = e3v   (ji,jj,ik)
1147               zprt(ji,jj,5) = e3f   (ji,jj,ik)
1148               zprt(ji,jj,6) = gdep3w(ji,jj,ik)
1149            END DO
1150         END DO
1151         WRITE(numout,*)
1152         WRITE(numout,*) 'domzgr e3t(mbathy)'      ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1153         WRITE(numout,*)
1154         WRITE(numout,*) 'domzgr e3w(mbathy)'      ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1155         WRITE(numout,*)
1156         WRITE(numout,*) 'domzgr e3u(mbathy)'      ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1157         WRITE(numout,*)
1158         WRITE(numout,*) 'domzgr e3v(mbathy)'      ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1159         WRITE(numout,*)
1160         WRITE(numout,*) 'domzgr e3f(mbathy)'      ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1161         WRITE(numout,*)
1162         WRITE(numout,*) 'domzgr gdep3w(mbathy)'   ;   CALL prihre(zprt(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
1163      ENDIF 
1164      !
1165      IF( wrk_not_released(3, 1) )   CALL ctl_stop('zgr_zps: failed to release workspace')
1166      !
1167   END SUBROUTINE zgr_zps
1168
1169
1170   FUNCTION fssig( pk ) RESULT( pf )
1171      !!----------------------------------------------------------------------
1172      !!                 ***  ROUTINE eos_init  ***
1173      !!       
1174      !! ** Purpose :   provide the analytical function in s-coordinate
1175      !!         
1176      !! ** Method  :   the function provide the non-dimensional position of
1177      !!                T and W (i.e. between 0 and 1)
1178      !!                T-points at integer values (between 1 and jpk)
1179      !!                W-points at integer values - 1/2 (between 0.5 and jpk-0.5)
1180      !!----------------------------------------------------------------------
1181      REAL(wp), INTENT(in) ::   pk   ! continuous "k" coordinate
1182      REAL(wp)             ::   pf   ! sigma value
1183      !!----------------------------------------------------------------------
1184      !
1185      pf =   (   TANH( rn_theta * ( -(pk-0.5_wp) / REAL(jpkm1) + rn_thetb )  )   &
1186         &     - TANH( rn_thetb * rn_theta                                )  )   &
1187         & * (   COSH( rn_theta                           )                      &
1188         &     + COSH( rn_theta * ( 2._wp * rn_thetb - 1._wp ) )  )              &
1189         & / ( 2._wp * SINH( rn_theta ) )
1190      !
1191   END FUNCTION fssig
1192
1193
1194   FUNCTION fssig1( pk1, pbb ) RESULT( pf1 )
1195      !!----------------------------------------------------------------------
1196      !!                 ***  ROUTINE eos_init  ***
1197      !!
1198      !! ** Purpose :   provide the Song and Haidvogel version of the analytical function in s-coordinate
1199      !!
1200      !! ** Method  :   the function provides the non-dimensional position of
1201      !!                T and W (i.e. between 0 and 1)
1202      !!                T-points at integer values (between 1 and jpk)
1203      !!                W-points at integer values - 1/2 (between 0.5 and jpk-0.5)
1204      !!----------------------------------------------------------------------
1205      REAL(wp), INTENT(in) ::   pk1   ! continuous "k" coordinate
1206      REAL(wp), INTENT(in) ::   pbb   ! Stretching coefficient
1207      REAL(wp)             ::   pf1   ! sigma value
1208      !!----------------------------------------------------------------------
1209      !
1210      IF ( rn_theta == 0 ) then      ! uniform sigma
1211         pf1 = - ( pk1 - 0.5_wp ) / REAL( jpkm1 )
1212      ELSE                        ! stretched sigma
1213         pf1 =   ( 1._wp - pbb ) * ( SINH( rn_theta*(-(pk1-0.5_wp)/REAL(jpkm1)) ) ) / SINH( rn_theta )              &
1214            &  + pbb * (  (TANH( rn_theta*( (-(pk1-0.5_wp)/REAL(jpkm1)) + 0.5_wp) ) - TANH( 0.5_wp * rn_theta )  )  &
1215            &        / ( 2._wp * TANH( 0.5_wp * rn_theta ) )  )
1216      ENDIF
1217      !
1218   END FUNCTION fssig1
1219
1220
1221   SUBROUTINE zgr_sco
1222      !!----------------------------------------------------------------------
1223      !!                  ***  ROUTINE zgr_sco  ***
1224      !!                     
1225      !! ** Purpose :   define the s-coordinate system
1226      !!
1227      !! ** Method  :   s-coordinate
1228      !!         The depth of model levels is defined as the product of an
1229      !!      analytical function by the local bathymetry, while the vertical
1230      !!      scale factors are defined as the product of the first derivative
1231      !!      of the analytical function by the bathymetry.
1232      !!      (this solution save memory as depth and scale factors are not
1233      !!      3d fields)
1234      !!          - Read bathymetry (in meters) at t-point and compute the
1235      !!         bathymetry at u-, v-, and f-points.
1236      !!            hbatu = mi( hbatt )
1237      !!            hbatv = mj( hbatt )
1238      !!            hbatf = mi( mj( hbatt ) )
1239      !!          - Compute gsigt, gsigw, esigt, esigw from an analytical
1240      !!         function and its derivative given as function.
1241      !!            gsigt(k) = fssig (k    )
1242      !!            gsigw(k) = fssig (k-0.5)
1243      !!            esigt(k) = fsdsig(k    )
1244      !!            esigw(k) = fsdsig(k-0.5)
1245      !!      This routine is given as an example, it must be modified
1246      !!      following the user s desiderata. nevertheless, the output as
1247      !!      well as the way to compute the model levels and scale factors
1248      !!      must be respected in order to insure second order a!!uracy
1249      !!      schemes.
1250      !!
1251      !! Reference : Madec, Lott, Delecluse and Crepon, 1996. JPO, 26, 1393-1408.
1252      !!----------------------------------------------------------------------
1253      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
1254      USE wrk_nemo, ONLY:   zenv => wrk_2d_1 , ztmp => wrk_2d_2 , zmsk  => wrk_2d_3
1255      USE wrk_nemo, ONLY:   ztmp2 => wrk_2d_4 , zhbat => wrk_2d_5
1256      USE wrk_nemo, ONLY:   gsigw3  => wrk_3d_1
1257      USE wrk_nemo, ONLY:   gsigt3  => wrk_3d_2
1258      USE wrk_nemo, ONLY:   gsi3w3  => wrk_3d_3
1259      USE wrk_nemo, ONLY:   esigt3  => wrk_3d_4
1260      USE wrk_nemo, ONLY:   esigw3  => wrk_3d_5
1261      USE wrk_nemo, ONLY:   esigtu3 => wrk_3d_6
1262      USE wrk_nemo, ONLY:   esigtv3 => wrk_3d_7
1263      USE wrk_nemo, ONLY:   esigtf3 => wrk_3d_8
1264      USE wrk_nemo, ONLY:   esigwu3 => wrk_3d_9
1265      USE wrk_nemo, ONLY:   esigwv3 => wrk_3d_10
1266      USE mapcomm_mod, ONLY: trimmed, cyclic_bc
1267      USE mapcomm_mod, ONLY: nidx, eidx, sidx, widx
1268
1269      !! DCSE_NEMO: wrk_nemo module variables renamed, need additional directives
1270!FTRANS gsigw3 :I :I :z
1271!FTRANS gsigt3 :I :I :z
1272!FTRANS gsi3w3 :I :I :z
1273!FTRANS esigt3 :I :I :z
1274!FTRANS esigw3 :I :I :z
1275!FTRANS esigtu3 :I :I :z
1276!FTRANS esigtv3 :I :I :z
1277!FTRANS esigtf3 :I :I :z
1278!FTRANS esigwu3 :I :I :z
1279!FTRANS esigwv3 :I :I :z
1280      !
1281      INTEGER  ::   ji, jj, jk, jl           ! dummy loop argument
1282      INTEGER  ::   iip1, ijp1, iim1, ijm1   ! temporary integers
1283      REAL(wp) ::   zcoeft, zcoefw, zrmax, ztaper, zri, zrj   ! temporary scalars
1284      REAL(wp), PARAMETER :: TOL_ZERO = 1.0E-20_wp ! Any value less than this assumed zero
1285      !
1286
1287!      NAMELIST/namzgr_sco/ rn_sbot_max, rn_sbot_min, rn_theta, rn_thetb, rn_rmax, ln_s_sigma, rn_bb, rn_hc
1288      !!----------------------------------------------------------------------
1289
1290      IF( wrk_in_use(2, 1,2,3,4,5) .OR. wrk_in_use(3, 1,2,3,4,5,6,7,8,9,10) ) THEN
1291         CALL ctl_stop('zgr_sco: ERROR - requested workspace arrays unavailable')   ;   RETURN
1292      ENDIF
1293
1294      REWIND( numnam )                       ! Read Namelist namzgr_sco : sigma-stretching parameters
1295      READ  ( numnam, namzgr_sco )
1296
1297      IF(lwp) THEN                           ! control print
1298         WRITE(numout,*)
1299         WRITE(numout,*) 'dom:zgr_sco : s-coordinate or hybrid z-s-coordinate'
1300         WRITE(numout,*) '~~~~~~~~~~~'
1301         WRITE(numout,*) '   Namelist namzgr_sco'
1302         WRITE(numout,*) '      sigma-stretching coeffs '
1303         WRITE(numout,*) '      maximum depth of s-bottom surface (>0)       rn_sbot_max   = ' ,rn_sbot_max
1304         WRITE(numout,*) '      minimum depth of s-bottom surface (>0)       rn_sbot_min   = ' ,rn_sbot_min
1305         WRITE(numout,*) '      surface control parameter (0<=rn_theta<=20)  rn_theta      = ', rn_theta
1306         WRITE(numout,*) '      bottom  control parameter (0<=rn_thetb<= 1)  rn_thetb      = ', rn_thetb
1307         WRITE(numout,*) '      maximum cut-off r-value allowed              rn_rmax       = ', rn_rmax
1308         WRITE(numout,*) '      Hybrid s-sigma-coordinate                    ln_s_sigma    = ', ln_s_sigma
1309         WRITE(numout,*) '      stretching parameter (song and haidvogel)    rn_bb         = ', rn_bb
1310         WRITE(numout,*) '      Critical depth                               rn_hc         = ', rn_hc
1311      ENDIF
1312
1313      gsigw3  = 0._wp   ;   gsigt3  = 0._wp   ;   gsi3w3  = 0._wp
1314      esigt3  = 0._wp   ;   esigw3  = 0._wp 
1315      esigtu3 = 0._wp   ;   esigtv3 = 0._wp   ;   esigtf3 = 0._wp
1316      esigwu3 = 0._wp   ;   esigwv3 = 0._wp
1317
1318      hift(:,:) = rn_sbot_min                     ! set the minimum depth for the s-coordinate
1319      hifu(:,:) = rn_sbot_min
1320      hifv(:,:) = rn_sbot_min
1321      hiff(:,:) = rn_sbot_min
1322
1323      !                                        ! set maximum ocean depth
1324      bathy(:,:) = MIN( rn_sbot_max, bathy(:,:) )
1325
1326      DO jj = 1, jpj
1327         DO ji = 1, jpi
1328           IF( bathy(ji,jj) > 0._wp )   bathy(ji,jj) = MAX( rn_sbot_min, bathy(ji,jj) )
1329         END DO
1330      END DO
1331      !                                        ! =============================
1332      !                                        ! Define the envelop bathymetry   (hbatt)
1333      !                                        ! =============================
1334      ! use r-value to create hybrid coordinates
1335      DO jj = 1, jpj
1336         DO ji = 1, jpi
1337            zenv(ji,jj) = MAX( bathy(ji,jj), rn_sbot_min )
1338         END DO
1339      END DO
1340
1341      CALL lbc_lnk( zenv, 'T', 1._wp, lzero=.FALSE. )
1342      !
1343      ! Smooth the bathymetry (if required)
1344      scosrf(:,:) = 0._wp             ! ocean surface depth (here zero: no under ice-shelf sea)
1345      scobot(:,:) = bathy(:,:)        ! ocean bottom  depth
1346      !
1347      jl = 0
1348      zrmax = 1._wp
1349      !                                                     ! ================ !
1350      DO WHILE( jl <= 10000 .AND. zrmax > rn_rmax )         !  Iterative loop  !
1351         !                                                  ! ================ !
1352         jl = jl + 1
1353         zrmax = 0._wp
1354         zmsk(:,:) = 0._wp
1355
1356         DO jj = 1, nlcj
1357            DO ji = 1, nlci
1358               iip1 = MIN( ji+1, nlci )      ! force zri = 0 on last line (ji=ncli+1 to jpi)
1359               ijp1 = MIN( jj+1, nlcj )      ! force zrj = 0 on last row  (jj=nclj+1 to jpj)
1360               zri = ABS( zenv(iip1,jj  ) - zenv(ji,jj) ) / ( zenv(iip1,jj  ) + zenv(ji,jj) )
1361               zrj = ABS( zenv(ji  ,ijp1) - zenv(ji,jj) ) / ( zenv(ji  ,ijp1) + zenv(ji,jj) )
1362               zrmax = MAX( zrmax, zri, zrj )
1363               IF( zri > rn_rmax )   zmsk(ji  ,jj  ) = 1._wp
1364               IF( zri > rn_rmax )   zmsk(iip1,jj  ) = 1._wp
1365               IF( zrj > rn_rmax )   zmsk(ji  ,jj  ) = 1._wp
1366               IF( zrj > rn_rmax )   zmsk(ji  ,ijp1) = 1._wp
1367            END DO
1368         END DO
1369
1370         ! lateral boundary condition on zmsk: retain any 1's along closed
1371         ! boundary (use of lzero flag to lbc_lnk)
1372         CALL lbc_lnk( zmsk, 'T', 1._wp, lzero=.FALSE. )
1373
1374         IF( lk_mpp )   CALL mpp_max( zrmax )   ! max over the global domain
1375         !
1376         IF(lwp)WRITE(numout,"('zgr_sco : iter=',I5,' rmax=',F8.4,' nb of pt= ',I8)") &
1377                                                         jl, zrmax, INT( SUM(zmsk(:,:) ) )
1378         !
1379
1380         ! Copy current surface before next smoothing iteration
1381         ztmp(:,:) = zenv(:,:)
1382
1383         DO jj = nldj, nlcj
1384            DO ji = nldi, nlci
1385               iip1 = MIN( ji+1, nlci )     ! last  line (ji=nlci)
1386               ijp1 = MIN( jj+1, nlcj )     ! last  raw  (jj=nlcj)
1387               iim1 = MAX( ji-1,  1  )      ! first line (ji=nlci)
1388               ijm1 = MAX( jj-1,  1  )      ! first raw  (jj=nlcj)
1389               IF( zmsk(ji,jj) == 1._wp ) THEN
1390                  ztmp(ji,jj) =   (                                                                                   &
1391             &      zenv(iim1,ijp1)*zmsk(iim1,ijp1) + zenv(ji,ijp1)*zmsk(ji,ijp1) + zenv(iip1,ijp1)*zmsk(iip1,ijp1)   &
1392             &    + zenv(iim1,jj  )*zmsk(iim1,jj  ) + zenv(ji,jj  )*    2._wp     + zenv(iip1,jj  )*zmsk(iip1,jj  )   &
1393             &    + zenv(iim1,ijm1)*zmsk(iim1,ijm1) + zenv(ji,ijm1)*zmsk(ji,ijm1) + zenv(iip1,ijm1)*zmsk(iip1,ijm1)   &
1394             &                    ) / (                                                                               &
1395             &                      zmsk(iim1,ijp1) +               zmsk(ji,ijp1) +                 zmsk(iip1,ijp1)   &
1396             &    +                 zmsk(iim1,jj  ) +                   2._wp     +                 zmsk(iip1,jj  )   &
1397             &    +                 zmsk(iim1,ijm1) +               zmsk(ji,ijm1) +                 zmsk(iip1,ijm1)   &
1398             &                        )
1399               ENDIF
1400            END DO
1401         END DO
1402         !
1403
1404         ! Need to update halos of ztmp here but do not zero halos on closed
1405         ! boundaries
1406         CALL lbc_lnk( ztmp, 'T', 1._wp, lzero=.FALSE.)
1407
1408         DO jj = 1,nlcj
1409            DO ji = 1,nlci
1410               IF( zmsk(ji,jj) >= 1._wp-TOL_ZERO ) zenv(ji,jj) = MAX( ztmp(ji,jj), bathy(ji,jj) )
1411            END DO
1412         END DO
1413         !
1414         ! Apply lateral boundary condition but do not zero on closed boundaries
1415         CALL lbc_lnk( zenv, 'T', 1._wp, lzero=.FALSE. )
1416
1417         !                                                  ! ================ !
1418      END DO                                                !     End loop     !
1419      !                                                     ! ================ !
1420      !
1421      !                                        ! envelop bathymetry saved in hbatt
1422      hbatt(:,:) = zenv(:,:) 
1423      IF( MINVAL( gphit(:,:) ) * MAXVAL( gphit(:,:) ) <= 0._wp ) THEN
1424         CALL ctl_warn( ' s-coordinates are tapered in vicinity of the Equator' )
1425         DO jj = 1, jpj
1426            DO ji = 1, jpi
1427               ztaper = EXP( -(gphit(ji,jj)/8._wp)**2 )
1428               hbatt(ji,jj) = rn_sbot_max * ztaper + hbatt(ji,jj) * ( 1._wp - ztaper )
1429            END DO
1430         END DO
1431      ENDIF
1432      !
1433      IF(lwp) THEN                             ! Control print
1434         WRITE(numout,*)
1435         WRITE(numout,*) ' domzgr: hbatt field; ocean depth in meters'
1436         WRITE(numout,*)
1437         CALL prihre( hbatt(1,1), jpi, jpj, 1, jpi, 1, 1, jpj, 1, 0._wp, numout )
1438         IF( nprint == 1 )   THEN       
1439            WRITE(numout,*) ' bathy  MAX ', MAXVAL( bathy(:,:) ), ' MIN ', MINVAL( bathy(:,:) )
1440            WRITE(numout,*) ' hbatt  MAX ', MAXVAL( hbatt(:,:) ), ' MIN ', MINVAL( hbatt(:,:) )
1441         ENDIF
1442      ENDIF
1443
1444!      CALL dump_array(0, 'hbatt', hbatt, withHalos=.FALSE.)
1445
1446      !                                        ! ==============================
1447      !                                        !   hbatu, hbatv, hbatf fields
1448      !                                        ! ==============================
1449      IF(lwp) THEN
1450         WRITE(numout,*)
1451         WRITE(numout,*) ' zgr_sco: minimum depth of the envelop topography set to : ', rn_sbot_min
1452      ENDIF
1453      hbatu(:,:) = rn_sbot_min
1454      hbatv(:,:) = rn_sbot_min
1455      hbatf(:,:) = rn_sbot_min
1456      DO jj = 1, jpjm1
1457        DO ji = 1, jpim1   ! NO vector opt.
1458           hbatu(ji,jj) = 0.50_wp * ( hbatt(ji  ,jj) + hbatt(ji+1,jj  ) )
1459           hbatv(ji,jj) = 0.50_wp * ( hbatt(ji  ,jj) + hbatt(ji  ,jj+1) )
1460           hbatf(ji,jj) = 0.25_wp * ( hbatt(ji  ,jj) + hbatt(ji  ,jj+1)   &
1461              &                     + hbatt(ji+1,jj) + hbatt(ji+1,jj+1) )
1462        END DO
1463      END DO
1464      !
1465      ! Apply lateral boundary condition
1466!!gm  ! CAUTION: retain non zero value in the initial file this should be OK for orca cfg, not for EEL
1467      zhbat(:,:) = hbatu(:,:)   ;   CALL lbc_lnk( hbatu, 'U', 1._wp )
1468      DO jj = 1, jpj
1469         DO ji = 1, jpi
1470            IF( hbatu(ji,jj) == 0._wp ) THEN
1471               IF( zhbat(ji,jj) == 0._wp )   hbatu(ji,jj) = rn_sbot_min
1472               IF( zhbat(ji,jj) /= 0._wp )   hbatu(ji,jj) = zhbat(ji,jj)
1473            ENDIF
1474         END DO
1475      END DO
1476      zhbat(:,:) = hbatv(:,:)   ;   CALL lbc_lnk( hbatv, 'V', 1._wp )
1477      DO jj = 1, jpj
1478         DO ji = 1, jpi
1479            IF( hbatv(ji,jj) == 0._wp ) THEN
1480               IF( zhbat(ji,jj) == 0._wp )   hbatv(ji,jj) = rn_sbot_min
1481               IF( zhbat(ji,jj) /= 0._wp )   hbatv(ji,jj) = zhbat(ji,jj)
1482            ENDIF
1483         END DO
1484      END DO
1485      zhbat(:,:) = hbatf(:,:)   ;   CALL lbc_lnk( hbatf, 'F', 1._wp )
1486      DO jj = 1, jpj
1487         DO ji = 1, jpi
1488            IF( hbatf(ji,jj) == 0._wp ) THEN
1489               IF( zhbat(ji,jj) == 0._wp )   hbatf(ji,jj) = rn_sbot_min
1490               IF( zhbat(ji,jj) /= 0._wp )   hbatf(ji,jj) = zhbat(ji,jj)
1491            ENDIF
1492         END DO
1493      END DO
1494
1495!!bug:  key_helsinki a verifer
1496      hift(:,:) = MIN( hift(:,:), hbatt(:,:) )
1497      hifu(:,:) = MIN( hifu(:,:), hbatu(:,:) )
1498      hifv(:,:) = MIN( hifv(:,:), hbatv(:,:) )
1499      hiff(:,:) = MIN( hiff(:,:), hbatf(:,:) )
1500
1501      IF( nprint == 1 .AND. lwp )   THEN
1502         WRITE(numout,*) ' MAX val hif   t ', MAXVAL( hift (:,:) ), ' f ', MAXVAL( hiff (:,:) ),  &
1503            &                        ' u ',   MAXVAL( hifu (:,:) ), ' v ', MAXVAL( hifv (:,:) )
1504         WRITE(numout,*) ' MIN val hif   t ', MINVAL( hift (:,:) ), ' f ', MINVAL( hiff (:,:) ),  &
1505            &                        ' u ',   MINVAL( hifu (:,:) ), ' v ', MINVAL( hifv (:,:) )
1506         WRITE(numout,*) ' MAX val hbat  t ', MAXVAL( hbatt(:,:) ), ' f ', MAXVAL( hbatf(:,:) ),  &
1507            &                        ' u ',   MAXVAL( hbatu(:,:) ), ' v ', MAXVAL( hbatv(:,:) )
1508         WRITE(numout,*) ' MIN val hbat  t ', MINVAL( hbatt(:,:) ), ' f ', MINVAL( hbatf(:,:) ),  &
1509            &                        ' u ',   MINVAL( hbatu(:,:) ), ' v ', MINVAL( hbatv(:,:) )
1510      ENDIF
1511!! helsinki
1512
1513      !                                            ! =======================
1514      !                                            !   s-ccordinate fields     (gdep., e3.)
1515      !                                            ! =======================
1516      !
1517      ! non-dimensional "sigma" for model level depth at w- and t-levels
1518
1519      IF( ln_s_sigma ) THEN        ! Song and Haidvogel style stretched sigma for depths
1520         !                         ! below rn_hc, with uniform sigma in shallower waters
1521         DO ji = 1, jpi
1522            DO jj = 1, jpj
1523
1524               IF( hbatt(ji,jj) > rn_hc ) THEN    !deep water, stretched sigma
1525                  DO jk = 1, jpk
1526                     gsigw3(ji,jj,jk) = -fssig1( REAL(jk,wp)-0.5_wp, rn_bb )
1527                     gsigt3(ji,jj,jk) = -fssig1( REAL(jk,wp)       , rn_bb )
1528                  END DO
1529               ELSE ! shallow water, uniform sigma
1530                  DO jk = 1, jpk
1531                     gsigw3(ji,jj,jk) =   REAL(jk-1,wp)            / REAL(jpk-1,wp)
1532                     gsigt3(ji,jj,jk) = ( REAL(jk-1,wp) + 0.5_wp ) / REAL(jpk-1,wp)
1533                  END DO
1534               ENDIF
1535               IF( nprint == 1 .AND. lwp )   WRITE(numout,*) 'gsigw3 1 jpk    ', gsigw3(ji,jj,1), gsigw3(ji,jj,jpk)
1536               !
1537               DO jk = 1, jpkm1
1538                  esigt3(ji,jj,jk  ) = gsigw3(ji,jj,jk+1) - gsigw3(ji,jj,jk)
1539                  esigw3(ji,jj,jk+1) = gsigt3(ji,jj,jk+1) - gsigt3(ji,jj,jk)
1540               END DO
1541               esigw3(ji,jj,1  ) = 2._wp * ( gsigt3(ji,jj,1  ) - gsigw3(ji,jj,1  ) )
1542               esigt3(ji,jj,jpk) = 2._wp * ( gsigt3(ji,jj,jpk) - gsigw3(ji,jj,jpk) )
1543               !
1544               ! Coefficients for vertical depth as the sum of e3w scale factors
1545               gsi3w3(ji,jj,1) = 0.5_wp * esigw3(ji,jj,1)
1546               DO jk = 2, jpk
1547                  gsi3w3(ji,jj,jk) = gsi3w3(ji,jj,jk-1) + esigw3(ji,jj,jk)
1548               END DO
1549               !
1550               DO jk = 1, jpk
1551                  zcoeft = ( REAL(jk,wp) - 0.5_wp ) / REAL(jpkm1,wp)
1552                  zcoefw = ( REAL(jk,wp) - 1.0_wp ) / REAL(jpkm1,wp)
1553                  gdept (ji,jj,jk) = ( scosrf(ji,jj) + (hbatt(ji,jj)-rn_hc)*gsigt3(ji,jj,jk)+rn_hc*zcoeft )
1554                  gdepw (ji,jj,jk) = ( scosrf(ji,jj) + (hbatt(ji,jj)-rn_hc)*gsigw3(ji,jj,jk)+rn_hc*zcoefw )
1555                  gdep3w(ji,jj,jk) = ( scosrf(ji,jj) + (hbatt(ji,jj)-rn_hc)*gsi3w3(ji,jj,jk)+rn_hc*zcoeft )
1556               END DO
1557               !
1558            END DO   ! for all jj's
1559         END DO    ! for all ji's
1560
1561         DO ji = 1, jpim1
1562            DO jj = 1, jpjm1
1563               DO jk = 1, jpk
1564                  esigtu3(ji,jj,jk) = ( hbatt(ji,jj)*esigt3(ji,jj,jk)+hbatt(ji+1,jj)*esigt3(ji+1,jj,jk) )   &
1565                     &              / ( hbatt(ji,jj)+hbatt(ji+1,jj) )
1566                  esigtv3(ji,jj,jk) = ( hbatt(ji,jj)*esigt3(ji,jj,jk)+hbatt(ji,jj+1)*esigt3(ji,jj+1,jk) )   &
1567                     &              / ( hbatt(ji,jj)+hbatt(ji,jj+1) )
1568                  esigtf3(ji,jj,jk) = ( hbatt(ji,jj)*esigt3(ji,jj,jk)+hbatt(ji+1,jj)*esigt3(ji+1,jj,jk)     &
1569                     &                + hbatt(ji,jj+1)*esigt3(ji,jj+1,jk)+hbatt(ji+1,jj+1)*esigt3(ji+1,jj+1,jk) )   &
1570                     &              / ( hbatt(ji,jj)+hbatt(ji+1,jj)+hbatt(ji,jj+1)+hbatt(ji+1,jj+1) )
1571                  esigwu3(ji,jj,jk) = ( hbatt(ji,jj)*esigw3(ji,jj,jk)+hbatt(ji+1,jj)*esigw3(ji+1,jj,jk) )   &
1572                     &              / ( hbatt(ji,jj)+hbatt(ji+1,jj) )
1573                  esigwv3(ji,jj,jk) = ( hbatt(ji,jj)*esigw3(ji,jj,jk)+hbatt(ji,jj+1)*esigw3(ji,jj+1,jk) )   &
1574                     &              / ( hbatt(ji,jj)+hbatt(ji,jj+1) )
1575                  !
1576                  e3t(ji,jj,jk) = ( (hbatt(ji,jj)-rn_hc)*esigt3 (ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1577                  e3u(ji,jj,jk) = ( (hbatu(ji,jj)-rn_hc)*esigtu3(ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1578                  e3v(ji,jj,jk) = ( (hbatv(ji,jj)-rn_hc)*esigtv3(ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1579                  e3f(ji,jj,jk) = ( (hbatf(ji,jj)-rn_hc)*esigtf3(ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1580                  !
1581                  e3w (ji,jj,jk) = ( (hbatt(ji,jj)-rn_hc)*esigw3 (ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1582                  e3uw(ji,jj,jk) = ( (hbatu(ji,jj)-rn_hc)*esigwu3(ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1583                  e3vw(ji,jj,jk) = ( (hbatv(ji,jj)-rn_hc)*esigwv3(ji,jj,jk) + rn_hc/FLOAT(jpkm1) )
1584               END DO
1585            END DO
1586         END DO
1587
1588         CALL lbc_lnk( e3t , 'T', 1._wp )
1589         CALL lbc_lnk( e3u , 'U', 1._wp )
1590         CALL lbc_lnk( e3v , 'V', 1._wp )
1591         CALL lbc_lnk( e3f , 'F', 1._wp )
1592         CALL lbc_lnk( e3w , 'W', 1._wp )
1593         CALL lbc_lnk( e3uw, 'U', 1._wp )
1594         CALL lbc_lnk( e3vw, 'V', 1._wp )
1595
1596         !
1597      ELSE   ! not ln_s_sigma
1598         !
1599         DO jk = 1, jpk
1600           gsigw(jk) = -fssig( REAL(jk,wp)-0.5_wp )
1601           gsigt(jk) = -fssig( REAL(jk,wp)        )
1602         END DO
1603         IF( nprint == 1 .AND. lwp )   WRITE(numout,*) 'gsigw 1 jpk    ', gsigw(1), gsigw(jpk)
1604         !
1605         ! Coefficients for vertical scale factors at w-, t- levels
1606!!gm bug :  define it from analytical function, not like juste bellow....
1607!!gm        or betteroffer the 2 possibilities....
1608         DO jk = 1, jpkm1
1609            esigt(jk  ) = gsigw(jk+1) - gsigw(jk)
1610            esigw(jk+1) = gsigt(jk+1) - gsigt(jk)
1611         END DO
1612         esigw( 1 ) = 2._wp * ( gsigt(1  ) - gsigw(1  ) ) 
1613         esigt(jpk) = 2._wp * ( gsigt(jpk) - gsigw(jpk) )
1614
1615!!gm  original form
1616!!org DO jk = 1, jpk
1617!!org    esigt(jk)=fsdsig( FLOAT(jk)     )
1618!!org    esigw(jk)=fsdsig( FLOAT(jk)-0.5 )
1619!!org END DO
1620!!gm
1621         !
1622         ! Coefficients for vertical depth as the sum of e3w scale factors
1623         gsi3w(1) = 0.5_wp * esigw(1)
1624         DO jk = 2, jpk
1625            gsi3w(jk) = gsi3w(jk-1) + esigw(jk)
1626         END DO
1627!!gm: depuw, depvw can be suppressed (modif in ldfslp) and depw=dep3w can be set (save 3 3D arrays)
1628         DO jk = 1, jpk
1629            zcoeft = ( REAL(jk,wp) - 0.5_wp ) / REAL(jpkm1,wp)
1630            zcoefw = ( REAL(jk,wp) - 1.0_wp ) / REAL(jpkm1,wp)
1631            gdept (:,:,jk) = ( scosrf(:,:) + (hbatt(:,:)-hift(:,:))*gsigt(jk) + hift(:,:)*zcoeft )
1632            gdepw (:,:,jk) = ( scosrf(:,:) + (hbatt(:,:)-hift(:,:))*gsigw(jk) + hift(:,:)*zcoefw )
1633            gdep3w(:,:,jk) = ( scosrf(:,:) + (hbatt(:,:)-hift(:,:))*gsi3w(jk) + hift(:,:)*zcoeft )
1634         END DO
1635!!gm: e3uw, e3vw can be suppressed  (modif in dynzdf, dynzdf_iso, zdfbfr) (save 2 3D arrays)
1636         DO jj = 1, jpj
1637            DO ji = 1, jpi
1638               DO jk = 1, jpk
1639                 e3t(ji,jj,jk) = ( (hbatt(ji,jj)-hift(ji,jj))*esigt(jk) + hift(ji,jj)/REAL(jpkm1,wp) )
1640                 e3u(ji,jj,jk) = ( (hbatu(ji,jj)-hifu(ji,jj))*esigt(jk) + hifu(ji,jj)/REAL(jpkm1,wp) )
1641                 e3v(ji,jj,jk) = ( (hbatv(ji,jj)-hifv(ji,jj))*esigt(jk) + hifv(ji,jj)/REAL(jpkm1,wp) )
1642                 e3f(ji,jj,jk) = ( (hbatf(ji,jj)-hiff(ji,jj))*esigt(jk) + hiff(ji,jj)/REAL(jpkm1,wp) )
1643                 !
1644                 e3w (ji,jj,jk) = ( (hbatt(ji,jj)-hift(ji,jj))*esigw(jk) + hift(ji,jj)/REAL(jpkm1,wp) )
1645                 e3uw(ji,jj,jk) = ( (hbatu(ji,jj)-hifu(ji,jj))*esigw(jk) + hifu(ji,jj)/REAL(jpkm1,wp) )
1646                 e3vw(ji,jj,jk) = ( (hbatv(ji,jj)-hifv(ji,jj))*esigw(jk) + hifv(ji,jj)/REAL(jpkm1,wp) )
1647               END DO
1648            END DO
1649         END DO
1650         !
1651      ENDIF ! ln_s_sigma
1652
1653
1654      !
1655!!    H. Liu, POL. April 2009. Added for passing the scale check for the new released vvl code.
1656      where (e3t   (:,:,:).eq.0.0)  e3t(:,:,:) = 1.0
1657      where (e3u   (:,:,:).eq.0.0)  e3u(:,:,:) = 1.0
1658      where (e3v   (:,:,:).eq.0.0)  e3v(:,:,:) = 1.0
1659      where (e3f   (:,:,:).eq.0.0)  e3f(:,:,:) = 1.0
1660      where (e3w   (:,:,:).eq.0.0)  e3w(:,:,:) = 1.0
1661      where (e3uw  (:,:,:).eq.0.0)  e3uw(:,:,:) = 1.0
1662      where (e3vw  (:,:,:).eq.0.0)  e3vw(:,:,:) = 1.0
1663
1664
1665      fsdept(:,:,:) = gdept (:,:,:)
1666      fsdepw(:,:,:) = gdepw (:,:,:)
1667      fsde3w(:,:,:) = gdep3w(:,:,:)
1668      fse3t (:,:,:) = e3t   (:,:,:)
1669      fse3u (:,:,:) = e3u   (:,:,:)
1670      fse3v (:,:,:) = e3v   (:,:,:)
1671      fse3f (:,:,:) = e3f   (:,:,:)
1672      fse3w (:,:,:) = e3w   (:,:,:)
1673      fse3uw(:,:,:) = e3uw  (:,:,:)
1674      fse3vw(:,:,:) = e3vw  (:,:,:)
1675!!
1676      ! HYBRID :
1677      DO jj = 1, jpj
1678         DO ji = 1, jpi
1679            DO jk = 1, jpkm1
1680               IF( scobot(ji,jj) >= fsdept(ji,jj,jk) )   mbathy(ji,jj) = MAX( 2, jk )
1681               IF( scobot(ji,jj) == 0._wp            )   mbathy(ji,jj) = 0
1682            END DO
1683         END DO
1684      END DO
1685
1686      IF( nprint == 1 .AND. lwp ) WRITE(numout,*) ' MIN val mbathy h90 ', MINVAL( mbathy(:,:) ),   &
1687         &                                                       ' MAX ', MAXVAL( mbathy(:,:) )
1688
1689      !                                               ! =============
1690      IF(lwp) THEN                                    ! Control print
1691         !                                            ! =============
1692         WRITE(numout,*) 
1693         WRITE(numout,*) ' domzgr: vertical coefficients for model level'
1694         WRITE(numout, "(9x,'  level    gsigt      gsigw      esigt      esigw      gsi3w')" )
1695         WRITE(numout, "(10x,i4,5f11.4)" ) ( jk, gsigt(jk), gsigw(jk), esigt(jk), esigw(jk), gsi3w(jk), jk=1,jpk )
1696      ENDIF
1697      IF( nprint == 1  .AND. lwp )   THEN         ! min max values over the local domain
1698         WRITE(numout,*) ' MIN val mbathy  ', MINVAL( mbathy(:,:)   ), ' MAX ', MAXVAL( mbathy(:,:) )
1699         WRITE(numout,*) ' MIN val depth t ', MINVAL( fsdept(:,:,:) ),   &
1700            &                          ' w ', MINVAL( fsdepw(:,:,:) ), '3w '  , MINVAL( fsde3w(:,:,:) )
1701         WRITE(numout,*) ' MIN val e3    t ', MINVAL( fse3t (:,:,:) ), ' f '  , MINVAL( fse3f (:,:,:) ),   &
1702            &                          ' u ', MINVAL( fse3u (:,:,:) ), ' u '  , MINVAL( fse3v (:,:,:) ),   &
1703            &                          ' uw', MINVAL( fse3uw(:,:,:) ), ' vw'  , MINVAL( fse3vw(:,:,:) ),   &
1704            &                          ' w ', MINVAL( fse3w (:,:,:) )
1705
1706         WRITE(numout,*) ' MAX val depth t ', MAXVAL( fsdept(:,:,:) ),   &
1707            &                          ' w ', MAXVAL( fsdepw(:,:,:) ), '3w '  , MAXVAL( fsde3w(:,:,:) )
1708         WRITE(numout,*) ' MAX val e3    t ', MAXVAL( fse3t (:,:,:) ), ' f '  , MAXVAL( fse3f (:,:,:) ),   &
1709            &                          ' u ', MAXVAL( fse3u (:,:,:) ), ' u '  , MAXVAL( fse3v (:,:,:) ),   &
1710            &                          ' uw', MAXVAL( fse3uw(:,:,:) ), ' vw'  , MAXVAL( fse3vw(:,:,:) ),   &
1711            &                          ' w ', MAXVAL( fse3w (:,:,:) )
1712      ENDIF
1713      !
1714      IF(lwp) THEN                                  ! selected vertical profiles
1715         WRITE(numout,*)
1716         WRITE(numout,*) ' domzgr: vertical coordinates : point (1,1,k) bathy = ', bathy(1,1), hbatt(1,1)
1717         WRITE(numout,*) ' ~~~~~~  --------------------'
1718         WRITE(numout,"(9x,' level   gdept    gdepw    gde3w     e3t      e3w  ')")
1719         WRITE(numout,"(10x,i4,4f9.2)") ( jk, fsdept(1,1,jk), fsdepw(1,1,jk),     &
1720            &                                 fse3t (1,1,jk), fse3w (1,1,jk), jk=1,jpk )
1721         DO jj = mj0(20), mj1(20)
1722            DO ji = mi0(20), mi1(20)
1723               WRITE(numout,*)
1724               WRITE(numout,*) ' domzgr: vertical coordinates : point (20,20,k)   bathy = ', bathy(ji,jj), hbatt(ji,jj)
1725               WRITE(numout,*) ' ~~~~~~  --------------------'
1726               WRITE(numout,"(9x,' level   gdept    gdepw    gde3w     e3t      e3w  ')")
1727               WRITE(numout,"(10x,i4,4f9.2)") ( jk, fsdept(ji,jj,jk), fsdepw(ji,jj,jk),     &
1728                  &                                 fse3t (ji,jj,jk), fse3w (ji,jj,jk), jk=1,jpk )
1729            END DO
1730         END DO
1731!!$ ARPDBG - out of bounds if jpj < 74 or jpi < 100, e.g. default GYRE
1732!!$         DO jj = mj0(74), mj1(74)
1733!!$            DO ji = mi0(100), mi1(100)
1734!!$               WRITE(numout,*)
1735!!$               WRITE(numout,*) ' domzgr: vertical coordinates : point (100,74,k)   bathy = ', bathy(ji,jj), hbatt(ji,jj)
1736!!$               WRITE(numout,*) ' ~~~~~~  --------------------'
1737!!$               WRITE(numout,"(9x,' level   gdept    gdepw    gde3w     e3t      e3w  ')")
1738!!$               WRITE(numout,"(10x,i4,4f9.2)") ( jk, fsdept(ji,jj,jk), fsdepw(ji,jj,jk),     &
1739!!$                  &                                 fse3t (ji,jj,jk), fse3w (ji,jj,jk), jk=1,jpk )
1740!!$            END DO
1741!!$         END DO
1742      ENDIF
1743
1744!!gm bug?  no more necessary?  if ! defined key_helsinki
1745#if defined key_z_first
1746      DO jj = 1, jpj
1747         DO ji = 1, jpi
1748            DO jk = 1, jpk
1749#else
1750      DO jk = 1, jpk
1751         DO jj = 1, jpj
1752            DO ji = 1, jpi
1753#endif
1754               IF( fse3w(ji,jj,jk) <= 0._wp .OR. fse3t(ji,jj,jk) <= 0._wp ) THEN
1755                  WRITE(ctmp1,*) 'zgr_sco :   e3w   or e3t   =< 0  at point (i,j,k)= ', ji, jj, jk
1756                  CALL ctl_stop( ctmp1 )
1757               ENDIF
1758#if defined key_vvl
1759               IF( gdepw_1(ji,jj,jk) < 0._wp .OR. gdept_1(ji,jj,jk) < 0._wp ) THEN
1760                  WRITE(ctmp1,*) 'zgr_sco :   gdepw or gdept =< 0  at point (i,j,k)= ', ji, jj, jk
1761                  CALL ctl_stop( ctmp1 )
1762               ENDIF
1763#endif
1764            END DO
1765         END DO
1766      END DO
1767!!gm bug    #endif
1768      !
1769      IF( wrk_not_released(2, 1,2,3,4,5) .OR. wrk_not_released(3, 1,2,3,4,5,6,7,8,9,10) )  &
1770        &  CALL ctl_stop('dom:zgr_sco: failed to release workspace arrays')
1771      !
1772   END SUBROUTINE zgr_sco
1773
1774   !!======================================================================
1775END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.