New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaptr.F90 in branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/OPA_SRC/DIA/diaptr.F90 @ 2789

Last change on this file since 2789 was 2789, checked in by cetlod, 13 years ago

Implementation of the merge of TRA/TRP : first guess, see ticket #842
  • Property svn:keywords set to Id
File size: 42.8 KB
Line 
1MODULE diaptr
2   !!======================================================================
3   !!                       ***  MODULE  diaptr  ***
4   !! Ocean physics:  Computes meridonal transports and zonal means
5   !!=====================================================================
6   !! History :  1.0  ! 2003-09  (C. Talandier, G. Madec)  Original code
7   !!            2.0  ! 2006-01  (A. Biastoch)  Allow sub-basins computation
8   !!            3.2  ! 2010-03  (O. Marti, S. Flavoni) Add fields
9   !!            3.3  ! 2010-10  (G. Madec)  dynamical allocation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dia_ptr      : Poleward Transport Diagnostics module
14   !!   dia_ptr_init : Initialization, namelist read
15   !!   dia_ptr_wri  : Output of poleward fluxes
16   !!   ptr_vjk      : "zonal" sum computation of a "meridional" flux array
17   !!   ptr_tjk      : "zonal" mean computation of a tracer field
18   !!   ptr_vj       : "zonal" and vertical sum computation of a "meridional" flux array
19   !!                   (Generic interface to ptr_vj_3d, ptr_vj_2d)
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and active tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE ldftra_oce       ! ocean active tracers: lateral physics
25   USE dianam           !
26   USE iom              ! IOM library
27   USE ioipsl           ! IO-IPSL library
28   USE in_out_manager   ! I/O manager
29   USE lib_mpp          ! MPP library
30   USE lbclnk           ! lateral boundary condition - processor exchanges
31
32   IMPLICIT NONE
33   PRIVATE
34
35   INTERFACE ptr_vj
36      MODULE PROCEDURE ptr_vj_3d, ptr_vj_2d
37   END INTERFACE
38
39   PUBLIC   dia_ptr_init   ! call in opa module
40   PUBLIC   dia_ptr        ! call in step module
41   PUBLIC   ptr_vj         ! call by tra_ldf & tra_adv routines
42   PUBLIC   ptr_vjk        ! call by tra_ldf & tra_adv routines
43
44   !                                           !!** namelist  namptr  **
45   LOGICAL , PUBLIC ::   ln_diaptr  = .FALSE.   !: Poleward transport flag (T) or not (F)
46   LOGICAL , PUBLIC ::   ln_subbas  = .FALSE.   !: Atlantic/Pacific/Indian basins calculation
47   LOGICAL , PUBLIC ::   ln_diaznl  = .FALSE.   !: Add zonal means and meridional stream functions
48   LOGICAL , PUBLIC ::   ln_ptrcomp = .FALSE.   !: Add decomposition : overturning (and gyre, soon ...)
49   INTEGER , PUBLIC ::   nn_fptr    = 15        !: frequency of ptr computation  [time step]
50   INTEGER , PUBLIC ::   nn_fwri    = 15        !: frequency of ptr outputs      [time step]
51
52   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   htr_adv, htr_ldf, htr_ove   !: Heat TRansports (adv, diff, overturn.)
53   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   str_adv, str_ldf, str_ove   !: Salt TRansports (adv, diff, overturn.)
54   
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   btmsk                  ! T-point basin interior masks
56   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   btm30                  ! mask out Southern Ocean (=0 south of 30°S)
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr  , str             ! adv heat and salt transports (approx)
58   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tn_jk, sn_jk , v_msf   ! i-mean T and S, j-Stream-Function
59   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sjk  , r1_sjk          ! i-mean i-k-surface and its inverse       
60   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr_eiv, str_eiv       ! bolus adv heat ans salt transports ('key_diaeiv')
61   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   v_msf_eiv              ! bolus j-streamfuction              ('key_diaeiv')
62
63
64   INTEGER ::   niter       !
65   INTEGER ::   nidom_ptr   !
66   INTEGER ::   numptr      ! logical unit for Poleward TRansports
67   INTEGER ::   nptr        ! = 1 (ln_subbas=F) or = 5 (glo, atl, pac, ind, ipc) (ln_subbas=T)
68
69   REAL(wp) ::   rc_sv    = 1.e-6_wp   ! conversion from m3/s to Sverdrup
70   REAL(wp) ::   rc_pwatt = 1.e-15_wp  ! conversion from W    to PW (further x rau0 x Cp)
71   REAL(wp) ::   rc_ggram = 1.e-6_wp   ! conversion from g    to Pg
72
73   REAL(wp), TARGET, DIMENSION(:),   ALLOCATABLE, SAVE :: p_fval1d
74   REAL(wp), TARGET, DIMENSION(:,:), ALLOCATABLE, SAVE :: p_fval2d
75
76   !! Integer, 1D workspace arrays. Not common enough to be implemented in
77   !! wrk_nemo module.
78   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex  , ndex_atl     , ndex_pac     , ndex_ind     , ndex_ipc
79   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) ::         ndex_atl_30  , ndex_pac_30  , ndex_ind_30  , ndex_ipc_30
80   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex_h, ndex_h_atl_30, ndex_h_pac_30, ndex_h_ind_30, ndex_h_ipc_30
81
82   !! * Substitutions
83#  include "domzgr_substitute.h90"
84#  include "vectopt_loop_substitute.h90"
85   !!----------------------------------------------------------------------
86   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
87   !! $Id$
88   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
89   !!----------------------------------------------------------------------
90CONTAINS
91
92   FUNCTION dia_ptr_alloc()
93      !!----------------------------------------------------------------------
94      !!                    ***  ROUTINE dia_ptr_alloc  ***
95      !!----------------------------------------------------------------------
96      INTEGER               ::   dia_ptr_alloc   ! return value
97      INTEGER, DIMENSION(5) ::   ierr
98      !!----------------------------------------------------------------------
99      ierr(:) = 0
100      !
101      ALLOCATE( btmsk(jpi,jpj,nptr) ,           &
102         &      htr_adv(jpj) , str_adv(jpj) ,   &
103         &      htr_ldf(jpj) , str_ldf(jpj) ,   &
104         &      htr_ove(jpj) , str_ove(jpj),    &
105         &      htr(jpj,nptr) , str(jpj,nptr) , &
106         &      tn_jk(jpj,jpk,nptr) , sn_jk (jpj,jpk,nptr) , v_msf(jpj,jpk,nptr) , &
107         &      sjk  (jpj,jpk,nptr) , r1_sjk(jpj,jpk,nptr) , STAT=ierr(1)  )
108         !
109#if defined key_diaeiv
110      ALLOCATE( htr_eiv(jpj,nptr) , str_eiv(jpj,nptr) , &
111         &      v_msf_eiv(jpj,jpk,nptr) , STAT=ierr(2) )
112#endif
113      ALLOCATE( p_fval1d(jpj), p_fval2d(jpj,jpk), Stat=ierr(3))
114      !
115      ALLOCATE(ndex(jpj*jpk),        ndex_atl(jpj*jpk), ndex_pac(jpj*jpk), &
116         &     ndex_ind(jpj*jpk),    ndex_ipc(jpj*jpk),                    &
117         &     ndex_atl_30(jpj*jpk), ndex_pac_30(jpj*jpk), Stat=ierr(4))
118
119      ALLOCATE(ndex_ind_30(jpj*jpk), ndex_ipc_30(jpj*jpk),                   &
120         &     ndex_h(jpj),          ndex_h_atl_30(jpj), ndex_h_pac_30(jpj), &
121         &     ndex_h_ind_30(jpj),   ndex_h_ipc_30(jpj), Stat=ierr(5) )
122         !
123      dia_ptr_alloc = MAXVAL( ierr )
124      IF(lk_mpp)   CALL mpp_sum( dia_ptr_alloc )
125      !
126   END FUNCTION dia_ptr_alloc
127
128
129   FUNCTION ptr_vj_3d( pva )   RESULT ( p_fval )
130      !!----------------------------------------------------------------------
131      !!                    ***  ROUTINE ptr_vj_3d  ***
132      !!
133      !! ** Purpose :   i-k sum computation of a j-flux array
134      !!
135      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
136      !!              pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
137      !!
138      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
139      !!----------------------------------------------------------------------
140      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pva   ! mask flux array at V-point
141      !!
142      INTEGER                  ::   ji, jj, jk   ! dummy loop arguments
143      INTEGER                  ::   ijpj         ! ???
144      REAL(wp), POINTER, DIMENSION(:) :: p_fval  ! function value
145      !!--------------------------------------------------------------------
146      !
147      p_fval => p_fval1d
148
149      ijpj = jpj
150      p_fval(:) = 0._wp
151      DO jk = 1, jpkm1
152         DO jj = 2, jpjm1
153            DO ji = fs_2, fs_jpim1   ! Vector opt.
154               p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj) 
155            END DO
156         END DO
157      END DO
158#if defined key_mpp_mpi
159      IF(lk_mpp)   CALL mpp_sum( p_fval, ijpj, ncomm_znl)
160#endif
161      !
162   END FUNCTION ptr_vj_3d
163
164
165   FUNCTION ptr_vj_2d( pva )   RESULT ( p_fval )
166      !!----------------------------------------------------------------------
167      !!                    ***  ROUTINE ptr_vj_2d  ***
168      !!
169      !! ** Purpose :   "zonal" and vertical sum computation of a i-flux array
170      !!
171      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
172      !!      pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
173      !!
174      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
175      !!----------------------------------------------------------------------
176      IMPLICIT none
177      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) ::   pva   ! mask flux array at V-point
178      !!
179      INTEGER                  ::   ji,jj       ! dummy loop arguments
180      INTEGER                  ::   ijpj        ! ???
181      REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
182      !!--------------------------------------------------------------------
183      !
184      p_fval => p_fval1d
185
186      ijpj = jpj
187      p_fval(:) = 0._wp
188      DO jj = 2, jpjm1
189         DO ji = nldi, nlei   ! No vector optimisation here. Better use a mask ?
190            p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj)
191         END DO
192      END DO
193#if defined key_mpp_mpi
194      CALL mpp_sum( p_fval, ijpj, ncomm_znl )
195#endif
196      !
197   END FUNCTION ptr_vj_2d
198
199
200   FUNCTION ptr_vjk( pva, pmsk )   RESULT ( p_fval )
201      !!----------------------------------------------------------------------
202      !!                    ***  ROUTINE ptr_vjk  ***
203      !!
204      !! ** Purpose :   i-sum computation of a j-velocity array
205      !!
206      !! ** Method  : - i-sum of pva using the interior 2D vmask (vmask_i).
207      !!              pva is supposed to be a masked flux (i.e. * vmask)
208      !!
209      !! ** Action  : - p_fval: i-mean poleward flux of pva
210      !!----------------------------------------------------------------------
211#if defined key_mpp_mpi
212      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
213      USE wrk_nemo, ONLY:   zwork => wrk_1d_1
214#endif
215      !!
216      IMPLICIT none
217      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk)           ::   pva    ! mask flux array at V-point
218      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)    , OPTIONAL ::   pmsk   ! Optional 2D basin mask
219      !!
220      INTEGER                           :: ji, jj, jk ! dummy loop arguments
221      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval     ! return function value
222#if defined key_mpp_mpi
223      INTEGER, DIMENSION(1) ::   ish
224      INTEGER, DIMENSION(2) ::   ish2
225      INTEGER               ::   ijpjjpk
226#endif
227      !!--------------------------------------------------------------------
228      !
229#if defined key_mpp_mpi
230      IF( wrk_in_use(1, 1) ) THEN
231         CALL ctl_stop('ptr_vjk: ERROR - requested workspace array is unavailable')   ;   RETURN
232      END IF
233#endif
234
235      p_fval => p_fval2d
236
237      p_fval(:,:) = 0._wp
238      !
239      IF( PRESENT( pmsk ) ) THEN
240         DO jk = 1, jpkm1
241            DO jj = 2, jpjm1
242!!gm here, use of tmask_i  ==> no need of loop over nldi, nlei....
243               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
244                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * pmsk(ji,jj)
245               END DO
246            END DO
247         END DO
248      ELSE
249         DO jk = 1, jpkm1
250            DO jj = 2, jpjm1
251               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
252                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * tmask_i(ji,jj)
253               END DO
254            END DO
255         END DO
256      END IF
257      !
258#if defined key_mpp_mpi
259      ijpjjpk = jpj*jpk
260      ish(1) = ijpjjpk  ;   ish2(1) = jpj   ;   ish2(2) = jpk
261      zwork(1:ijpjjpk) = RESHAPE( p_fval, ish )
262      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
263      p_fval(:,:) = RESHAPE( zwork, ish2 )
264#endif
265      !
266#if defined key_mpp_mpi
267      IF( wrk_not_released(1, 1) )   CALL ctl_stop('ptr_vjk: ERROR - failed to release workspace array')
268#endif
269      !
270   END FUNCTION ptr_vjk
271
272
273   FUNCTION ptr_tjk( pta, pmsk )   RESULT ( p_fval )
274      !!----------------------------------------------------------------------
275      !!                    ***  ROUTINE ptr_tjk  ***
276      !!
277      !! ** Purpose :   i-sum computation of e1t*e3t * a tracer field
278      !!
279      !! ** Method  : - i-sum of mj(pta) using tmask
280      !!
281      !! ** Action  : - p_fval: i-sum of e1t*e3t*pta
282      !!----------------------------------------------------------------------
283#if defined key_mpp_mpi
284      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
285      USE wrk_nemo, ONLY:   zwork => wrk_1d_1
286#endif
287      !!
288      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pta    ! tracer flux array at T-point
289      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)     ::   pmsk   ! Optional 2D basin mask
290      !!
291      INTEGER                           :: ji, jj, jk   ! dummy loop arguments
292      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval       ! return function value
293#if defined key_mpp_mpi
294      INTEGER, DIMENSION(1) ::   ish
295      INTEGER, DIMENSION(2) ::   ish2
296      INTEGER               ::   ijpjjpk
297#endif
298      !!--------------------------------------------------------------------
299      !
300#if defined key_mpp_mpi
301      IF( wrk_in_use(1, 1) ) THEN
302         CALL ctl_stop('ptr_tjk: requested workspace array unavailable')   ;   RETURN
303      ENDIF
304#endif
305
306      p_fval => p_fval2d
307
308      p_fval(:,:) = 0._wp
309      DO jk = 1, jpkm1
310         DO jj = 2, jpjm1
311            DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
312               p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * e1t(ji,jj) * fse3t(ji,jj,jk) * pmsk(ji,jj)
313            END DO
314         END DO
315      END DO
316#if defined key_mpp_mpi
317      ijpjjpk = jpj*jpk
318      ish(1) = jpj*jpk   ;   ish2(1) = jpj   ;   ish2(2) = jpk
319      zwork(1:ijpjjpk)= RESHAPE( p_fval, ish )
320      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
321      p_fval(:,:)= RESHAPE( zwork, ish2 )
322#endif
323      !
324#if defined key_mpp_mpi
325      IF( wrk_not_released(1, 1) )   CALL ctl_stop('ptr_tjk: failed to release workspace array')
326#endif
327      !   
328   END FUNCTION ptr_tjk
329
330
331   SUBROUTINE dia_ptr( kt )
332      !!----------------------------------------------------------------------
333      !!                  ***  ROUTINE dia_ptr  ***
334      !!----------------------------------------------------------------------
335      USE oce,     vt  =>   ua   ! use ua as workspace
336      USE oce,     vs  =>   ua   ! use ua as workspace
337      IMPLICIT none
338      !!
339      INTEGER, INTENT(in) ::   kt   ! ocean time step index
340      !
341      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
342      REAL(wp) ::   zv               ! local scalar
343      !!----------------------------------------------------------------------
344      !
345      IF( kt == nit000 .OR. MOD( kt, nn_fptr ) == 0 )   THEN
346         !
347         IF( MOD( kt, nn_fptr ) == 0 ) THEN 
348            !
349            IF( ln_diaznl ) THEN               ! i-mean temperature and salinity
350               DO jn = 1, nptr
351                  tn_jk(:,:,jn) = ptr_tjk( tsn(:,:,:,jp_tem), btmsk(:,:,jn) ) * r1_sjk(:,:,jn)
352               END DO
353            ENDIF
354            !
355            !                          ! horizontal integral and vertical dz
356            !                                ! eulerian velocity
357            v_msf(:,:,1) = ptr_vjk( vn(:,:,:) ) 
358            DO jn = 2, nptr
359               v_msf(:,:,jn) = ptr_vjk( vn(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) 
360            END DO
361#if defined key_diaeiv
362            DO jn = 1, nptr                  ! bolus velocity
363               v_msf_eiv(:,:,jn) = ptr_vjk( v_eiv(:,:,:), btmsk(:,:,jn) )   ! here no btm30 for MSFeiv
364            END DO
365            !                                ! add bolus stream-function to the eulerian one
366            v_msf(:,:,:) = v_msf(:,:,:) + v_msf_eiv(:,:,:)
367#endif
368            !
369            !                          ! Transports
370            !                                ! local heat & salt transports at T-points  ( tsn*mj[vn+v_eiv] )
371            vt(:,:,jpk) = 0._wp   ;   vs(:,:,jpk) = 0._wp
372            DO jk= 1, jpkm1
373               DO jj = 2, jpj
374                  DO ji = 1, jpi
375#if defined key_diaeiv 
376                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) + v_eiv(ji,jj,jk) + v_eiv(ji,jj-1,jk) ) * 0.5_wp
377#else
378                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) ) * 0.5_wp
379#endif
380                     vt(:,jj,jk) = zv * tsn(:,jj,jk,jp_tem)
381                     vs(:,jj,jk) = zv * tsn(:,jj,jk,jp_sal)
382                  END DO
383               END DO
384            END DO
385!!gm useless as overlap areas are not used in ptr_vjk
386            CALL lbc_lnk( vs, 'V', -1. )   ;   CALL lbc_lnk( vt, 'V', -1. )
387!!gm
388            !                                ! heat & salt advective transports (approximation)
389            htr(:,1) = SUM( ptr_vjk( vt(:,:,:) ) , 2 ) * rc_pwatt   ! SUM over jk + conversion
390            str(:,1) = SUM( ptr_vjk( vs(:,:,:) ) , 2 ) * rc_ggram
391            DO jn = 2, nptr 
392               htr(:,jn) = SUM( ptr_vjk( vt(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_pwatt   ! mask Southern Ocean
393               str(:,jn) = SUM( ptr_vjk( vs(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_ggram   ! mask Southern Ocean
394            END DO
395
396            IF( ln_ptrcomp ) THEN            ! overturning transport
397               htr_ove(:) = SUM( v_msf(:,:,1) * tn_jk(:,:,1), 2 ) * rc_pwatt   ! SUM over jk + conversion
398               str_ove(:) = SUM( v_msf(:,:,1) * sn_jk(:,:,1), 2 ) * rc_ggram
399            END IF
400            !                                ! Advective and diffusive transport
401            htr_adv(:) = htr_adv(:) * rc_pwatt        ! these are computed in tra_adv... and tra_ldf... routines
402            htr_ldf(:) = htr_ldf(:) * rc_pwatt        ! here just the conversion in PW and Gg
403            str_adv(:) = str_adv(:) * rc_ggram
404            str_ldf(:) = str_ldf(:) * rc_ggram
405
406#if defined key_diaeiv
407            DO jn = 1, nptr                  ! Bolus component
408               htr_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * tn_jk(:,:,jn), 2 ) * rc_pwatt   ! SUM over jk
409               str_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * sn_jk(:,:,jn), 2 ) * rc_ggram   ! SUM over jk
410            END DO
411#endif
412            !                                ! "Meridional" Stream-Function
413            DO jn = 1, nptr
414               DO jk = 2, jpk 
415                  v_msf    (:,jk,jn) = v_msf    (:,jk-1,jn) + v_msf    (:,jk,jn)       ! Eulerian j-Stream-Function
416#if defined key_diaeiv
417                  v_msf_eiv(:,jk,jn) = v_msf_eiv(:,jk-1,jn) + v_msf_eiv(:,jk,jn)       ! Bolus    j-Stream-Function
418
419#endif
420               END DO
421            END DO
422            v_msf    (:,:,:) = v_msf    (:,:,:) * rc_sv       ! converte in Sverdrups
423#if defined key_diaeiv
424            v_msf_eiv(:,:,:) = v_msf_eiv(:,:,:) * rc_sv
425#endif
426         ENDIF
427         !
428         CALL dia_ptr_wri( kt )                        ! outputs
429         !
430      ENDIF
431      !
432      IF( kt == nitend )   CALL histclo( numptr )      ! Close the file
433      !
434   END SUBROUTINE dia_ptr
435
436
437   SUBROUTINE dia_ptr_init
438      !!----------------------------------------------------------------------
439      !!                  ***  ROUTINE dia_ptr_init  ***
440      !!                   
441      !! ** Purpose :   Initialization, namelist read
442      !!----------------------------------------------------------------------
443      INTEGER ::   jn           ! dummy loop indices
444      INTEGER ::   inum, ierr   ! local integers
445#if defined key_mpp_mpi
446      INTEGER, DIMENSION(1) :: iglo, iloc, iabsf, iabsl, ihals, ihale, idid
447#endif
448      !!
449      NAMELIST/namptr/ ln_diaptr, ln_diaznl, ln_subbas, ln_ptrcomp, nn_fptr, nn_fwri
450      !!----------------------------------------------------------------------
451
452      !                                      ! allocate dia_ptr arrays
453      IF( dia_ptr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate arrays' )
454
455      REWIND( numnam )                 ! Read Namelist namptr : poleward transport parameters
456      READ  ( numnam, namptr )
457
458      IF(lwp) THEN                     ! Control print
459         WRITE(numout,*)
460         WRITE(numout,*) 'dia_ptr_init : poleward transport and msf initialization'
461         WRITE(numout,*) '~~~~~~~~~~~~'
462         WRITE(numout,*) '   Namelist namptr : set ptr parameters'
463         WRITE(numout,*) '      Poleward heat & salt transport (T) or not (F)      ln_diaptr  = ', ln_diaptr
464         WRITE(numout,*) '      Overturning heat & salt transport                  ln_ptrcomp = ', ln_ptrcomp
465         WRITE(numout,*) '      T & S zonal mean and meridional stream function    ln_diaznl  = ', ln_diaznl 
466         WRITE(numout,*) '      Global (F) or glo/Atl/Pac/Ind/Indo-Pac basins      ln_subbas  = ', ln_subbas
467         WRITE(numout,*) '      Frequency of computation                           nn_fptr    = ', nn_fptr
468         WRITE(numout,*) '      Frequency of outputs                               nn_fwri    = ', nn_fwri
469      ENDIF
470
471      IF( ln_subbas ) THEN   ;   nptr = 5       ! Global, Atlantic, Pacific, Indian, Indo-Pacific
472      ELSE                   ;   nptr = 1       ! Global only
473      ENDIF
474
475      rc_pwatt = rc_pwatt * rau0 * rcp          ! conversion from K.s-1 to PetaWatt
476
477      IF( .NOT. ln_diaptr ) THEN       ! diaptr not used
478        RETURN
479      ENDIF
480     
481      IF( lk_mpp )   CALL mpp_ini_znl( numout )     ! Define MPI communicator for zonal sum
482
483      IF( ln_subbas ) THEN                ! load sub-basin mask
484         CALL iom_open( 'subbasins', inum )
485         CALL iom_get( inum, jpdom_data, 'atlmsk', btmsk(:,:,2) )   ! Atlantic basin
486         CALL iom_get( inum, jpdom_data, 'pacmsk', btmsk(:,:,3) )   ! Pacific  basin
487         CALL iom_get( inum, jpdom_data, 'indmsk', btmsk(:,:,4) )   ! Indian   basin
488         CALL iom_close( inum )
489         btmsk(:,:,5) = MAX ( btmsk(:,:,3), btmsk(:,:,4) )          ! Indo-Pacific basin
490         WHERE( gphit(:,:) < -30._wp)   ;   btm30(:,:) = 0._wp      ! mask out Southern Ocean
491         ELSE WHERE                     ;   btm30(:,:) = tmask(:,:,1)
492         END WHERE
493      ENDIF
494      btmsk(:,:,1) = tmask_i(:,:)                                   ! global ocean
495     
496      DO jn = 1, nptr
497         btmsk(:,:,jn) = btmsk(:,:,jn) * tmask_i(:,:)               ! interior domain only
498      END DO
499     
500      IF( lk_vvl )   CALL ctl_stop( 'diaptr: error in vvl case as constant i-mean surface is used' )
501
502      !                                   ! i-sum of e1v*e3v surface and its inverse
503      DO jn = 1, nptr
504         sjk(:,:,jn) = ptr_tjk( tmask(:,:,:), btmsk(:,:,jn) )
505         r1_sjk(:,:,jn) = 0._wp
506         WHERE( sjk(:,:,jn) /= 0._wp )   r1_sjk(:,:,jn) = 1._wp / sjk(:,:,jn)
507      END DO
508
509#if defined key_mpp_mpi 
510      iglo (1) = jpjglo                   ! MPP case using MPI  ('key_mpp_mpi')
511      iloc (1) = nlcj
512      iabsf(1) = njmppt(narea)
513      iabsl(:) = iabsf(:) + iloc(:) - 1
514      ihals(1) = nldj - 1
515      ihale(1) = nlcj - nlej
516      idid (1) = 2
517      CALL flio_dom_set( jpnj, nproc/jpni, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom_ptr )
518#else
519      nidom_ptr = FLIO_DOM_NONE
520#endif
521      !
522   END SUBROUTINE dia_ptr_init
523
524
525   SUBROUTINE dia_ptr_wri( kt )
526      !!---------------------------------------------------------------------
527      !!                ***  ROUTINE dia_ptr_wri  ***
528      !!
529      !! ** Purpose :   output of poleward fluxes
530      !!
531      !! ** Method  :   NetCDF file
532      !!----------------------------------------------------------------------
533      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
534      USE wrk_nemo, ONLY:   zphi => wrk_1d_1, zfoo => wrk_1d_2    ! 1D workspace
535      USE wrk_nemo, ONLY:   z_1  => wrk_2d_1                      ! 2D      -
536      !!
537      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
538      !!
539      INTEGER, SAVE ::   nhoridz, ndepidzt, ndepidzw
540      INTEGER, SAVE ::   ndim  , ndim_atl     , ndim_pac     , ndim_ind     , ndim_ipc
541      INTEGER, SAVE ::           ndim_atl_30  , ndim_pac_30  , ndim_ind_30  , ndim_ipc_30
542      INTEGER, SAVE ::   ndim_h, ndim_h_atl_30, ndim_h_pac_30, ndim_h_ind_30, ndim_h_ipc_30
543      !!
544      CHARACTER (len=40) ::   clhstnam, clop, clop_once, cl_comment   ! temporary names
545      INTEGER            ::   iline, it, itmod, ji, jj, jk            !
546#if defined key_iomput
547      INTEGER            ::   inum                                    ! temporary logical unit
548#endif
549      REAL(wp)           ::   zsto, zout, zdt, zjulian                ! temporary scalars
550      !!----------------------------------------------------------------------
551
552      IF( wrk_in_use(1, 1,2) .OR. wrk_in_use(2, 1) ) THEN
553         CALL ctl_stop('dia_ptr_wri: requested workspace arrays unavailable')   ;   RETURN
554      ENDIF
555
556      ! define time axis
557      it    = kt / nn_fptr
558      itmod = kt - nit000 + 1
559     
560      ! Initialization
561      ! --------------
562      IF( kt == nit000 ) THEN
563         niter = ( nit000 - 1 ) / nn_fptr
564         zdt = rdt
565         IF( nacc == 1 )   zdt = rdtmin
566         !
567         IF(lwp) THEN
568            WRITE(numout,*)
569            WRITE(numout,*) 'dia_ptr_wri : poleward transport and msf writing: initialization , niter = ', niter
570            WRITE(numout,*) '~~~~~~~~~~~~'
571         ENDIF
572
573         ! Reference latitude (used in plots)
574         ! ------------------
575         !                                           ! =======================
576         IF( cp_cfg == "orca" ) THEN                 !   ORCA configurations
577            !                                        ! =======================
578            IF( jp_cfg == 05  )   iline = 192   ! i-line that passes near the North Pole
579            IF( jp_cfg == 025 )   iline = 384   ! i-line that passes near the North Pole
580            IF( jp_cfg == 1   )   iline =  96   ! i-line that passes near the North Pole
581            IF( jp_cfg == 2   )   iline =  48   ! i-line that passes near the North Pole
582            IF( jp_cfg == 4   )   iline =  24   ! i-line that passes near the North Pole
583            zphi(1:jpj) = 0._wp
584            DO ji = mi0(iline), mi1(iline) 
585               zphi(1:jpj) = gphiv(ji,:)         ! if iline is in the local domain
586               ! Correct highest latitude for some configurations - will work if domain is parallelized in J ?
587               IF( jp_cfg == 05 ) THEN
588                  DO jj = mj0(jpjdta), mj1(jpjdta) 
589                     zphi( jj ) = zphi(mj0(jpjdta-1)) + ( zphi(mj0(jpjdta-1))-zphi(mj0(jpjdta-2)) ) * 0.5_wp
590                     zphi( jj ) = MIN( zphi(jj), 90._wp )
591                  END DO
592               END IF
593               IF( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) THEN
594                  DO jj = mj0(jpjdta-1), mj1(jpjdta-1) 
595                     zphi( jj ) = 88.5_wp
596                  END DO
597                  DO jj = mj0(jpjdta  ), mj1(jpjdta  ) 
598                     zphi( jj ) = 89.5_wp
599                  END DO
600               END IF
601            END DO
602            ! provide the correct zphi to all local domains
603#if defined key_mpp_mpi
604            CALL mpp_sum( zphi, jpj, ncomm_znl )       
605#endif
606            !                                        ! =======================
607         ELSE                                        !   OTHER configurations
608            !                                        ! =======================
609            zphi(1:jpj) = gphiv(1,:)             ! assume lat/lon coordinate, select the first i-line
610            !
611         ENDIF
612         !
613         ! Work only on westmost processor (will not work if mppini2 is used)
614#if defined key_mpp_mpi
615         IF( l_znl_root ) THEN 
616#endif
617            !
618            ! OPEN netcdf file
619            ! ----------------
620            ! Define frequency of output and means
621            zsto = nn_fptr * zdt
622            IF( ln_mskland )   THEN    ! put 1.e+20 on land (very expensive!!)
623               clop      = "ave(only(x))"
624               clop_once = "once(only(x))"
625            ELSE                       ! no use of the mask value (require less cpu time)
626               clop      = "ave(x)"       
627               clop_once = "once"
628            ENDIF
629
630            zout = nn_fwri * zdt
631            zfoo(1:jpj) = 0._wp
632
633            CALL ymds2ju( nyear, nmonth, nday, rdt, zjulian )  ! Compute julian date from starting date of the run
634            zjulian = zjulian - adatrj                         ! set calendar origin to the beginning of the experiment
635
636#if defined key_iomput
637            ! Requested by IPSL people, use by their postpro...
638            IF(lwp) THEN
639               CALL dia_nam( clhstnam, nn_fwri,' ' )
640               CALL ctl_opn( inum, 'date.file', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
641               WRITE(inum,*) clhstnam
642               CLOSE(inum)
643            ENDIF
644#endif
645
646            CALL dia_nam( clhstnam, nn_fwri, 'diaptr' )
647            IF(lwp)WRITE( numout,*)" Name of diaptr NETCDF file : ", clhstnam
648
649            ! Horizontal grid : zphi()
650            CALL histbeg(clhstnam, 1, zfoo, jpj, zphi,   &
651               1, 1, 1, jpj, niter, zjulian, zdt*nn_fptr, nhoridz, numptr, domain_id=nidom_ptr)
652            ! Vertical grids : gdept_0, gdepw_0
653            CALL histvert( numptr, "deptht", "Vertical T levels",   &
654               &                   "m", jpk, gdept_0, ndepidzt, "down" )
655            CALL histvert( numptr, "depthw", "Vertical W levels",   &
656               &                   "m", jpk, gdepw_0, ndepidzw, "down" )
657            !
658            CALL wheneq ( jpj*jpk, MIN(sjk(:,:,1), 1._wp), 1, 1., ndex  , ndim  )      ! Lat-Depth
659            CALL wheneq ( jpj    , MIN(sjk(:,1,1), 1._wp), 1, 1., ndex_h, ndim_h )     ! Lat
660
661            IF( ln_subbas ) THEN
662               z_1(:,1) = 1._wp
663               WHERE ( gphit(jpi/2,:) < -30._wp )   z_1(:,1) = 0._wp
664               DO jk = 2, jpk
665                  z_1(:,jk) = z_1(:,1)
666               END DO
667               !                       ! Atlantic (jn=2)
668               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)         , 1._wp), 1, 1., ndex_atl     , ndim_atl      ) ! Lat-Depth
669               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)*z_1(:,:), 1._wp), 1, 1., ndex_atl_30  , ndim_atl_30   ) ! Lat-Depth
670               CALL wheneq ( jpj    , MIN(sjk(:,1,2)*z_1(:,1), 1._wp), 1, 1., ndex_h_atl_30, ndim_h_atl_30 ) ! Lat
671               !                       ! Pacific (jn=3)
672               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)         , 1._wp), 1, 1., ndex_pac     , ndim_pac      ) ! Lat-Depth
673               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)*z_1(:,:), 1._wp), 1, 1., ndex_pac_30  , ndim_pac_30   ) ! Lat-Depth
674               CALL wheneq ( jpj    , MIN(sjk(:,1,3)*z_1(:,1), 1._wp), 1, 1., ndex_h_pac_30, ndim_h_pac_30 ) ! Lat
675               !                       ! Indian (jn=4)
676               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)         , 1._wp), 1, 1., ndex_ind     , ndim_ind      ) ! Lat-Depth
677               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)*z_1(:,:), 1._wp), 1, 1., ndex_ind_30  , ndim_ind_30   ) ! Lat-Depth
678               CALL wheneq ( jpj    , MIN(sjk(:,1,4)*z_1(:,1), 1._wp), 1, 1., ndex_h_ind_30, ndim_h_ind_30 ) ! Lat
679               !                       ! Indo-Pacific (jn=5)
680               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)         , 1._wp), 1, 1., ndex_ipc     , ndim_ipc      ) ! Lat-Depth
681               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)*z_1(:,:), 1._wp), 1, 1., ndex_ipc_30  , ndim_ipc_30   ) ! Lat-Depth
682               CALL wheneq ( jpj    , MIN(sjk(:,1,5)*z_1(:,1), 1._wp), 1, 1., ndex_h_ipc_30, ndim_h_ipc_30 ) ! Lat
683            ENDIF
684            !
685#if defined key_diaeiv
686            cl_comment = ' (Bolus part included)'
687#else
688            cl_comment = '                      '
689#endif
690            IF( ln_diaznl ) THEN             !  Zonal mean T and S
691               CALL histdef( numptr, "zotemglo", "Zonal Mean Temperature","C" ,   &
692                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
693               CALL histdef( numptr, "zosalglo", "Zonal Mean Salinity","PSU"  ,   &
694                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
695
696               CALL histdef( numptr, "zosrfglo", "Zonal Mean Surface","m^2"   ,   &
697                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
698               !
699               IF (ln_subbas) THEN
700                  CALL histdef( numptr, "zotematl", "Zonal Mean Temperature: Atlantic","C" ,   &
701                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
702                  CALL histdef( numptr, "zosalatl", "Zonal Mean Salinity: Atlantic","PSU"  ,   &
703                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
704                  CALL histdef( numptr, "zosrfatl", "Zonal Mean Surface: Atlantic","m^2"   ,   &
705                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
706
707                  CALL histdef( numptr, "zotempac", "Zonal Mean Temperature: Pacific","C"  ,   &
708                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
709                  CALL histdef( numptr, "zosalpac", "Zonal Mean Salinity: Pacific","PSU"   ,   &
710                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
711                  CALL histdef( numptr, "zosrfpac", "Zonal Mean Surface: Pacific","m^2"    ,   &
712                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
713
714                  CALL histdef( numptr, "zotemind", "Zonal Mean Temperature: Indian","C"   ,   &
715                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
716                  CALL histdef( numptr, "zosalind", "Zonal Mean Salinity: Indian","PSU"    ,   &
717                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
718                  CALL histdef( numptr, "zosrfind", "Zonal Mean Surface: Indian","m^2"     ,   &
719                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
720
721                  CALL histdef( numptr, "zotemipc", "Zonal Mean Temperature: Pacific+Indian","C" ,   &
722                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
723                  CALL histdef( numptr, "zosalipc", "Zonal Mean Salinity: Pacific+Indian","PSU"  ,   &
724                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
725                  CALL histdef( numptr, "zosrfipc", "Zonal Mean Surface: Pacific+Indian","m^2"   ,   &
726                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
727               ENDIF
728            ENDIF
729            !
730            !  Meridional Stream-Function (Eulerian and Bolus)
731            CALL histdef( numptr, "zomsfglo", "Meridional Stream-Function: Global"//TRIM(cl_comment),"Sv" ,   &
732               1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
733            IF( ln_subbas .AND. ln_diaznl ) THEN
734               CALL histdef( numptr, "zomsfatl", "Meridional Stream-Function: Atlantic"//TRIM(cl_comment),"Sv" ,   &
735                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
736               CALL histdef( numptr, "zomsfpac", "Meridional Stream-Function: Pacific"//TRIM(cl_comment),"Sv"  ,   &
737                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
738               CALL histdef( numptr, "zomsfind", "Meridional Stream-Function: Indian"//TRIM(cl_comment),"Sv"   ,   &
739                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
740               CALL histdef( numptr, "zomsfipc", "Meridional Stream-Function: Indo-Pacific"//TRIM(cl_comment),"Sv" ,&
741                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
742            ENDIF
743            !
744            !  Heat transport
745            CALL histdef( numptr, "sophtadv", "Advective Heat Transport"      ,   &
746               "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
747            CALL histdef( numptr, "sophtldf", "Diffusive Heat Transport"      ,   &
748               "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
749            IF ( ln_ptrcomp ) THEN
750               CALL histdef( numptr, "sophtove", "Overturning Heat Transport"    ,   &
751                  "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
752            END IF
753            IF( ln_subbas ) THEN
754               CALL histdef( numptr, "sohtatl", "Heat Transport Atlantic"//TRIM(cl_comment),  &
755                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
756               CALL histdef( numptr, "sohtpac", "Heat Transport Pacific"//TRIM(cl_comment) ,  &
757                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
758               CALL histdef( numptr, "sohtind", "Heat Transport Indian"//TRIM(cl_comment)  ,  &
759                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
760               CALL histdef( numptr, "sohtipc", "Heat Transport Pacific+Indian"//TRIM(cl_comment), &
761                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
762            ENDIF
763            !
764            !  Salt transport
765            CALL histdef( numptr, "sopstadv", "Advective Salt Transport"      ,   &
766               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
767            CALL histdef( numptr, "sopstldf", "Diffusive Salt Transport"      ,   &
768               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
769            IF ( ln_ptrcomp ) THEN
770               CALL histdef( numptr, "sopstove", "Overturning Salt Transport"    ,   &
771                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
772            END IF
773#if defined key_diaeiv
774            ! Eddy induced velocity
775            CALL histdef( numptr, "zomsfeiv", "Bolus Meridional Stream-Function: global",   &
776               "Sv"      , 1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
777            CALL histdef( numptr, "sophteiv", "Bolus Advective Heat Transport",   &
778               "PW"      , 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
779            CALL histdef( numptr, "sopsteiv", "Bolus Advective Salt Transport",   &
780               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
781#endif
782            IF( ln_subbas ) THEN
783               CALL histdef( numptr, "sostatl", "Salt Transport Atlantic"//TRIM(cl_comment)      ,  &
784                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
785               CALL histdef( numptr, "sostpac", "Salt Transport Pacific"//TRIM(cl_comment)      ,   &
786                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
787               CALL histdef( numptr, "sostind", "Salt Transport Indian"//TRIM(cl_comment)      ,    &
788                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
789               CALL histdef( numptr, "sostipc", "Salt Transport Pacific+Indian"//TRIM(cl_comment),  &
790                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
791            ENDIF
792            !
793            CALL histend( numptr )
794            !
795         END IF
796#if defined key_mpp_mpi
797      END IF
798#endif
799
800#if defined key_mpp_mpi
801      IF( MOD( itmod, nn_fptr ) == 0 .AND. l_znl_root ) THEN
802#else
803      IF( MOD( itmod, nn_fptr ) == 0  ) THEN
804#endif
805         niter = niter + 1
806
807         IF( ln_diaznl ) THEN
808            CALL histwrite( numptr, "zosrfglo", niter, sjk  (:,:,1) , ndim, ndex )
809            CALL histwrite( numptr, "zotemglo", niter, tn_jk(:,:,1)  , ndim, ndex )
810            CALL histwrite( numptr, "zosalglo", niter, sn_jk(:,:,1)  , ndim, ndex )
811
812            IF (ln_subbas) THEN
813               CALL histwrite( numptr, "zosrfatl", niter, sjk(:,:,2), ndim_atl, ndex_atl )
814               CALL histwrite( numptr, "zosrfpac", niter, sjk(:,:,3), ndim_pac, ndex_pac )
815               CALL histwrite( numptr, "zosrfind", niter, sjk(:,:,4), ndim_ind, ndex_ind )
816               CALL histwrite( numptr, "zosrfipc", niter, sjk(:,:,5), ndim_ipc, ndex_ipc )
817
818               CALL histwrite( numptr, "zotematl", niter, tn_jk(:,:,2)  , ndim_atl, ndex_atl )
819               CALL histwrite( numptr, "zosalatl", niter, sn_jk(:,:,2)  , ndim_atl, ndex_atl )
820               CALL histwrite( numptr, "zotempac", niter, tn_jk(:,:,3)  , ndim_pac, ndex_pac )
821               CALL histwrite( numptr, "zosalpac", niter, sn_jk(:,:,3)  , ndim_pac, ndex_pac )
822               CALL histwrite( numptr, "zotemind", niter, tn_jk(:,:,4)  , ndim_ind, ndex_ind )
823               CALL histwrite( numptr, "zosalind", niter, sn_jk(:,:,4)  , ndim_ind, ndex_ind )
824               CALL histwrite( numptr, "zotemipc", niter, tn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
825               CALL histwrite( numptr, "zosalipc", niter, sn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
826            END IF
827         ENDIF
828
829         ! overturning outputs:
830         CALL histwrite( numptr, "zomsfglo", niter, v_msf(:,:,1), ndim, ndex )
831         IF( ln_subbas .AND. ln_diaznl ) THEN
832            CALL histwrite( numptr, "zomsfatl", niter, v_msf(:,:,2) , ndim_atl_30, ndex_atl_30 )
833            CALL histwrite( numptr, "zomsfpac", niter, v_msf(:,:,3) , ndim_pac_30, ndex_pac_30 )
834            CALL histwrite( numptr, "zomsfind", niter, v_msf(:,:,4) , ndim_ind_30, ndex_ind_30 )
835            CALL histwrite( numptr, "zomsfipc", niter, v_msf(:,:,5) , ndim_ipc_30, ndex_ipc_30 )
836         ENDIF
837#if defined key_diaeiv
838         CALL histwrite( numptr, "zomsfeiv", niter, v_msf_eiv(:,:,1), ndim  , ndex   )
839#endif
840
841         ! heat transport outputs:
842         IF( ln_subbas ) THEN
843            CALL histwrite( numptr, "sohtatl", niter, htr(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
844            CALL histwrite( numptr, "sohtpac", niter, htr(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
845            CALL histwrite( numptr, "sohtind", niter, htr(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
846            CALL histwrite( numptr, "sohtipc", niter, htr(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
847            CALL histwrite( numptr, "sostatl", niter, str(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
848            CALL histwrite( numptr, "sostpac", niter, str(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
849            CALL histwrite( numptr, "sostind", niter, str(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
850            CALL histwrite( numptr, "sostipc", niter, str(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
851         ENDIF
852
853         CALL histwrite( numptr, "sophtadv", niter, htr_adv     , ndim_h, ndex_h )
854         CALL histwrite( numptr, "sophtldf", niter, htr_ldf     , ndim_h, ndex_h )
855         CALL histwrite( numptr, "sopstadv", niter, str_adv     , ndim_h, ndex_h )
856         CALL histwrite( numptr, "sopstldf", niter, str_ldf     , ndim_h, ndex_h )
857         IF( ln_ptrcomp ) THEN
858            CALL histwrite( numptr, "sopstove", niter, str_ove(:) , ndim_h, ndex_h )
859            CALL histwrite( numptr, "sophtove", niter, htr_ove(:) , ndim_h, ndex_h )
860         ENDIF
861#if defined key_diaeiv
862         CALL histwrite( numptr, "sophteiv", niter, htr_eiv(:,1)  , ndim_h, ndex_h )
863         CALL histwrite( numptr, "sopsteiv", niter, str_eiv(:,1)  , ndim_h, ndex_h )
864#endif
865         !
866      ENDIF
867      !
868      IF( wrk_not_released(1, 1,2) .OR.    &
869          wrk_not_released(2, 1)    )   CALL ctl_stop('dia_ptr_wri: failed to release workspace arrays')
870      !
871  END SUBROUTINE dia_ptr_wri
872
873   !!======================================================================
874END MODULE diaptr
Note: See TracBrowser for help on using the repository browser.