source: branches/2011/DEV_r2739_STFC_dCSE/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 4401

Last change on this file since 4401 was 4401, checked in by trackstand2, 7 years ago

Put jpkf into traldf_iso and traadv_tvd (inc nonosc)

  • Property svn:keywords set to Id
File size: 22.1 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra          ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp         ! MPP library
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL ::   l_trd   ! flag to compute trends
42
43   !! * Control permutation of array indices
44#  include "oce_ftrans.h90"
45#  include "dom_oce_ftrans.h90"
46#  include "trc_oce_ftrans.h90"
47
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_tvd ( kt, cdtype, p2dt, pun, pvn, pwn,      &
59      &                                       ptb, ptn, pta, kjpt )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_tvd  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of
64      !!       tracers and add it to the general trend of tracer equations
65      !!
66      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
67      !!       corrected flux (monotonic correction)
68      !!       note: - this advection scheme needs a leap-frog time scheme
69      !!
70      !! ** Action : - update (pta) with the now advective tracer trends
71      !!             - save the trends
72      !!----------------------------------------------------------------------
73      USE timing,   ONLY: timing_start, timing_stop
74      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
75      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
76      USE wrk_nemo, ONLY:   zwi => wrk_3d_12 , zwz => wrk_3d_13   ! 3D workspace
77
78      !! DCSE_NEMO: need additional directives for renamed module variables
79!FTRANS zwx zwy zwi zwz :I :I :z
80
81      !
82      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
83      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
84      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
85      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
86
87      !! DCSE_NEMO: This style defeats ftrans
88!     REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
89!     REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
90!     REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
91
92!FTRANS pun pvn pwn :I :I :z
93!FTRANS ptb ptn pta :I :I :z :
94      REAL(wp), INTENT(in   ) ::   pun(jpi,jpj,jpk)        ! ocean velocity component (u)
95      REAL(wp), INTENT(in   ) ::   pvn(jpi,jpj,jpk)        ! ocean velocity component (v)
96      REAL(wp), INTENT(in   ) ::   pwn(jpi,jpj,jpk)        ! ocean velocity component (w)
97      REAL(wp), INTENT(in   ) ::   ptb(jpi,jpj,jpk,kjpt)   ! tracer fields (before)
98      REAL(wp), INTENT(in   ) ::   ptn(jpi,jpj,jpk,kjpt)   ! tracer fields (now)
99      REAL(wp), INTENT(inout) ::   pta(jpi,jpj,jpk,kjpt)   ! tracer trend
100
101      !
102      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
103      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
104      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
105      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
106      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
107!FTRANS ztrdx ztrdy ztrdz :I :I :z
108
109      !!----------------------------------------------------------------------
110
111      CALL timing_start('tra_adv_tvd')
112
113      IF( wrk_in_use(3, 12,13) ) THEN
114         CALL ctl_stop('tra_adv_tvd: requested workspace arrays unavailable')   ;   RETURN
115      ENDIF
116
117      IF( kt == nit000 )  THEN
118         IF(lwp) WRITE(numout,*)
119         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
120         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
121         !
122         l_trd = .FALSE.
123         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
124      ENDIF
125      !
126      IF( l_trd )  THEN
127        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.e0
128        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.e0
129        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.e0
130      END IF
131      !
132      zwi(:,:,1:jpkf) = 0.e0
133      !
134      !                                                          ! ===========
135      DO jn = 1, kjpt                                            ! tracer loop
136         !                                                       ! ===========
137         ! 1. Bottom value : flux set to zero
138         ! ----------------------------------
139         ! ARPDBG: FINISS was using jpk correct here given that it can be
140         ! below the ocean floor??
141         zwx(:,:,jpkf) = 0.e0    ;    zwz(:,:,jpkf) = 0.e0
142         zwy(:,:,jpkf) = 0.e0    ;    zwi(:,:,jpkf) = 0.e0
143
144         ! 2. upstream advection with initial mass fluxes & intermediate update
145         ! --------------------------------------------------------------------
146         ! upstream tracer flux in the i and j direction
147         CALL timing_start('tvd_upstream')
148#if defined key_z_first
149         DO jj = 1, jpjm1
150            DO ji = 1, jpim1
151               DO jk = 1, jpkfm1
152#else
153         DO jk = 1, jpkfm1
154            DO jj = 1, jpjm1
155               DO ji = 1, fs_jpim1   ! vector opt.
156#endif
157                  ! upstream scheme
158                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
159                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
160                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
161                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
162                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
163                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
164               END DO
165            END DO
166         END DO
167         CALL timing_stop('tvd_upstream','section')
168
169         ! upstream tracer flux in the k direction
170         ! Surface value
171         CALL timing_start('tvd_upstreamk')
172         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
173         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
174         ENDIF
175         ! Interior value
176#if defined key_z_first
177         DO jj = 1, jpj
178            DO ji = 1, jpi
179               DO jk = 2, jpkfm1
180#else
181         DO jk = 2, jpkfm1
182            DO jj = 1, jpj
183               DO ji = 1, jpi
184#endif
185                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
186                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
187                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
188               END DO
189            END DO
190         END DO
191         CALL timing_stop('tvd_upstreamk','section')
192
193         ! total advective trend
194         CALL timing_start('tvd_tot')
195#if defined key_z_first
196         DO jj = 2, jpjm1
197            DO ji = 2, jpim1
198               DO jk = 1, jpkfm1
199                  z2dtt = p2dt(jk)
200#else
201         DO jk = 1, jpkfm1
202            z2dtt = p2dt(jk)
203            DO jj = 2, jpjm1
204               DO ji = fs_2, fs_jpim1   ! vector opt.
205#endif
206                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
207                  ! total intermediate advective trends
208                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
209                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
210                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
211                  ! update and guess with monotonic sheme
212                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
213                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
214               END DO
215            END DO
216         END DO
217         CALL timing_stop('tvd_tot','section')
218
219         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
220         CALL timing_start('tvd_lbc')
221         CALL lbc_lnk( zwi, 'T', 1. ) 
222         CALL timing_stop('tvd_lbc','section')
223
224         !                                 ! trend diagnostics (contribution of upstream fluxes)
225         IF( l_trd )  THEN 
226            ! store intermediate advective trends
227            ztrdx(:,:,1:jpkf) = zwx(:,:,1:jpkf)   ;    ztrdy(:,:,1:jpkf) = zwy(:,:,1:jpkf)  ;   ztrdz(:,:,1:jpkf) = zwz(:,:,1:jpkf)
228         END IF
229         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
230         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
231           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
232           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
233         ENDIF
234
235         ! 3. antidiffusive flux : high order minus low order
236         ! --------------------------------------------------
237         ! antidiffusive flux on i and j
238         CALL timing_start('tvd_antidiff')
239#if defined key_z_first
240         DO jj = 1, jpjm1
241            DO ji = 1, jpim1
242               DO jk = 1, jpkfm1
243#else
244         DO jk = 1, jpkfm1
245            DO jj = 1, jpjm1
246               DO ji = 1, fs_jpim1   ! vector opt.
247#endif
248                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
249                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
250               END DO
251            END DO
252         END DO
253         CALL timing_stop('tvd_antidiff','section')
254     
255         ! antidiffusive flux on k
256         CALL timing_start('tvd_antidiffk')
257#if defined key_z_first
258         DO jj = 1, jpj
259            DO ji = 1, jpi
260               zwz(ji,jj,1) = 0.e0   ! Surface value
261               DO jk = 2, jpkfm1
262#else
263         zwz(:,:,1) = 0.e0           ! Surface value
264         !
265         DO jk = 2, jpkfm1            ! Interior value
266            DO jj = 1, jpj
267               DO ji = 1, jpi
268#endif
269                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
270               END DO
271            END DO
272         END DO
273         CALL timing_stop('tvd_antidiffk','section')
274
275         CALL timing_start('tvd_lbc')
276         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
277         CALL lbc_lnk( zwz, 'W',  1. )
278         CALL timing_stop('tvd_lbc','section')
279
280         ! 4. monotonicity algorithm
281         ! -------------------------
282         CALL timing_start('tvd_nonosc')
283         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
284         CALL timing_stop('tvd_nonosc','section')
285
286
287         ! 5. final trend with corrected fluxes
288         ! ------------------------------------
289         CALL timing_start('tvd_finaltr')
290#if defined key_z_first
291         DO jj = 2, jpjm1
292            DO ji = 2, jpim1
293               DO jk = 1, jpkfm1
294#else
295         DO jk = 1, jpkfm1
296            DO jj = 2, jpjm1
297               DO ji = fs_2, fs_jpim1   ! vector opt. 
298#endif
299                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
300                  ! total advective trends
301                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
302                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
303                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
304                  ! add them to the general tracer trends
305                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
306               END DO
307            END DO
308         END DO
309
310         !                                 ! trend diagnostics (contribution of upstream fluxes)
311         IF( l_trd )  THEN
312            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
313            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
314            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
315           
316            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
317            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
318            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
319         END IF
320         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
321         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
322           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
323           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
324         ENDIF
325         !
326         CALL timing_stop('tvd_finaltr','section')
327
328      END DO
329      !
330      IF( l_trd )  THEN
331        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
332      END IF
333      !
334      IF( wrk_not_released(3, 12,13) )   CALL ctl_stop('tra_adv_tvd: failed to release workspace arrays')
335      !
336      CALL timing_stop('tra_adv_tvd','section')
337
338      !! * Reset control of array index permutation
339!FTRANS CLEAR
340#  include "oce_ftrans.h90"
341#  include "dom_oce_ftrans.h90"
342#  include "trc_oce_ftrans.h90"
343
344   END SUBROUTINE tra_adv_tvd
345
346
347   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
348      !!---------------------------------------------------------------------
349      !!                    ***  ROUTINE nonosc  ***
350      !!     
351      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
352      !!       scheme and the before field by a nonoscillatory algorithm
353      !!
354      !! **  Method  :   ... ???
355      !!       warning : pbef and paft must be masked, but the boundaries
356      !!       conditions on the fluxes are not necessary zalezak (1979)
357      !!       drange (1995) multi-dimensional forward-in-time and upstream-
358      !!       in-space based differencing for fluid
359      !!----------------------------------------------------------------------
360      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
361      USE wrk_nemo, ONLY:   zbetup => wrk_3d_8  , zbetdo => wrk_3d_9    ! 3D workspace
362      USE wrk_nemo, ONLY:   zbup   => wrk_3d_10 , zbdo   => wrk_3d_11   !  -     -
363      USE timing,   ONLY:   timing_start, timing_stop
364
365      !! DCSE_NEMO: need additional directives for renamed module variables
366!FTRANS zbetup zbetdo zbup zbdo :I :I :z
367
368      !
369      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
370
371      !! DCSE_NEMO: This style defeats ftrans
372!     REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
373!     REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
374
375!FTRANS pbef paft :I :I :z
376!FTRANS paa pbb pcc :I :I :z
377      REAL(wp), INTENT(in   ) ::   pbef(jpi,jpj,jpk), paft(jpi,jpj,jpk)     ! before & after field
378      REAL(wp), INTENT(inout) ::   paa(jpi,jpj,jpk)                         ! monotonic fluxes in the 1st direction
379      REAL(wp), INTENT(inout) ::   pbb(jpi,jpj,jpk)                         ! monotonic fluxes in the 2nd direction
380      REAL(wp), INTENT(inout) ::   pcc(jpi,jpj,jpk)                         ! monotonic fluxes in the 3rd direction
381      !
382      INTEGER ::   ji, jj, jk   ! dummy loop indices
383      INTEGER ::   ikm1         ! local integer
384      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
385      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
386      !!----------------------------------------------------------------------
387
388      IF( wrk_in_use(3, 8,9,10,11) ) THEN
389         CALL ctl_stop('nonosc: requested workspace array unavailable')   ;   RETURN
390      ENDIF
391
392      zbig  = 1.e+40_wp
393      zrtrn = 1.e-15_wp
394      zbetup(:,:,jpkf) = 0._wp   ;   zbetdo(:,:,jpkf) = 0._wp
395
396
397      ! Search local extrema
398      ! --------------------
399      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
400      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
401         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
402      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
403         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
404
405#if defined key_z_first
406      DO jj = 2, jpjm1
407         DO ji = 2, jpim1
408            DO jk = 1, jpkfm1
409               ikm1 = MAX(jk-1,1)
410               z2dtt = p2dt(jk)
411#else
412      DO jk = 1, jpkfm1
413         ikm1 = MAX(jk-1,1)
414         z2dtt = p2dt(jk)
415         DO jj = 2, jpjm1
416            DO ji = fs_2, fs_jpim1   ! vector opt.
417#endif
418
419               ! search maximum in neighbourhood
420               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
421                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
422                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
423                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
424
425               ! search minimum in neighbourhood
426               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
427                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
428                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
429                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
430
431               ! positive part of the flux
432               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
433                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
434                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
435
436               ! negative part of the flux
437               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
438                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
439                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
440
441               ! up & down beta terms
442               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
443               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
444               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
445            END DO
446         END DO
447      END DO
448      CALL timing_start('tvd_lbc')
449      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
450      CALL timing_stop('tvd_lbc','section')
451
452
453
454      ! 3. monotonic flux in the i & j direction (paa & pbb)
455      ! ----------------------------------------
456#if defined key_z_first
457      DO jj = 2, jpjm1
458         DO ji = 2, jpim1
459            DO jk = 1, jpkfm1
460#else
461      DO jk = 1, jpkfm1
462         DO jj = 2, jpjm1
463            DO ji = fs_2, fs_jpim1   ! vector opt.
464#endif
465               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
466               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
467               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
468               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
469
470               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
471               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
472               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
473               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
474
475      ! monotonic flux in the k direction, i.e. pcc
476      ! -------------------------------------------
477               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
478               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
479               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
480               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
481            END DO
482         END DO
483      END DO
484      CALL timing_start('tvd_lbc')
485      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
486      CALL timing_stop('tvd_lbc','section')
487
488      !
489      IF( wrk_not_released(3, 8,9,10,11) )   CALL ctl_stop('nonosc: failed to release workspace arrays')
490      !
491   END SUBROUTINE nonosc
492
493   !!======================================================================
494END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.