New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaptr.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DIA/diaptr.F90 @ 3208

Last change on this file since 3208 was 3208, checked in by smasson, 12 years ago

simplified syntaxe for performance tests
  • Property svn:keywords set to Id
File size: 42.8 KB
Line 
1MODULE diaptr
2   !!======================================================================
3   !!                       ***  MODULE  diaptr  ***
4   !! Ocean physics:  Computes meridonal transports and zonal means
5   !!=====================================================================
6   !! History :  1.0  ! 2003-09  (C. Talandier, G. Madec)  Original code
7   !!            2.0  ! 2006-01  (A. Biastoch)  Allow sub-basins computation
8   !!            3.2  ! 2010-03  (O. Marti, S. Flavoni) Add fields
9   !!            3.3  ! 2010-10  (G. Madec)  dynamical allocation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dia_ptr      : Poleward Transport Diagnostics module
14   !!   dia_ptr_init : Initialization, namelist read
15   !!   dia_ptr_wri  : Output of poleward fluxes
16   !!   ptr_vjk      : "zonal" sum computation of a "meridional" flux array
17   !!   ptr_tjk      : "zonal" mean computation of a tracer field
18   !!   ptr_vj       : "zonal" and vertical sum computation of a "meridional" flux array
19   !!                   (Generic interface to ptr_vj_3d, ptr_vj_2d)
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and active tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE ldftra_oce       ! ocean active tracers: lateral physics
25   USE dianam           !
26   USE iom              ! IOM library
27   USE ioipsl           ! IO-IPSL library
28   USE in_out_manager   ! I/O manager
29   USE lib_mpp          ! MPP library
30   USE lbclnk           ! lateral boundary condition - processor exchanges
31   USE timing           ! preformance summary
32   USE wrk_nemo         ! working arrays
33
34   IMPLICIT NONE
35   PRIVATE
36
37   INTERFACE ptr_vj
38      MODULE PROCEDURE ptr_vj_3d, ptr_vj_2d
39   END INTERFACE
40
41   PUBLIC   dia_ptr_init   ! call in opa module
42   PUBLIC   dia_ptr        ! call in step module
43   PUBLIC   ptr_vj         ! call by tra_ldf & tra_adv routines
44   PUBLIC   ptr_vjk        ! call by tra_ldf & tra_adv routines
45
46   !                                           !!** namelist  namptr  **
47   LOGICAL , PUBLIC ::   ln_diaptr  = .FALSE.   !: Poleward transport flag (T) or not (F)
48   LOGICAL , PUBLIC ::   ln_subbas  = .FALSE.   !: Atlantic/Pacific/Indian basins calculation
49   LOGICAL , PUBLIC ::   ln_diaznl  = .FALSE.   !: Add zonal means and meridional stream functions
50   LOGICAL , PUBLIC ::   ln_ptrcomp = .FALSE.   !: Add decomposition : overturning (and gyre, soon ...)
51   INTEGER , PUBLIC ::   nn_fptr    = 15        !: frequency of ptr computation  [time step]
52   INTEGER , PUBLIC ::   nn_fwri    = 15        !: frequency of ptr outputs      [time step]
53
54   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   htr_adv, htr_ldf, htr_ove   !: Heat TRansports (adv, diff, overturn.)
55   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   str_adv, str_ldf, str_ove   !: Salt TRansports (adv, diff, overturn.)
56   
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   btmsk                  ! T-point basin interior masks
58   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   btm30                  ! mask out Southern Ocean (=0 south of 30°S)
59   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr  , str             ! adv heat and salt transports (approx)
60   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tn_jk, sn_jk , v_msf   ! i-mean T and S, j-Stream-Function
61   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sjk  , r1_sjk          ! i-mean i-k-surface and its inverse       
62   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr_eiv, str_eiv       ! bolus adv heat ans salt transports ('key_diaeiv')
63   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   v_msf_eiv              ! bolus j-streamfuction              ('key_diaeiv')
64
65
66   INTEGER ::   niter       !
67   INTEGER ::   nidom_ptr   !
68   INTEGER ::   numptr      ! logical unit for Poleward TRansports
69   INTEGER ::   nptr        ! = 1 (ln_subbas=F) or = 5 (glo, atl, pac, ind, ipc) (ln_subbas=T)
70
71   REAL(wp) ::   rc_sv    = 1.e-6_wp   ! conversion from m3/s to Sverdrup
72   REAL(wp) ::   rc_pwatt = 1.e-15_wp  ! conversion from W    to PW (further x rau0 x Cp)
73   REAL(wp) ::   rc_ggram = 1.e-6_wp   ! conversion from g    to Pg
74
75   REAL(wp), TARGET, DIMENSION(:),   ALLOCATABLE, SAVE :: p_fval1d
76   REAL(wp), TARGET, DIMENSION(:,:), ALLOCATABLE, SAVE :: p_fval2d
77
78   !! Integer, 1D workspace arrays. Not common enough to be implemented in
79   !! wrk_nemo module.
80   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex  , ndex_atl     , ndex_pac     , ndex_ind     , ndex_ipc
81   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) ::         ndex_atl_30  , ndex_pac_30  , ndex_ind_30  , ndex_ipc_30
82   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex_h, ndex_h_atl_30, ndex_h_pac_30, ndex_h_ind_30, ndex_h_ipc_30
83
84   !! * Substitutions
85#  include "domzgr_substitute.h90"
86#  include "vectopt_loop_substitute.h90"
87   !!----------------------------------------------------------------------
88   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
89   !! $Id$
90   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
91   !!----------------------------------------------------------------------
92CONTAINS
93
94   FUNCTION dia_ptr_alloc()
95      !!----------------------------------------------------------------------
96      !!                    ***  ROUTINE dia_ptr_alloc  ***
97      !!----------------------------------------------------------------------
98      INTEGER               ::   dia_ptr_alloc   ! return value
99      INTEGER, DIMENSION(5) ::   ierr
100      !!----------------------------------------------------------------------
101      ierr(:) = 0
102      !
103      ALLOCATE( btmsk(jpi,jpj,nptr) ,           &
104         &      htr_adv(jpj) , str_adv(jpj) ,   &
105         &      htr_ldf(jpj) , str_ldf(jpj) ,   &
106         &      htr_ove(jpj) , str_ove(jpj),    &
107         &      htr(jpj,nptr) , str(jpj,nptr) , &
108         &      tn_jk(jpj,jpk,nptr) , sn_jk (jpj,jpk,nptr) , v_msf(jpj,jpk,nptr) , &
109         &      sjk  (jpj,jpk,nptr) , r1_sjk(jpj,jpk,nptr) , STAT=ierr(1)  )
110         !
111#if defined key_diaeiv
112      ALLOCATE( htr_eiv(jpj,nptr) , str_eiv(jpj,nptr) , &
113         &      v_msf_eiv(jpj,jpk,nptr) , STAT=ierr(2) )
114#endif
115      ALLOCATE( p_fval1d(jpj), p_fval2d(jpj,jpk), Stat=ierr(3))
116      !
117      ALLOCATE(ndex(jpj*jpk),        ndex_atl(jpj*jpk), ndex_pac(jpj*jpk), &
118         &     ndex_ind(jpj*jpk),    ndex_ipc(jpj*jpk),                    &
119         &     ndex_atl_30(jpj*jpk), ndex_pac_30(jpj*jpk), Stat=ierr(4))
120
121      ALLOCATE(ndex_ind_30(jpj*jpk), ndex_ipc_30(jpj*jpk),                   &
122         &     ndex_h(jpj),          ndex_h_atl_30(jpj), ndex_h_pac_30(jpj), &
123         &     ndex_h_ind_30(jpj),   ndex_h_ipc_30(jpj), Stat=ierr(5) )
124         !
125      dia_ptr_alloc = MAXVAL( ierr )
126      IF(lk_mpp)   CALL mpp_sum( dia_ptr_alloc )
127      !
128   END FUNCTION dia_ptr_alloc
129
130
131   FUNCTION ptr_vj_3d( pva )   RESULT ( p_fval )
132      !!----------------------------------------------------------------------
133      !!                    ***  ROUTINE ptr_vj_3d  ***
134      !!
135      !! ** Purpose :   i-k sum computation of a j-flux array
136      !!
137      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
138      !!              pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
139      !!
140      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
141      !!----------------------------------------------------------------------
142      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pva   ! mask flux array at V-point
143      !!
144      INTEGER                  ::   ji, jj, jk   ! dummy loop arguments
145      INTEGER                  ::   ijpj         ! ???
146      REAL(wp), POINTER, DIMENSION(:) :: p_fval  ! function value
147      !!--------------------------------------------------------------------
148      !
149      p_fval => p_fval1d
150
151      ijpj = jpj
152      p_fval(:) = 0._wp
153      DO jk = 1, jpkm1
154         DO jj = 2, jpjm1
155            DO ji = fs_2, fs_jpim1   ! Vector opt.
156               p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj) 
157            END DO
158         END DO
159      END DO
160#if defined key_mpp_mpi
161      IF(lk_mpp)   CALL mpp_sum( p_fval, ijpj, ncomm_znl)
162#endif
163      !
164   END FUNCTION ptr_vj_3d
165
166
167   FUNCTION ptr_vj_2d( pva )   RESULT ( p_fval )
168      !!----------------------------------------------------------------------
169      !!                    ***  ROUTINE ptr_vj_2d  ***
170      !!
171      !! ** Purpose :   "zonal" and vertical sum computation of a i-flux array
172      !!
173      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
174      !!      pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
175      !!
176      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
177      !!----------------------------------------------------------------------
178      IMPLICIT none
179      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) ::   pva   ! mask flux array at V-point
180      !!
181      INTEGER                  ::   ji,jj       ! dummy loop arguments
182      INTEGER                  ::   ijpj        ! ???
183      REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
184      !!--------------------------------------------------------------------
185      !
186      p_fval => p_fval1d
187
188      ijpj = jpj
189      p_fval(:) = 0._wp
190      DO jj = 2, jpjm1
191         DO ji = nldi, nlei   ! No vector optimisation here. Better use a mask ?
192            p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj)
193         END DO
194      END DO
195#if defined key_mpp_mpi
196      CALL mpp_sum( p_fval, ijpj, ncomm_znl )
197#endif
198      !
199   END FUNCTION ptr_vj_2d
200
201
202   FUNCTION ptr_vjk( pva, pmsk )   RESULT ( p_fval )
203      !!----------------------------------------------------------------------
204      !!                    ***  ROUTINE ptr_vjk  ***
205      !!
206      !! ** Purpose :   i-sum computation of a j-velocity array
207      !!
208      !! ** Method  : - i-sum of pva using the interior 2D vmask (vmask_i).
209      !!              pva is supposed to be a masked flux (i.e. * vmask)
210      !!
211      !! ** Action  : - p_fval: i-mean poleward flux of pva
212      !!----------------------------------------------------------------------
213      !!
214      IMPLICIT none
215      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk)           ::   pva    ! mask flux array at V-point
216      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)    , OPTIONAL ::   pmsk   ! Optional 2D basin mask
217      !!
218      INTEGER                           :: ji, jj, jk ! dummy loop arguments
219      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval     ! return function value
220#if defined key_mpp_mpi
221      INTEGER, DIMENSION(1) ::   ish
222      INTEGER, DIMENSION(2) ::   ish2
223      INTEGER               ::   ijpjjpk
224#endif
225#if defined key_mpp_mpi
226      REAL(wp), POINTER, DIMENSION(:) ::   zwork    ! mask flux array at V-point
227#endif
228      !!--------------------------------------------------------------------
229      !
230#if defined key_mpp_mpi
231      ijpjjpk = jpj*jpk
232      CALL wrk_alloc( jpj*jpk, zwork )
233#endif
234
235      p_fval => p_fval2d
236
237      p_fval(:,:) = 0._wp
238      !
239      IF( PRESENT( pmsk ) ) THEN
240         DO jk = 1, jpkm1
241            DO jj = 2, jpjm1
242!!gm here, use of tmask_i  ==> no need of loop over nldi, nlei....
243               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
244                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * pmsk(ji,jj)
245               END DO
246            END DO
247         END DO
248      ELSE
249         DO jk = 1, jpkm1
250            DO jj = 2, jpjm1
251               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
252                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * tmask_i(ji,jj)
253               END DO
254            END DO
255         END DO
256      END IF
257      !
258#if defined key_mpp_mpi
259      ish(1) = ijpjjpk  ;   ish2(1) = jpj   ;   ish2(2) = jpk
260      zwork(1:ijpjjpk) = RESHAPE( p_fval, ish )
261      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
262      p_fval(:,:) = RESHAPE( zwork, ish2 )
263#endif
264      !
265#if defined key_mpp_mpi
266      CALL wrk_dealloc( jpj*jpk, zwork )
267#endif
268      !
269   END FUNCTION ptr_vjk
270
271
272   FUNCTION ptr_tjk( pta, pmsk )   RESULT ( p_fval )
273      !!----------------------------------------------------------------------
274      !!                    ***  ROUTINE ptr_tjk  ***
275      !!
276      !! ** Purpose :   i-sum computation of e1t*e3t * a tracer field
277      !!
278      !! ** Method  : - i-sum of mj(pta) using tmask
279      !!
280      !! ** Action  : - p_fval: i-sum of e1t*e3t*pta
281      !!----------------------------------------------------------------------
282      !!
283      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pta    ! tracer flux array at T-point
284      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)     ::   pmsk   ! Optional 2D basin mask
285      !!
286      INTEGER                           :: ji, jj, jk   ! dummy loop arguments
287      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval       ! return function value
288#if defined key_mpp_mpi
289      INTEGER, DIMENSION(1) ::   ish
290      INTEGER, DIMENSION(2) ::   ish2
291      INTEGER               ::   ijpjjpk
292#endif
293#if defined key_mpp_mpi
294      REAL(wp), POINTER, DIMENSION(:) ::   zwork    ! mask flux array at V-point
295#endif
296      !!--------------------------------------------------------------------
297      !
298#if defined key_mpp_mpi
299      ijpjjpk = jpj*jpk
300      CALL wrk_alloc( jpj*jpk, zwork )
301#endif
302
303      p_fval => p_fval2d
304
305      p_fval(:,:) = 0._wp
306      DO jk = 1, jpkm1
307         DO jj = 2, jpjm1
308            DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
309               p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * e1t(ji,jj) * fse3t(ji,jj,jk) * pmsk(ji,jj)
310            END DO
311         END DO
312      END DO
313#if defined key_mpp_mpi
314      ish(1) = jpj*jpk   ;   ish2(1) = jpj   ;   ish2(2) = jpk
315      zwork(1:ijpjjpk)= RESHAPE( p_fval, ish )
316      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
317      p_fval(:,:)= RESHAPE( zwork, ish2 )
318#endif
319      !
320#if defined key_mpp_mpi
321      CALL wrk_dealloc( jpj*jpk, zwork )
322#endif
323      !   
324   END FUNCTION ptr_tjk
325
326
327   SUBROUTINE dia_ptr( kt )
328      !!----------------------------------------------------------------------
329      !!                  ***  ROUTINE dia_ptr  ***
330      !!----------------------------------------------------------------------
331      USE oce,     vt  =>   ua   ! use ua as workspace
332      USE oce,     vs  =>   ua   ! use ua as workspace
333      IMPLICIT none
334      !!
335      INTEGER, INTENT(in) ::   kt   ! ocean time step index
336      !
337      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
338      REAL(wp) ::   zv               ! local scalar
339      !!----------------------------------------------------------------------
340      !
341      IF( nn_timing == 1 )   CALL timing_start('dia_ptr')
342      !
343      IF( kt == nit000 .OR. MOD( kt, nn_fptr ) == 0 )   THEN
344         !
345         IF( MOD( kt, nn_fptr ) == 0 ) THEN 
346            !
347            IF( ln_diaznl ) THEN               ! i-mean temperature and salinity
348               DO jn = 1, nptr
349                  tn_jk(:,:,jn) = ptr_tjk( tsn(:,:,:,jp_tem), btmsk(:,:,jn) ) * r1_sjk(:,:,jn)
350               END DO
351            ENDIF
352            !
353            !                          ! horizontal integral and vertical dz
354            !                                ! eulerian velocity
355            v_msf(:,:,1) = ptr_vjk( vn(:,:,:) ) 
356            DO jn = 2, nptr
357               v_msf(:,:,jn) = ptr_vjk( vn(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) 
358            END DO
359#if defined key_diaeiv
360            DO jn = 1, nptr                  ! bolus velocity
361               v_msf_eiv(:,:,jn) = ptr_vjk( v_eiv(:,:,:), btmsk(:,:,jn) )   ! here no btm30 for MSFeiv
362            END DO
363            !                                ! add bolus stream-function to the eulerian one
364            v_msf(:,:,:) = v_msf(:,:,:) + v_msf_eiv(:,:,:)
365#endif
366            !
367            !                          ! Transports
368            !                                ! local heat & salt transports at T-points  ( tsn*mj[vn+v_eiv] )
369            vt(:,:,jpk) = 0._wp   ;   vs(:,:,jpk) = 0._wp
370            DO jk= 1, jpkm1
371               DO jj = 2, jpj
372                  DO ji = 1, jpi
373#if defined key_diaeiv 
374                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) + v_eiv(ji,jj,jk) + v_eiv(ji,jj-1,jk) ) * 0.5_wp
375#else
376                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) ) * 0.5_wp
377#endif
378                     vt(:,jj,jk) = zv * tsn(:,jj,jk,jp_tem)
379                     vs(:,jj,jk) = zv * tsn(:,jj,jk,jp_sal)
380                  END DO
381               END DO
382            END DO
383!!gm useless as overlap areas are not used in ptr_vjk
384            CALL lbc_lnk( vs, 'V', -1. )   ;   CALL lbc_lnk( vt, 'V', -1. )
385!!gm
386            !                                ! heat & salt advective transports (approximation)
387            htr(:,1) = SUM( ptr_vjk( vt(:,:,:) ) , 2 ) * rc_pwatt   ! SUM over jk + conversion
388            str(:,1) = SUM( ptr_vjk( vs(:,:,:) ) , 2 ) * rc_ggram
389            DO jn = 2, nptr 
390               htr(:,jn) = SUM( ptr_vjk( vt(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_pwatt   ! mask Southern Ocean
391               str(:,jn) = SUM( ptr_vjk( vs(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_ggram   ! mask Southern Ocean
392            END DO
393
394            IF( ln_ptrcomp ) THEN            ! overturning transport
395               htr_ove(:) = SUM( v_msf(:,:,1) * tn_jk(:,:,1), 2 ) * rc_pwatt   ! SUM over jk + conversion
396               str_ove(:) = SUM( v_msf(:,:,1) * sn_jk(:,:,1), 2 ) * rc_ggram
397            END IF
398            !                                ! Advective and diffusive transport
399            htr_adv(:) = htr_adv(:) * rc_pwatt        ! these are computed in tra_adv... and tra_ldf... routines
400            htr_ldf(:) = htr_ldf(:) * rc_pwatt        ! here just the conversion in PW and Gg
401            str_adv(:) = str_adv(:) * rc_ggram
402            str_ldf(:) = str_ldf(:) * rc_ggram
403
404#if defined key_diaeiv
405            DO jn = 1, nptr                  ! Bolus component
406               htr_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * tn_jk(:,:,jn), 2 ) * rc_pwatt   ! SUM over jk
407               str_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * sn_jk(:,:,jn), 2 ) * rc_ggram   ! SUM over jk
408            END DO
409#endif
410            !                                ! "Meridional" Stream-Function
411            DO jn = 1, nptr
412               DO jk = 2, jpk 
413                  v_msf    (:,jk,jn) = v_msf    (:,jk-1,jn) + v_msf    (:,jk,jn)       ! Eulerian j-Stream-Function
414#if defined key_diaeiv
415                  v_msf_eiv(:,jk,jn) = v_msf_eiv(:,jk-1,jn) + v_msf_eiv(:,jk,jn)       ! Bolus    j-Stream-Function
416
417#endif
418               END DO
419            END DO
420            v_msf    (:,:,:) = v_msf    (:,:,:) * rc_sv       ! converte in Sverdrups
421#if defined key_diaeiv
422            v_msf_eiv(:,:,:) = v_msf_eiv(:,:,:) * rc_sv
423#endif
424         ENDIF
425         !
426         CALL dia_ptr_wri( kt )                        ! outputs
427         !
428      ENDIF
429      !
430#if defined key_mpp_mpi
431      IF( kt == nitend .AND. l_znl_root )   CALL histclo( numptr )      ! Close the file
432#else
433      IF( kt == nitend )                    CALL histclo( numptr )      ! Close the file
434#endif
435      !
436      IF( nn_timing == 1 )   CALL timing_stop('dia_ptr')
437      !
438   END SUBROUTINE dia_ptr
439
440
441   SUBROUTINE dia_ptr_init
442      !!----------------------------------------------------------------------
443      !!                  ***  ROUTINE dia_ptr_init  ***
444      !!                   
445      !! ** Purpose :   Initialization, namelist read
446      !!----------------------------------------------------------------------
447      INTEGER ::   jn           ! dummy loop indices
448      INTEGER ::   inum, ierr   ! local integers
449#if defined key_mpp_mpi
450      INTEGER, DIMENSION(1) :: iglo, iloc, iabsf, iabsl, ihals, ihale, idid
451#endif
452      !!
453      NAMELIST/namptr/ ln_diaptr, ln_diaznl, ln_subbas, ln_ptrcomp, nn_fptr, nn_fwri
454      !!----------------------------------------------------------------------
455      IF( nn_timing == 1 )   CALL timing_start('dia_ptr_init')
456
457      REWIND( numnam )                 ! Read Namelist namptr : poleward transport parameters
458      READ  ( numnam, namptr )
459
460      IF(lwp) THEN                     ! Control print
461         WRITE(numout,*)
462         WRITE(numout,*) 'dia_ptr_init : poleward transport and msf initialization'
463         WRITE(numout,*) '~~~~~~~~~~~~'
464         WRITE(numout,*) '   Namelist namptr : set ptr parameters'
465         WRITE(numout,*) '      Poleward heat & salt transport (T) or not (F)      ln_diaptr  = ', ln_diaptr
466         WRITE(numout,*) '      Overturning heat & salt transport                  ln_ptrcomp = ', ln_ptrcomp
467         WRITE(numout,*) '      T & S zonal mean and meridional stream function    ln_diaznl  = ', ln_diaznl 
468         WRITE(numout,*) '      Global (F) or glo/Atl/Pac/Ind/Indo-Pac basins      ln_subbas  = ', ln_subbas
469         WRITE(numout,*) '      Frequency of computation                           nn_fptr    = ', nn_fptr
470         WRITE(numout,*) '      Frequency of outputs                               nn_fwri    = ', nn_fwri
471      ENDIF
472
473      IF( ln_subbas ) THEN   ;   nptr = 5       ! Global, Atlantic, Pacific, Indian, Indo-Pacific
474      ELSE                   ;   nptr = 1       ! Global only
475      ENDIF
476
477      !                                      ! allocate dia_ptr arrays
478      IF( dia_ptr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate arrays' )
479
480      rc_pwatt = rc_pwatt * rau0 * rcp          ! conversion from K.s-1 to PetaWatt
481
482      IF( .NOT. ln_diaptr ) THEN       ! diaptr not used
483        RETURN
484      ENDIF
485     
486      IF( lk_mpp )   CALL mpp_ini_znl( numout )     ! Define MPI communicator for zonal sum
487
488      IF( ln_subbas ) THEN                ! load sub-basin mask
489         CALL iom_open( 'subbasins', inum )
490         CALL iom_get( inum, jpdom_data, 'atlmsk', btmsk(:,:,2) )   ! Atlantic basin
491         CALL iom_get( inum, jpdom_data, 'pacmsk', btmsk(:,:,3) )   ! Pacific  basin
492         CALL iom_get( inum, jpdom_data, 'indmsk', btmsk(:,:,4) )   ! Indian   basin
493         CALL iom_close( inum )
494         btmsk(:,:,5) = MAX ( btmsk(:,:,3), btmsk(:,:,4) )          ! Indo-Pacific basin
495         WHERE( gphit(:,:) < -30._wp)   ;   btm30(:,:) = 0._wp      ! mask out Southern Ocean
496         ELSE WHERE                     ;   btm30(:,:) = tmask(:,:,1)
497         END WHERE
498      ENDIF
499      btmsk(:,:,1) = tmask_i(:,:)                                   ! global ocean
500     
501      DO jn = 1, nptr
502         btmsk(:,:,jn) = btmsk(:,:,jn) * tmask_i(:,:)               ! interior domain only
503      END DO
504     
505      IF( lk_vvl )   CALL ctl_stop( 'diaptr: error in vvl case as constant i-mean surface is used' )
506
507      !                                   ! i-sum of e1v*e3v surface and its inverse
508      DO jn = 1, nptr
509         sjk(:,:,jn) = ptr_tjk( tmask(:,:,:), btmsk(:,:,jn) )
510         r1_sjk(:,:,jn) = 0._wp
511         WHERE( sjk(:,:,jn) /= 0._wp )   r1_sjk(:,:,jn) = 1._wp / sjk(:,:,jn)
512      END DO
513
514#if defined key_mpp_mpi 
515      iglo (1) = jpjglo                   ! MPP case using MPI  ('key_mpp_mpi')
516      iloc (1) = nlcj
517      iabsf(1) = njmppt(narea)
518      iabsl(:) = iabsf(:) + iloc(:) - 1
519      ihals(1) = nldj - 1
520      ihale(1) = nlcj - nlej
521      idid (1) = 2
522      CALL flio_dom_set( jpnj, nproc/jpni, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom_ptr )
523#else
524      nidom_ptr = FLIO_DOM_NONE
525#endif
526      !
527      IF( nn_timing == 1 )   CALL timing_stop('dia_ptr_init')
528      !
529   END SUBROUTINE dia_ptr_init
530
531
532   SUBROUTINE dia_ptr_wri( kt )
533      !!---------------------------------------------------------------------
534      !!                ***  ROUTINE dia_ptr_wri  ***
535      !!
536      !! ** Purpose :   output of poleward fluxes
537      !!
538      !! ** Method  :   NetCDF file
539      !!----------------------------------------------------------------------
540      !!
541      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
542      !!
543      INTEGER, SAVE ::   nhoridz, ndepidzt, ndepidzw
544      INTEGER, SAVE ::   ndim  , ndim_atl     , ndim_pac     , ndim_ind     , ndim_ipc
545      INTEGER, SAVE ::           ndim_atl_30  , ndim_pac_30  , ndim_ind_30  , ndim_ipc_30
546      INTEGER, SAVE ::   ndim_h, ndim_h_atl_30, ndim_h_pac_30, ndim_h_ind_30, ndim_h_ipc_30
547      !!
548      CHARACTER (len=40) ::   clhstnam, clop, clop_once, cl_comment   ! temporary names
549      INTEGER            ::   iline, it, itmod, ji, jj, jk            !
550#if defined key_iomput
551      INTEGER            ::   inum                                    ! temporary logical unit
552#endif
553      REAL(wp)           ::   zsto, zout, zdt, zjulian                ! temporary scalars
554      !!
555      REAL(wp), POINTER, DIMENSION(:)   ::   zphi, zfoo    ! 1D workspace
556      REAL(wp), POINTER, DIMENSION(:,:) ::   z_1           ! 2D workspace
557      !!--------------------------------------------------------------------
558      !
559      CALL wrk_alloc( jpi      , zphi , zfoo )
560      CALL wrk_alloc( jpi , jpk, z_1 )
561
562      ! define time axis
563      it    = kt / nn_fptr
564      itmod = kt - nit000 + 1
565     
566      ! Initialization
567      ! --------------
568      IF( kt == nit000 ) THEN
569         niter = ( nit000 - 1 ) / nn_fptr
570         zdt = rdt
571         IF( nacc == 1 )   zdt = rdtmin
572         !
573         IF(lwp) THEN
574            WRITE(numout,*)
575            WRITE(numout,*) 'dia_ptr_wri : poleward transport and msf writing: initialization , niter = ', niter
576            WRITE(numout,*) '~~~~~~~~~~~~'
577         ENDIF
578
579         ! Reference latitude (used in plots)
580         ! ------------------
581         !                                           ! =======================
582         IF( cp_cfg == "orca" ) THEN                 !   ORCA configurations
583            !                                        ! =======================
584            IF( jp_cfg == 05  )   iline = 192   ! i-line that passes near the North Pole
585            IF( jp_cfg == 025 )   iline = 384   ! i-line that passes near the North Pole
586            IF( jp_cfg == 1   )   iline =  96   ! i-line that passes near the North Pole
587            IF( jp_cfg == 2   )   iline =  48   ! i-line that passes near the North Pole
588            IF( jp_cfg == 4   )   iline =  24   ! i-line that passes near the North Pole
589            zphi(1:jpj) = 0._wp
590            DO ji = mi0(iline), mi1(iline) 
591               zphi(1:jpj) = gphiv(ji,:)         ! if iline is in the local domain
592               ! Correct highest latitude for some configurations - will work if domain is parallelized in J ?
593               IF( jp_cfg == 05 ) THEN
594                  DO jj = mj0(jpjdta), mj1(jpjdta) 
595                     zphi( jj ) = zphi(mj0(jpjdta-1)) + ( zphi(mj0(jpjdta-1))-zphi(mj0(jpjdta-2)) ) * 0.5_wp
596                     zphi( jj ) = MIN( zphi(jj), 90._wp )
597                  END DO
598               END IF
599               IF( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) THEN
600                  DO jj = mj0(jpjdta-1), mj1(jpjdta-1) 
601                     zphi( jj ) = 88.5_wp
602                  END DO
603                  DO jj = mj0(jpjdta  ), mj1(jpjdta  ) 
604                     zphi( jj ) = 89.5_wp
605                  END DO
606               END IF
607            END DO
608            ! provide the correct zphi to all local domains
609#if defined key_mpp_mpi
610            CALL mpp_sum( zphi, jpj, ncomm_znl )       
611#endif
612            !                                        ! =======================
613         ELSE                                        !   OTHER configurations
614            !                                        ! =======================
615            zphi(1:jpj) = gphiv(1,:)             ! assume lat/lon coordinate, select the first i-line
616            !
617         ENDIF
618         !
619         ! Work only on westmost processor (will not work if mppini2 is used)
620#if defined key_mpp_mpi
621         IF( l_znl_root ) THEN 
622#endif
623            !
624            ! OPEN netcdf file
625            ! ----------------
626            ! Define frequency of output and means
627            zsto = nn_fptr * zdt
628            IF( ln_mskland )   THEN    ! put 1.e+20 on land (very expensive!!)
629               clop      = "ave(only(x))"
630               clop_once = "once(only(x))"
631            ELSE                       ! no use of the mask value (require less cpu time)
632               clop      = "ave(x)"       
633               clop_once = "once"
634            ENDIF
635
636            zout = nn_fwri * zdt
637            zfoo(1:jpj) = 0._wp
638
639            CALL ymds2ju( nyear, nmonth, nday, rdt, zjulian )  ! Compute julian date from starting date of the run
640            zjulian = zjulian - adatrj                         ! set calendar origin to the beginning of the experiment
641
642#if defined key_iomput
643            ! Requested by IPSL people, use by their postpro...
644            IF(lwp) THEN
645               CALL dia_nam( clhstnam, nn_fwri,' ' )
646               CALL ctl_opn( inum, 'date.file', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
647               WRITE(inum,*) clhstnam
648               CLOSE(inum)
649            ENDIF
650#endif
651
652            CALL dia_nam( clhstnam, nn_fwri, 'diaptr' )
653            IF(lwp)WRITE( numout,*)" Name of diaptr NETCDF file : ", clhstnam
654
655            ! Horizontal grid : zphi()
656            CALL histbeg(clhstnam, 1, zfoo, jpj, zphi,   &
657               1, 1, 1, jpj, niter, zjulian, zdt*nn_fptr, nhoridz, numptr, domain_id=nidom_ptr)
658            ! Vertical grids : gdept_0, gdepw_0
659            CALL histvert( numptr, "deptht", "Vertical T levels",   &
660               &                   "m", jpk, gdept_0, ndepidzt, "down" )
661            CALL histvert( numptr, "depthw", "Vertical W levels",   &
662               &                   "m", jpk, gdepw_0, ndepidzw, "down" )
663            !
664            CALL wheneq ( jpj*jpk, MIN(sjk(:,:,1), 1._wp), 1, 1., ndex  , ndim  )      ! Lat-Depth
665            CALL wheneq ( jpj    , MIN(sjk(:,1,1), 1._wp), 1, 1., ndex_h, ndim_h )     ! Lat
666
667            IF( ln_subbas ) THEN
668               z_1(:,1) = 1._wp
669               WHERE ( gphit(jpi/2,:) < -30._wp )   z_1(:,1) = 0._wp
670               DO jk = 2, jpk
671                  z_1(:,jk) = z_1(:,1)
672               END DO
673               !                       ! Atlantic (jn=2)
674               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)         , 1._wp), 1, 1., ndex_atl     , ndim_atl      ) ! Lat-Depth
675               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)*z_1(:,:), 1._wp), 1, 1., ndex_atl_30  , ndim_atl_30   ) ! Lat-Depth
676               CALL wheneq ( jpj    , MIN(sjk(:,1,2)*z_1(:,1), 1._wp), 1, 1., ndex_h_atl_30, ndim_h_atl_30 ) ! Lat
677               !                       ! Pacific (jn=3)
678               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)         , 1._wp), 1, 1., ndex_pac     , ndim_pac      ) ! Lat-Depth
679               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)*z_1(:,:), 1._wp), 1, 1., ndex_pac_30  , ndim_pac_30   ) ! Lat-Depth
680               CALL wheneq ( jpj    , MIN(sjk(:,1,3)*z_1(:,1), 1._wp), 1, 1., ndex_h_pac_30, ndim_h_pac_30 ) ! Lat
681               !                       ! Indian (jn=4)
682               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)         , 1._wp), 1, 1., ndex_ind     , ndim_ind      ) ! Lat-Depth
683               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)*z_1(:,:), 1._wp), 1, 1., ndex_ind_30  , ndim_ind_30   ) ! Lat-Depth
684               CALL wheneq ( jpj    , MIN(sjk(:,1,4)*z_1(:,1), 1._wp), 1, 1., ndex_h_ind_30, ndim_h_ind_30 ) ! Lat
685               !                       ! Indo-Pacific (jn=5)
686               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)         , 1._wp), 1, 1., ndex_ipc     , ndim_ipc      ) ! Lat-Depth
687               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)*z_1(:,:), 1._wp), 1, 1., ndex_ipc_30  , ndim_ipc_30   ) ! Lat-Depth
688               CALL wheneq ( jpj    , MIN(sjk(:,1,5)*z_1(:,1), 1._wp), 1, 1., ndex_h_ipc_30, ndim_h_ipc_30 ) ! Lat
689            ENDIF
690            !
691#if defined key_diaeiv
692            cl_comment = ' (Bolus part included)'
693#else
694            cl_comment = '                      '
695#endif
696            IF( ln_diaznl ) THEN             !  Zonal mean T and S
697               CALL histdef( numptr, "zotemglo", "Zonal Mean Temperature","C" ,   &
698                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
699               CALL histdef( numptr, "zosalglo", "Zonal Mean Salinity","PSU"  ,   &
700                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
701
702               CALL histdef( numptr, "zosrfglo", "Zonal Mean Surface","m^2"   ,   &
703                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
704               !
705               IF (ln_subbas) THEN
706                  CALL histdef( numptr, "zotematl", "Zonal Mean Temperature: Atlantic","C" ,   &
707                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
708                  CALL histdef( numptr, "zosalatl", "Zonal Mean Salinity: Atlantic","PSU"  ,   &
709                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
710                  CALL histdef( numptr, "zosrfatl", "Zonal Mean Surface: Atlantic","m^2"   ,   &
711                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
712
713                  CALL histdef( numptr, "zotempac", "Zonal Mean Temperature: Pacific","C"  ,   &
714                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
715                  CALL histdef( numptr, "zosalpac", "Zonal Mean Salinity: Pacific","PSU"   ,   &
716                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
717                  CALL histdef( numptr, "zosrfpac", "Zonal Mean Surface: Pacific","m^2"    ,   &
718                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
719
720                  CALL histdef( numptr, "zotemind", "Zonal Mean Temperature: Indian","C"   ,   &
721                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
722                  CALL histdef( numptr, "zosalind", "Zonal Mean Salinity: Indian","PSU"    ,   &
723                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
724                  CALL histdef( numptr, "zosrfind", "Zonal Mean Surface: Indian","m^2"     ,   &
725                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
726
727                  CALL histdef( numptr, "zotemipc", "Zonal Mean Temperature: Pacific+Indian","C" ,   &
728                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
729                  CALL histdef( numptr, "zosalipc", "Zonal Mean Salinity: Pacific+Indian","PSU"  ,   &
730                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
731                  CALL histdef( numptr, "zosrfipc", "Zonal Mean Surface: Pacific+Indian","m^2"   ,   &
732                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
733               ENDIF
734            ENDIF
735            !
736            !  Meridional Stream-Function (Eulerian and Bolus)
737            CALL histdef( numptr, "zomsfglo", "Meridional Stream-Function: Global"//TRIM(cl_comment),"Sv" ,   &
738               1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
739            IF( ln_subbas .AND. ln_diaznl ) THEN
740               CALL histdef( numptr, "zomsfatl", "Meridional Stream-Function: Atlantic"//TRIM(cl_comment),"Sv" ,   &
741                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
742               CALL histdef( numptr, "zomsfpac", "Meridional Stream-Function: Pacific"//TRIM(cl_comment),"Sv"  ,   &
743                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
744               CALL histdef( numptr, "zomsfind", "Meridional Stream-Function: Indian"//TRIM(cl_comment),"Sv"   ,   &
745                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
746               CALL histdef( numptr, "zomsfipc", "Meridional Stream-Function: Indo-Pacific"//TRIM(cl_comment),"Sv" ,&
747                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
748            ENDIF
749            !
750            !  Heat transport
751            CALL histdef( numptr, "sophtadv", "Advective Heat Transport"      ,   &
752               "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
753            CALL histdef( numptr, "sophtldf", "Diffusive Heat Transport"      ,   &
754               "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
755            IF ( ln_ptrcomp ) THEN
756               CALL histdef( numptr, "sophtove", "Overturning Heat Transport"    ,   &
757                  "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
758            END IF
759            IF( ln_subbas ) THEN
760               CALL histdef( numptr, "sohtatl", "Heat Transport Atlantic"//TRIM(cl_comment),  &
761                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
762               CALL histdef( numptr, "sohtpac", "Heat Transport Pacific"//TRIM(cl_comment) ,  &
763                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
764               CALL histdef( numptr, "sohtind", "Heat Transport Indian"//TRIM(cl_comment)  ,  &
765                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
766               CALL histdef( numptr, "sohtipc", "Heat Transport Pacific+Indian"//TRIM(cl_comment), &
767                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
768            ENDIF
769            !
770            !  Salt transport
771            CALL histdef( numptr, "sopstadv", "Advective Salt Transport"      ,   &
772               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
773            CALL histdef( numptr, "sopstldf", "Diffusive Salt Transport"      ,   &
774               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
775            IF ( ln_ptrcomp ) THEN
776               CALL histdef( numptr, "sopstove", "Overturning Salt Transport"    ,   &
777                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
778            END IF
779#if defined key_diaeiv
780            ! Eddy induced velocity
781            CALL histdef( numptr, "zomsfeiv", "Bolus Meridional Stream-Function: global",   &
782               "Sv"      , 1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
783            CALL histdef( numptr, "sophteiv", "Bolus Advective Heat Transport",   &
784               "PW"      , 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
785            CALL histdef( numptr, "sopsteiv", "Bolus Advective Salt Transport",   &
786               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
787#endif
788            IF( ln_subbas ) THEN
789               CALL histdef( numptr, "sostatl", "Salt Transport Atlantic"//TRIM(cl_comment)      ,  &
790                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
791               CALL histdef( numptr, "sostpac", "Salt Transport Pacific"//TRIM(cl_comment)      ,   &
792                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
793               CALL histdef( numptr, "sostind", "Salt Transport Indian"//TRIM(cl_comment)      ,    &
794                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
795               CALL histdef( numptr, "sostipc", "Salt Transport Pacific+Indian"//TRIM(cl_comment),  &
796                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
797            ENDIF
798            !
799            CALL histend( numptr )
800            !
801         END IF
802#if defined key_mpp_mpi
803      END IF
804#endif
805
806#if defined key_mpp_mpi
807      IF( MOD( itmod, nn_fptr ) == 0 .AND. l_znl_root ) THEN
808#else
809      IF( MOD( itmod, nn_fptr ) == 0  ) THEN
810#endif
811         niter = niter + 1
812
813         IF( ln_diaznl ) THEN
814            CALL histwrite( numptr, "zosrfglo", niter, sjk  (:,:,1) , ndim, ndex )
815            CALL histwrite( numptr, "zotemglo", niter, tn_jk(:,:,1)  , ndim, ndex )
816            CALL histwrite( numptr, "zosalglo", niter, sn_jk(:,:,1)  , ndim, ndex )
817
818            IF (ln_subbas) THEN
819               CALL histwrite( numptr, "zosrfatl", niter, sjk(:,:,2), ndim_atl, ndex_atl )
820               CALL histwrite( numptr, "zosrfpac", niter, sjk(:,:,3), ndim_pac, ndex_pac )
821               CALL histwrite( numptr, "zosrfind", niter, sjk(:,:,4), ndim_ind, ndex_ind )
822               CALL histwrite( numptr, "zosrfipc", niter, sjk(:,:,5), ndim_ipc, ndex_ipc )
823
824               CALL histwrite( numptr, "zotematl", niter, tn_jk(:,:,2)  , ndim_atl, ndex_atl )
825               CALL histwrite( numptr, "zosalatl", niter, sn_jk(:,:,2)  , ndim_atl, ndex_atl )
826               CALL histwrite( numptr, "zotempac", niter, tn_jk(:,:,3)  , ndim_pac, ndex_pac )
827               CALL histwrite( numptr, "zosalpac", niter, sn_jk(:,:,3)  , ndim_pac, ndex_pac )
828               CALL histwrite( numptr, "zotemind", niter, tn_jk(:,:,4)  , ndim_ind, ndex_ind )
829               CALL histwrite( numptr, "zosalind", niter, sn_jk(:,:,4)  , ndim_ind, ndex_ind )
830               CALL histwrite( numptr, "zotemipc", niter, tn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
831               CALL histwrite( numptr, "zosalipc", niter, sn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
832            END IF
833         ENDIF
834
835         ! overturning outputs:
836         CALL histwrite( numptr, "zomsfglo", niter, v_msf(:,:,1), ndim, ndex )
837         IF( ln_subbas .AND. ln_diaznl ) THEN
838            CALL histwrite( numptr, "zomsfatl", niter, v_msf(:,:,2) , ndim_atl_30, ndex_atl_30 )
839            CALL histwrite( numptr, "zomsfpac", niter, v_msf(:,:,3) , ndim_pac_30, ndex_pac_30 )
840            CALL histwrite( numptr, "zomsfind", niter, v_msf(:,:,4) , ndim_ind_30, ndex_ind_30 )
841            CALL histwrite( numptr, "zomsfipc", niter, v_msf(:,:,5) , ndim_ipc_30, ndex_ipc_30 )
842         ENDIF
843#if defined key_diaeiv
844         CALL histwrite( numptr, "zomsfeiv", niter, v_msf_eiv(:,:,1), ndim  , ndex   )
845#endif
846
847         ! heat transport outputs:
848         IF( ln_subbas ) THEN
849            CALL histwrite( numptr, "sohtatl", niter, htr(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
850            CALL histwrite( numptr, "sohtpac", niter, htr(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
851            CALL histwrite( numptr, "sohtind", niter, htr(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
852            CALL histwrite( numptr, "sohtipc", niter, htr(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
853            CALL histwrite( numptr, "sostatl", niter, str(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
854            CALL histwrite( numptr, "sostpac", niter, str(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
855            CALL histwrite( numptr, "sostind", niter, str(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
856            CALL histwrite( numptr, "sostipc", niter, str(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
857         ENDIF
858
859         CALL histwrite( numptr, "sophtadv", niter, htr_adv     , ndim_h, ndex_h )
860         CALL histwrite( numptr, "sophtldf", niter, htr_ldf     , ndim_h, ndex_h )
861         CALL histwrite( numptr, "sopstadv", niter, str_adv     , ndim_h, ndex_h )
862         CALL histwrite( numptr, "sopstldf", niter, str_ldf     , ndim_h, ndex_h )
863         IF( ln_ptrcomp ) THEN
864            CALL histwrite( numptr, "sopstove", niter, str_ove(:) , ndim_h, ndex_h )
865            CALL histwrite( numptr, "sophtove", niter, htr_ove(:) , ndim_h, ndex_h )
866         ENDIF
867#if defined key_diaeiv
868         CALL histwrite( numptr, "sophteiv", niter, htr_eiv(:,1)  , ndim_h, ndex_h )
869         CALL histwrite( numptr, "sopsteiv", niter, str_eiv(:,1)  , ndim_h, ndex_h )
870#endif
871         !
872      ENDIF
873      !
874      CALL wrk_dealloc( jpi      , zphi , zfoo )
875      CALL wrk_dealloc( jpi , jpk, z_1 )
876      !
877  END SUBROUTINE dia_ptr_wri
878
879   !!======================================================================
880END MODULE diaptr
Note: See TracBrowser for help on using the repository browser.