New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in branches/2011/dev_r2802_UKMO8_sbccpl/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2011/dev_r2802_UKMO8_sbccpl/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 2813

Last change on this file since 2813 was 2813, checked in by charris, 13 years ago

#662 First set of changes - more details in ticket.
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3 V. prism_2_4
5   !!               special case: NEMO OPA/LIM coupled to ECHAM5
6   !!=====================================================================
7   !! History :   
8   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
9   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
10   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
11   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
12   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
13   !!   " "  !  06-01  (W. Park) modification of physical part
14   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
15   !!----------------------------------------------------------------------
16#if defined key_oasis3
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3
19   !!----------------------------------------------------------------------
20   !!   cpl_prism_init     : initialization of coupled mode communication
21   !!   cpl_prism_define   : definition of grid and fields
22   !!   cpl_prism_snd     : snd out fields in coupled mode
23   !!   cpl_prism_rcv     : receive fields in coupled mode
24   !!   cpl_prism_finalize : finalize the coupled mode communication
25   !!----------------------------------------------------------------------
26   USE mod_prism_proto              ! OASIS3 prism module
27   USE mod_prism_def_partition_proto! OASIS3 prism module for partitioning
28   USE mod_prism_put_proto          ! OASIS3 prism module for snding
29   USE mod_prism_get_proto          ! OASIS3 prism module for receiving
30   USE mod_comprism_proto           ! OASIS3 prism module to get coupling frequency
31   USE par_oce                      ! ocean parameters
32   USE dom_oce                      ! ocean space and time domain
33   USE in_out_manager               ! I/O manager
34   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   cpl_prism_init
40   PUBLIC   cpl_prism_define
41   PUBLIC   cpl_prism_snd
42   PUBLIC   cpl_prism_rcv
43   PUBLIC   cpl_prism_freq
44   PUBLIC   cpl_prism_finalize
45
46   LOGICAL, PUBLIC, PARAMETER ::   lk_cpl = .TRUE.   !: coupled flag
47   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
48   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
49   INTEGER                    ::   ncomp_id          ! id returned by prism_init_comp
50   INTEGER                    ::   nerror            ! return error code
51
52   INTEGER, PARAMETER ::   nmaxfld=40    ! Maximum number of coupling fields
53   
54   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
55      LOGICAL               ::   laction   ! To be coupled or not
56      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
57      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
58      REAL(wp)              ::   nsgn      ! Control of the sign change
59      INTEGER, DIMENSION(9) ::   nid       ! Id of the field (no more than 9 categories)
60      INTEGER               ::   nct       ! Number of categories in field
61   END TYPE FLD_CPL
62
63   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
64
65   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
66
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE cpl_prism_init( kl_comm )
75      !!-------------------------------------------------------------------
76      !!             ***  ROUTINE cpl_prism_init  ***
77      !!
78      !! ** Purpose :   Initialize coupled mode communication for ocean
79      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
80      !!
81      !! ** Method  :   OASIS3 MPI communication
82      !!--------------------------------------------------------------------
83      INTEGER, INTENT(out) ::   kl_comm   ! local communicator of the model
84      !!--------------------------------------------------------------------
85
86      ! WARNING: No write in numout in this routine
87      !============================================
88
89      !------------------------------------------------------------------
90      ! 1st Initialize the PRISM system for the application
91      !------------------------------------------------------------------
92      CALL prism_init_comp_proto ( ncomp_id, 'oceanx', nerror )
93      IF ( nerror /= PRISM_Ok ) &
94         CALL prism_abort_proto (ncomp_id, 'cpl_prism_init', 'Failure in prism_init_comp_proto')
95
96      !------------------------------------------------------------------
97      ! 3rd Get an MPI communicator for OPA local communication
98      !------------------------------------------------------------------
99
100      CALL prism_get_localcomm_proto ( kl_comm, nerror )
101      IF ( nerror /= PRISM_Ok ) &
102         CALL prism_abort_proto (ncomp_id, 'cpl_prism_init','Failure in prism_get_localcomm_proto' )
103      !
104   END SUBROUTINE cpl_prism_init
105
106
107   SUBROUTINE cpl_prism_define( krcv, ksnd )
108      !!-------------------------------------------------------------------
109      !!             ***  ROUTINE cpl_prism_define  ***
110      !!
111      !! ** Purpose :   Define grid and field information for ocean
112      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
113      !!
114      !! ** Method  :   OASIS3 MPI communication
115      !!--------------------------------------------------------------------
116      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
117      !
118      INTEGER :: id_part
119      INTEGER :: paral(5)       ! OASIS3 box partition
120      INTEGER :: ishape(2,2)    ! shape of arrays passed to PSMILe
121      INTEGER :: ji,jc          ! local loop indicees
122      CHARACTER(LEN=8) :: zclname
123      !!--------------------------------------------------------------------
124
125      IF(lwp) WRITE(numout,*)
126      IF(lwp) WRITE(numout,*) 'cpl_prism_define : initialization in coupled ocean/atmosphere case'
127      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
128      IF(lwp) WRITE(numout,*)
129
130      !
131      ! ... Define the shape for the area that excludes the halo
132      !     For serial configuration (key_mpp_mpi not being active)
133      !     nl* is set to the global values 1 and jp*glo.
134      !
135      ishape(:,1) = (/ 1, nlei-nldi+1 /)
136      ishape(:,2) = (/ 1, nlej-nldj+1 /)
137      !
138      ! ... Allocate memory for data exchange
139      !
140      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
141      IF( nerror > 0 ) THEN
142         CALL prism_abort_proto ( ncomp_id, 'cpl_prism_define', 'Failure in allocating exfld')   ;   RETURN
143      ENDIF
144      !
145      ! -----------------------------------------------------------------
146      ! ... Define the partition
147      ! -----------------------------------------------------------------
148     
149      paral(1) = 2                                              ! box partitioning
150      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
151      paral(3) = nlei-nldi+1                                    ! local extent in i
152      paral(4) = nlej-nldj+1                                    ! local extent in j
153      paral(5) = jpiglo                                         ! global extent in x
154     
155      IF( ln_ctl ) THEN
156         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
157         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
158         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
159         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
160      ENDIF
161     
162      CALL prism_def_partition_proto ( id_part, paral, nerror )
163      !
164      ! ... Announce send variables.
165      !
166      DO ji = 1, ksnd
167         IF ( ssnd(ji)%laction ) THEN
168            DO jc = 1, ssnd(ji)%nct
169               IF ( ssnd(ji)%nct .gt. 1 ) THEN
170                  WRITE(zclname,'( a7, i1)') ssnd(ji)%clname,jc
171               ELSE
172                  zclname=ssnd(ji)%clname
173               ENDIF
174               WRITE(numout,*) "Define",ji,jc,zclname," for",PRISM_Out
175               CALL prism_def_var_proto (ssnd(ji)%nid(jc), zclname, id_part, (/ 2, 0/),   &
176                    PRISM_Out, ishape, PRISM_REAL, nerror)
177               IF ( nerror /= PRISM_Ok ) THEN
178                  WRITE(numout,*) 'Failed to define transient ', ji, TRIM(zclname)
179                  CALL prism_abort_proto ( ssnd(ji)%nid(jc), 'cpl_prism_define', 'Failure in prism_def_var')
180               ENDIF
181            END DO
182         ENDIF
183      END DO
184      !
185      ! ... Announce received variables.
186      !
187      DO ji = 1, krcv
188         IF ( srcv(ji)%laction ) THEN
189            DO jc = 1, srcv(ji)%nct
190               IF ( srcv(ji)%nct .gt. 1 ) THEN
191                  WRITE(zclname,'( a7, i1)') srcv(ji)%clname,jc
192               ELSE
193                  zclname=srcv(ji)%clname
194               ENDIF
195               WRITE(numout,*) "Define",ji,zclname," for",PRISM_In
196               CALL prism_def_var_proto ( srcv(ji)%nid(jc), zclname, id_part, (/ 2, 0/),   &
197                    &                      PRISM_In    , ishape   , PRISM_REAL, nerror)
198               IF ( nerror /= PRISM_Ok ) THEN
199                  WRITE(numout,*) 'Failed to define transient ', ji, TRIM(zclname)
200                  CALL prism_abort_proto ( srcv(ji)%nid(jc), 'cpl_prism_define', 'Failure in prism_def_var')
201               ENDIF
202            END DO
203         ENDIF
204      END DO
205     
206      !------------------------------------------------------------------
207      ! End of definition phase
208      !------------------------------------------------------------------
209     
210      CALL prism_enddef_proto(nerror)
211      IF( nerror /= PRISM_Ok )   CALL prism_abort_proto ( ncomp_id, 'cpl_prism_define', 'Failure in prism_enddef')
212      !
213   END SUBROUTINE cpl_prism_define
214   
215   
216   SUBROUTINE cpl_prism_snd( kid, kstep, pdata, kinfo )
217      !!---------------------------------------------------------------------
218      !!              ***  ROUTINE cpl_prism_snd  ***
219      !!
220      !! ** Purpose : - At each coupling time-step,this routine sends fields
221      !!      like sst or ice cover to the coupler or remote application.
222      !!----------------------------------------------------------------------
223      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
224      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
225      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
226      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
227      !!
228      INTEGER                                   ::   jc        ! local loop index
229      !!--------------------------------------------------------------------
230      !
231      ! snd data to OASIS3
232      !
233      DO jc = 1, ssnd(kid)%nct
234
235         CALL prism_put_proto ( ssnd(kid)%nid(jc), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
236         
237         IF ( ln_ctl ) THEN       
238            IF ( kinfo == PRISM_Sent     .OR. kinfo == PRISM_ToRest .OR.   &
239                 & kinfo == PRISM_SentOut  .OR. kinfo == PRISM_ToRestOut ) THEN
240               WRITE(numout,*) '****************'
241               WRITE(numout,*) 'prism_put_proto: Outgoing ', ssnd(kid)%clname
242               WRITE(numout,*) 'prism_put_proto: ivarid ', ssnd(kid)%nid(jc)
243               WRITE(numout,*) 'prism_put_proto:  kstep ', kstep
244               WRITE(numout,*) 'prism_put_proto:   info ', kinfo
245               WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
246               WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
247               WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
248               WRITE(numout,*) '****************'
249            ENDIF
250         ENDIF
251
252      ENDDO
253      !
254    END SUBROUTINE cpl_prism_snd
255
256
257   SUBROUTINE cpl_prism_rcv( kid, kstep, pdata, kinfo )
258      !!---------------------------------------------------------------------
259      !!              ***  ROUTINE cpl_prism_rcv  ***
260      !!
261      !! ** Purpose : - At each coupling time-step,this routine receives fields
262      !!      like stresses and fluxes from the coupler or remote application.
263      !!----------------------------------------------------------------------
264      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
265      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
266      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
267      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
268      !!
269      INTEGER                                   ::   jc        ! local loop index
270      LOGICAL                                   ::   llaction
271      !!--------------------------------------------------------------------
272      !
273      ! receive local data from OASIS3 on every process
274      !
275      DO jc = 1, srcv(kid)%nct
276
277         CALL prism_get_proto ( srcv(kid)%nid(jc), kstep, exfld, kinfo )         
278         
279         llaction = .false.
280         IF( kinfo == PRISM_Recvd   .OR. kinfo == PRISM_FromRest .OR.   &
281              kinfo == PRISM_RecvOut .OR. kinfo == PRISM_FromRestOut )   llaction = .TRUE.
282         
283         IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc)
284         
285         IF ( llaction ) THEN
286           
287            kinfo = OASIS_Rcv
288            pdata(nldi:nlei, nldj:nlej,jc) = exfld(:,:)
289           
290            !--- Fill the overlap areas and extra hallows (mpp)
291            !--- check periodicity conditions (all cases)
292            CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
293           
294            IF ( ln_ctl ) THEN       
295               WRITE(numout,*) '****************'
296               WRITE(numout,*) 'prism_get_proto: Incoming ', srcv(kid)%clname
297               WRITE(numout,*) 'prism_get_proto: ivarid '  , srcv(kid)%nid(jc)
298               WRITE(numout,*) 'prism_get_proto:   kstep', kstep
299               WRITE(numout,*) 'prism_get_proto:   info ', kinfo
300               WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
301               WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
302               WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
303               WRITE(numout,*) '****************'
304            ENDIF
305           
306         ELSE
307            kinfo = OASIS_idle     
308         ENDIF
309         
310      ENDDO
311      !
312   END SUBROUTINE cpl_prism_rcv
313
314
315   INTEGER FUNCTION cpl_prism_freq( kid ) 
316      !!---------------------------------------------------------------------
317      !!              ***  ROUTINE cpl_prism_freq  ***
318      !!
319      !! ** Purpose : - send back the coupling frequency for a particular field
320      !!----------------------------------------------------------------------
321      INTEGER,INTENT(in) ::   kid   ! variable index
322      !!----------------------------------------------------------------------
323      cpl_prism_freq = ig_def_freq( kid )
324      !
325   END FUNCTION cpl_prism_freq
326
327
328   SUBROUTINE cpl_prism_finalize
329      !!---------------------------------------------------------------------
330      !!              ***  ROUTINE cpl_prism_finalize  ***
331      !!
332      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
333      !!      called explicitly before cpl_prism_init it will also close
334      !!      MPI communication.
335      !!----------------------------------------------------------------------
336      !
337      DEALLOCATE( exfld )
338      CALL prism_terminate_proto( nerror )         
339      !
340   END SUBROUTINE cpl_prism_finalize
341
342#else
343   !!----------------------------------------------------------------------
344   !!   Default case          Dummy module          Forced Ocean/Atmosphere
345   !!----------------------------------------------------------------------
346   USE in_out_manager               ! I/O manager
347   LOGICAL, PUBLIC, PARAMETER :: lk_cpl = .FALSE.   !: coupled flag
348   PUBLIC cpl_prism_init
349   PUBLIC cpl_prism_finalize
350CONTAINS
351   SUBROUTINE cpl_prism_init (kl_comm) 
352      INTEGER, INTENT(out)   :: kl_comm       ! local communicator of the model
353      kl_comm = -1
354      WRITE(numout,*) 'cpl_prism_init: Error you sould not be there...'
355   END SUBROUTINE cpl_prism_init
356   SUBROUTINE cpl_prism_finalize
357      WRITE(numout,*) 'cpl_prism_finalize: Error you sould not be there...'
358   END SUBROUTINE cpl_prism_finalize
359#endif
360
361   !!=====================================================================
362END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.