New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 3186

Last change on this file since 3186 was 3186, checked in by smasson, 12 years ago

dev_NEMO_MERGE_2011: replace the old wrk_nemo with the new wrk_nemo
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE wrk_nemo        ! work arrays
25   USE lbclnk          ! ocean lateral boundary conditions
26   USE lib_fortran
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_fwb    ! routine called by step
32
33   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
34   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
35   REAL(wp) ::   fwfold    ! fwfold to be suppressed
36   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
49      !!---------------------------------------------------------------------
50      !!                  ***  ROUTINE sbc_fwb  ***
51      !!
52      !! ** Purpose :   Control the mean sea surface drift
53      !!
54      !! ** Method  :   several ways  depending on kn_fwb
55      !!                =0 no control
56      !!                =1 global mean of emp set to zero at each nn_fsbc time step
57      !!                =2 annual global mean corrected from previous year
58      !!                =3 global mean of emp set to zero at each nn_fsbc time step
59      !!                   & spread out over erp area depending its sign
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
62      INTEGER, INTENT( in ) ::   kn_fsbc  !
63      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
64      !
65      INTEGER  ::   inum, ikty, iyear   ! local integers
66      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp   ! local scalars
67      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread    !   -      -
68      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor
69      !!----------------------------------------------------------------------
70      !
71      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
72      !
73      IF( kt == nit000 ) THEN
74         IF(lwp) THEN
75            WRITE(numout,*)
76            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
77            WRITE(numout,*) '~~~~~~~'
78            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
79            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
80            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
81         ENDIF
82         !
83         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
84         !
85         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
86      ENDIF
87     
88
89      SELECT CASE ( kn_fwb )
90      !
91      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
92         !
93         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
94            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
95            emp (:,:) = emp (:,:) - z_fwf 
96            emps(:,:) = emps(:,:) - z_fwf 
97         ENDIF
98         !
99      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
100         !
101         IF( kt == nit000 ) THEN                   ! initialisation
102            !                                         ! Read the corrective factor on precipitations (fwfold)
103            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
104            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
105            CLOSE( inum )
106            fwfold = a_fwb                            ! current year freshwater budget correction
107            !                                         ! estimate from the previous year budget
108            IF(lwp)WRITE(numout,*)
109            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
110            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
111            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
112         ENDIF   
113         !                                         ! Update fwfold if new year start
114         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
115         IF( MOD( kt, ikty ) == 0 ) THEN
116            a_fwb_b = a_fwb
117            a_fwb   = glob_sum( e1e2t(:,:) * sshn(:,:) )   ! sum over the global domain
118            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
119!!gm        !                                                      !!bug 365d year
120            fwfold =  a_fwb                           ! current year freshwater budget correction
121            !                                         ! estimate from the previous year budget
122         ENDIF
123         !
124         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
125            emp (:,:) = emp (:,:) + fwfold
126            emps(:,:) = emps(:,:) + fwfold
127         ENDIF
128         !
129         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
130            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
131            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
132            CLOSE( inum )
133         ENDIF
134         !
135      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
136         !
137         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
138            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
139            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
140            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
141            !
142            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
143            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
144            !                                                  ! fwf global mean
145            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
146            !           
147            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
148                zsurf_tospread      = zsurf_pos
149                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
150            ELSE                             ! spread out over <0 erp area to increase precipitation
151                zsurf_tospread      = zsurf_neg
152                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
153            ENDIF
154            !
155            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
156!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
157            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
158            !                                                  ! weight to respect erp field 2D structure
159            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
160            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
161            !                                                  ! final correction term to apply
162            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
163            !
164!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
165            CALL lbc_lnk( zerp_cor, 'T', 1. )
166            !
167            emp (:,:) = emp (:,:) + zerp_cor(:,:)
168            emps(:,:) = emps(:,:) + zerp_cor(:,:)
169            erp (:,:) = erp (:,:) + zerp_cor(:,:)
170            !
171            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
172               IF( z_fwf < 0._wp ) THEN
173                  WRITE(numout,*)'   z_fwf < 0'
174                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
175               ELSE
176                  WRITE(numout,*)'   z_fwf >= 0'
177                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
178               ENDIF
179               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
180               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
181               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
182               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
183               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
184            ENDIF
185         ENDIF
186         !
187      CASE DEFAULT                           !==  you should never be there  ==!
188         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
189         !
190      END SELECT
191      !
192      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
193      !
194   END SUBROUTINE sbc_fwb
195
196   !!======================================================================
197END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.