New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 2830

Last change on this file since 2830 was 2830, checked in by kpedwards, 13 years ago

Updates to average physics variables for TOP substepping.
  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE traadv_muscl2
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24   USE trc_oce         ! share passive tracers/Ocean variables
25#if defined key_top
26   USE trc, ONLY: nittrc000  !get first time step for passive tracers
27#endif
28
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_muscl2        ! routine called by step.F90
34
35   LOGICAL  :: l_trd       ! flag to compute trends
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_muscl2( kt, cdtype, p2dt, pun, pvn, pwn,      &
48      &                                         ptb, ptn, pta, kjpt )
49      !!----------------------------------------------------------------------
50      !!                   ***  ROUTINE tra_adv_muscl2  ***
51      !!
52      !! ** Purpose :   Compute the now trend due to total advection of T and
53      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
54      !!      Conservation Laws) and add it to the general tracer trend.
55      !!
56      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
57      !!
58      !! ** Action  : - update (pta) with the now advective tracer trends
59      !!              - save trends
60      !!
61      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
62      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
63      !!----------------------------------------------------------------------
64      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
65      USE oce     , ONLY:   zwx   => ua       , zwy   => va         ! (ua,va) used as 3D workspace
66      USE wrk_nemo, ONLY:   zslpx => wrk_3d_1 , zslpy => wrk_3d_2   ! 3D workspace
67      !!
68      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
71      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
72      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before & now tracer fields
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
75      !!
76      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
77      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
78      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
79      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
80      !!----------------------------------------------------------------------
81
82      IF( wrk_in_use(3, 1,2) ) THEN
83         CALL ctl_stop('tra_adv_muscl2: requested workspace arrays are unavailable')   ;   RETURN
84      ENDIF
85
86#if defined key_top
87      IF( kt == nit000 .OR. (kt == nittrc000 .AND. cdtype == 'TRC'))  THEN
88#else
89      IF( kt == nit000 )  THEN
90#endif
91         IF(lwp) WRITE(numout,*)
92         IF(lwp) WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme on ', cdtype
93         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
94         !
95         l_trd = .FALSE.
96         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      ENDIF
98
99      !                                                          ! ===========
100      DO jn = 1, kjpt                                            ! tracer loop
101         !                                                       ! ===========
102         ! I. Horizontal advective fluxes
103         ! ------------------------------
104         ! first guess of the slopes
105         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
106         ! interior values
107         DO jk = 1, jpkm1
108            DO jj = 1, jpjm1     
109               DO ji = 1, fs_jpim1   ! vector opt.
110                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
111                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
112               END DO
113           END DO
114         END DO
115         !
116         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
117         CALL lbc_lnk( zwy, 'V', -1. )
118         !                                             !-- Slopes of tracer
119         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
120         DO jk = 1, jpkm1                                     ! interior values
121            DO jj = 2, jpj
122               DO ji = fs_2, jpi   ! vector opt.
123                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
124                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
125                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
126                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
127               END DO
128            END DO
129         END DO
130         !
131         DO jk = 1, jpkm1                                     ! Slopes limitation
132            DO jj = 2, jpj
133               DO ji = fs_2, jpi   ! vector opt.
134                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
135                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
136                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
137                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
138                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
139                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
140               END DO
141           END DO
142         END DO             ! interior values
143
144        !                                             !-- MUSCL horizontal advective fluxes
145         DO jk = 1, jpkm1                                     ! interior values
146            zdt  = p2dt(jk)
147            DO jj = 2, jpjm1
148               DO ji = fs_2, fs_jpim1   ! vector opt.
149                  ! MUSCL fluxes
150                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
151                  zalpha = 0.5 - z0u
152                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
153                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
154                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
155                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
156                  !
157                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
158                  zalpha = 0.5 - z0v
159                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
160                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
161                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
162                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
163               END DO
164            END DO
165         END DO
166
167         !!  centered scheme at lateral b.C. if off-shore velocity
168         DO jk = 1, jpkm1
169            DO jj = 2, jpjm1
170               DO ji = fs_2, fs_jpim1   ! vector opt.
171                  IF( umask(ji,jj,jk) == 0. ) THEN
172                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
173                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
174                     ENDIF
175                     IF( pun(ji-1,jj,jk) < 0. ) THEN
176                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
177                     ENDIF
178                  ENDIF
179                  IF( vmask(ji,jj,jk) == 0. ) THEN
180                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
181                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
182                     ENDIF
183                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
184                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
185                     ENDIF
186                  ENDIF
187               END DO
188            END DO
189         END DO
190         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary condition (changed sign)
191
192         ! Tracer flux divergence at t-point added to the general trend
193         DO jk = 1, jpkm1
194            DO jj = 2, jpjm1
195               DO ji = fs_2, fs_jpim1   ! vector opt.
196                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
197                  ! horizontal advective trends
198                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
199                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
200                  ! added to the general tracer trends
201                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
202               END DO
203           END DO
204         END DO
205         !                                 ! trend diagnostics (contribution of upstream fluxes)
206         IF( l_trd ) THEN
207            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
208            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
209         END IF
210
211         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
212         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
213            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
214            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
215         ENDIF
216
217         ! II. Vertical advective fluxes
218         ! -----------------------------
219         !                                             !-- first guess of the slopes
220         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
221         DO jk = 2, jpkm1                                     ! interior values
222            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
223         END DO
224
225         !                                             !-- Slopes of tracer
226         zslpx(:,:,1) = 0.e0                                  ! surface values
227         DO jk = 2, jpkm1                                     ! interior value
228            DO jj = 1, jpj
229               DO ji = 1, jpi
230                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
231                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
232               END DO
233            END DO
234         END DO
235         !                                             !-- Slopes limitation
236         DO jk = 2, jpkm1                                     ! interior values
237            DO jj = 1, jpj
238               DO ji = 1, jpi
239                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
240                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
241                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
242               END DO
243            END DO
244         END DO
245         !                                             !-- vertical advective flux
246         !                                                    ! surface values  (bottom already set to zero)
247         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
248         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
249         ENDIF
250         !
251         DO jk = 1, jpkm1                                     ! interior values
252            zdt  = p2dt(jk)
253            DO jj = 2, jpjm1
254               DO ji = fs_2, fs_jpim1   ! vector opt.
255                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
256                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
257                  zalpha = 0.5 + z0w
258                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
259                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
260                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
261                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
262               END DO
263            END DO
264         END DO
265         !
266         DO jk = 2, jpkm1        ! centered near the bottom
267            DO jj = 2, jpjm1
268               DO ji = fs_2, fs_jpim1   ! vector opt.
269                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
270                     IF( pwn(ji,jj,jk) > 0. ) THEN
271                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
272                     ENDIF
273                  ENDIF
274               END DO
275            END DO
276         END DO
277         !
278         DO jk = 1, jpkm1        ! Compute & add the vertical advective trend
279            DO jj = 2, jpjm1     
280               DO ji = fs_2, fs_jpim1   ! vector opt.
281                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
282                  ! vertical advective trends
283                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
284                  ! added to the general tracer trends
285                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
286               END DO
287            END DO
288         END DO
289         !                       ! trend diagnostics (contribution of upstream fluxes)
290         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
291         !
292      END DO
293      !
294      IF( wrk_not_released(3, 1,2) )   CALL ctl_stop('tra_adv_muscl2: failed to release workspace arrays')
295      !
296   END SUBROUTINE tra_adv_muscl2
297
298   !!======================================================================
299END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.