New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 2789

Last change on this file since 2789 was 2789, checked in by cetlod, 13 years ago

Implementation of the merge of TRA/TRP : first guess, see ticket #842
  • Property svn:keywords set to Id
File size: 8.6 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trdmod_oce     ! ocean variables trends
18   USE trdmod         ! ocean dynamics trends
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "domzgr_substitute.h90"
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the now momentum advection trend in flux form
43      !!              and the general trend of the momentum equation.
44      !!
45      !! ** Method  :   Trend evaluated using now fields (centered in time)
46      !!
47      !! ** Action  :   (ua,va) updated with the now vorticity term trend
48      !!----------------------------------------------------------------------
49      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
50      USE oce     , ONLY:   tsa             ! tsa used as 2 3D workspace
51      USE wrk_nemo, ONLY:   zfu_t => wrk_3d_1 , zfv_t => wrk_3d_4 , zfu_uw =>wrk_3d_6   ! 3D workspaces
52      USE wrk_nemo, ONLY:   zfu_f => wrk_3d_2 , zfv_f => wrk_3d_5 , zfv_vw =>wrk_3d_7
53      USE wrk_nemo, ONLY:   zfw   => wrk_3d_3
54      !
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !
57      INTEGER  ::   ji, jj, jk   ! dummy loop indices
58      REAL(wp) ::   zbu, zbv     ! local scalars
59      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
60      !!----------------------------------------------------------------------
61
62      IF( kt == nit000 .AND. lwp ) THEN
63         WRITE(numout,*)
64         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
65         WRITE(numout,*) '~~~~~~~~~~~~'
66      ENDIF
67
68      ! Check that global workspace arrays aren't already in use
69      IF( wrk_in_use(3, 1,2,3,4,5,6,7) ) THEN
70         CALL ctl_stop('dyn_adv_cen2 : requested workspace array unavailable')   ;   RETURN
71      ENDIF
72      !
73      zfu => tsa(:,:,:,1) 
74      zfv => tsa(:,:,:,2) 
75      !
76      IF( l_trddyn ) THEN           ! Save ua and va trends
77         zfu_uw(:,:,:) = ua(:,:,:)
78         zfv_vw(:,:,:) = va(:,:,:)
79      ENDIF
80
81      !                                      ! ====================== !
82      !                                      !  Horizontal advection  !
83      DO jk = 1, jpkm1                       ! ====================== !
84         !                                         ! horizontal volume fluxes
85         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
86         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
87         !
88         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
89            DO ji = 1, fs_jpim1   ! vector opt.
90               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
91               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
92               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
93               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
94            END DO
95         END DO
96         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
97            DO ji = fs_2, fs_jpim1   ! vector opt.
98               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
99               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
100               !
101               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
102                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
103               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
104                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
105            END DO
106         END DO
107      END DO
108      !
109      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
110         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
111         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
112         CALL trd_mod( zfu_uw, zfv_vw, jpdyn_trd_had, 'DYN', kt )
113         zfu_t(:,:,:) = ua(:,:,:)
114         zfv_t(:,:,:) = va(:,:,:)
115      ENDIF
116      !
117
118      !                                      ! ==================== !
119      !                                      !  Vertical advection  !
120      DO jk = 1, jpkm1                       ! ==================== !
121         !                                         ! Vertical volume fluxesÊ
122         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
123         !
124         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
125            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
126            zfv_vw(:,:,jpk) = 0.e0
127            !                                           ! Surface value :
128            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
129               zfu_uw(:,:, 1 ) = 0.e0   
130               zfv_vw(:,:, 1 ) = 0.e0
131            ELSE                                             ! constant volume : advection through the surface
132               DO jj = 2, jpjm1
133                  DO ji = fs_2, fs_jpim1
134                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
135                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
136                  END DO
137               END DO
138            ENDIF
139         ELSE                                      ! interior fluxes
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
143                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
144               END DO
145            END DO
146         ENDIF
147      END DO
148      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
149         DO jj = 2, jpjm1 
150            DO ji = fs_2, fs_jpim1   ! vector opt.
151               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
152                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
153               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
154                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
155            END DO
156         END DO
157      END DO
158      !
159      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
160         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
161         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
162         CALL trd_mod( zfu_t, zfv_t, jpdyn_trd_zad, 'DYN', kt )
163      ENDIF
164      !                                            ! Control print
165      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
166         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
167      !
168      IF( wrk_not_released(3, 1,2,3,4,5,6,7) )   CALL ctl_stop('dyn_adv_cen2: failed to release workspace array')
169      !
170   END SUBROUTINE dyn_adv_cen2
171
172   !!==============================================================================
173END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.