New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 3186

Last change on this file since 3186 was 3186, checked in by smasson, 12 years ago

dev_NEMO_MERGE_2011: replace the old wrk_nemo with the new wrk_nemo
  • Property svn:keywords set to Id
File size: 27.1 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdtra          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29   USE restart         ! ocean restart
30   USE lib_mpp         ! MPP library
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
39   PUBLIC   tra_qsr_init  ! routine called by opa.F90
40
41   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
42   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
43   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
44   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
45   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
46   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
47   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
48   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
49   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
50   
51   ! Module variables
52   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
53   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
55   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
56   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_qsr( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE tra_qsr  ***
71      !!
72      !! ** Purpose :   Compute the temperature trend due to the solar radiation
73      !!      penetration and add it to the general temperature trend.
74      !!
75      !! ** Method  : The profile of the solar radiation within the ocean is defined
76      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
77      !!      Considering the 2 wavebands case:
78      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
79      !!         The temperature trend associated with the solar radiation penetration
80      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
81      !!         At the bottom, boudary condition for the radiation is no flux :
82      !!      all heat which has not been absorbed in the above levels is put
83      !!      in the last ocean level.
84      !!         In z-coordinate case, the computation is only done down to the
85      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
86      !!      used for the computation are calculated one for once as they
87      !!      depends on k only.
88      !!
89      !! ** Action  : - update ta with the penetrative solar radiation trend
90      !!              - save the trend in ttrd ('key_trdtra')
91      !!
92      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
93      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
94      !!----------------------------------------------------------------------
95      !
96      INTEGER, INTENT(in) ::   kt     ! ocean time-step
97      !
98      INTEGER  ::   ji, jj, jk           ! dummy loop indices
99      INTEGER  ::   irgb                 ! local integers
100      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
101      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
102      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
103      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
104      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
105      !!----------------------------------------------------------------------
106      !
107      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
108      !
109      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
110      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
111      !
112      IF( kt == nit000 ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
115         IF(lwp) WRITE(numout,*) '~~~~~~~'
116         IF( .NOT.ln_traqsr )   RETURN
117      ENDIF
118
119      IF( l_trdtra ) THEN      ! Save ta and sa trends
120         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
121         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
122      ENDIF
123
124      !                                        Set before qsr tracer content field
125      !                                        ***********************************
126      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
127         !                                        ! -----------------------------------
128         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
129              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
130            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
131            zfact = 0.5e0
132            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
133         ELSE                                           ! No restart or restart not found: Euler forward time stepping
134            zfact = 1.e0
135            qsr_hc_b(:,:,:) = 0.e0
136         ENDIF
137      ELSE                                        ! Swap of forcing field
138         !                                        ! ---------------------
139         zfact = 0.5e0
140         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
141      ENDIF
142      !                                        Compute now qsr tracer content field
143      !                                        ************************************
144     
145      !                                           ! ============================================== !
146      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
147         !                                        ! ============================================== !
148         DO jk = 1, jpkm1
149            qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
150         END DO
151         !                                        Add to the general trend
152         DO jk = 1, jpkm1
153            DO jj = 2, jpjm1 
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  z1_e3t = zfact / fse3t(ji,jj,jk)
156                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
157               END DO
158            END DO
159         END DO
160         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
161         !                                        ! ============================================== !
162      ELSE                                        !  Ocean alone :
163         !                                        ! ============================================== !
164         !
165         !                                                ! ------------------------- !
166         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
167            !                                             ! ------------------------- !
168            ! Set chlorophyl concentration
169            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
170               !
171               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
172                  !
173                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
174                  !         
175!CDIR COLLAPSE
176!CDIR NOVERRCHK
177                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
178!CDIR NOVERRCHK
179                     DO ji = 1, jpi
180                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
181                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
182                        zekb(ji,jj) = rkrgb(1,irgb)
183                        zekg(ji,jj) = rkrgb(2,irgb)
184                        zekr(ji,jj) = rkrgb(3,irgb)
185                     END DO
186                  END DO
187               ELSE                                            ! Variable ocean volume but constant chrlorophyll
188                  zchl = 0.05                                     ! constant chlorophyll
189                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
190                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
191                  zekg(:,:) = rkrgb(2,irgb)
192                  zekr(:,:) = rkrgb(3,irgb)
193               ENDIF
194               !
195               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
196               ze0(:,:,1) = rn_abs  * qsr(:,:)
197               ze1(:,:,1) = zcoef * qsr(:,:)
198               ze2(:,:,1) = zcoef * qsr(:,:)
199               ze3(:,:,1) = zcoef * qsr(:,:)
200               zea(:,:,1) =         qsr(:,:)
201               !
202               DO jk = 2, nksr+1
203!CDIR NOVERRCHK
204                  DO jj = 1, jpj
205!CDIR NOVERRCHK   
206                     DO ji = 1, jpi
207                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
208                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
209                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
210                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
211                        ze0(ji,jj,jk) = zc0
212                        ze1(ji,jj,jk) = zc1
213                        ze2(ji,jj,jk) = zc2
214                        ze3(ji,jj,jk) = zc3
215                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
216                     END DO
217                  END DO
218               END DO
219               !
220               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
221                  qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) )
222               END DO
223               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
224               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
225               !
226            ELSE                                                 !*  Constant Chlorophyll
227               DO jk = 1, nksr
228                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
229               END DO
230            ENDIF
231
232         ENDIF
233         !                                                ! ------------------------- !
234         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
235            !                                             ! ------------------------- !
236            !
237            IF( lk_vvl ) THEN                                  !* variable volume
238               zz0   =        rn_abs   * ro0cpr
239               zz1   = ( 1. - rn_abs ) * ro0cpr
240               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
241                  DO jj = 2, jpjm1
242                     DO ji = 2, jpim1
243                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
244                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
245                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
246                     END DO
247                  END DO
248               END DO
249            ELSE                                               !* constant volume: coef. computed one for all
250               DO jk = 1, nksr
251                  DO jj = 2, jpjm1
252                     DO ji = fs_2, fs_jpim1   ! vector opt.
253                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
254                     END DO
255                  END DO
256               END DO
257               !
258            ENDIF
259            !
260         ENDIF
261         !
262         !                                        Add to the general trend
263         DO jk = 1, nksr
264            DO jj = 2, jpjm1 
265               DO ji = fs_2, fs_jpim1   ! vector opt.
266                  z1_e3t = zfact / fse3t(ji,jj,jk)
267                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
268               END DO
269            END DO
270         END DO
271         !
272      ENDIF
273      !
274      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
275         !                                     *******************************
276         IF(lwp) WRITE(numout,*)
277         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
278            &                    'at it= ', kt,' date= ', ndastp
279         IF(lwp) WRITE(numout,*) '~~~~'
280         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
281         !
282      ENDIF
283
284      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
285         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
286         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt )
287         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
288      ENDIF
289      !                       ! print mean trends (used for debugging)
290      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
291      !
292      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
293      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
294      !
295      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
296      !
297   END SUBROUTINE tra_qsr
298
299
300   SUBROUTINE tra_qsr_init
301      !!----------------------------------------------------------------------
302      !!                  ***  ROUTINE tra_qsr_init  ***
303      !!
304      !! ** Purpose :   Initialization for the penetrative solar radiation
305      !!
306      !! ** Method  :   The profile of solar radiation within the ocean is set
307      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
308      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
309      !!      default values correspond to clear water (type I in Jerlov'
310      !!      (1968) classification.
311      !!         called by tra_qsr at the first timestep (nit000)
312      !!
313      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
314      !!
315      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
316      !!----------------------------------------------------------------------
317      !
318      INTEGER  ::   ji, jj, jk     ! dummy loop indices
319      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
320      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
321      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
322      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
323      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
324      !
325      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
326      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
327      !!
328      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
329         &                  nn_chldta, rn_abs, rn_si0, rn_si1
330      !!----------------------------------------------------------------------
331
332      !
333      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
334      !
335      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
336      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
337      !
338
339      cn_dir = './'       ! directory in which the model is executed
340      ! ... default values (NB: frequency positive => hours, negative => months)
341      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
342      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
343      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
344      !
345      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
346      READ  ( numnam, namtra_qsr )
347      !
348      IF(lwp) THEN                ! control print
349         WRITE(numout,*)
350         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
351         WRITE(numout,*) '~~~~~~~~~~~~'
352         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
353         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
354         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
355         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
356         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
357         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
358         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
359         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
360         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
361      ENDIF
362
363      IF( ln_traqsr ) THEN     ! control consistency
364         !                     
365         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
366            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
367            ln_qsr_bio = .FALSE.
368         ENDIF
369         !
370         ioptio = 0                      ! Parameter control
371         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
372         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
373         IF( ln_qsr_bio  )   ioptio = ioptio + 1
374         !
375         IF( ioptio /= 1 ) &
376            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
377            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
378         !
379         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
380         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
381         IF( ln_qsr_2bd                      )   nqsr =  3
382         IF( ln_qsr_bio                      )   nqsr =  4
383         !
384         IF(lwp) THEN                   ! Print the choice
385            WRITE(numout,*)
386            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
387            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
388            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
389            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
390         ENDIF
391         !
392      ENDIF
393      !                          ! ===================================== !
394      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
395         !                       ! ===================================== !
396         !
397         xsi0r = 1.e0 / rn_si0
398         xsi1r = 1.e0 / rn_si1
399         !                                ! ---------------------------------- !
400         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
401            !                             ! ---------------------------------- !
402            !
403            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
404            !
405            !                                   !* level of light extinction
406            IF(  ln_sco ) THEN   ;   nksr = jpkm1
407            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
408            ENDIF
409
410            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
411            !
412            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
413               IF(lwp) WRITE(numout,*)
414               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
415               ALLOCATE( sf_chl(1), STAT=ierror )
416               IF( ierror > 0 ) THEN
417                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
418               ENDIF
419               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
420               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
421               !                                        ! fill sf_chl with sn_chl and control print
422               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
423                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
424               !
425            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
426               IF(lwp) WRITE(numout,*)
427               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
428               IF( lk_vvl ) THEN                   ! variable volume
429                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
430               ELSE                                ! constant volume: computes one for all
431                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
432                  !
433                  zchl = 0.05                                 ! constant chlorophyll
434                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
435                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
436                  zekg(:,:) = rkrgb(2,irgb)
437                  zekr(:,:) = rkrgb(3,irgb)
438                  !
439                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
440                  ze0(:,:,1) = rn_abs
441                  ze1(:,:,1) = zcoef
442                  ze2(:,:,1) = zcoef 
443                  ze3(:,:,1) = zcoef
444                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
445               
446                  DO jk = 2, nksr+1
447!CDIR NOVERRCHK
448                     DO jj = 1, jpj
449!CDIR NOVERRCHK   
450                        DO ji = 1, jpi
451                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
452                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
453                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
454                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
455                           ze0(ji,jj,jk) = zc0
456                           ze1(ji,jj,jk) = zc1
457                           ze2(ji,jj,jk) = zc2
458                           ze3(ji,jj,jk) = zc3
459                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
460                        END DO
461                     END DO
462                  END DO 
463                  !
464                  DO jk = 1, nksr
465                     etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
466                  END DO
467                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
468               ENDIF
469            ENDIF
470            !
471         ENDIF
472            !                             ! ---------------------------------- !
473         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
474            !                             ! ---------------------------------- !
475            !
476            !                                ! level of light extinction
477            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
478            IF(lwp) THEN
479               WRITE(numout,*)
480            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
481            ENDIF
482            !
483            IF( lk_vvl ) THEN                   ! variable volume
484               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
485            ELSE                                ! constant volume: computes one for all
486               zz0 =        rn_abs   * ro0cpr
487               zz1 = ( 1. - rn_abs ) * ro0cpr
488               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
489                  DO jj = 1, jpj                              ! top 400 meters
490                     DO ji = 1, jpi
491                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
492                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
493                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
494                     END DO
495                  END DO
496               END DO
497               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
498               !
499            ENDIF
500         ENDIF
501         !                       ! ===================================== !
502      ELSE                       !        No light penetration           !                   
503         !                       ! ===================================== !
504         IF(lwp) THEN
505            WRITE(numout,*)
506            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
507            WRITE(numout,*) '~~~~~~~~~~~~'
508         ENDIF
509      ENDIF
510      !
511      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
512      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
513      !
514      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
515      !
516   END SUBROUTINE tra_qsr_init
517
518   !!======================================================================
519END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.