New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limhdf_2.F90 in branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/LIM_SRC_2/limhdf_2.F90 @ 2833

Last change on this file since 2833 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk

  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1MODULE limhdf_2
2   !!======================================================================
3   !!                    ***  MODULE limhdf_2   ***
4   !! LIM 2.0 ice model : horizontal diffusion of sea-ice quantities
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (LIM) Original code
7   !!             -   !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!            1.0  !  2002-08 (C. Ethe)  F90, free form
9   !!----------------------------------------------------------------------
10#if defined key_lim2
11   !!----------------------------------------------------------------------
12   !!   'key_lim2'                                    LIM 2.0 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_hdf_2  : diffusion trend on sea-ice variable
15   !!----------------------------------------------------------------------
16   USE dom_oce          ! ocean domain
17   USE ice_2            ! LIM-2: ice variables
18   USE lbclnk           ! lateral boundary condition - MPP exchanges
19   USE lib_mpp          ! MPP library
20   USE prtctl           ! Print control
21   USE in_out_manager   ! I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   lim_hdf_2         ! called by limtrp_2.F90
27
28   LOGICAL  ::   linit = .TRUE.   ! ! initialization flag (set to flase after the 1st call)
29   REAL(wp) ::   epsi04 = 1e-04   ! constant
30   
31   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   efact   ! metric coefficient
32
33   !! * Substitution
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE lim_hdf_2( ptab )
43      !!-------------------------------------------------------------------
44      !!                  ***  ROUTINE lim_hdf_2  ***
45      !!
46      !! ** purpose :   Compute and add the diffusive trend on sea-ice variables
47      !!
48      !! ** method  :   Second order diffusive operator evaluated using a
49      !!              Cranck-Nicholson time Scheme.
50      !!
51      !! ** Action  :    update ptab with the diffusive contribution
52      !!-------------------------------------------------------------------
53      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
54      USE wrk_nemo, ONLY:   zflu => wrk_2d_11, zdiv  => wrk_2d_13, zrlx  => wrk_2d_15 
55      USE wrk_nemo, ONLY:   zflv => wrk_2d_12, zdiv0 => wrk_2d_14, ztab0 => wrk_2d_16
56      !
57      REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) ::   ptab   ! Field on which the diffusion is applied 
58      !
59      INTEGER  ::   ji, jj            ! dummy loop indices
60      INTEGER  ::   its, iter, ierr   ! local integers
61      REAL(wp) ::   zalfa, zrlxint, zconv, zeps   ! local scalars
62      CHARACTER (len=55) :: charout
63      !!-------------------------------------------------------------------
64
65      IF( wrk_in_use(2, 11,12,13,14,15,16) ) THEN
66         CALL ctl_stop( 'lim_hdf_2 : requested workspace arrays unavailable.' )   ;   RETURN
67      END IF
68
69      !                       !==  Initialisation  ==!
70      !
71      IF( linit ) THEN              ! Metric coefficient (compute at the first call and saved in efact)
72         ALLOCATE( efact(jpi,jpj) , STAT=ierr )
73         IF( lk_mpp    )   CALL mpp_sum( ierr )
74         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'lim_hdf_2 : unable to allocate standard arrays' )
75         DO jj = 2, jpjm1 
76            DO ji = fs_2 , fs_jpim1   ! vector opt.
77               efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) / ( e1t(ji,jj) * e2t(ji,jj) )
78            END DO
79         END DO
80         linit = .FALSE.
81      ENDIF
82      !
83      !                             ! Time integration parameters
84      zalfa = 0.5_wp                      ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit
85      its   = 100                         ! Maximum number of iteration
86      zeps  =  2._wp * epsi04
87      !
88      ztab0(:, : ) = ptab(:,:)      ! Arrays initialization
89      zdiv0(:, 1 ) = 0._wp
90      zdiv0(:,jpj) = 0._wp
91      IF( .NOT.lk_vopt_loop ) THEN
92         zflu (jpi,:) = 0._wp   
93         zflv (jpi,:) = 0._wp
94         zdiv0(1,  :) = 0._wp
95         zdiv0(jpi,:) = 0._wp
96      ENDIF
97
98      zconv = 1._wp           !==  horizontal diffusion using a Crant-Nicholson scheme  ==!
99      iter  = 0
100      !
101      DO WHILE (  zconv > zeps  .AND.  iter <= its  )    ! Sub-time step loop
102         !
103         iter = iter + 1                                       ! incrementation of the sub-time step number
104         !
105         DO jj = 1, jpjm1                                      ! diffusive fluxes in U- and V- direction
106            DO ji = 1 , fs_jpim1   ! vector opt.
107               zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) / e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) )
108               zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) / e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) )
109            END DO
110         END DO
111         !
112         DO jj= 2, jpjm1                                       ! diffusive trend : divergence of the fluxes
113            DO ji = fs_2 , fs_jpim1   ! vector opt.
114               zdiv (ji,jj) = (  zflu(ji,jj) - zflu(ji-1,jj  )   &
115                  &            + zflv(ji,jj) - zflv(ji  ,jj-1)  ) / ( e1t (ji,jj) * e2t (ji,jj) )
116            END DO
117         END DO
118         !
119         IF( iter == 1 )   zdiv0(:,:) = zdiv(:,:)              ! save the 1st evaluation of the diffusive trend in zdiv0
120         !
121         DO jj = 2, jpjm1                                      ! iterative evaluation
122            DO ji = fs_2 , fs_jpim1   ! vector opt.
123               zrlxint = (   ztab0(ji,jj)    &
124                  &       +  rdt_ice * (           zalfa   * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) )   &
125                  &                      + ( 1.0 - zalfa ) *   zdiv0(ji,jj) )  )                             & 
126                  &    / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) )
127               zrlx(ji,jj) = ptab(ji,jj) + om * ( zrlxint - ptab(ji,jj) )
128            END DO
129         END DO
130         CALL lbc_lnk( zrlx, 'T', 1. )                         ! lateral boundary condition
131
132         zconv = 0._wp                                         ! convergence test
133
134         DO jj = 2, jpjm1
135            DO ji = 2, jpim1
136               zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) )  )
137            END DO
138         END DO
139         IF( lk_mpp )   CALL mpp_max( zconv )                  ! max over the global domain
140
141         ptab(:,:) = zrlx(:,:)
142         !
143      END DO                                             ! end of sub-time step loop
144
145      IF(ln_ctl)   THEN
146         zrlx(:,:) = ptab(:,:) - ztab0(:,:)
147         WRITE(charout,FMT="(' lim_hdf  : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter
148         CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout )
149      ENDIF
150      !
151      IF( wrk_not_released(2, 11,12,13,14,15,16) )   CALL ctl_stop('lim_hdf_2: failed to release workspace arrays')
152      !
153   END SUBROUTINE lim_hdf_2
154
155#else
156   !!----------------------------------------------------------------------
157   !!   Default option          Dummy module       NO LIM 2.0 sea-ice model
158   !!----------------------------------------------------------------------
159CONTAINS
160   SUBROUTINE lim_hdf_2       ! Empty routine
161   END SUBROUTINE lim_hdf_2
162#endif
163
164   !!======================================================================
165END MODULE limhdf_2
Note: See TracBrowser for help on using the repository browser.