New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zmeso.F90 @ 2823

Last change on this file since 2823 was 2823, checked in by cetlod, 13 years ago

Add new parameterisation in PISCES, see ticket #854
  • Property svn:keywords set to Id
File size: 15.4 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2    = 0.5_wp     !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc   = 1.0_wp     !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp   = 0.3_wp     !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz   = 1.0_wp     !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc = 0.3_wp     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2 = 2E-7_wp    !: feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  resrat2  = 0.005_wp   !: exsudation rate of mesozooplankton
40   REAL(wp), PUBLIC ::  mzrat2   = 0.04_wp    !: microzooplankton mortality rate
41   REAL(wp), PUBLIC ::  grazrat2 = 0.9_wp     !: maximal mesozoo grazing rate
42   REAL(wp), PUBLIC ::  xkgraz2  = 20E-6_wp   !: non assimilated fraction of P by mesozoo
43   REAL(wp), PUBLIC ::  unass2   = 0.3_wp     !: Efficicency of mesozoo growth
44   REAL(wp), PUBLIC ::  sigma2   = 0.6_wp     !: Fraction of mesozoo excretion as DOM
45   REAL(wp), PUBLIC ::  epsher2  = 0.3_wp     !: half sturation constant for grazing 2
46   REAL(wp), PUBLIC ::  grazflux = 3.E3_wp    !: mesozoo flux feeding rate
47
48   !!* Substitution
49#  include "top_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
52   !! $Id$
53   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55
56CONTAINS
57
58   SUBROUTINE p4z_meso( kt, jnt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_meso  ***
61      !!
62      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
63      !!
64      !! ** Method  : - ???
65      !!---------------------------------------------------------------------
66      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
67      INTEGER  :: ji, jj, jk
68      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
69      REAL(wp) :: zgraze2 , zdenom, zncratio
70      REAL(wp) :: zfact   , zstep, zfood, zfoodlim
71      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotf
72      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat
73#if defined key_kriest
74      REAL znumpoc
75#endif
76      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
77      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
78      REAL(wp) :: zgrazfff, zgrazffe
79      CHARACTER (len=25) :: charout
80      REAL(wp) :: zrfact2
81
82      !!---------------------------------------------------------------------
83
84      DO jk = 1, jpkm1
85         DO jj = 1, jpj
86            DO ji = 1, jpi
87               zcompam   = MAX( ( trn(ji,jj,jk,jpmes) - 1.e-8 ), 0.e0 )
88# if defined key_degrad
89               zstep     = xstep * facvol(ji,jj,jk)
90# else
91               zstep     = xstep
92# endif
93               zfact     = zstep * tgfunc(ji,jj,jk) * zcompam
94
95               !  Respiration rates of both zooplankton
96               !  -------------------------------------
97               zrespz2   = resrat2 * zfact * trn(ji,jj,jk,jpmes) / ( xkmort + trn(ji,jj,jk,jpmes) )  &
98                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
99
100               !  Zooplankton mortality. A square function has been selected with
101               !  no real reason except that it seems to be more stable and may mimic predation
102               !  ---------------------------------------------------------------
103               ztortz2   = mzrat2 * 1.e6 * zfact * trn(ji,jj,jk,jpmes)
104               !
105
106               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - 1.e-8 ), 0.e0 )
107               zcompaz   = MAX( ( trn(ji,jj,jk,jpzoo) - 1.e-8 ), 0.e0 )
108               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - 1.e-8 ), 0.e0 )
109               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - 1.e-8 ), 0.e0 )
110
111               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc + rtrn
112               zfoodlim  = MAX( 0., zfood - xthresh2 )
113               zdenom    = zfoodlim / zfood / (xkgraz2 + zfoodlim)
114
115               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpmes) * zdenom
116               zgrazd    = zgraze2  * xprefc   * zcompadi
117               zgrazz    = zgraze2  * xprefz   * zcompaz
118               zgrazn    = zgraze2  * xprefp   * zcompaph
119               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc
120
121               zgraznf   = zgrazn   * trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy) + rtrn)
122               zgrazf    = zgrazd   * trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia) + rtrn)
123               zgrazpof  = zgrazpoc * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
124
125               !  Mesozooplankton flux feeding on GOC
126               !  ----------------------------------
127# if ! defined key_kriest
128               zgrazffe  = grazflux * zstep * wsbio4(ji,jj,jk)          &
129                 &                 * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)
130               zgrazfff  = zgrazffe * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
131# else
132               !!--------------------------- KRIEST3 -------------------------------------------
133               !!               zgrazffe = 0.5 * 1.3e-2 / 5.5e-7 * 0.3 * zstep * wsbio3(ji,jj,jk)     &
134               !!                  &     * tgfunc(ji,jj,jk) * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)    &
135               !! #  if defined key_degrad
136               !!                  &     * facvol(ji,jj,jk)          &
137               !! #  endif
138               !!                  &     /  (trn(ji,jj,jk,jppoc) * 1.e7 + 0.1)
139               !!--------------------------- KRIEST3 -------------------------------------------
140
141              zgrazffe   = grazflux * zstep * wsbio3(ji,jj,jk)     &
142                  &                * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)
143              zgrazfff   = zgrazffe * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
144# endif
145              !
146              zgraztot   = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffe
147              zgraztotf  = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfff 
148#if defined key_diatrc
149              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
150              grazing(ji,jj,jk) = grazing(ji,jj,jk) + zgraztot
151#endif
152              !    Mesozooplankton efficiency
153              !    --------------------------
154              zgrasrat   =  zgraztotf / ( zgraztot + rtrn )
155              zncratio   = (  xprefc   * zcompadi * quotad(ji,jj,jk)  &
156                  &         + xprefp   * zcompaph * quotan(ji,jj,jk)  &
157                  &         + xprefz   * zcompaz                      &
158                  &         + xprefpoc * zcompapoc   ) / zfood 
159               zepshert  = epsher2 * MIN( 1., zncratio )
160               zepsherv  = zepshert * MIN( 1., zgrasrat / ferat3 )
161               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 )
162               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepshert ) 
163               zgrapoc2  = zgraztot * unass2
164
165               !   Update the arrays TRA which contain the biological sources and sinks
166               zgrarsig  = zgrarem2 * sigma2
167               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
168               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
169               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
170               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
171               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
172               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
173               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
174#if defined key_kriest
175               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc2
176               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc2 * xkr_dmeso
177               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass2
178#else
179               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zgrapoc2
180               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zgraztotf * unass2
181#endif
182               zmortz2 = ztortz2 + zrespz2
183               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
184               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
185               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
186               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
187               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trn(ji,jj,jk,jpnch) / ( trn(ji,jj,jk,jpphy) + rtrn )
188               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
189               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zgrazd * trn(ji,jj,jk,jpbsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
190               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zgrazd * trn(ji,jj,jk,jpbsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
191               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
192               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
193
194               zprcaca = xfracal(ji,jj,jk) * zgrazn
195               ! calcite production
196#if defined key_diatrc
197               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
198#endif
199               zprcaca = part2 * zprcaca
200               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
201               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
202               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
203#if defined key_kriest
204               znumpoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
205               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz2 - zgrazpoc - zgrazffe
206               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc &
207                  &    + zmortz2  * xkr_dmeso - zgrazffe * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
208               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz2 - zgrazfff - zgrazpof
209#else
210               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc
211               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortz2 - zgrazffe
212               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof
213               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortz2 - zgrazfff
214#endif
215
216            END DO
217         END DO
218      END DO
219      !
220#if defined key_diatrc && defined key_iomput
221      zrfact2 = 1.e3 * rfact2r
222      grazing(:,:,:) = grazing(:,:,:) * zrfact2 * tmask(:,:,:)   ! Total grazing of phyto by zoo
223      prodcal(:,:,:) = prodcal(:,:,:) * zrfact2 * tmask(:,:,:)   ! Calcite production
224      IF( jnt == nrdttrc ) THEN
225         CALL iom_put( "GRAZ" , grazing  )  ! Total grazing of phyto by zooplankton
226         CALL iom_put( "PCAL" , prodcal  )  ! Calcite production
227      ENDIF
228#endif
229      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
230        WRITE(charout, FMT="('meso')")
231        CALL prt_ctl_trc_info(charout)
232        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
233      ENDIF
234
235   END SUBROUTINE p4z_meso
236
237   SUBROUTINE p4z_meso_init
238
239      !!----------------------------------------------------------------------
240      !!                  ***  ROUTINE p4z_meso_init  ***
241      !!
242      !! ** Purpose :   Initialization of mesozooplankton parameters
243      !!
244      !! ** Method  :   Read the nampismes namelist and check the parameters
245      !!      called at the first timestep (nit000)
246      !!
247      !! ** input   :   Namelist nampismes
248      !!
249      !!----------------------------------------------------------------------
250
251      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
252         &                xprefpoc, xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
253
254      REWIND( numnatp )                     ! read numnat
255      READ  ( numnatp, nampismes )
256
257
258      IF(lwp) THEN                         ! control print
259         WRITE(numout,*) ' ' 
260         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
261         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
262         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2     =', part2
263         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc    =', xprefc
264         WRITE(numout,*) '    mesozoo preference for POC                     xprefp    =', xprefp
265         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz    =', xprefz
266         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc  =', xprefpoc
267         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2  =', xthresh2
268         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2   =', resrat2
269         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2    =', mzrat2
270         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2  =', grazrat2
271         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux  =', grazflux
272         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2    =', unass2
273         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2   =', epsher2
274         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2    =', sigma2
275         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2   =', xkgraz2
276      ENDIF
277
278
279   END SUBROUTINE p4z_meso_init
280
281
282#else
283   !!======================================================================
284   !!  Dummy module :                                   No PISCES bio-model
285   !!======================================================================
286CONTAINS
287   SUBROUTINE p4z_meso                    ! Empty routine
288   END SUBROUTINE p4z_meso
289#endif 
290
291   !!======================================================================
292END MODULE  p4zmeso
Note: See TracBrowser for help on using the repository browser.