MODULE obctra
   !!======================================================================
   !!                       ***  MODULE  obctra  ***
   !! Ocean tracers:   Flow Relaxation Scheme of tracers on each open boundary
   !!======================================================================
   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
   !!----------------------------------------------------------------------
#if defined key_obc
   !!----------------------------------------------------------------------
   !!   'key_obc'                     Unstructured Open Boundary Conditions
   !!----------------------------------------------------------------------
   !!   obc_tra            : Apply open boundary conditions to T and S
   !!   obc_tra_frs        : Apply Flow Relaxation Scheme
   !!----------------------------------------------------------------------
   USE oce             ! ocean dynamics and tracers variables
   USE dom_oce         ! ocean space and time domain variables 
   USE obc_oce         ! ocean open boundary conditions
   USE obcdta, ONLY:   bf
   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
   USE in_out_manager  ! I/O manager

   IMPLICIT NONE
   PRIVATE

   PUBLIC obc_tra      ! routine called in tranxt.F90 

   !!----------------------------------------------------------------------
   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
   !! $Id$ 
   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------
CONTAINS

   SUBROUTINE obc_tra( kt )
      !!----------------------------------------------------------------------
      !!                  ***  SUBROUTINE obc_dyn3d  ***
      !!
      !! ** Purpose : - Apply open boundary conditions for baroclinic velocities
      !!
      !!----------------------------------------------------------------------
      INTEGER, INTENT( in ) :: kt     ! Main time step counter
      !!
      INTEGER               :: ib_obc ! Loop index

      DO ib_obc=1, nb_obc

         SELECT CASE( nn_tra(ib_obc) )
         CASE(jp_none)
            CYCLE
         CASE(jp_frs)
            CALL obc_tra_frs( idx_obc(ib_obc), dta_obc(ib_obc), kt )
         CASE DEFAULT
            CALL ctl_stop( 'obc_tra : unrecognised option for open boundaries for T and S' )
         END SELECT
      ENDDO

   END SUBROUTINE obc_tra

   SUBROUTINE obc_tra_frs( idx, dta, kt )
      !!----------------------------------------------------------------------
      !!                 ***  SUBROUTINE obc_tra_frs  ***
      !!                    
      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
      !! 
      !! Reference : Engedahl H., 1995, Tellus, 365-382.
      !!----------------------------------------------------------------------
      INTEGER,         INTENT(in) ::   kt
      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
      !! 
      REAL(wp) ::   zwgt           ! boundary weight
      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
      INTEGER  ::   ii, ij         ! 2D addresses
      !!----------------------------------------------------------------------
      !
      !
      igrd = 1                       ! Everything is at T-points here
      DO ib = 1, idx%nblen(igrd)
         DO ik = 1, jpkm1
            ii = idx%nbi(ib,igrd)
            ij = idx%nbj(ib,igrd)
            zwgt = idx%nbw(ib,igrd)
            ta(ii,ij,ik) = ( ta(ii,ij,ik) + zwgt * ( dta%tem(ib,ik) - ta(ii,ij,ik) ) ) * tmask(ii,ij,ik)         
            sa(ii,ij,ik) = ( sa(ii,ij,ik) + zwgt * ( dta%sal(ib,ik) - sa(ii,ij,ik) ) ) * tmask(ii,ij,ik)
         END DO
      END DO 
      !
      CALL lbc_lnk( ta, 'T', 1. )   ; CALL lbc_lnk( sa, 'T', 1. )    ! Boundary points should be updated
      !
      IF( kt .eq. nit000 ) CLOSE( unit = 102 )
   !
   END SUBROUTINE obc_tra_frs
   
#else
   !!----------------------------------------------------------------------
   !!   Dummy module                   NO Unstruct Open Boundary Conditions
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE obc_tra(kt)      ! Empty routine
      WRITE(*,*) 'obc_tra: You should not have seen this print! error?', kt
   END SUBROUTINE obc_tra
#endif

   !!======================================================================
END MODULE obctra