New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 3186

Last change on this file since 3186 was 3186, checked in by smasson, 12 years ago

dev_NEMO_MERGE_2011: replace the old wrk_nemo with the new wrk_nemo

File size: 15.7 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init   = .FALSE.    !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp = .FALSE.    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id: dtatem.F90 2392 2010-11-15 21:20:05Z gm $
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dta_tsd_init( ld_tradmp )
47      !!----------------------------------------------------------------------
48      !!                   ***  ROUTINE dta_tsd_init  ***
49      !!                   
50      !! ** Purpose :   initialisation of T & S input data
51      !!
52      !! ** Method  : - Read namtsd namelist
53      !!              - allocates T & S data structure
54      !!----------------------------------------------------------------------
55      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
56      !
57      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
58      !
59      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
60      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
61      TYPE(FLD_N)                   ::   sn_tem, sn_sal
62      !!
63      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
64      !!----------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
67      !
68      !                             ! set default namelist values
69      cn_dir = './'                       ! directory in which the model is executed
70      !                                   ! sn_... default values (NB: frequency positive => hours, negative => months)
71      !            !   file    ! frequency ! variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation !
72      !            !   name    !  (hours)  !  name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    !
73      sn_tem = FLD_N( 'temperature',  -1.  , 'votemper',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
74      sn_sal = FLD_N( 'salinity'   ,  -1.  , 'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
75
76      REWIND( numnam )              ! read in namlist namdta_tsd
77      READ  ( numnam, namtsd ) 
78
79      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
80     
81      IF(lwp) THEN                  ! control print
82         WRITE(numout,*)
83         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
84         WRITE(numout,*) '~~~~~~~~~~~~ '
85         WRITE(numout,*) '   Namelist namtsd'
86         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
87         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
88         WRITE(numout,*)
89         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
90            WRITE(numout,*)
91            WRITE(numout,*) '   T & S data not used'
92         ENDIF
93      ENDIF
94      !
95      IF( ln_rstart .AND. ln_tsd_init ) THEN
96         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
97            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
98         ln_tsd_init = .FALSE.
99      ENDIF
100      !
101      !                             ! allocate the arrays (if necessary)
102      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
103         !
104         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
105         IF( ierr0 > 0 ) THEN
106            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
107         ENDIF
108         !
109                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
110         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
111                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
112         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
113         !
114         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
115            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
116         ENDIF
117         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
118         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
119         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
120         !
121      ENDIF
122      !
123      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
124      !
125   END SUBROUTINE dta_tsd_init
126
127
128   SUBROUTINE dta_tsd( kt, ptsd )
129      !!----------------------------------------------------------------------
130      !!                   ***  ROUTINE dta_tsd  ***
131      !!                   
132      !! ** Purpose :   provides T and S data at kt
133      !!
134      !! ** Method  : - call fldread routine
135      !!              - ORCA_R2: add some hand made alteration to read data 
136      !!              - 'key_orca_lev10' interpolates on 10 times more levels
137      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
138      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
139      !!                as T-S data are no are used
140      !!
141      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
142      !!----------------------------------------------------------------------
143      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
144      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
145      !
146      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
147      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
148      REAL(wp)::   zl, zi
149      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
150      !!----------------------------------------------------------------------
151      !
152      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
153      !
154      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
155      !
156      !
157      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
158      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
159         !
160         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
161         ii0 = 141   ;   ii1 = 155
162         DO jj = mj0(ij0), mj1(ij1)
163            DO ji = mi0(ii0), mi1(ii1)
164               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
165               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
166               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
167               !
168               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
169               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
170               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
171               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
172            END DO
173         END DO
174         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
175            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
176            ij0 = 101   ;   ij1 = 102
177            ii0 = 139   ;   ii1 = 139
178            DO jl = mi0(il0), mi1(il1)
179               DO jj = mj0(ij0), mj1(ij1)
180                  DO ji = mi0(ii0), mi1(ii1)
181                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
182                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
183                  END DO
184               END DO
185            END DO
186            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
187            ij0 =  87   ;   ij1 =  88
188            ii0 = 161   ;   ii1 = 163
189            DO jl = mi0(il0), mi1(il1)
190               DO jj = mj0(ij0), mj1(ij1)
191                  DO ji = mi0(ii0), mi1(ii1)
192                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
193                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
194                  END DO
195               END DO
196            END DO
197         ELSE                                            ! No Cross Land advection
198            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
199            ii0 = 148   ;   ii1 = 160
200            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
201            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
202            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
203         ENDIF
204      ENDIF
205      !
206      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
207      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
208      !
209      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
210         !
211         CALL wrk_alloc( jpk, ztp, zsp )
212         !
213         IF( kt == nit000 .AND. lwp )THEN
214            WRITE(numout,*)
215            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
216         ENDIF
217         !
218         DO jj = 1, jpj                         ! vertical interpolation of T & S
219            DO ji = 1, jpi
220               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
221                  zl = fsdept_0(ji,jj,jk)
222                  IF(     zl < gdept_0(1  ) ) THEN          ! above the first level of data
223                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
224                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
225                  ELSEIF( zl > gdept_0(jpk) ) THEN          ! below the last level of data
226                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
227                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
228                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
229                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
230                        IF( (zl-gdept_0(jkk)) * (zl-gdept_0(jkk+1)) <= 0._wp ) THEN
231                           zi = ( zl - gdept_0(jkk) ) / (gdept_0(jkk+1)-gdept_0(jkk))
232                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
233                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
234                        ENDIF
235                     END DO
236                  ENDIF
237               END DO
238               DO jk = 1, jpkm1
239                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
240                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
241               END DO
242               ptsd(ji,jj,jpk,jp_tem) = 0._wp
243               ptsd(ji,jj,jpk,jp_sal) = 0._wp
244            END DO
245         END DO
246         !
247         CALL wrk_dealloc( jpk, ztp, zsp )
248         !
249      ELSE                                !==   z- or zps- coordinate   ==!
250         !                             
251         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
252         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
253         !
254         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
255            DO jj = 1, jpj
256               DO ji = 1, jpi
257                  ik = mbkt(ji,jj) 
258                  IF( ik > 1 ) THEN
259                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
260                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
261                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
262                  ENDIF
263               END DO
264            END DO
265         ENDIF
266         !
267      ENDIF
268      !
269      IF( lwp .AND. kt == nit000 ) THEN
270         WRITE(numout,*) ' temperature Levitus '
271         WRITE(numout,*)
272         WRITE(numout,*)'  level = 1'
273         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
274         WRITE(numout,*)'  level = ', jpk/2
275         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
276         WRITE(numout,*)'  level = ', jpkm1
277         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
278         WRITE(numout,*)
279         WRITE(numout,*) ' salinity Levitus '
280         WRITE(numout,*)
281         WRITE(numout,*)'  level = 1'
282         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
283         WRITE(numout,*)'  level = ', jpk/2
284         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
285         WRITE(numout,*)'  level = ', jpkm1
286         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
287         WRITE(numout,*)
288      ENDIF
289      !
290      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
291         !                                              (data used only for initialisation)
292         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
293                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
294         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
295                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
296         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
297                                        DEALLOCATE( sf_tsd              )     ! the structure itself
298      ENDIF
299      !
300      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
301      !
302   END SUBROUTINE dta_tsd
303
304   !!======================================================================
305END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.