New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfeiv.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/LDF/ldfeiv.F90 @ 3186

Last change on this file since 3186 was 3186, checked in by smasson, 12 years ago

dev_NEMO_MERGE_2011: replace the old wrk_nemo with the new wrk_nemo

  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE ldfeiv
2   !!======================================================================
3   !!                     ***  MODULE  ldfeiv  ***
4   !! Ocean physics:  variable eddy induced velocity coefficients
5   !!======================================================================
6   !! History :  OPA  ! 1999-03  (G. Madec, A. Jouzeau)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  Free form, F90
8   !!----------------------------------------------------------------------
9#if   defined key_traldf_eiv   &&   defined key_traldf_c2d
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'      and                     eddy induced velocity
12   !!   'key_traldf_c2d'                    2D tracer lateral  mixing coef.
13   !!----------------------------------------------------------------------
14   !!   ldf_eiv      : compute the eddy induced velocity coefficients
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE sbcrnf          ! river runoffs
20   USE ldftra_oce      ! ocean tracer   lateral physics
21   USE phycst          ! physical constants
22   USE ldfslp          ! iso-neutral slopes
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE prtctl          ! Print control
26   USE iom             ! I/O library
27   USE wrk_nemo        ! work arrays
28
29   IMPLICIT NONE
30   PRIVATE
31   
32   PUBLIC   ldf_eiv    ! routine called by step.F90
33   
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE ldf_eiv( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE ldf_eiv  ***
47      !!
48      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
49      !!              growth rate of baroclinic instability.
50      !!
51      !! ** Method :
52      !!
53      !! ** Action : - uslp , vslp  : i- and j-slopes of neutral surfaces at u- & v-points
54      !!             - wslpi, wslpj : i- and j-slopes of neutral surfaces at w-points.
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
57      !
58      INTEGER  ::   ji, jj, jk   ! dummy loop indices
59      REAL(wp) ::   zfw, ze3w, zn2, zf20, zaht, zaht_min      ! temporary scalars
60      REAL(wp), DIMENSION(:,:), POINTER ::   zn, zah, zhw, zross   ! 2D workspace
61      !!----------------------------------------------------------------------
62     
63      CALL wrk_alloc( jpi,jpj, zn, zah, zhw, zross )
64
65      IF( kt == nit000 ) THEN
66         IF(lwp) WRITE(numout,*)
67         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
68         IF(lwp) WRITE(numout,*) '~~~~~~~'
69      ENDIF
70     
71      ! 0. Local initialization
72      ! -----------------------
73      zn   (:,:) = 0._wp
74      zhw  (:,:) = 5._wp
75      zah  (:,:) = 0._wp
76      zross(:,:) = 0._wp
77
78
79      ! 1. Compute lateral diffusive coefficient
80      ! ----------------------------------------
81      IF( ln_traldf_grif ) THEN
82         DO jk = 1, jpk
83#  if defined key_vectopt_loop 
84!CDIR NOVERRCHK
85            DO ji = 1, jpij   ! vector opt.
86               ! Take the max of N^2 and zero then take the vertical sum
87               ! of the square root of the resulting N^2 ( required to compute
88               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
89               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
90               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
91               ! Compute elements required for the inverse time scale of baroclinic
92               ! eddies using the isopycnal slopes calculated in ldfslp.F :
93               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
94               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
95               zah(ji,1) = zah(ji,1) + zn2 * wslp2(ji,1,jk) * ze3w
96               zhw(ji,1) = zhw(ji,1) + ze3w
97            END DO
98#  else
99            DO jj = 2, jpjm1
100!CDIR NOVERRCHK
101               DO ji = 2, jpim1
102                  ! Take the max of N^2 and zero then take the vertical sum
103                  ! of the square root of the resulting N^2 ( required to compute
104                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
105                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
106                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
107                  ! Compute elements required for the inverse time scale of baroclinic
108                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
109                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
110                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
111                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
112                  zhw(ji,jj) = zhw(ji,jj) + ze3w
113               END DO
114            END DO
115#  endif
116         END DO
117      ELSE
118         DO jk = 1, jpk
119#  if defined key_vectopt_loop 
120!CDIR NOVERRCHK
121            DO ji = 1, jpij   ! vector opt.
122               ! Take the max of N^2 and zero then take the vertical sum
123               ! of the square root of the resulting N^2 ( required to compute
124               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
125               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
126               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
127               ! Compute elements required for the inverse time scale of baroclinic
128               ! eddies using the isopycnal slopes calculated in ldfslp.F :
129               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
130               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
131               zah(ji,1) = zah(ji,1) + zn2 * ( wslpi(ji,1,jk) * wslpi(ji,1,jk)   &
132                  &                          + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) * ze3w
133               zhw(ji,1) = zhw(ji,1) + ze3w
134            END DO
135#  else
136            DO jj = 2, jpjm1
137!CDIR NOVERRCHK
138               DO ji = 2, jpim1
139                  ! Take the max of N^2 and zero then take the vertical sum
140                  ! of the square root of the resulting N^2 ( required to compute
141                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
142                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
143                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
144                  ! Compute elements required for the inverse time scale of baroclinic
145                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
146                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
147                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
148                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
149                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
150                  zhw(ji,jj) = zhw(ji,jj) + ze3w
151               END DO
152            END DO
153#  endif
154         END DO
155      END IF
156
157      DO jj = 2, jpjm1
158!CDIR NOVERRCHK
159         DO ji = fs_2, fs_jpim1   ! vector opt.
160            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
161            ! Rossby radius at w-point taken < 40km and  > 2km
162            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
163            ! Compute aeiw by multiplying Ro^2 and T^-1
164            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
165         END DO
166      END DO
167
168      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
169         DO jj = 2, jpjm1
170!CDIR NOVERRCHK
171            DO ji = fs_2, fs_jpim1   ! vector opt.
172               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
173               IF( mbkt(ji,jj) <= 20 )   aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
174            END DO
175         END DO
176      ENDIF
177
178      ! Decrease the coefficient in the tropics (20N-20S)
179      zf20 = 2._wp * omega * sin( rad * 20._wp )
180      DO jj = 2, jpjm1
181         DO ji = fs_2, fs_jpim1   ! vector opt.
182            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
183         END DO
184      END DO
185
186      ! ORCA R05: Take the minimum between aeiw  and aeiv0
187      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
188         DO jj = 2, jpjm1
189            DO ji = fs_2, fs_jpim1   ! vector opt.
190               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
191            END DO
192         END DO
193      ENDIF
194      CALL lbc_lnk( aeiw, 'W', 1. )      ! lateral boundary condition on aeiw
195
196
197      ! Average the diffusive coefficient at u- v- points
198      DO jj = 2, jpjm1
199         DO ji = fs_2, fs_jpim1   ! vector opt.
200            aeiu(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
201            aeiv(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
202         END DO
203      END DO
204      CALL lbc_lnk( aeiu, 'U', 1. )   ;   CALL lbc_lnk( aeiv, 'V', 1. )      ! lateral boundary condition
205
206
207      IF(ln_ctl) THEN
208         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
209         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
210      ENDIF
211
212      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
213      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
214         zf20     = 2._wp * omega * SIN( rad * 20._wp )
215         zaht_min = 100._wp                           ! minimum value for aht
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218               zaht      = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
219                  &      + aht0 * rnfmsk(ji,jj)                          ! enhanced near river mouths
220               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
221               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
222               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
223            END DO
224         END DO
225         IF(ln_ctl) THEN
226            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
227            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
228            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
229         ENDIF
230      ENDIF
231
232      IF( aeiv0 == 0._wp ) THEN
233         aeiu(:,:) = 0._wp
234         aeiv(:,:) = 0._wp
235         aeiw(:,:) = 0._wp
236      ENDIF
237
238      CALL iom_put( "aht2d"    , ahtw )   ! lateral eddy diffusivity
239      CALL iom_put( "aht2d_eiv", aeiw )   ! EIV lateral eddy diffusivity
240     
241      CALL wrk_dealloc( jpi,jpj, zn, zah, zhw, zross )
242      !
243   END SUBROUTINE ldf_eiv
244
245#else
246   !!----------------------------------------------------------------------
247   !!   Default option                                         Dummy module
248   !!----------------------------------------------------------------------
249CONTAINS
250   SUBROUTINE ldf_eiv( kt )       ! Empty routine
251      INTEGER :: kt
252      WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt
253   END SUBROUTINE ldf_eiv
254#endif
255
256   !!======================================================================
257END MODULE ldfeiv
Note: See TracBrowser for help on using the repository browser.