New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/TRP/trcldf.F90 @ 3160

Last change on this file since 3160 was 3160, checked in by cetlod, 12 years ago

Add timing in TOP routines

  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE trcldf
2   !!======================================================================
3   !!                       ***  MODULE  trcldf  ***
4   !! Ocean Passive tracers : lateral diffusive trends
5   !!=====================================================================
6   !! History :  9.0  ! 2005-11 (G. Madec)  Original code
7   !!       NEMO 3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!----------------------------------------------------------------------
14   !!   trc_ldf     : update the tracer trend with the lateral diffusion
15   !!       ldf_ctl : initialization, namelist read, and parameters control
16   !!----------------------------------------------------------------------
17   USE oce_trc         ! ocean dynamics and active tracers
18   USE trc             ! ocean passive tracers variables
19   USE trcnam_trp      ! passive tracers transport namelist variables
20   USE ldftra_oce      ! lateral diffusion coefficient on tracers
21   USE ldfslp          ! ???
22   USE traldf_bilapg   ! lateral mixing            (tra_ldf_bilapg routine)
23   USE traldf_bilap    ! lateral mixing            (tra_ldf_bilap routine)
24   USE traldf_iso      ! lateral mixing            (tra_ldf_iso routine)
25   USE traldf_iso_grif ! lateral mixing          (tra_ldf_iso_grif routine)
26   USE traldf_lap      ! lateral mixing            (tra_ldf_lap routine)
27   USE trdmod_oce
28   USE trdtra
29   USE prtctl_trc      ! Print control
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   trc_ldf    ! called by step.F90
35   !                                                 !!: ** lateral mixing namelist (nam_trcldf) **
36   REAL(wp) ::  rldf_rat    ! ratio between active and passive tracers diffusive coefficient
37   INTEGER  ::  nldf = 0   ! type of lateral diffusion used defined from ln_trcldf_... namlist logicals)
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE trc_ldf( kt )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf  ***
52      !!
53      !! ** Purpose :   compute the lateral ocean tracer physics.
54      !!
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
57      !!
58      INTEGER            :: jn
59      CHARACTER (len=22) :: charout
60      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrtrd
61      !!----------------------------------------------------------------------
62      !
63      IF( nn_timing == 1 )   CALL timing_start('trc_ldf')
64      !
65      IF( kt == nittrc000 )   CALL ldf_ctl          ! initialisation & control of options
66
67      rldf = rldf_rat
68
69      IF( l_trdtrc )  THEN
70         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrtrd )
71         ztrtrd(:,:,:,:)  = tra(:,:,:,:)
72      ENDIF
73
74      SELECT CASE ( nldf )                       ! compute lateral mixing trend and add it to the general trend
75      CASE ( 0 )   ;   CALL tra_ldf_lap   ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )  ! iso-level laplacian
76      CASE ( 1 )                                                                                            ! rotated laplacian
77                       IF( ln_traldf_grif ) THEN
78                          CALL tra_ldf_iso_grif( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
79                       ELSE
80                          CALL tra_ldf_iso     ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
81                       ENDIF
82      CASE ( 2 )   ;   CALL tra_ldf_bilap ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )  ! iso-level bilaplacian
83      CASE ( 3 )   ;   CALL tra_ldf_bilapg( kt, nittrc000, 'TRC',             trb, tra, jptra            )  ! s-coord. horizontal bilaplacian
84         !
85      CASE ( -1 )                                     ! esopa: test all possibility with control print
86         CALL tra_ldf_lap   ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )
87         WRITE(charout, FMT="('ldf0 ')") ;  CALL prt_ctl_trc_info(charout)
88                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
89         IF( ln_traldf_grif ) THEN
90            CALL tra_ldf_iso_grif( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
91         ELSE
92            CALL tra_ldf_iso     ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
93         ENDIF
94         WRITE(charout, FMT="('ldf1 ')") ;  CALL prt_ctl_trc_info(charout)
95                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
96         CALL tra_ldf_bilap ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )
97         WRITE(charout, FMT="('ldf2 ')") ;  CALL prt_ctl_trc_info(charout)
98                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
99         CALL tra_ldf_bilapg( kt, nittrc000, 'TRC',             trb, tra, jptra            )
100         WRITE(charout, FMT="('ldf3 ')") ;  CALL prt_ctl_trc_info(charout)
101                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
102      END SELECT
103      !
104      IF( l_trdtrc )   THEN                      ! save the horizontal diffusive trends for further diagnostics
105        DO jn = 1, jptra
106           ztrtrd(:,:,:,jn) = tra(:,:,:,jn) - ztrtrd(:,:,:,jn)
107           CALL trd_tra( kt, 'TRC', jn, jptra_trd_ldf, ztrtrd(:,:,:,jn) )
108        END DO
109        CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrtrd )
110      ENDIF
111      !                                          ! print mean trends (used for debugging)
112      IF( ln_ctl )   THEN
113         WRITE(charout, FMT="('ldf ')") ;  CALL prt_ctl_trc_info(charout)
114                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
115      ENDIF
116      !
117      IF( nn_timing == 1 )   CALL timing_stop('trc_ldf')
118      !
119   END SUBROUTINE trc_ldf
120
121
122   SUBROUTINE ldf_ctl
123      !!----------------------------------------------------------------------
124      !!                  ***  ROUTINE ldf_ctl  ***
125      !!
126      !! ** Purpose :   Choice of the operator for the lateral tracer diffusion
127      !!
128      !! ** Method  :   set nldf from the namtra_ldf logicals
129      !!      nldf == -2   No lateral diffusion
130      !!      nldf == -1   ESOPA test: ALL operators are used
131      !!      nldf ==  0   laplacian operator
132      !!      nldf ==  1   Rotated laplacian operator
133      !!      nldf ==  2   bilaplacian operator
134      !!      nldf ==  3   Rotated bilaplacian
135      !!----------------------------------------------------------------------
136      INTEGER ::   ioptio, ierr         ! temporary integers
137      !!----------------------------------------------------------------------
138
139      rldf_rat = rn_ahtrc_0 / rn_aht_0
140
141      !  Define the lateral mixing oparator for tracers
142      ! ===============================================
143
144      !                               ! control the input
145      ioptio = 0
146      IF( ln_trcldf_lap   )   ioptio = ioptio + 1
147      IF( ln_trcldf_bilap )   ioptio = ioptio + 1
148      IF( ioptio >  1 )   CALL ctl_stop( '          use ONE or NONE of the 2 lap/bilap operator type on tracer' )
149      IF( ioptio == 0 )   nldf = -2   ! No lateral diffusion
150      ioptio = 0
151      IF( ln_trcldf_level )   ioptio = ioptio + 1
152      IF( ln_trcldf_hor   )   ioptio = ioptio + 1
153      IF( ln_trcldf_iso   )   ioptio = ioptio + 1
154      IF( ioptio /= 1 )   CALL ctl_stop( '          use only ONE direction (level/hor/iso)' )
155
156      ! defined the type of lateral diffusion from ln_trcldf_... logicals
157      ! CAUTION : nldf = 1 is used in trazdf_imp, change it carefully
158      ierr = 0
159      IF( ln_trcldf_lap ) THEN       ! laplacian operator
160         IF ( ln_zco ) THEN                ! z-coordinate
161            IF ( ln_trcldf_level )   nldf = 0      ! iso-level  (no rotation)
162            IF ( ln_trcldf_hor   )   nldf = 0      ! horizontal (no rotation)
163            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
164         ENDIF
165         IF ( ln_zps ) THEN             ! z-coordinate
166            IF ( ln_trcldf_level )   ierr = 1      ! iso-level not allowed
167            IF ( ln_trcldf_hor   )   nldf = 0      ! horizontal (no rotation)
168            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
169         ENDIF
170         IF ( ln_sco ) THEN             ! z-coordinate
171            IF ( ln_trcldf_level )   nldf = 0      ! iso-level  (no rotation)
172            IF ( ln_trcldf_hor   )   nldf = 1      ! horizontal (   rotation)
173            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
174         ENDIF
175      ENDIF
176
177      IF( ln_trcldf_bilap ) THEN      ! bilaplacian operator
178         IF ( ln_zco ) THEN                ! z-coordinate
179            IF ( ln_trcldf_level )   nldf = 2      ! iso-level  (no rotation)
180            IF ( ln_trcldf_hor   )   nldf = 2      ! horizontal (no rotation)
181            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
182         ENDIF
183         IF ( ln_zps ) THEN             ! z-coordinate
184            IF ( ln_trcldf_level )   ierr = 1      ! iso-level not allowed
185            IF ( ln_trcldf_hor   )   nldf = 2      ! horizontal (no rotation)
186            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
187         ENDIF
188         IF ( ln_sco ) THEN             ! z-coordinate
189            IF ( ln_trcldf_level )   nldf = 2      ! iso-level  (no rotation)
190            IF ( ln_trcldf_hor   )   nldf = 3      ! horizontal (   rotation)
191            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
192         ENDIF
193      ENDIF
194
195      IF( ierr == 1 )   CALL ctl_stop( ' iso-level in z-coordinate - partial step, not allowed' )
196      IF( ierr == 2 )   CALL ctl_stop( ' isoneutral bilaplacian operator does not exist' )
197      IF( lk_traldf_eiv .AND. .NOT.ln_trcldf_iso )   &
198           CALL ctl_stop( '          eddy induced velocity on tracers',   &
199           &              ' the eddy induced velocity on tracers requires isopycnal laplacian diffusion' )
200      IF( nldf == 1 .OR. nldf == 3 ) THEN      ! rotation
201         IF( .NOT.lk_ldfslp )   CALL ctl_stop( '          the rotation of the diffusive tensor require key_ldfslp' )
202#if defined key_offline
203         l_traldf_rot = .TRUE.                 ! needed for trazdf_imp
204#endif
205      ENDIF
206
207      IF( lk_esopa ) THEN
208         IF(lwp) WRITE(numout,*) '          esopa control: use all lateral physics options'
209         nldf = -1
210      ENDIF
211
212      IF( .NOT. ln_trcldf_diff ) THEN
213         IF(lwp) WRITE(numout,*) '          No lateral diffusion on passive tracers'
214         nldf = -2
215      ENDIF
216
217      IF(lwp) THEN
218         WRITE(numout,*)
219         IF( nldf == -2 )   WRITE(numout,*) '          NO lateral diffusion'
220         IF( nldf == -1 )   WRITE(numout,*) '          ESOPA test All scheme used'
221         IF( nldf ==  0 )   WRITE(numout,*) '          laplacian operator'
222         IF( nldf ==  1 )   WRITE(numout,*) '          Rotated laplacian operator'
223         IF( nldf ==  2 )   WRITE(numout,*) '          bilaplacian operator'
224         IF( nldf ==  3 )   WRITE(numout,*) '          Rotated bilaplacian'
225      ENDIF
226
227      IF( ln_trcldf_bilap ) THEN
228         IF(lwp) WRITE(numout,*) '          biharmonic tracer diffusion'
229         IF( rn_ahtrc_0 > 0 .AND. .NOT. lk_esopa )   CALL ctl_stop( 'The horizontal diffusivity coef. rn_ahtrc_0 must be negative' )
230      ELSE
231         IF(lwp) WRITE(numout,*) '          harmonic tracer diffusion (default)'
232         IF( rn_ahtrc_0 < 0 .AND. .NOT. lk_esopa )   CALL ctl_stop('The horizontal diffusivity coef. rn_ahtrc_0 must be positive' )
233      ENDIF
234
235      ! ratio between active and passive tracers diffusive coef.
236      rldf_rat = rn_ahtrc_0 / rn_aht_0
237      IF( rldf_rat < 0 ) THEN
238         IF( .NOT.lk_offline ) THEN
239            CALL ctl_stop( 'Choose the same type of diffusive scheme both for active & passive tracers' )
240         ELSE
241            CALL ctl_stop( 'Change the sign of rn_aht_0 in namelist to -/+1' )
242         ENDIF
243      ENDIF
244      !
245   END SUBROUTINE ldf_ctl
246#else
247   !!----------------------------------------------------------------------
248   !!   Default option                                         Empty module
249   !!----------------------------------------------------------------------
250CONTAINS
251   SUBROUTINE trc_ldf( kt )
252      INTEGER, INTENT(in) :: kt
253      WRITE(*,*) 'trc_ldf: You should not have seen this print! error?', kt
254   END SUBROUTINE trc_ldf
255#endif
256   !!======================================================================
257END MODULE trcldf
Note: See TracBrowser for help on using the repository browser.