| 1 | MODULE p4zche |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zche *** |
|---|
| 4 | !! TOP : PISCES Sea water chemistry computed following OCMIP protocol |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1988 (E. Maier-Reimer) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) addition |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modification |
|---|
| 9 | !! NEMO 1.0 ! 2004 (O. Aumont) modification |
|---|
| 10 | !! - ! 2006 (R. Gangsto) modification |
|---|
| 11 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 12 | !! ! 2011-02 (J. Simeon, J.Orr ) update O2 solubility constants |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_pisces |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_pisces' PISCES bio-model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! p4z_che : Sea water chemistry computed following OCMIP protocol |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 21 | USE trc ! passive tracers common variables |
|---|
| 22 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 23 | USE lib_mpp ! MPP library |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC p4z_che ! |
|---|
| 29 | PUBLIC p4z_che_alloc ! |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sio3eq ! chemistry of Si |
|---|
| 32 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: fekeq ! chemistry of Fe |
|---|
| 33 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemc ! Solubilities of O2 and CO2 |
|---|
| 34 | |
|---|
| 35 | REAL(wp), PUBLIC :: atcox = 0.20946 ! units atm |
|---|
| 36 | |
|---|
| 37 | REAL(wp) :: salchl = 1. / 1.80655 ! conversion factor for salinity --> chlorinity (Wooster et al. 1969) |
|---|
| 38 | REAL(wp) :: o2atm = 1. / ( 1000. * 0.20946 ) |
|---|
| 39 | |
|---|
| 40 | REAL(wp) :: akcc1 = -171.9065 ! coeff. for apparent solubility equilibrium |
|---|
| 41 | REAL(wp) :: akcc2 = -0.077993 ! Millero et al. 1995 from Mucci 1983 |
|---|
| 42 | REAL(wp) :: akcc3 = 2839.319 |
|---|
| 43 | REAL(wp) :: akcc4 = 71.595 |
|---|
| 44 | REAL(wp) :: akcc5 = -0.77712 |
|---|
| 45 | REAL(wp) :: akcc6 = 0.00284263 |
|---|
| 46 | REAL(wp) :: akcc7 = 178.34 |
|---|
| 47 | REAL(wp) :: akcc8 = -0.07711 |
|---|
| 48 | REAL(wp) :: akcc9 = 0.0041249 |
|---|
| 49 | |
|---|
| 50 | REAL(wp) :: rgas = 83.143 ! universal gas constants |
|---|
| 51 | REAL(wp) :: oxyco = 1. / 22.4144 ! converts from liters of an ideal gas to moles |
|---|
| 52 | |
|---|
| 53 | REAL(wp) :: bor1 = 0.00023 ! borat constants |
|---|
| 54 | REAL(wp) :: bor2 = 1. / 10.82 |
|---|
| 55 | |
|---|
| 56 | REAL(wp) :: ca0 = -162.8301 ! WEISS & PRICE 1980, units mol/(kg atm) |
|---|
| 57 | REAL(wp) :: ca1 = 218.2968 |
|---|
| 58 | REAL(wp) :: ca2 = 90.9241 |
|---|
| 59 | REAL(wp) :: ca3 = -1.47696 |
|---|
| 60 | REAL(wp) :: ca4 = 0.025695 |
|---|
| 61 | REAL(wp) :: ca5 = -0.025225 |
|---|
| 62 | REAL(wp) :: ca6 = 0.0049867 |
|---|
| 63 | |
|---|
| 64 | REAL(wp) :: c10 = -3670.7 ! Coeff. for 1. dissoc. of carbonic acid (Edmond and Gieskes, 1970) |
|---|
| 65 | REAL(wp) :: c11 = 62.008 |
|---|
| 66 | REAL(wp) :: c12 = -9.7944 |
|---|
| 67 | REAL(wp) :: c13 = 0.0118 |
|---|
| 68 | REAL(wp) :: c14 = -0.000116 |
|---|
| 69 | |
|---|
| 70 | REAL(wp) :: c20 = -1394.7 ! coeff. for 2. dissoc. of carbonic acid (Millero, 1995) |
|---|
| 71 | REAL(wp) :: c21 = -4.777 |
|---|
| 72 | REAL(wp) :: c22 = 0.0184 |
|---|
| 73 | REAL(wp) :: c23 = -0.000118 |
|---|
| 74 | |
|---|
| 75 | REAL(wp) :: st1 = 0.14 ! constants for calculate concentrations for sulfate |
|---|
| 76 | REAL(wp) :: st2 = 1./96.062 ! (Morris & Riley 1966) |
|---|
| 77 | REAL(wp) :: ks0 = 141.328 |
|---|
| 78 | REAL(wp) :: ks1 = -4276.1 |
|---|
| 79 | REAL(wp) :: ks2 = -23.093 |
|---|
| 80 | REAL(wp) :: ks3 = -13856. |
|---|
| 81 | REAL(wp) :: ks4 = 324.57 |
|---|
| 82 | REAL(wp) :: ks5 = -47.986 |
|---|
| 83 | REAL(wp) :: ks6 = 35474. |
|---|
| 84 | REAL(wp) :: ks7 = -771.54 |
|---|
| 85 | REAL(wp) :: ks8 = 114.723 |
|---|
| 86 | REAL(wp) :: ks9 = -2698. |
|---|
| 87 | REAL(wp) :: ks10 = 1776. |
|---|
| 88 | REAL(wp) :: ks11 = 1. |
|---|
| 89 | REAL(wp) :: ks12 = -0.001005 |
|---|
| 90 | |
|---|
| 91 | REAL(wp) :: ft1 = 0.000067 ! constants for calculate concentrations for fluorides |
|---|
| 92 | REAL(wp) :: ft2 = 1./18.9984 ! (Dickson & Riley 1979 ) |
|---|
| 93 | REAL(wp) :: kf0 = -12.641 |
|---|
| 94 | REAL(wp) :: kf1 = 1590.2 |
|---|
| 95 | REAL(wp) :: kf2 = 1.525 |
|---|
| 96 | REAL(wp) :: kf3 = 1.0 |
|---|
| 97 | REAL(wp) :: kf4 = -0.001005 |
|---|
| 98 | |
|---|
| 99 | REAL(wp) :: cb0 = -8966.90 ! Coeff. for 1. dissoc. of boric acid |
|---|
| 100 | REAL(wp) :: cb1 = -2890.53 ! (Dickson and Goyet, 1994) |
|---|
| 101 | REAL(wp) :: cb2 = -77.942 |
|---|
| 102 | REAL(wp) :: cb3 = 1.728 |
|---|
| 103 | REAL(wp) :: cb4 = -0.0996 |
|---|
| 104 | REAL(wp) :: cb5 = 148.0248 |
|---|
| 105 | REAL(wp) :: cb6 = 137.1942 |
|---|
| 106 | REAL(wp) :: cb7 = 1.62142 |
|---|
| 107 | REAL(wp) :: cb8 = -24.4344 |
|---|
| 108 | REAL(wp) :: cb9 = -25.085 |
|---|
| 109 | REAL(wp) :: cb10 = -0.2474 |
|---|
| 110 | REAL(wp) :: cb11 = 0.053105 |
|---|
| 111 | |
|---|
| 112 | REAL(wp) :: cw0 = -13847.26 ! Coeff. for dissoc. of water (Dickson and Riley, 1979 ) |
|---|
| 113 | REAL(wp) :: cw1 = 148.9652 |
|---|
| 114 | REAL(wp) :: cw2 = -23.6521 |
|---|
| 115 | REAL(wp) :: cw3 = 118.67 |
|---|
| 116 | REAL(wp) :: cw4 = -5.977 |
|---|
| 117 | REAL(wp) :: cw5 = 1.0495 |
|---|
| 118 | REAL(wp) :: cw6 = -0.01615 |
|---|
| 119 | |
|---|
| 120 | ! ! volumetric solubility constants for o2 in ml/L |
|---|
| 121 | REAL(wp) :: ox0 = 2.00856 ! from Table 1 for Eq 8 of Garcia and Gordon, 1992. |
|---|
| 122 | REAL(wp) :: ox1 = 3.22400 ! corrects for moisture and fugacity, but not total atmospheric pressure |
|---|
| 123 | REAL(wp) :: ox2 = 3.99063 ! Original PISCES code noted this was a solubility, but |
|---|
| 124 | REAL(wp) :: ox3 = 4.80299 ! was in fact a bunsen coefficient with units L-O2/(Lsw atm-O2) |
|---|
| 125 | REAL(wp) :: ox4 = 9.78188e-1 ! Hence, need to divide EXP( zoxy ) by 1000, ml-O2 => L-O2 |
|---|
| 126 | REAL(wp) :: ox5 = 1.71069 ! and atcox = 0.20946 to add the 1/atm dimension. |
|---|
| 127 | REAL(wp) :: ox6 = -6.24097e-3 |
|---|
| 128 | REAL(wp) :: ox7 = -6.93498e-3 |
|---|
| 129 | REAL(wp) :: ox8 = -6.90358e-3 |
|---|
| 130 | REAL(wp) :: ox9 = -4.29155e-3 |
|---|
| 131 | REAL(wp) :: ox10 = -3.11680e-7 |
|---|
| 132 | |
|---|
| 133 | REAL(wp), DIMENSION(5) :: devk1, devk2, devk3, devk4, devk5 ! coeff. for seawater pressure correction |
|---|
| 134 | ! ! (millero 95) |
|---|
| 135 | DATA devk1 / -25.5 , -15.82 , -29.48 , -25.60 , -48.76 / |
|---|
| 136 | DATA devk2 / 0.1271 , -0.0219 , 0.1622 , 0.2324 , 0.5304 / |
|---|
| 137 | DATA devk3 / 0. , 0. , 2.608E-3, -3.6246E-3, 0. / |
|---|
| 138 | DATA devk4 / -3.08E-3 , 1.13E-3 , -2.84E-3, -5.13E-3 , -11.76E-3 / |
|---|
| 139 | DATA devk5 / 0.0877E-3, -0.1475E-3, 0. , 0.0794E-3 , 0.3692E-3 / |
|---|
| 140 | |
|---|
| 141 | !!* Substitution |
|---|
| 142 | #include "top_substitute.h90" |
|---|
| 143 | !!---------------------------------------------------------------------- |
|---|
| 144 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 145 | !! $Id$ |
|---|
| 146 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | CONTAINS |
|---|
| 149 | |
|---|
| 150 | SUBROUTINE p4z_che |
|---|
| 151 | !!--------------------------------------------------------------------- |
|---|
| 152 | !! *** ROUTINE p4z_che *** |
|---|
| 153 | !! |
|---|
| 154 | !! ** Purpose : Sea water chemistry computed following OCMIP protocol |
|---|
| 155 | !! |
|---|
| 156 | !! ** Method : - ... |
|---|
| 157 | !!--------------------------------------------------------------------- |
|---|
| 158 | INTEGER :: ji, jj, jk |
|---|
| 159 | REAL(wp) :: ztkel, zt , zt2 , zsal , zsal2 , zbuf1 , zbuf2 |
|---|
| 160 | REAL(wp) :: ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5 |
|---|
| 161 | REAL(wp) :: zpres, ztc , zcl , zcpexp, zoxy , zcpexp2 |
|---|
| 162 | REAL(wp) :: zsqrt, ztr , zlogt , zcek1 |
|---|
| 163 | REAL(wp) :: zis , zis2 , zsal15, zisqrt |
|---|
| 164 | REAL(wp) :: zckb , zck1 , zck2 , zckw , zak1 , zak2 , zakb , zaksp0, zakw |
|---|
| 165 | REAL(wp) :: zst , zft , zcks , zckf , zaksp1 |
|---|
| 166 | !!--------------------------------------------------------------------- |
|---|
| 167 | |
|---|
| 168 | ! CHEMICAL CONSTANTS - SURFACE LAYER |
|---|
| 169 | ! ---------------------------------- |
|---|
| 170 | !CDIR NOVERRCHK |
|---|
| 171 | DO jj = 1, jpj |
|---|
| 172 | !CDIR NOVERRCHK |
|---|
| 173 | DO ji = 1, jpi |
|---|
| 174 | ! ! SET ABSOLUTE TEMPERATURE |
|---|
| 175 | ztkel = tsn(ji,jj,1,jp_tem) + 273.16 |
|---|
| 176 | zt = ztkel * 0.01 |
|---|
| 177 | zt2 = zt * zt |
|---|
| 178 | zsal = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 179 | zsal2 = zsal * zsal |
|---|
| 180 | zlogt = LOG( zt ) |
|---|
| 181 | ! ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980) |
|---|
| 182 | ! ! AND FOR THE ATMOSPHERE FOR NON IDEAL GAS |
|---|
| 183 | zcek1 = ca0 + ca1 / zt + ca2 * zlogt + ca3 * zt2 + zsal * ( ca4 + ca5 * zt + ca6 * zt2 ) |
|---|
| 184 | ! ! LN(K0) OF SOLUBILITY OF O2 and N2 in ml/L (EQ. 8, GARCIA AND GORDON, 1992) |
|---|
| 185 | ztgg = LOG( ( 298.15 - tsn(ji,jj,1,jp_tem) ) / ztkel ) ! Set the GORDON & GARCIA scaled temperature |
|---|
| 186 | ztgg2 = ztgg * ztgg |
|---|
| 187 | ztgg3 = ztgg2 * ztgg |
|---|
| 188 | ztgg4 = ztgg3 * ztgg |
|---|
| 189 | ztgg5 = ztgg4 * ztgg |
|---|
| 190 | zoxy = ox0 + ox1 * ztgg + ox2 * ztgg2 + ox3 * ztgg3 + ox4 * ztgg4 + ox5 * ztgg5 & |
|---|
| 191 | + zsal * ( ox6 + ox7 * ztgg + ox8 * ztgg2 + ox9 * ztgg3 ) + ox10 * zsal2 |
|---|
| 192 | |
|---|
| 193 | ! ! SET SOLUBILITIES OF O2 AND CO2 |
|---|
| 194 | chemc(ji,jj,1) = EXP( zcek1 ) * 1.e-6 * rhop(ji,jj,1) / 1000. ! mol/(L uatm) |
|---|
| 195 | chemc(ji,jj,2) = ( EXP( zoxy ) * o2atm ) * oxyco ! mol/(L atm) |
|---|
| 196 | ! |
|---|
| 197 | END DO |
|---|
| 198 | END DO |
|---|
| 199 | |
|---|
| 200 | ! CHEMICAL CONSTANTS - DEEP OCEAN |
|---|
| 201 | ! ------------------------------- |
|---|
| 202 | !CDIR NOVERRCHK |
|---|
| 203 | DO jk = 1, jpk |
|---|
| 204 | !CDIR NOVERRCHK |
|---|
| 205 | DO jj = 1, jpj |
|---|
| 206 | !CDIR NOVERRCHK |
|---|
| 207 | DO ji = 1, jpi |
|---|
| 208 | |
|---|
| 209 | ! SET PRESSION |
|---|
| 210 | zpres = 1.025e-1 * fsdept(ji,jj,jk) |
|---|
| 211 | |
|---|
| 212 | ! SET ABSOLUTE TEMPERATURE |
|---|
| 213 | ztkel = tsn(ji,jj,jk,jp_tem) + 273.16 |
|---|
| 214 | zsal = tsn(ji,jj,jk,jp_sal) + ( 1.-tmask(ji,jj,jk) ) * 35. |
|---|
| 215 | zsqrt = SQRT( zsal ) |
|---|
| 216 | zsal15 = zsqrt * zsal |
|---|
| 217 | zlogt = LOG( ztkel ) |
|---|
| 218 | ztr = 1. / ztkel |
|---|
| 219 | zis = 19.924 * zsal / ( 1000.- 1.005 * zsal ) |
|---|
| 220 | zis2 = zis * zis |
|---|
| 221 | zisqrt = SQRT( zis ) |
|---|
| 222 | ztc = tsn(ji,jj,jk,jp_tem) + ( 1.- tmask(ji,jj,jk) ) * 20. |
|---|
| 223 | |
|---|
| 224 | ! CHLORINITY (WOOSTER ET AL., 1969) |
|---|
| 225 | zcl = zsal * salchl |
|---|
| 226 | |
|---|
| 227 | ! TOTAL SULFATE CONCENTR. [MOLES/kg soln] |
|---|
| 228 | zst = st1 * zcl * st2 |
|---|
| 229 | |
|---|
| 230 | ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln] |
|---|
| 231 | zft = ft1 * zcl * ft2 |
|---|
| 232 | |
|---|
| 233 | ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990) |
|---|
| 234 | zcks = EXP( ks1 * ztr + ks0 + ks2 * zlogt & |
|---|
| 235 | & + ( ks3 * ztr + ks4 + ks5 * zlogt ) * zisqrt & |
|---|
| 236 | & + ( ks6 * ztr + ks7 + ks8 * zlogt ) * zis & |
|---|
| 237 | & + ks9 * ztr * zis * zisqrt + ks10 * ztr *zis2 + LOG( ks11 + ks12 *zsal ) ) |
|---|
| 238 | |
|---|
| 239 | ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79) |
|---|
| 240 | zckf = EXP( kf1 * ztr + kf0 + kf2 * zisqrt + LOG( kf3 + kf4 * zsal ) ) |
|---|
| 241 | |
|---|
| 242 | ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE |
|---|
| 243 | zckb = ( cb0 + cb1 * zsqrt + cb2 * zsal + cb3 * zsal15 + cb4 * zsal * zsal ) * ztr & |
|---|
| 244 | & + ( cb5 + cb6 * zsqrt + cb7 * zsal ) & |
|---|
| 245 | & + ( cb8 + cb9 * zsqrt + cb10 * zsal ) * zlogt + cb11 * zsqrt * ztkel & |
|---|
| 246 | & + LOG( ( 1.+ zst / zcks + zft / zckf ) / ( 1.+ zst / zcks ) ) |
|---|
| 247 | |
|---|
| 248 | zck1 = c10 * ztr + c11 + c12 * zlogt + c13 * zsal + c14 * zsal * zsal |
|---|
| 249 | zck2 = c20 * ztr + c21 + c22 * zsal + c23 * zsal**2 |
|---|
| 250 | |
|---|
| 251 | ! PKW (H2O) (DICKSON AND RILEY, 1979) |
|---|
| 252 | zckw = cw0 * ztr + cw1 + cw2 * zlogt + ( cw3 * ztr + cw4 + cw5 * zlogt ) * zsqrt + cw6 * zsal |
|---|
| 253 | |
|---|
| 254 | |
|---|
| 255 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER |
|---|
| 256 | ! (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983) |
|---|
| 257 | zaksp0 = akcc1 + akcc2 * ztkel + akcc3 * ztr + akcc4 * LOG10( ztkel ) & |
|---|
| 258 | & + ( akcc5 + akcc6 * ztkel + akcc7 * ztr ) * zsqrt + akcc8 * zsal + akcc9 * zsal15 |
|---|
| 259 | |
|---|
| 260 | ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?) |
|---|
| 261 | zak1 = 10**(zck1) |
|---|
| 262 | zak2 = 10**(zck2) |
|---|
| 263 | zakb = EXP( zckb ) |
|---|
| 264 | zakw = EXP( zckw ) |
|---|
| 265 | zaksp1 = 10**(zaksp0) |
|---|
| 266 | |
|---|
| 267 | ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970) |
|---|
| 268 | ! (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE |
|---|
| 269 | ! IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS |
|---|
| 270 | ! TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres IN |
|---|
| 271 | ! DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS |
|---|
| 272 | ! MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION |
|---|
| 273 | ! WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND |
|---|
| 274 | ! & GIESKES (1970), P. 1285-1286 (THE SMALL |
|---|
| 275 | ! FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE |
|---|
| 276 | ! SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285)) |
|---|
| 277 | zcpexp = zpres /(rgas*ztkel) |
|---|
| 278 | zcpexp2 = zpres * zpres/(rgas*ztkel) |
|---|
| 279 | |
|---|
| 280 | ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE |
|---|
| 281 | ! CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968) |
|---|
| 282 | ! (CF. BROECKER ET AL., 1982) |
|---|
| 283 | |
|---|
| 284 | zbuf1 = -(devk1(1)+devk2(1)*ztc+devk3(1)*ztc*ztc) |
|---|
| 285 | zbuf2 = 0.5*(devk4(1)+devk5(1)*ztc) |
|---|
| 286 | ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 287 | |
|---|
| 288 | zbuf1 = - ( devk1(2) + devk2(2) * ztc + devk3(2) * ztc * ztc ) |
|---|
| 289 | zbuf2 = 0.5 * ( devk4(2) + devk5(2) * ztc ) |
|---|
| 290 | ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 291 | |
|---|
| 292 | zbuf1 = - ( devk1(3) + devk2(3) * ztc + devk3(3) * ztc * ztc ) |
|---|
| 293 | zbuf2 = 0.5 * ( devk4(3) + devk5(3) * ztc ) |
|---|
| 294 | akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 295 | |
|---|
| 296 | zbuf1 = - ( devk1(4) + devk2(4) * ztc + devk3(4) * ztc * ztc ) |
|---|
| 297 | zbuf2 = 0.5 * ( devk4(4) + devk5(4) * ztc ) |
|---|
| 298 | akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 299 | |
|---|
| 300 | |
|---|
| 301 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE |
|---|
| 302 | ! AS FUNCTION OF PRESSURE FOLLOWING MILLERO |
|---|
| 303 | ! (P. 1285) AND BERNER (1976) |
|---|
| 304 | zbuf1 = - ( devk1(5) + devk2(5) * ztc + devk3(5) * ztc * ztc ) |
|---|
| 305 | zbuf2 = 0.5 * ( devk4(5) + devk5(5) * ztc ) |
|---|
| 306 | aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 307 | |
|---|
| 308 | |
|---|
| 309 | ! TOTAL BORATE CONCENTR. [MOLES/L] |
|---|
| 310 | borat(ji,jj,jk) = bor1 * zcl * bor2 |
|---|
| 311 | |
|---|
| 312 | ! Iron and SIO3 saturation concentration from ... |
|---|
| 313 | sio3eq(ji,jj,jk) = EXP( LOG( 10.) * ( 6.44 - 968. / ztkel ) ) * 1.e-6 |
|---|
| 314 | fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ( 273.15 + ztc ) ) |
|---|
| 315 | |
|---|
| 316 | END DO |
|---|
| 317 | END DO |
|---|
| 318 | END DO |
|---|
| 319 | ! |
|---|
| 320 | END SUBROUTINE p4z_che |
|---|
| 321 | |
|---|
| 322 | |
|---|
| 323 | INTEGER FUNCTION p4z_che_alloc() |
|---|
| 324 | !!---------------------------------------------------------------------- |
|---|
| 325 | !! *** ROUTINE p4z_che_alloc *** |
|---|
| 326 | !!---------------------------------------------------------------------- |
|---|
| 327 | ALLOCATE( sio3eq(jpi,jpj,jpk) , fekeq(jpi,jpj,jpk) , chemc (jpi,jpj,2), STAT=p4z_che_alloc ) |
|---|
| 328 | ! |
|---|
| 329 | IF( p4z_che_alloc /= 0 ) CALL ctl_warn('p4z_che_alloc : failed to allocate arrays.') |
|---|
| 330 | ! |
|---|
| 331 | END FUNCTION p4z_che_alloc |
|---|
| 332 | |
|---|
| 333 | #else |
|---|
| 334 | !!====================================================================== |
|---|
| 335 | !! Dummy module : No PISCES bio-model |
|---|
| 336 | !!====================================================================== |
|---|
| 337 | CONTAINS |
|---|
| 338 | SUBROUTINE p4z_che( kt ) ! Empty routine |
|---|
| 339 | INTEGER, INTENT(in) :: kt |
|---|
| 340 | WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt |
|---|
| 341 | END SUBROUTINE p4z_che |
|---|
| 342 | #endif |
|---|
| 343 | |
|---|
| 344 | !!====================================================================== |
|---|
| 345 | END MODULE p4zche |
|---|
