New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 3223

Last change on this file since 3223 was 3223, checked in by hliu, 12 years ago

updated hpg_prj in dynhpg.F90: 1) some optimisation in c-spline subroutine to save some computational amount. 2) added some explanations text in Subroutine hpg_prj(). 3) modifications on the head information about hpg_prj
  • Property svn:keywords set to Id
File size: 53.1 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dyn_hpg        ! routine called by step module
46   PUBLIC   dyn_hpg_init   ! routine called by opa module
47
48   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
49   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
50   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
51   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
52   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
53   LOGICAL , PUBLIC ::   ln_hpg_prj    = .FALSE.   !: s-coordinate (Pressure Jacobian scheme)
54   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
55
56   INTEGER  ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!   
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - Save the trend (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
79      !!
80      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
85      !
86      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
87         ztrdu => tsa(:,:,:,1) 
88         ztrdv => tsa(:,:,:,2) 
89         !
90         ztrdu(:,:,:) = ua(:,:,:) 
91         ztrdv(:,:,:) = va(:,:,:) 
92      ENDIF     
93      !
94      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
95      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
96      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
97      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
98      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
99      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
100      END SELECT
101      !
102      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
103         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
104         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
105         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
106      ENDIF         
107      !
108      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
109         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
110      !
111      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
112      !
113   END SUBROUTINE dyn_hpg
114
115
116   SUBROUTINE dyn_hpg_init
117      !!----------------------------------------------------------------------
118      !!                 ***  ROUTINE dyn_hpg_init  ***
119      !!
120      !! ** Purpose :   initializations for the hydrostatic pressure gradient
121      !!              computation and consistency control
122      !!
123      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
124      !!      with the type of vertical coordinate used (zco, zps, sco)
125      !!----------------------------------------------------------------------
126      INTEGER ::   ioptio = 0      ! temporary integer
127      !!
128      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
129         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
130      !!----------------------------------------------------------------------
131      !
132      REWIND( numnam )               ! Read Namelist namdyn_hpg
133      READ  ( numnam, namdyn_hpg )
134      !
135      IF(lwp) THEN                   ! Control print
136         WRITE(numout,*)
137         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
138         WRITE(numout,*) '~~~~~~~~~~~~'
139         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
140         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
141         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
142         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
143         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
144         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
145         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
146      ENDIF
147      !
148      IF( ln_hpg_djc )   &
149         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
150                           & currently disabled (bugs under investigation). Please select &
151                           & either  ln_hpg_sco or  ln_hpg_prj instead')
152      !
153      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
154         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
155                           & the standard jacobian formulation hpg_sco or &
156                           & the pressure jacobian formulation hpg_prj')
157      !
158      !                               ! Set nhpg from ln_hpg_... flags
159      IF( ln_hpg_zco )   nhpg = 0
160      IF( ln_hpg_zps )   nhpg = 1
161      IF( ln_hpg_sco )   nhpg = 2
162      IF( ln_hpg_djc )   nhpg = 3
163      IF( ln_hpg_prj )   nhpg = 4
164      !
165      !                               ! Consistency check
166      ioptio = 0 
167      IF( ln_hpg_zco )   ioptio = ioptio + 1
168      IF( ln_hpg_zps )   ioptio = ioptio + 1
169      IF( ln_hpg_sco )   ioptio = ioptio + 1
170      IF( ln_hpg_djc )   ioptio = ioptio + 1
171      IF( ln_hpg_prj )   ioptio = ioptio + 1
172      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
173      !
174   END SUBROUTINE dyn_hpg_init
175
176
177   SUBROUTINE hpg_zco( kt )
178      !!---------------------------------------------------------------------
179      !!                  ***  ROUTINE hpg_zco  ***
180      !!
181      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
182      !!      The now hydrostatic pressure gradient at a given level, jk,
183      !!      is computed by taking the vertical integral of the in-situ
184      !!      density gradient along the model level from the suface to that
185      !!      level:    zhpi = grav .....
186      !!                zhpj = grav .....
187      !!      add it to the general momentum trend (ua,va).
188      !!            ua = ua - 1/e1u * zhpi
189      !!            va = va - 1/e2v * zhpj
190      !!
191      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
192      !!----------------------------------------------------------------------
193      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
194      !!
195      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
196      !!
197      INTEGER  ::   ji, jj, jk       ! dummy loop indices
198      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
199      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
200      !!----------------------------------------------------------------------
201     
202      zhpi => tsa(:,:,:,1) 
203      zhpj => tsa(:,:,:,2) 
204      !
205      IF( kt == nit000 ) THEN
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
208         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
209      ENDIF
210     
211      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
212
213      ! Surface value
214      DO jj = 2, jpjm1
215         DO ji = fs_2, fs_jpim1   ! vector opt.
216            zcoef1 = zcoef0 * fse3w(ji,jj,1)
217            ! hydrostatic pressure gradient
218            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
219            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
220            ! add to the general momentum trend
221            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
222            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
223         END DO
224      END DO
225
226      !
227      ! interior value (2=<jk=<jpkm1)
228      DO jk = 2, jpkm1
229         DO jj = 2, jpjm1
230            DO ji = fs_2, fs_jpim1   ! vector opt.
231               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
232               ! hydrostatic pressure gradient
233               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
234                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
235                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
236
237               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
238                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
239                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
240               ! add to the general momentum trend
241               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
242               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
243            END DO
244         END DO
245      END DO
246      !
247   END SUBROUTINE hpg_zco
248
249
250   SUBROUTINE hpg_zps( kt )
251      !!---------------------------------------------------------------------
252      !!                 ***  ROUTINE hpg_zps  ***
253      !!                   
254      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
255      !!
256      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
257      !!----------------------------------------------------------------------
258      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
259      !!
260      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
261      !!
262      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
263      INTEGER  ::   iku, ikv                         ! temporary integers
264      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
265      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
266      !!----------------------------------------------------------------------
267       
268      zhpi => tsa(:,:,:,1) 
269      zhpj => tsa(:,:,:,2) 
270      !
271      IF( kt == nit000 ) THEN
272         IF(lwp) WRITE(numout,*)
273         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
274         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
275      ENDIF
276
277
278      ! Local constant initialization
279      zcoef0 = - grav * 0.5_wp
280
281      !  Surface value (also valid in partial step case)
282      DO jj = 2, jpjm1
283         DO ji = fs_2, fs_jpim1   ! vector opt.
284            zcoef1 = zcoef0 * fse3w(ji,jj,1)
285            ! hydrostatic pressure gradient
286            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
287            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
288            ! add to the general momentum trend
289            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
290            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
291         END DO
292      END DO
293
294
295      ! interior value (2=<jk=<jpkm1)
296      DO jk = 2, jpkm1
297         DO jj = 2, jpjm1
298            DO ji = fs_2, fs_jpim1   ! vector opt.
299               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
300               ! hydrostatic pressure gradient
301               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
302                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
303                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
304
305               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
306                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
307                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
308               ! add to the general momentum trend
309               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
310               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
311            END DO
312         END DO
313      END DO
314
315
316      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
317# if defined key_vectopt_loop
318         jj = 1
319         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
320# else
321      DO jj = 2, jpjm1
322         DO ji = 2, jpim1
323# endif
324            iku = mbku(ji,jj)
325            ikv = mbkv(ji,jj)
326            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
327            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
328            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
329               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
330               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
331                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
332               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
333            ENDIF
334            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
335               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
336               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
337                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
338               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
339            ENDIF
340# if ! defined key_vectopt_loop
341         END DO
342# endif
343      END DO
344      !
345
346   END SUBROUTINE hpg_zps
347
348
349   SUBROUTINE hpg_sco( kt )
350      !!---------------------------------------------------------------------
351      !!                  ***  ROUTINE hpg_sco  ***
352      !!
353      !! ** Method  :   s-coordinate case. Jacobian scheme.
354      !!      The now hydrostatic pressure gradient at a given level, jk,
355      !!      is computed by taking the vertical integral of the in-situ
356      !!      density gradient along the model level from the suface to that
357      !!      level. s-coordinates (ln_sco): a corrective term is added
358      !!      to the horizontal pressure gradient :
359      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
360      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
361      !!      add it to the general momentum trend (ua,va).
362      !!         ua = ua - 1/e1u * zhpi
363      !!         va = va - 1/e2v * zhpj
364      !!
365      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
366      !!----------------------------------------------------------------------
367      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
368      !!
369      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
370      !!
371      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
372      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
373      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
374      !!----------------------------------------------------------------------
375
376      zhpi => tsa(:,:,:,1) 
377      zhpj => tsa(:,:,:,2) 
378      !
379      IF( kt == nit000 ) THEN
380         IF(lwp) WRITE(numout,*)
381         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
382         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
383      ENDIF
384
385      ! Local constant initialization
386      zcoef0 = - grav * 0.5_wp
387      ! To use density and not density anomaly
388      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
389      ELSE                 ;     znad = 0._wp         ! Fixed volume
390      ENDIF
391
392      ! Surface value
393      DO jj = 2, jpjm1
394         DO ji = fs_2, fs_jpim1   ! vector opt.   
395            ! hydrostatic pressure gradient along s-surfaces
396            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
397               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
398            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
399               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
400            ! s-coordinate pressure gradient correction
401            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
402               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
403            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
404               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
405            ! add to the general momentum trend
406            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
407            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
408         END DO 
409      END DO   
410           
411      ! interior value (2=<jk=<jpkm1)
412      DO jk = 2, jpkm1                                 
413         DO jj = 2, jpjm1     
414            DO ji = fs_2, fs_jpim1   ! vector opt.     
415               ! hydrostatic pressure gradient along s-surfaces
416               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
417                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
418                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
419               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
420                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
421                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
422               ! s-coordinate pressure gradient correction
423               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
424                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
425               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
426                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
427               ! add to the general momentum trend
428               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
429               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
430            END DO
431         END DO
432      END DO
433      !
434   END SUBROUTINE hpg_sco
435
436   SUBROUTINE hpg_djc( kt )
437      !!---------------------------------------------------------------------
438      !!                  ***  ROUTINE hpg_djc  ***
439      !!
440      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
441      !!
442      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
443      !!----------------------------------------------------------------------
444      USE oce     , ONLY:   tsa                         ! (tsa) used as 2 3D workspace
445      !!
446      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
447      !!
448      INTEGER  ::   ji, jj, jk          ! dummy loop indices
449      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
450      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
451      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
452      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
453      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
454      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
455      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
456      !!----------------------------------------------------------------------
457      !
458      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
459      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
460      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k                      ) 
461      zhpi => tsa(:,:,:,1) 
462      zhpj => tsa(:,:,:,2) 
463      !
464
465      IF( kt == nit000 ) THEN
466         IF(lwp) WRITE(numout,*)
467         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
468         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
469      ENDIF
470
471      ! Local constant initialization
472      zcoef0 = - grav * 0.5_wp
473      z1_10  = 1._wp / 10._wp
474      z1_12  = 1._wp / 12._wp
475
476      !----------------------------------------------------------------------------------------
477      !  compute and store in provisional arrays elementary vertical and horizontal differences
478      !----------------------------------------------------------------------------------------
479
480!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
481
482      DO jk = 2, jpkm1
483         DO jj = 2, jpjm1
484            DO ji = fs_2, fs_jpim1   ! vector opt.
485               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
486               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
487               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
488               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
489               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
490               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
491            END DO
492         END DO
493      END DO
494
495      !-------------------------------------------------------------------------
496      ! compute harmonic averages using eq. 5.18
497      !-------------------------------------------------------------------------
498      zep = 1.e-15
499
500!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
501!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
502
503      DO jk = 2, jpkm1
504         DO jj = 2, jpjm1
505            DO ji = fs_2, fs_jpim1   ! vector opt.
506               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
507
508               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
509               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
510 
511               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
512               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
513
514               IF( cffw > zep) THEN
515                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
516                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
517               ELSE
518                  drhow(ji,jj,jk) = 0._wp
519               ENDIF
520
521               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
522                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
523
524               IF( cffu > zep ) THEN
525                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
526                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
527               ELSE
528                  drhou(ji,jj,jk ) = 0._wp
529               ENDIF
530
531               IF( cffx > zep ) THEN
532                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
533                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
534               ELSE
535                  dzu(ji,jj,jk) = 0._wp
536               ENDIF
537
538               IF( cffv > zep ) THEN
539                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
540                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
541               ELSE
542                  drhov(ji,jj,jk) = 0._wp
543               ENDIF
544
545               IF( cffy > zep ) THEN
546                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
547                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
548               ELSE
549                  dzv(ji,jj,jk) = 0._wp
550               ENDIF
551
552            END DO
553         END DO
554      END DO
555
556      !----------------------------------------------------------------------------------
557      ! apply boundary conditions at top and bottom using 5.36-5.37
558      !----------------------------------------------------------------------------------
559      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
560      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
561      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
562
563      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
564      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
565      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
566
567
568      !--------------------------------------------------------------
569      ! Upper half of top-most grid box, compute and store
570      !-------------------------------------------------------------
571
572!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
573!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
574
575      DO jj = 2, jpjm1
576         DO ji = fs_2, fs_jpim1   ! vector opt.
577            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
578               &                   * (  rhd(ji,jj,1)                                    &
579               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
580               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
581               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
582         END DO
583      END DO
584
585!!bug gm    : here also, simplification is possible
586!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
587
588      DO jk = 2, jpkm1
589         DO jj = 2, jpjm1
590            DO ji = fs_2, fs_jpim1   ! vector opt.
591
592               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
593                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
594                  &            - grav * z1_10 * (                                                                     &
595                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
596                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
597                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
598                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
599                  &                             )
600
601               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
602                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
603                  &            - grav* z1_10 * (                                                                      &
604                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
605                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
606                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
607                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
608                  &                            )
609
610               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
611                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
612                  &            - grav* z1_10 * (                                                                      &
613                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
614                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
615                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
616                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
617                  &                            )
618
619            END DO
620         END DO
621      END DO
622      CALL lbc_lnk(rho_k,'W',1.)
623      CALL lbc_lnk(rho_i,'U',1.)
624      CALL lbc_lnk(rho_j,'V',1.)
625
626
627      ! ---------------
628      !  Surface value
629      ! ---------------
630      DO jj = 2, jpjm1
631         DO ji = fs_2, fs_jpim1   ! vector opt.
632            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
633            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
634            ! add to the general momentum trend
635            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
636            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
637         END DO
638      END DO
639
640      ! ----------------
641      !  interior value   (2=<jk=<jpkm1)
642      ! ----------------
643      DO jk = 2, jpkm1
644         DO jj = 2, jpjm1 
645            DO ji = fs_2, fs_jpim1   ! vector opt.
646               ! hydrostatic pressure gradient along s-surfaces
647               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
648                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
649                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
650               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
651                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
652                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
653               ! add to the general momentum trend
654               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
655               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
656            END DO
657         END DO
658      END DO
659      !
660      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
661      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
662      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k                      ) 
663      !
664   END SUBROUTINE hpg_djc
665
666
667   SUBROUTINE hpg_prj( kt )
668      !!---------------------------------------------------------------------
669      !!                  ***  ROUTINE hpg_prj  ***
670      !!
671      !! ** Method  :   s-coordinate case.
672      !!      A Pressure-Jacobian horizontal pressure gradient method
673      !!      based on the constrained cubic-spline interpolation for
674      !!      all vertical coordinate systems
675      !!
676      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
677      !!             - Save the trend (l_trddyn=T)
678      !!
679      !!----------------------------------------------------------------------
680      USE oce     , ONLY:   tsa                          ! (tsa) used as 2 3D workspace
681      !!----------------------------------------------------------------------
682      !!
683      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
684      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
685      !!
686      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
687      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
688      !!
689      !! The local variables for the correction term
690      INTEGER  :: jk1, jis, jid, jjs, jjd
691      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
692      REAL(wp) :: zrhdt1 
693      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
694      INTEGER  :: zbhitwe, zbhitns
695      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdeptht, zrhh 
696      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
697      !!----------------------------------------------------------------------
698      !
699      CALL wrk_alloc( jpi, jpj, jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
700      zdeptht => tsa(:,:,:,1) 
701      zrhh    => tsa(:,:,:,2) 
702      !
703      IF( kt == nit000 ) THEN
704         IF(lwp) WRITE(numout,*)
705         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
706         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
707      ENDIF
708
709      !!----------------------------------------------------------------------
710      ! Local constant initialization
711      zcoef0 = - grav 
712      znad = 0.0_wp
713      IF( lk_vvl ) znad = 1._wp
714
715      ! Clean 3-D work arrays
716      zhpi(:,:,:) = 0._wp
717      zrhh(:,:,:) = rhd(:,:,:)
718     
719      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
720      DO jj = 1, jpj
721        DO ji = 1, jpi   
722          jk = mbathy(ji,jj)
723          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
724          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
725          ELSE IF(jk < jpkm1) THEN
726             DO jkk = jk+1, jpk
727                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
728                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
729             END DO
730          ENDIF
731        END DO
732      END DO
733
734      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdeptht(:,:,:)"
735      DO jj = 1, jpj
736        DO ji = 1, jpi
737          zdeptht(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1)
738          zdeptht(ji,jj,1) = zdeptht(ji,jj,1) - sshn(ji,jj) * znad
739          DO jk = 2, jpk
740             zdeptht(ji,jj,jk) = zdeptht(ji,jj,jk-1) + fse3w(ji,jj,jk)
741          END DO
742        END DO
743      END DO
744
745      DO jk = 1, jpkm1
746        DO jj = 1, jpj
747          DO ji = 1, jpi
748            fsp(ji,jj,jk) = zrhh(ji,jj,jk)
749            xsp(ji,jj,jk) = zdeptht(ji,jj,jk)
750          END DO
751        END DO
752      END DO
753
754      ! Construct the vertical density profile with the
755      ! constrained cubic spline interpolation
756      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
757      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)     
758
759      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
760      DO jj = 2, jpj
761        DO ji = 2, jpi 
762          zrhdt1 = zrhh(ji,jj,1) - interp3(zdeptht(ji,jj,1),asp(ji,jj,1), &
763                                         bsp(ji,jj,1),   csp(ji,jj,1), &
764                                         dsp(ji,jj,1) ) * 0.5_wp * zdeptht(ji,jj,1)
765          zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
766
767          ! assuming linear profile across the top half surface layer
768          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1 
769        END DO
770      END DO
771
772      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
773      DO jk = 2, jpkm1                                 
774        DO jj = 2, jpj     
775          DO ji = 2, jpi
776            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
777                             integ2(zdeptht(ji,jj,jk-1), zdeptht(ji,jj,jk),&
778                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
779                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
780          END DO
781        END DO
782      END DO
783
784      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
785      DO jj = 2, jpjm1     
786        DO ji = 2, jpim1 
787          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshu_n(ji,jj) * znad)
788          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshv_n(ji,jj) * znad)
789        END DO
790      END DO
791
792      DO jk = 2, jpkm1                                 
793        DO jj = 2, jpjm1     
794          DO ji = 2, jpim1 
795            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
796            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
797          END DO
798        END DO
799      END DO
800               
801      DO jk = 1, jpkm1                                 
802        DO jj = 2, jpjm1     
803          DO ji = 2, jpim1 
804            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
805            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
806          END DO
807        END DO
808      END DO
809
810      DO jk = 1, jpkm1                                 
811        DO jj = 2, jpjm1     
812          DO ji = 2, jpim1 
813            zpwes = 0._wp; zpwed = 0._wp
814            zpnss = 0._wp; zpnsd = 0._wp
815            zuijk = zu(ji,jj,jk)
816            zvijk = zv(ji,jj,jk)
817
818            !!!!!     for u equation
819            IF( jk <= mbku(ji,jj) ) THEN
820               IF( -zdeptht(ji+1,jj,mbku(ji,jj)) >= -zdeptht(ji,jj,mbku(ji,jj)) ) THEN
821                 jis = ji + 1; jid = ji
822               ELSE
823                 jis = ji;     jid = ji +1
824               ENDIF
825
826               ! integrate the pressure on the shallow side
827               jk1 = jk 
828               zbhitwe = 0
829               DO WHILE ( -zdeptht(jis,jj,jk1) > zuijk )
830                 IF( jk1 == mbku(ji,jj) ) THEN
831                   zbhitwe = 1
832                   EXIT
833                 ENDIF
834                 zdeps = MIN(zdeptht(jis,jj,jk1+1), -zuijk)
835                 zpwes = zpwes +                                    & 
836                      integ2(zdeptht(jis,jj,jk1), zdeps,            &
837                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
838                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
839                 jk1 = jk1 + 1
840               END DO
841           
842               IF(zbhitwe == 1) THEN
843                 zuijk = -zdeptht(jis,jj,jk1)
844               ENDIF
845
846               ! integrate the pressure on the deep side
847               jk1 = jk 
848               zbhitwe = 0
849               DO WHILE ( -zdeptht(jid,jj,jk1) < zuijk )
850                 IF( jk1 == 1 ) THEN
851                   zbhitwe = 1
852                   EXIT
853                 ENDIF
854                 zdeps = MAX(zdeptht(jid,jj,jk1-1), -zuijk)
855                 zpwed = zpwed +                                        & 
856                        integ2(zdeps,              zdeptht(jid,jj,jk1), &
857                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
858                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
859                 jk1 = jk1 - 1
860               END DO
861           
862               IF( zbhitwe == 1 ) THEN
863                 zdeps = zdeptht(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
864                 zrhdt1 = zrhh(jid,jj,1) - interp3(zdeptht(jid,jj,1), asp(jid,jj,1), &
865                                                 bsp(jid,jj,1),    csp(jid,jj,1), &
866                                                 dsp(jid,jj,1)) * zdeps
867                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
868                 zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
869               ENDIF
870
871               ! update the momentum trends in u direction
872
873               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
874               IF( lk_vvl ) THEN
875                 zdpdx2 = zcoef0 / e1u(ji,jj) * & 
876                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) ) 
877                ELSE
878                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed) 
879               ENDIF
880
881               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
882               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
883            ENDIF
884 
885            !!!!!     for v equation
886            IF( jk <= mbkv(ji,jj) ) THEN
887               IF( -zdeptht(ji,jj+1,mbkv(ji,jj)) >= -zdeptht(ji,jj,mbkv(ji,jj)) ) THEN
888                 jjs = jj + 1; jjd = jj
889               ELSE
890                 jjs = jj    ; jjd = jj + 1
891               ENDIF
892
893               ! integrate the pressure on the shallow side
894               jk1 = jk 
895               zbhitns = 0
896               DO WHILE ( -zdeptht(ji,jjs,jk1) > zvijk )
897                 IF( jk1 == mbkv(ji,jj) ) THEN
898                   zbhitns = 1
899                   EXIT
900                 ENDIF
901                 zdeps = MIN(zdeptht(ji,jjs,jk1+1), -zvijk)
902                 zpnss = zpnss +                                      & 
903                        integ2(zdeptht(ji,jjs,jk1), zdeps,            &
904                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
905                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
906                 jk1 = jk1 + 1
907               END DO
908           
909               IF(zbhitns == 1) THEN
910                 zvijk = -zdeptht(ji,jjs,jk1)
911               ENDIF
912
913               ! integrate the pressure on the deep side
914               jk1 = jk 
915               zbhitns = 0
916               DO WHILE ( -zdeptht(ji,jjd,jk1) < zvijk )
917                 IF( jk1 == 1 ) THEN
918                   zbhitns = 1
919                   EXIT
920                 ENDIF
921                 zdeps = MAX(zdeptht(ji,jjd,jk1-1), -zvijk)
922                 zpnsd = zpnsd +                                        & 
923                        integ2(zdeps,              zdeptht(ji,jjd,jk1), &
924                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
925                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
926                 jk1 = jk1 - 1
927               END DO
928           
929               IF( zbhitns == 1 ) THEN
930                 zdeps = zdeptht(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
931                 zrhdt1 = zrhh(ji,jjd,1) - interp3(zdeptht(ji,jjd,1), asp(ji,jjd,1), &
932                                                 bsp(ji,jjd,1),    csp(ji,jjd,1), &
933                                                 dsp(ji,jjd,1) ) * zdeps
934                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
935                 zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
936               ENDIF
937
938               ! update the momentum trends in v direction
939
940               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
941               IF( lk_vvl ) THEN
942                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
943                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) ) 
944               ELSE
945                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd ) 
946               ENDIF
947
948               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
949               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
950            ENDIF
951
952                   
953           END DO
954        END DO
955      END DO
956      !
957      CALL wrk_dealloc( jpi, jpj, jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
958      !
959   END SUBROUTINE hpg_prj
960
961   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
962      !!----------------------------------------------------------------------
963      !!                 ***  ROUTINE cspline  ***
964      !!       
965      !! ** Purpose :   constrained cubic spline interpolation
966      !!         
967      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
968      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
969      !!
970      !!----------------------------------------------------------------------
971      IMPLICIT NONE
972      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
973      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
974                                                                    ! the interpoated function
975      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
976                                                                    ! 2: Linear
977
978      ! Local Variables     
979      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
980      INTEGER  ::   jpi, jpj, jpkm1
981      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
982      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
983      REAL(wp) ::   zdf(size(fsp,3))
984      !!----------------------------------------------------------------------
985
986      jpi   = size(fsp,1)
987      jpj   = size(fsp,2)
988      jpkm1 = size(fsp,3) - 1
989
990     
991      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
992         DO ji = 1, jpi
993            DO jj = 1, jpj
994           !!Fritsch&Butland's method, 1984 (preferred, but more computation)             
995           !    DO jk = 2, jpkm1-1
996           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1) 
997           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
998           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
999           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1000           !
1001           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1002           !     
1003           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1004           !           zdf(jk) = 0._wp
1005           !       ELSE
1006           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1007           !       ENDIF
1008           !    END DO
1009           
1010           !!Simply geometric average
1011               DO jk = 2, jpkm1-1
1012                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1013                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1014           
1015                  IF(zdf1 * zdf2 <= 0._wp) THEN
1016                     zdf(jk) = 0._wp
1017                  ELSE
1018                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1019                  ENDIF
1020               END DO
1021           
1022               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1023                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1024               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1025                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1026                          & 0.5_wp * zdf(jpkm1 - 1)
1027   
1028               DO jk = 1, jpkm1 - 1
1029                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1030                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1031                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1032                 zddf1  = -2._wp * ztmp1 + ztmp2 
1033                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1034                 zddf2  =  2._wp * ztmp1 - ztmp2 
1035     
1036                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1037                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1038                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - & 
1039                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1040                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1041                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1042                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1043                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1044                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1045               END DO
1046            END DO
1047         END DO
1048 
1049      ELSE IF (polynomial_type == 2) THEN     ! Linear
1050         DO ji = 1, jpi
1051            DO jj = 1, jpj
1052               DO jk = 1, jpkm1-1
1053                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1054                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1055   
1056                  dsp(ji,jj,jk) = 0._wp
1057                  csp(ji,jj,jk) = 0._wp
1058                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1059                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1060               END DO
1061            END DO
1062         END DO
1063
1064      ELSE
1065           CALL ctl_stop( 'invalid polynomial type in cspline' )
1066      ENDIF
1067
1068     
1069   END SUBROUTINE cspline
1070
1071
1072   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f) 
1073      !!----------------------------------------------------------------------
1074      !!                 ***  ROUTINE interp1  ***
1075      !!       
1076      !! ** Purpose :   1-d linear interpolation
1077      !!         
1078      !! ** Method  : 
1079      !!                interpolation is straight forward
1080      !!                extrapolation is also permitted (no value limit)
1081      !!
1082      !!----------------------------------------------------------------------
1083      IMPLICIT NONE
1084      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr   
1085      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1086      REAL(wp)             ::  zdeltx
1087      !!----------------------------------------------------------------------
1088
1089      zdeltx = xr - xl
1090      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1091        f = 0.5_wp * (fl + fr)
1092      ELSE
1093        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1094      ENDIF
1095     
1096   END FUNCTION interp1
1097
1098   FUNCTION interp2(x, a, b, c, d)  RESULT(f) 
1099      !!----------------------------------------------------------------------
1100      !!                 ***  ROUTINE interp1  ***
1101      !!       
1102      !! ** Purpose :   1-d constrained cubic spline interpolation
1103      !!         
1104      !! ** Method  :  cubic spline interpolation
1105      !!
1106      !!----------------------------------------------------------------------
1107      IMPLICIT NONE
1108      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1109      REAL(wp)             ::  f ! value from the interpolation
1110      !!----------------------------------------------------------------------
1111
1112      f = a + x* ( b + x * ( c + d * x ) ) 
1113
1114   END FUNCTION interp2
1115
1116
1117   FUNCTION interp3(x, a, b, c, d)  RESULT(f) 
1118      !!----------------------------------------------------------------------
1119      !!                 ***  ROUTINE interp1  ***
1120      !!       
1121      !! ** Purpose :   Calculate the first order of deriavtive of
1122      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1123      !!         
1124      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1125      !!
1126      !!----------------------------------------------------------------------
1127      IMPLICIT NONE
1128      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1129      REAL(wp)             ::  f ! value from the interpolation
1130      !!----------------------------------------------------------------------
1131
1132      f = b + x * ( 2._wp * c + 3._wp * d * x)
1133
1134   END FUNCTION interp3
1135
1136   
1137   FUNCTION integ2(xl, xr, a, b, c, d)  RESULT(f) 
1138      !!----------------------------------------------------------------------
1139      !!                 ***  ROUTINE interp1  ***
1140      !!       
1141      !! ** Purpose :   1-d constrained cubic spline integration
1142      !!         
1143      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1144      !!
1145      !!----------------------------------------------------------------------
1146      IMPLICIT NONE
1147      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d   
1148      REAL(wp)             ::  za1, za2, za3     
1149      REAL(wp)             ::  f                   ! integration result
1150      !!----------------------------------------------------------------------
1151
1152      za1 = 0.5_wp * b 
1153      za2 = c / 3.0_wp 
1154      za3 = 0.25_wp * d 
1155
1156      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1157         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1158
1159   END FUNCTION integ2
1160
1161
1162   !!======================================================================
1163END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.