source: branches/2011/dev_r2802_LOCEAN10_agrif_lim/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 2804

Last change on this file since 2804 was 2804, checked in by rblod, 9 years ago

dev_r2802_LOCEAN10_agrif_lim: first implementation see ticket #848

  • Property svn:keywords set to Id
File size: 29.0 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            4.0  ! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!----------------------------------------------------------------------
31
32   !!----------------------------------------------------------------------
33   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
34   !!   nemo_init      : initialization of the NEMO system
35   !!   nemo_ctl       : initialisation of the contol print
36   !!   nemo_closefile : close remaining open files
37   !!   nemo_alloc     : dynamical allocation
38   !!   nemo_partition : calculate MPP domain decomposition
39   !!   factorise      : calculate the factors of the no. of MPI processes
40   !!----------------------------------------------------------------------
41   USE step_oce        ! module used in the ocean time stepping module
42   USE sbc_oce         ! surface boundary condition: ocean
43   USE cla             ! cross land advection               (tra_cla routine)
44   USE domcfg          ! domain configuration               (dom_cfg routine)
45   USE mppini          ! shared/distributed memory setting (mpp_init routine)
46   USE domain          ! domain initialization             (dom_init routine)
47   USE obcini          ! open boundary cond. initialization (obc_ini routine)
48   USE bdyini          ! unstructured open boundary cond. initialization (bdy_init routine)
49   USE istate          ! initial state setting          (istate_init routine)
50   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
51   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
52   USE zdfini          ! vertical physics setting          (zdf_init routine)
53   USE phycst          ! physical constant                  (par_cst routine)
54   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
55   USE asminc          ! assimilation increments       (asm_inc_init routine)
56   USE asmtrj          ! writing out state trajectory
57   USE sshwzv          ! vertical velocity used in asm
58   USE diaptr          ! poleward transports           (dia_ptr_init routine)
59   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
60   USE step            ! NEMO time-stepping                 (stp     routine)
61#if defined key_oasis3
62   USE cpl_oasis3      ! OASIS3 coupling
63#elif defined key_oasis4
64   USE cpl_oasis4      ! OASIS4 coupling (not working)
65#endif
66   USE c1d             ! 1D configuration
67   USE step_c1d        ! Time stepping loop for the 1D configuration
68#if defined key_top
69   USE trcini          ! passive tracer initialisation
70#endif
71   USE lib_mpp         ! distributed memory computing
72#if defined key_iomput
73   USE mod_ioclient
74#endif
75
76   IMPLICIT NONE
77   PRIVATE
78
79   PUBLIC   nemo_gcm    ! called by model.F90
80   PUBLIC   nemo_init   ! needed by AGRIF
81
82   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
86   !! $Id$
87   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE nemo_gcm
92      !!----------------------------------------------------------------------
93      !!                     ***  ROUTINE nemo_gcm  ***
94      !!
95      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
96      !!              curvilinear mesh on the sphere.
97      !!
98      !! ** Method  : - model general initialization
99      !!              - launch the time-stepping (stp routine)
100      !!              - finalize the run by closing files and communications
101      !!
102      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
103      !!              Madec, 2008, internal report, IPSL.
104      !!----------------------------------------------------------------------
105      INTEGER ::   istp       ! time step index
106      !!----------------------------------------------------------------------
107      !
108#if defined key_agrif
109      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
110#endif
111
112      !                            !-----------------------!
113      CALL nemo_init               !==  Initialisations  ==!
114      !                            !-----------------------!
115#if defined key_agrif
116      CALL Agrif_Declare_Var       ! AGRIF: set the meshes
117# if defined key_lim2
118      CALL Agrif_Declare_Var_lim2  ! AGRIF: set the meshes
119# endif
120# if defined key_top
121      CALL Agrif_Declare_Var_Top   ! AGRIF: set the meshes
122# endif
123#endif
124      ! check that all process are still there... If some process have an error,
125      ! they will never enter in step and other processes will wait until the end of the cpu time!
126      IF( lk_mpp )   CALL mpp_max( nstop )
127
128      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
129
130      !                            !-----------------------!
131      !                            !==   time stepping   ==!
132      !                            !-----------------------!
133      istp = nit000
134#if defined key_c1d
135         DO WHILE ( istp <= nitend .AND. nstop == 0 )
136            CALL stp_c1d( istp )
137            istp = istp + 1
138         END DO
139#else
140          IF( lk_asminc ) THEN
141             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
142             IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 )    ! Output trajectory fields
143             IF( ln_asmdin ) THEN                        ! Direct initialization
144                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
145                IF( ln_dyninc ) THEN
146                   CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
147                   IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 )      ! update vertical velocity
148                ENDIF
149                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
150             ENDIF
151          ENDIF
152       
153         DO WHILE ( istp <= nitend .AND. nstop == 0 )
154#if defined key_agrif
155            CALL Agrif_Step( stp )           ! AGRIF: time stepping
156#else
157            CALL stp( istp )                 ! standard time stepping
158#endif
159            istp = istp + 1
160            IF( lk_mpp )   CALL mpp_max( nstop )
161         END DO
162#endif
163
164      IF( lk_diaobs ) CALL dia_obs_wri
165       
166      !                            !------------------------!
167      !                            !==  finalize the run  ==!
168      !                            !------------------------!
169      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
170      !
171      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
172         WRITE(numout,cform_err)
173         WRITE(numout,*) nstop, ' error have been found' 
174      ENDIF
175      !
176      CALL nemo_closefile
177#if defined key_oasis3 || defined key_oasis4
178      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
179#else
180      IF( lk_mpp )   CALL mppstop       ! end mpp communications
181#endif
182      !
183   END SUBROUTINE nemo_gcm
184
185
186   SUBROUTINE nemo_init
187      !!----------------------------------------------------------------------
188      !!                     ***  ROUTINE nemo_init  ***
189      !!
190      !! ** Purpose :   initialization of the NEMO GCM
191      !!----------------------------------------------------------------------
192      INTEGER ::   ji            ! dummy loop indices
193      INTEGER ::   ilocal_comm   ! local integer
194      CHARACTER(len=80), DIMENSION(16) ::   cltxt
195      !!
196      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
197         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle, nn_bench
198      !!----------------------------------------------------------------------
199      !
200      cltxt = ''
201      !
202      !                             ! open Namelist file
203      CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
204      !
205      READ( numnam, namctl )        ! Namelist namctl : Control prints & Benchmark
206      !
207      !                             !--------------------------------------------!
208      !                             !  set communicator & select the local node  !
209      !                             !--------------------------------------------!
210#if defined key_iomput
211      IF( Agrif_Root() ) THEN
212# if defined key_oasis3 || defined key_oasis4
213         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
214# endif
215         CALL  init_ioclient( ilocal_comm )                 ! exchange io_server nemo local communicator with the io_server
216      ENDIF
217      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection
218#else
219# if defined key_oasis3 || defined key_oasis4
220      IF( Agrif_Root() ) THEN
221         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
222      ENDIF
223      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
224# else
225      ilocal_comm = 0
226      narea = mynode( cltxt, numnam, nstop )                 ! Nodes selection (control print return in cltxt)
227# endif
228#endif
229      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
230
231      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
232
233      ! If dimensions of processor grid weren't specified in the namelist file
234      ! then we calculate them here now that we have our communicator size
235      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
236#if   defined key_mpp_mpi
237         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
238#else
239         jpni  = 1
240         jpnj  = 1
241         jpnij = jpni*jpnj
242#endif
243      END IF
244
245      ! Calculate domain dimensions given calculated jpni and jpnj
246      ! This used to be done in par_oce.F90 when they were parameters rather
247      ! than variables
248      IF( Agrif_Root() ) THEN
249         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
250         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
251         jpk = jpkdta                                             ! third dim
252         jpim1 = jpi-1                                            ! inner domain indices
253         jpjm1 = jpj-1                                            !   "           "
254         jpkm1 = jpk-1                                            !   "           "
255         jpij  = jpi*jpj                                          !  jpi x j
256      ENDIF
257
258      IF(lwp) THEN                            ! open listing units
259         !
260         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
261         !
262         WRITE(numout,*)
263         WRITE(numout,*) '         CNRS - NERC - Met OFFICE - MERCATOR-ocean'
264         WRITE(numout,*) '                       NEMO team'
265         WRITE(numout,*) '            Ocean General Circulation Model'
266         WRITE(numout,*) '                  version 3.3  (2010) '
267         WRITE(numout,*)
268         WRITE(numout,*)
269         DO ji = 1, SIZE(cltxt) 
270            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
271         END DO
272         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
273         !
274      ENDIF
275
276      ! Now we know the dimensions of the grid and numout has been set we can
277      ! allocate arrays
278      CALL nemo_alloc()
279
280      !                             !-------------------------------!
281      !                             !  NEMO general initialization  !
282      !                             !-------------------------------!
283
284      CALL nemo_ctl                          ! Control prints & Benchmark
285
286      !                                      ! Domain decomposition
287      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
288      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
289      ENDIF
290      !
291      !                                      ! General initialization
292                            CALL     phy_cst    ! Physical constants
293                            CALL     eos_init   ! Equation of state
294                            CALL     dom_cfg    ! Domain configuration
295                            CALL     dom_init   ! Domain
296
297      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
298
299      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
300      IF( lk_bdy        )   CALL     bdy_init   ! Unstructured open boundaries
301
302                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
303
304      !                                     ! Ocean physics
305                            CALL     sbc_init   ! Forcings : surface module
306      !                                         ! Vertical physics
307                            CALL     zdf_init      ! namelist read
308                            CALL zdf_bfr_init      ! bottom friction
309      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
310      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
311      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
312      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
313      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
314      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   & 
315         &                  CALL zdf_ddm_init      ! double diffusive mixing
316      !                                         ! Lateral physics
317                            CALL ldf_tra_init      ! Lateral ocean tracer physics
318                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
319      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
320
321      !                                     ! Active tracers
322                            CALL tra_qsr_init   ! penetrative solar radiation qsr
323                            CALL tra_bbc_init   ! bottom heat flux
324      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
325      IF( lk_tradmp     )   CALL tra_dmp_init   ! internal damping trends
326                            CALL tra_adv_init   ! horizontal & vertical advection
327                            CALL tra_ldf_init   ! lateral mixing
328                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
329
330      !                                     ! Dynamics
331                            CALL dyn_adv_init   ! advection (vector or flux form)
332                            CALL dyn_vor_init   ! vorticity term including Coriolis
333                            CALL dyn_ldf_init   ! lateral mixing
334                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
335                            CALL dyn_zdf_init   ! vertical diffusion
336                            CALL dyn_spg_init   ! surface pressure gradient
337                           
338      !                                     ! Misc. options
339      IF( nn_cla == 1   )   CALL cla_init       ! Cross Land Advection
340     
341#if defined key_top
342      !                                     ! Passive tracers
343                            CALL     trc_init
344#endif
345      !                                     ! Diagnostics
346                            CALL     iom_init   ! iom_put initialization
347      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
348      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
349                            CALL dia_ptr_init   ! Poleward TRansports initialization
350                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
351                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
352      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
353                            CALL dia_obs_init            ! Initialize observational data
354                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
355      ENDIF     
356      !                                     ! Assimilation increments
357      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
358      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
359      !
360   END SUBROUTINE nemo_init
361
362
363   SUBROUTINE nemo_ctl
364      !!----------------------------------------------------------------------
365      !!                     ***  ROUTINE nemo_ctl  ***
366      !!
367      !! ** Purpose :   control print setting
368      !!
369      !! ** Method  : - print namctl information and check some consistencies
370      !!----------------------------------------------------------------------
371      !
372      IF(lwp) THEN                  ! control print
373         WRITE(numout,*)
374         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
375         WRITE(numout,*) '~~~~~~~ '
376         WRITE(numout,*) '   Namelist namctl'
377         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
378         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
379         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
380         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
381         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
382         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
383         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
384         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
385         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
386      ENDIF
387      !
388      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
389      nictls    = nn_ictls
390      nictle    = nn_ictle
391      njctls    = nn_jctls
392      njctle    = nn_jctle
393      isplt     = nn_isplt
394      jsplt     = nn_jsplt
395      nbench    = nn_bench
396      !                             ! Parameter control
397      !
398      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
399         IF( lk_mpp ) THEN
400            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
401         ELSE
402            IF( isplt == 1 .AND. jsplt == 1  ) THEN
403               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
404                  &           ' - the print control will be done over the whole domain' )
405            ENDIF
406            ijsplt = isplt * jsplt            ! total number of processors ijsplt
407         ENDIF
408         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
409         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
410         !
411         !                              ! indices used for the SUM control
412         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
413            lsp_area = .FALSE.                       
414         ELSE                                             ! print control done over a specific  area
415            lsp_area = .TRUE.
416            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
417               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
418               nictls = 1
419            ENDIF
420            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
421               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
422               nictle = jpiglo
423            ENDIF
424            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
425               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
426               njctls = 1
427            ENDIF
428            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
429               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
430               njctle = jpjglo
431            ENDIF
432         ENDIF
433      ENDIF
434      !
435      IF( nbench == 1 ) THEN              ! Benchmark
436         SELECT CASE ( cp_cfg )
437         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
438         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
439            &                                 ' key_gyre must be used or set nbench = 0' )
440         END SELECT
441      ENDIF
442      !
443      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
444         &                                               'with the IOM Input/Output manager. '         ,   &
445         &                                               'Compile with key_iomput enabled' )
446      !
447   END SUBROUTINE nemo_ctl
448
449
450   SUBROUTINE nemo_closefile
451      !!----------------------------------------------------------------------
452      !!                     ***  ROUTINE nemo_closefile  ***
453      !!
454      !! ** Purpose :   Close the files
455      !!----------------------------------------------------------------------
456      !
457      IF( lk_mpp )   CALL mppsync
458      !
459      CALL iom_close                                 ! close all input/output files managed by iom_*
460      !
461      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
462      IF( numsol     /= -1 )   CLOSE( numsol     )   ! solver file
463      IF( numnam     /= -1 )   CLOSE( numnam     )   ! oce namelist
464      IF( numnam_ice /= -1 )   CLOSE( numnam_ice )   ! ice namelist
465      IF( numevo_ice /= -1 )   CLOSE( numevo_ice )   ! ice variables (temp. evolution)
466      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
467      !
468      numout = 6                                     ! redefine numout in case it is used after this point...
469      !
470   END SUBROUTINE nemo_closefile
471
472
473   SUBROUTINE nemo_alloc
474      !!----------------------------------------------------------------------
475      !!                     ***  ROUTINE nemo_alloc  ***
476      !!
477      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
478      !!
479      !! ** Method  :
480      !!----------------------------------------------------------------------
481      USE diawri    , ONLY: dia_wri_alloc
482      USE dom_oce   , ONLY: dom_oce_alloc
483      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
484      USE ldftra_oce, ONLY: ldftra_oce_alloc
485      USE trc_oce   , ONLY: trc_oce_alloc
486      USE wrk_nemo  , ONLY: wrk_alloc
487      !
488      INTEGER :: ierr
489      !!----------------------------------------------------------------------
490      !
491      ierr =        oce_alloc       ()          ! ocean
492      ierr = ierr + dia_wri_alloc   ()
493      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
494      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
495      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
496      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
497      !
498      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
499      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
500      !
501      ierr = ierr + wrk_alloc(numout, lwp)      ! workspace
502      !
503      IF( lk_mpp    )   CALL mpp_sum( ierr )
504      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
505      !
506   END SUBROUTINE nemo_alloc
507
508
509   SUBROUTINE nemo_partition( num_pes )
510      !!----------------------------------------------------------------------
511      !!                 ***  ROUTINE nemo_partition  ***
512      !!
513      !! ** Purpose :   
514      !!
515      !! ** Method  :
516      !!----------------------------------------------------------------------
517      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
518      !
519      INTEGER, PARAMETER :: nfactmax = 20
520      INTEGER :: nfact ! The no. of factors returned
521      INTEGER :: ierr  ! Error flag
522      INTEGER :: ji
523      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
524      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
525      !!----------------------------------------------------------------------
526
527      ierr = 0
528
529      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
530
531      IF( nfact <= 1 ) THEN
532         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
533         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
534         jpnj = 1
535         jpni = num_pes
536      ELSE
537         ! Search through factors for the pair that are closest in value
538         mindiff = 1000000
539         imin    = 1
540         DO ji = 1, nfact-1, 2
541            idiff = ABS( ifact(ji) - ifact(ji+1) )
542            IF( idiff < mindiff ) THEN
543               mindiff = idiff
544               imin = ji
545            ENDIF
546         END DO
547         jpnj = ifact(imin)
548         jpni = ifact(imin + 1)
549      ENDIF
550      !
551      jpnij = jpni*jpnj
552      !
553   END SUBROUTINE nemo_partition
554
555
556   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
557      !!----------------------------------------------------------------------
558      !!                     ***  ROUTINE factorise  ***
559      !!
560      !! ** Purpose :   return the prime factors of n.
561      !!                knfax factors are returned in array kfax which is of
562      !!                maximum dimension kmaxfax.
563      !! ** Method  :
564      !!----------------------------------------------------------------------
565      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
566      INTEGER                    , INTENT(  out) ::   kerr, knfax
567      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
568      !
569      INTEGER :: ifac, jl, inu
570      INTEGER, PARAMETER :: ntest = 14
571      INTEGER :: ilfax(ntest)
572
573      ! lfax contains the set of allowed factors.
574      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
575         &                            128,   64,   32,   16,    8,   4,   2  /
576      !!----------------------------------------------------------------------
577
578      ! Clear the error flag and initialise output vars
579      kerr = 0
580      kfax = 1
581      knfax = 0
582
583      ! Find the factors of n.
584      IF( kn == 1 )   GOTO 20
585
586      ! nu holds the unfactorised part of the number.
587      ! knfax holds the number of factors found.
588      ! l points to the allowed factor list.
589      ! ifac holds the current factor.
590
591      inu   = kn
592      knfax = 0
593
594      DO jl = ntest, 1, -1
595         !
596         ifac = ilfax(jl)
597         IF( ifac > inu )   CYCLE
598
599         ! Test whether the factor will divide.
600
601         IF( MOD(inu,ifac) == 0 ) THEN
602            !
603            knfax = knfax + 1            ! Add the factor to the list
604            IF( knfax > kmaxfax ) THEN
605               kerr = 6
606               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
607               return
608            ENDIF
609            kfax(knfax) = ifac
610            ! Store the other factor that goes with this one
611            knfax = knfax + 1
612            kfax(knfax) = inu / ifac
613            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
614         ENDIF
615         !
616      END DO
617
618   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
619      !
620   END SUBROUTINE factorise
621
622   !!======================================================================
623END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.