New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcrst_pisces.F90 in branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES/trcrst_pisces.F90 @ 2823

Last change on this file since 2823 was 2823, checked in by cetlod, 13 years ago

Add new parameterisation in PISCES, see ticket #854
  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE trcrst_pisces
2   !!======================================================================
3   !!                       ***  MODULE trcrst_pisces  ***
4   !! TOP :   create, write, read the restart files of PISCES tracer
5   !!======================================================================
6   !! History :   1.0  !  2010-01 (C. Ethe) Original
7   !!----------------------------------------------------------------------
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   'key_pisces'                                               pisces tracers
11   !!----------------------------------------------------------------------
12   !!   trc_rst_read_pisces   : read  restart file
13   !!   trc_rst_wri_pisces    : write restart file
14   !!----------------------------------------------------------------------
15   USE oce_trc         ! Ocean variables
16   USE par_trc         ! TOP parameters
17   USE trc             ! TOP variables
18   USE trcsms_pisces          ! pisces sms trends
19   USE sms_pisces          ! pisces sms variables
20   USE iom
21   USE trcdta
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC  trc_rst_read_pisces   ! called by trcini.F90 module
27   PUBLIC  trc_rst_wri_pisces   ! called by trcini.F90 module
28
29CONTAINS
30   
31   SUBROUTINE trc_rst_read_pisces( knum ) 
32      !!----------------------------------------------------------------------
33      !!                     ***  trc_rst_read_pisces  *** 
34      !!
35      !! ** Purpose : Read in restart file specific variables from pisces model
36      !!
37      !!----------------------------------------------------------------------
38      INTEGER, INTENT(in)  :: knum  ! unit of the restart file
39      INTEGER  ::  ji, jj, jk
40      REAL(wp) ::  zcaralk, zbicarb, zco3
41      REAL(wp) ::  ztmas, ztmas1
42      !!----------------------------------------------------------------------
43
44      !
45      IF( ln_trcdta .AND. ln_pisclo ) CALL pis_dmp_clo  ! restoring of nutrients on close seas
46      IF( ln_pisdmp )                 CALL pis_dmp_ini  ! relaxation of some tracers
47      !
48      IF(lwp) WRITE(numout,*)
49      IF(lwp) WRITE(numout,*) ' trc_rst_read_pisces : Read specific variables from pisces model '
50      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
51      !
52      IF( iom_varid( knum, 'PH', ldstop = .FALSE. ) > 0 ) THEN
53         CALL iom_get( knum, jpdom_autoglo, 'PH' , hi(:,:,:)  )
54      ELSE
55         ! Set PH from  total alkalinity, borat (???), akb3 (???) and ak23 (???)
56         ! --------------------------------------------------------
57         DO jk = 1, jpk
58            DO jj = 1, jpj
59               DO ji = 1, jpi
60                  ztmas   = tmask(ji,jj,jk)
61                  ztmas1  = 1. - tmask(ji,jj,jk)
62                  zcaralk = trn(ji,jj,jk,jptal) - borat(ji,jj,jk) / (  1. + 1.E-8 / ( rtrn + akb3(ji,jj,jk) )  )
63                  zco3    = ( zcaralk - trn(ji,jj,jk,jpdic) ) * ztmas + 0.5e-3 * ztmas1
64                  zbicarb = ( 2. * trn(ji,jj,jk,jpdic) - zcaralk )
65                  hi(ji,jj,jk) = ( ak23(ji,jj,jk) * zbicarb / zco3 ) * ztmas + 1.e-9 * ztmas1
66               END DO
67            END DO
68         END DO
69      ENDIF
70      CALL iom_get( knum, jpdom_autoglo, 'Silicalim', xksi(:,:) ) 
71      IF( iom_varid( knum, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
72         CALL iom_get( knum, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
73      ELSE
74         xksimax(:,:) = xksi(:,:)
75      ENDIF
76
77   END SUBROUTINE trc_rst_read_pisces
78
79   SUBROUTINE trc_rst_wri_pisces( kt, kitrst, knum )
80      !!----------------------------------------------------------------------
81      !!                     ***  trc_rst_read_pisces  ***
82      !!
83      !! ** Purpose : Read in restart file specific variables from pisces model
84      !!
85      !!----------------------------------------------------------------------
86      INTEGER, INTENT(in)  :: kt      ! time step
87      INTEGER, INTENT(in)  :: kitrst  ! time step of restart write
88      INTEGER, INTENT(in)  :: knum    ! unit of the restart file
89      !!----------------------------------------------------------------------
90
91      IF(lwp) WRITE(numout,*)
92      IF(lwp) WRITE(numout,*) ' trc_rst_wri_pisces : Write specific variables from pisces model '
93      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
94
95      CALL iom_rstput( kt, kitrst, knum, 'PH', hi(:,:,:) )
96      CALL iom_rstput( kt, kitrst, knum, 'Silicalim', xksi(:,:) ) 
97      CALL iom_rstput( kt, kitrst, knum, 'Silicamax', xksimax(:,:) )
98
99   END SUBROUTINE trc_rst_wri_pisces
100
101   SUBROUTINE pis_dmp_ini
102      !!----------------------------------------------------------------------
103      !!                    ***  pis_dmp_ini  ***
104      !!
105      !! ** purpose  : Relaxation of some tracers
106      !!----------------------------------------------------------------------
107      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
108      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
109      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
110      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
111
112      REAL(wp) :: zarea, zalksum, zpo4sum, zno3sum, zsilsum
113
114
115      IF(lwp)  WRITE(numout,*)
116
117      IF( cp_cfg == "orca" .AND. .NOT. lk_c1d ) THEN      ! ORCA condiguration (not 1D) !
118         !                                                    ! --------------------------- !
119         ! set total alkalinity, phosphate, nitrate & silicate
120
121         zarea   = 1. / areatot * 1.e6
122         IF( lk_degrad ) THEN
123            zalksum = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:) * facvol(:,:,:) ) * zarea
124            zpo4sum = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:) * facvol(:,:,:) ) * zarea / 122.
125            zno3sum = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:) * facvol(:,:,:) ) * zarea / 7.6
126            zsilsum = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:) * facvol(:,:,:) ) * zarea
127         ELSE
128            zalksum = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
129            zpo4sum = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea / 122.
130            zno3sum = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea / 7.6
131            zsilsum = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
132         ENDIF
133
134         IF(lwp) WRITE(numout,*) '       TALK mean : ', zalksum
135         trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksum
136           
137         IF(lwp) WRITE(numout,*) '       PO4  mean : ', zpo4sum
138         trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sum
139
140         IF(lwp) WRITE(numout,*) '       NO3  mean : ', zno3sum
141         trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sum
142
143         IF(lwp) WRITE(numout,*) '       SiO3 mean : ', zsilsum
144         trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsum )
145         !
146      ENDIF
147
148!#if defined key_kriest
149!     !! Initialize number of particles from a standart restart file
150!     !! The name of big organic particles jpgoc has been only change
151!     !! and replace by jpnum but the values here are concentration
152!     trn(:,:,:,jppoc) = trn(:,:,:,jppoc) + trn(:,:,:,jpnum)
153!     trn(:,:,:,jpnum) = trn(:,:,:,jppoc) / ( 6. * xkr_massp )
154!#endif
155
156   END SUBROUTINE pis_dmp_ini
157
158   SUBROUTINE pis_dmp_clo   
159      !!---------------------------------------------------------------------
160      !!                  ***  ROUTINE pis_dmp_clo  ***
161      !!
162      !! ** Purpose :   Closed sea domain initialization
163      !!
164      !! ** Method  :   if a closed sea is located only in a model grid point
165      !!                we restore to initial data
166      !!
167      !! ** Action  :   ictsi1(), ictsj1() : south-west closed sea limits (i,j)
168      !!                ictsi2(), ictsj2() : north-east Closed sea limits (i,j)
169      !!----------------------------------------------------------------------
170      INTEGER, PARAMETER           ::   npicts   = 4        ! number of closed sea
171      INTEGER, DIMENSION(npicts)   ::   ictsi1, ictsj1      ! south-west closed sea limits (i,j)
172      INTEGER, DIMENSION(npicts)   ::   ictsi2, ictsj2      ! north-east closed sea limits (i,j)
173      INTEGER :: ji, jj, jk, jn, jl, jc                     ! dummy loop indices
174      INTEGER :: ierr                                       ! local integer
175      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  ztrcdta ! 4D  workspace
176      !!----------------------------------------------------------------------
177
178      IF(lwp) WRITE(numout,*) 
179      IF(lwp) WRITE(numout,*)' pis_dmp_clo : closed seas '
180      IF(lwp) WRITE(numout,*)'~~~~~~~'
181
182      ! initial values
183      ictsi1(:) = 1  ;  ictsi2(:) = 1
184      ictsj1(:) = 1  ;  ictsj2(:) = 1
185
186      ! set the closed seas (in data domain indices)
187      ! -------------------
188
189      IF( cp_cfg == "orca" ) THEN
190         !
191         SELECT CASE ( jp_cfg )
192         !                                           ! =======================
193         CASE ( 2 )                                  !  ORCA_R2 configuration
194            !                                        ! =======================
195            !                                            ! Caspian Sea
196            ictsi1(1)   =  11  ;  ictsj1(1)   = 103
197            ictsi2(1)   =  17  ;  ictsj2(1)   = 112
198            !                                            ! Great North American Lakes
199            ictsi1(2)   =  97  ;  ictsj1(2)   = 107
200            ictsi2(2)   = 103  ;  ictsj2(2)   = 111
201            !                                            ! Black Sea 1 : west part of the Black Sea
202            ictsi1(3)   = 174  ; ictsj1(3)   = 107
203            ictsi2(3)   = 181  ; ictsj2(3)   = 112
204            !                                            ! Black Sea 2 : est part of the Black Sea
205            ictsi1(4)   =   2  ;  ictsj1(4)   = 107
206            ictsi2(4)   =   6  ;  ictsj2(4)   = 112
207            !                                        ! =======================
208         CASE ( 4 )                                  !  ORCA_R4 configuration
209            !                                        ! =======================
210            !                                            ! Caspian Sea
211            ictsi1(1)   =  4  ;  ictsj1(1)   = 53
212            ictsi2(1)   =  4  ;  ictsj2(1)   = 56
213            !                                            ! Great North American Lakes
214            ictsi1(2)   = 49  ;  ictsj1(2)   = 55
215            ictsi2(2)   = 51  ;  ictsj2(2)   = 56
216            !                                            ! Black Sea
217            ictsi1(3)   = 88  ;  ictsj1(3)   = 55
218            ictsi2(3)   = 91  ;  ictsj2(3)   = 56
219            !                                            ! Baltic Sea
220            ictsi1(4)   = 75  ;  ictsj1(4)   = 59
221            ictsi2(4)   = 76  ;  ictsj2(4)   = 61
222            !                                        ! =======================
223            !                                        ! =======================
224         CASE ( 025 )                                ! ORCA_R025 configuration
225            !                                        ! =======================
226                                                     ! Caspian + Aral sea
227            ictsi1(1)   = 1330 ; ictsj1(1)   = 645
228            ictsi2(1)   = 1400 ; ictsj2(1)   = 795
229            !                                        ! Azov Sea
230            ictsi1(2)   = 1284 ; ictsj1(2)   = 722
231            ictsi2(2)   = 1304 ; ictsj2(2)   = 747
232            !
233         END SELECT
234         !
235      ENDIF
236
237      ! convert the position in local domain indices
238      ! --------------------------------------------
239      DO jc = 1, npicts
240         ictsi1(jc)   = mi0( ictsi1(jc) )
241         ictsj1(jc)   = mj0( ictsj1(jc) )
242
243         ictsi2(jc)   = mi1( ictsi2(jc) )
244         ictsj2(jc)   = mj1( ictsj2(jc) )
245      END DO
246
247      ! Restore close seas values to initial data
248      IF( nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
249        ALLOCATE( ztrcdta(jpi,jpj,jpk,nb_trcdta), STAT=ierr )
250        IF( ierr > 0 ) THEN
251           CALL ctl_stop( 'trc_ini: unable to allocate ztrcdta array' )   ;   RETURN
252        ENDIF
253        !
254        CALL trc_dta( nit000, ztrcdta )   ! read tracer data at nit000
255        !
256        DO jn = 1, jptra
257           IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
258              jl = n_trc_index(jn)
259              DO jc = 1, npicts
260                 DO jk = 1, jpkm1
261                    DO jj = ictsj1(jc), ictsj2(jc)
262                       DO ji = ictsi1(jc), ictsi2(jc)
263                          trn(ji,jj,jk,jn) = ztrcdta(ji,jj,jk,jl) * tmask(ji,jj,jk) 
264                          trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn)
265                       ENDDO
266                    ENDDO
267                 ENDDO
268              ENDDO
269           ENDIF
270        ENDDO
271        DEALLOCATE( ztrcdta )
272      ENDIF
273      !
274   END SUBROUTINE pis_dmp_clo
275
276#else
277   !!----------------------------------------------------------------------
278   !!  Dummy module :                                     No passive tracer
279   !!----------------------------------------------------------------------
280CONTAINS
281   SUBROUTINE trc_rst_read_pisces( knum )
282      INTEGER, INTENT(in)  :: knum
283      WRITE(*,*) 'trc_rst_read_pisces: You should not have seen this print! error?', knum
284   END SUBROUTINE trc_rst_read_pisces
285
286   SUBROUTINE trc_rst_wri_pisces( kt, kitrst, knum )
287     INTEGER, INTENT(in)  :: kt, kitrst, knum
288     WRITE(*,*) 'trc_rst_wri_pisces: You should not have seen this print! error?', kt, kitrst, knum
289   END SUBROUTINE trc_rst_wri_pisces
290#endif
291
292   !!======================================================================
293END MODULE trcrst_pisces
Note: See TracBrowser for help on using the repository browser.