New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 3215

Last change on this file since 3215 was 3215, checked in by cbricaud, 12 years ago

add missing argument kit000 in tra_ldf_iso_grif dummy routine

  • Property svn:keywords set to Id
File size: 21.5 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE trc_oce         ! share passive tracers/Ocean variables
20   USE zdf_oce         ! ocean vertical physics
21   USE ldftra_oce      ! ocean active tracers: lateral physics
22   USE ldfslp          ! iso-neutral slopes
23   USE diaptr          ! poleward transport diagnostics
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp         ! MPP library
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_ldf_iso_grif   ! routine called by traldf.F90
36
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
38   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   ah_wslp2             !: aeiv*w-slope^2
39   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d               !: vertical tracer gradient at 2 levels
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45#  include "ldfeiv_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53  SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv,              &
54       &                                   ptb, pta, kjpt, pahtb0 )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
57      !!
58      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
60      !!      add it to the general trend of tracer equation.
61      !!
62      !! ** Method  :   The horizontal component of the lateral diffusive trends
63      !!      is provided by a 2nd order operator rotated along neural or geopo-
64      !!      tential surfaces to which an eddy induced advection can be added
65      !!      It is computed using before fields (forward in time) and isopyc-
66      !!      nal or geopotential slopes computed in routine ldfslp.
67      !!
68      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
69      !!      ========    with partial cell update if ln_zps=T.
70      !!
71      !!      2nd part :  horizontal fluxes of the lateral mixing operator
72      !!      ========
73      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
74      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
75      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
76      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
77      !!      take the horizontal divergence of the fluxes:
78      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79      !!      Add this trend to the general trend (ta,sa):
80      !!         ta = ta + difft
81      !!
82      !!      3rd part: vertical trends of the lateral mixing operator
83      !!      ========  (excluding the vertical flux proportional to dk[t] )
84      !!      vertical fluxes associated with the rotated lateral mixing:
85      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
86      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
87      !!      take the horizontal divergence of the fluxes:
88      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
89      !!      Add this trend to the general trend (ta,sa):
90      !!         pta = pta + difft
91      !!
92      !! ** Action :   Update pta arrays with the before rotated diffusion
93      !!----------------------------------------------------------------------
94      USE oce     , ONLY:   zftu => ua       , zftv => va            ! (ua,va) used as 3D workspace
95      !
96      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
97      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
98      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
99      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104      !
105      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
106      INTEGER  ::  ip,jp,kp        ! dummy loop indices
107      INTEGER  ::  ierr            ! temporary integer
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, zbtr                  !   -      -
111      !
112      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
113      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
114      REAL(wp) ::   zah, zah_slp, zaei_slp
115#if defined key_diaar5
116      REAL(wp) ::   zztmp              ! local scalar
117#endif
118      REAL(wp), POINTER, DIMENSION(:,:  ) :: z2d
119      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, ztfw 
120      !!----------------------------------------------------------------------
121      !
122      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso_grif')
123      !
124      CALL wrk_alloc( jpi, jpj,      z2d ) 
125      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
126      !
127
128      IF( kt == kit000 .AND. .NOT.ALLOCATED(ah_wslp2) )  THEN
129         IF(lwp) WRITE(numout,*)
130         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
131         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
132         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt3d(jpi,jpj,0:1), STAT=ierr )
133         IF( lk_mpp   )   CALL mpp_sum ( ierr )
134         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays')
135         IF( ln_traldf_gdia ) THEN
136            IF (.not. ALLOCATED(psix_eiv))THEN
137                ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
138                IF( lk_mpp   )   CALL mpp_sum ( ierr )
139                IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics')
140            ENDIF
141         ENDIF
142      ENDIF
143
144      !!----------------------------------------------------------------------
145      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
146      !!----------------------------------------------------------------------
147
148      !!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
149
150      ah_wslp2(:,:,:) = 0._wp
151      IF( ln_traldf_gdia ) THEN
152         psix_eiv(:,:,:) = 0._wp
153         psiy_eiv(:,:,:) = 0._wp
154      ENDIF
155
156      DO ip = 0, 1
157         DO kp = 0, 1
158            DO jk = 1, jpkm1
159               DO jj = 1, jpjm1
160                  DO ji = 1, fs_jpim1
161                     ze1ur = 1._wp / e1u(ji,jj)
162                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
163                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
164                     zah   = fsahtu(ji,jj,jk)                                  ! fsaht(ji+ip,jj,jk)
165                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
166                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
167                     ! (do this by *adding* gradient of depth)
168                     zslope2 = zslope_skew + ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
169                     zslope2 = zslope2 *zslope2
170                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
171                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
172                     IF( ln_traldf_gdia ) THEN
173                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew           ! fsaeit(ji+ip,jj,jk)*zslope_skew
174                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
175                     ENDIF
176                  END DO
177               END DO
178            END DO
179         END DO
180      END DO
181      !
182      DO jp = 0, 1
183         DO kp = 0, 1
184            DO jk = 1, jpkm1
185               DO jj = 1, jpjm1
186                  DO ji=1,fs_jpim1
187                     ze2vr = 1._wp / e2v(ji,jj)
188                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
189                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
190                     zah   = fsahtv(ji,jj,jk)                                  ! fsaht(ji,jj+jp,jk)
191                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
192                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
193                     !    (do this by *adding* gradient of depth)
194                     zslope2 = zslope_skew + ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
195                     zslope2 = zslope2 * zslope2
196                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
197                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
198                     IF( ln_traldf_gdia ) THEN
199                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew           ! fsaeit(ji,jj+jp,jk)*zslope_skew
200                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
201                     ENDIF
202                  END DO
203               END DO
204            END DO
205         END DO
206      END DO
207      !
208      !                                                          ! ===========
209      DO jn = 1, kjpt                                            ! tracer loop
210         !                                                       ! ===========
211         ! Zero fluxes for each tracer
212         ztfw(:,:,:) = 0._wp
213         zftu(:,:,:) = 0._wp
214         zftv(:,:,:) = 0._wp
215         !
216         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
217            DO jj = 1, jpjm1
218               DO ji = 1, fs_jpim1   ! vector opt.
219                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
220                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
221               END DO
222            END DO
223         END DO
224         IF( ln_zps.and.l_grad_zps ) THEN              ! partial steps: correction at the last level
225# if defined key_vectopt_loop
226            DO jj = 1, 1
227               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
228# else
229            DO jj = 1, jpjm1
230               DO ji = 1, jpim1
231# endif
232                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
233                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
234               END DO
235            END DO
236         ENDIF
237
238         !!----------------------------------------------------------------------
239         !!   II - horizontal trend  (full)
240         !!----------------------------------------------------------------------
241         !
242         DO jk = 1, jpkm1
243            !
244            !                    !==  Vertical tracer gradient at level jk and jk+1
245            zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
246            !
247            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
248            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
249            ELSE                 ;   zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
250            ENDIF
251
252
253            IF (ln_botmix_grif) THEN
254               DO ip = 0, 1              !==  Horizontal & vertical fluxes
255                  DO kp = 0, 1
256                     DO jj = 1, jpjm1
257                        DO ji = 1, fs_jpim1
258                           ze1ur = 1._wp / e1u(ji,jj)
259                           zdxt  = zdit(ji,jj,jk) * ze1ur
260                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
261                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
262                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
263                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
264
265                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
266                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
267                           zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
268                           zah_slp  = zah * zslope_iso
269                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
270                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
271                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
272                        END DO
273                     END DO
274                  END DO
275               END DO
276
277               DO jp = 0, 1
278                  DO kp = 0, 1
279                     DO jj = 1, jpjm1
280                        DO ji = 1, fs_jpim1
281                           ze2vr = 1._wp / e2v(ji,jj)
282                           zdyt  = zdjt(ji,jj,jk) * ze2vr
283                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
284                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
285                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
286                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
287                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
288                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
289                           zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)  ! fsaht(ji,jj+jp,jk)
290                           zah_slp = zah * zslope_iso
291                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
292                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
293                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
294                        END DO
295                     END DO
296                  END DO
297               END DO
298            ELSE
299               DO ip = 0, 1              !==  Horizontal & vertical fluxes
300                  DO kp = 0, 1
301                     DO jj = 1, jpjm1
302                        DO ji = 1, fs_jpim1
303                           ze1ur = 1._wp / e1u(ji,jj)
304                           zdxt  = zdit(ji,jj,jk) * ze1ur
305                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
306                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
307                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
308                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
309
310                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
311                           ! ln_botmix_grif is .F. mask zah for bottom half cells
312                           zah = fsahtu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! fsaht(ji+ip,jj,jk)   ===>>  ????
313                           zah_slp  = zah * zslope_iso
314                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        ! fsaeit(ji+ip,jj,jk)*zslope_skew
315                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
316                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
317                        END DO
318                     END DO
319                  END DO
320               END DO
321
322               DO jp = 0, 1
323                  DO kp = 0, 1
324                     DO jj = 1, jpjm1
325                        DO ji = 1, fs_jpim1
326                           ze2vr = 1._wp / e2v(ji,jj)
327                           zdyt  = zdjt(ji,jj,jk) * ze2vr
328                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
329                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
330                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
331                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
332                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
333                           ! ln_botmix_grif is .F. mask zah for bottom half cells
334                           zah = fsahtv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! fsaht(ji,jj+jp,jk)
335                           zah_slp = zah * zslope_iso
336                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
337                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
338                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
339                        END DO
340                     END DO
341                  END DO
342               END DO
343            END IF
344            !                          !==  divergence and add to the general trend  ==!
345            DO jj = 2 , jpjm1
346               DO ji = fs_2, fs_jpim1  ! vector opt.
347                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
348                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
349                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
350               END DO
351            END DO
352            !
353         END DO
354         !
355         DO jk = 1, jpkm1              !== Divergence of vertical fluxes added to the general tracer trend
356            DO jj = 2, jpjm1
357               DO ji = fs_2, fs_jpim1  ! vector opt.
358                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
359                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
360               END DO
361            END DO
362         END DO
363         !
364         !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
365         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
366            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
367            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
368         ENDIF
369
370#if defined key_diaar5
371         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
372            z2d(:,:) = 0._wp
373            zztmp = rau0 * rcp
374            DO jk = 1, jpkm1
375               DO jj = 2, jpjm1
376                  DO ji = fs_2, fs_jpim1   ! vector opt.
377                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk)
378                  END DO
379               END DO
380            END DO
381            z2d(:,:) = zztmp * z2d(:,:)
382            CALL lbc_lnk( z2d, 'U', -1. )
383            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
384            z2d(:,:) = 0._wp
385            DO jk = 1, jpkm1
386               DO jj = 2, jpjm1
387                  DO ji = fs_2, fs_jpim1   ! vector opt.
388                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk)
389                  END DO
390               END DO
391            END DO
392            z2d(:,:) = zztmp * z2d(:,:)
393            CALL lbc_lnk( z2d, 'V', -1. )
394            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in j-direction
395         END IF
396#endif
397         !
398      END DO
399      !
400      CALL wrk_dealloc( jpi, jpj,      z2d ) 
401      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
402      !
403      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso_grif')
404      !
405  END SUBROUTINE tra_ldf_iso_grif
406
407#else
408   !!----------------------------------------------------------------------
409   !!   default option :   Dummy code   NO rotation of the diffusive tensor
410   !!----------------------------------------------------------------------
411CONTAINS
412   SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv,              &
413       &                                   ptb, pta, kjpt, pahtb0 )
414      CHARACTER(len=3) ::   cdtype
415      INTEGER          ::   kit000     ! first time step index
416      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
417      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
418      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
419         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
420   END SUBROUTINE tra_ldf_iso_grif
421#endif
422
423   !!==============================================================================
424END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.