New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp_2.F90 in branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/LIM_SRC_2/limtrp_2.F90 @ 3584

Last change on this file since 3584 was 3584, checked in by cetlod, 11 years ago

Add in branch 2012/dev_LOCEAN_2012 changes from dev_r3438_LOCEAN15_PISLOB & dev_r3387_LOCEAN6_AGRIF_LIM, see ticket 1000
  • Property svn:keywords set to Id
File size: 17.1 KB
Line 
1MODULE limtrp_2
2   !!======================================================================
3   !!                       ***  MODULE limtrp_2   ***
4   !! LIM 2.0 transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (UCL)  Original code
7   !!            2.0  !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!             -   !  2004-01 (G. Madec, C. Ethe)  F90, mpp
9   !!            3.3  !  2009-05  (G. Garric, C. Bricaud) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_trp_2      : advection/diffusion process of sea ice
16   !!   lim_trp_init_2 : initialization and namelist read
17   !!----------------------------------------------------------------------
18   USE phycst          ! physical constant
19   USE sbc_oce         ! ocean surface boundary condition
20   USE dom_oce         ! ocean domain
21   USE in_out_manager  ! I/O manager
22   USE dom_ice_2       ! LIM-2 domain
23   USE ice_2           ! LIM-2 variables
24   USE limistate_2     ! LIM-2 initial state
25   USE limadv_2        ! LIM-2 advection
26   USE limhdf_2        ! LIM-2 horizontal diffusion
27   USE lbclnk          ! lateral boundary conditions -- MPP exchanges
28   USE lib_mpp         ! MPP library
29   USE wrk_nemo        ! work arrays
30# if defined key_agrif
31   USE agrif_lim2_interp ! nesting
32# endif
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   lim_trp_2   ! called by sbc_ice_lim_2
38
39   REAL(wp), PUBLIC ::   bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
40
41   REAL(wp)  ::   epsi06 = 1.e-06   ! constant values
42   REAL(wp)  ::   epsi03 = 1.e-03 
43   REAL(wp)  ::   epsi16 = 1.e-16 
44   REAL(wp)  ::   rzero  = 0.e0   
45   REAL(wp)  ::   rone   = 1.e0
46
47   !! * Substitution
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54
55CONTAINS
56
57   SUBROUTINE lim_trp_2( kt )
58      !!-------------------------------------------------------------------
59      !!                   ***  ROUTINE lim_trp_2 ***
60      !!                   
61      !! ** purpose : advection/diffusion process of sea ice
62      !!
63      !! ** method  : variables included in the process are scalar,   
64      !!     other values are considered as second order.
65      !!     For advection, a second order Prather scheme is used. 
66      !!
67      !! ** action :
68      !!---------------------------------------------------------------------
69      INTEGER, INTENT(in) ::   kt     ! number of iteration
70      !!
71      INTEGER  ::   ji, jj, jk   ! dummy loop indices
72      INTEGER  ::   initad       ! number of sub-timestep for the advection
73      REAL(wp) ::   zindb  , zindsn , zindic, zacrith   ! local scalars
74      REAL(wp) ::   zusvosn, zusvoic, zignm , zindhe    !   -      -
75      REAL(wp) ::   zvbord , zcfl   , zusnit            !   -      -
76      REAL(wp) ::   zrtt   , ztsn   , ztic1 , ztic2     !   -      -
77      REAL(wp), POINTER, DIMENSION(:,:)  ::   zui_u , zvi_v , zsm             ! 2D workspace
78      REAL(wp), POINTER, DIMENSION(:,:)  ::   zs0ice, zs0sn , zs0a            !  -      -
79      REAL(wp), POINTER, DIMENSION(:,:)  ::   zs0c0 , zs0c1 , zs0c2 , zs0st   !  -      -
80      !---------------------------------------------------------------------
81
82      CALL wrk_alloc( jpi, jpj, zui_u , zvi_v , zsm, zs0ice, zs0sn , zs0a, zs0c0 , zs0c1 , zs0c2 , zs0st )
83
84      IF( kt == nit000  )   CALL lim_trp_init_2      ! Initialization (first time-step only)
85
86# if defined key_agrif
87      CALL agrif_trp_lim2_load      ! First interpolation
88# endif
89
90      zsm(:,:) = area(:,:)
91     
92      IF( ln_limdyn ) THEN
93         !-------------------------------------!
94         !   Advection of sea ice properties   !
95         !-------------------------------------!
96
97         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
98         ! ---------------------------------------
99         IF( lk_lim2_vp ) THEN      ! VP rheology : B-grid sea-ice dynamics (I-point ice velocity)
100            zvbord = 1._wp + ( 1._wp - bound )      ! zvbord=2 no-slip, =0 free slip boundary conditions       
101            DO jj = 1, jpjm1
102               DO ji = 1, jpim1   ! NO vector opt.
103                  zui_u(ji,jj) = ( u_ice(ji+1,jj) + u_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj)+tmu(ji+1,jj+1), zvbord ) )
104                  zvi_v(ji,jj) = ( v_ice(ji,jj+1) + v_ice(ji+1,jj+1) ) / ( MAX( tmu(ji,jj+1)+tmu(ji+1,jj+1), zvbord ) )
105               END DO
106            END DO
107            CALL lbc_lnk( zui_u, 'U', -1. )   ;   CALL lbc_lnk( zvi_v, 'V', -1. )      ! Lateral boundary conditions
108            !
109         ELSE                       ! EVP rheology : C-grid sea-ice dynamics (u- & v-points ice velocity)
110            zui_u(:,:) = u_ice(:,:)      ! EVP rheology: ice (u,v) at u- and v-points
111            zvi_v(:,:) = v_ice(:,:)
112         ENDIF
113
114         ! CFL test for stability
115         ! ----------------------
116         zcfl  = 0._wp
117         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
118         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
119         !
120         IF(lk_mpp)   CALL mpp_max( zcfl )
121         !
122         IF( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp_2 : violation of cfl criterion the ',nday,'th day, cfl = ', zcfl
123
124         ! content of properties
125         ! ---------------------
126         zs0sn (:,:) =  hsnm(:,:)              * area  (:,:)  ! Snow volume.
127         zs0ice(:,:) =  hicm(:,:)              * area  (:,:)  ! Ice volume.
128         zs0a  (:,:) =  ( 1.0 - frld(:,:) )    * area  (:,:)  ! Surface covered by ice.
129         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn (:,:)  ! Heat content of the snow layer.
130         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
131         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
132         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a  (:,:)  ! Heat reservoir for brine pockets.
133         
134 
135         ! Advection (Prather scheme)
136         ! ---------
137         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )   ! If ice drift field is too fast,         
138         zusnit = 1.0 / REAL( initad )                              ! split the ice time step in two
139         !
140         IF( MOD( ( kt - 1) / nn_fsbc , 2 ) == 0) THEN        !==  odd ice time step:  adv_x then adv_y  ==!
141            DO jk = 1, initad
142               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
143               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
144               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
145               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
146               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
147               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
148               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
149               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
150               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
151               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
152               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
153               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
154               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
155               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
156            END DO
157         ELSE                                                 !==  even ice time step:  adv_x then adv_y  ==!
158            DO jk = 1, initad
159               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
160               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
161               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
162               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
163               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
164               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
165               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
166               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
167               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
168               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
169               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
170               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
171               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
172               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
173            END DO
174         ENDIF
175                       
176         ! recover the properties from their contents
177         ! ------------------------------------------
178!!gm Define in limmsh one for all area = 1 /area  (CPU time saved !)
179         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
180         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
181         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
182         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
183         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
184         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
185         zs0st (:,:) = zs0st (:,:) / area(:,:)
186
187
188         !-------------------------------------!
189         !   Diffusion of sea ice properties   !
190         !-------------------------------------!
191
192         ! Masked eddy diffusivity coefficient at ocean U- and V-points
193         ! ------------------------------------------------------------
194         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
195            DO ji = 1 , fs_jpim1   ! vector opt.
196               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
197                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
198               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
199                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
200            END DO
201         END DO
202!!gm more readable coding: (and avoid an error in F90 with sign of zero)
203!        DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
204!           DO ji = 1 , fs_jpim1   ! vector opt.
205!              IF( MIN( zs0a(ji,jj) , zs0a(ji+1,jj) ) == 0.e0 )   pahu(ji,jj) = 0._wp
206!              IF( MIN( zs0a(ji,jj) , zs0a(ji,jj+1) ) == 0.e0 )   pahv(ji,jj) = 0._wp
207!           END DO
208!        END DO
209!!gm end
210
211         ! diffusion
212         ! ---------
213         CALL lim_hdf_2( zs0ice )
214         CALL lim_hdf_2( zs0sn  )
215         CALL lim_hdf_2( zs0a   )
216         CALL lim_hdf_2( zs0c0  )
217         CALL lim_hdf_2( zs0c1  )
218         CALL lim_hdf_2( zs0c2  )
219         CALL lim_hdf_2( zs0st  )
220
221!!gm see comment this can be skipped
222         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  useless
223         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  just below
224         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! caution: the suppression of the 2 changes
225         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )    !! the last digit of the results
226         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
227         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
228         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
229
230
231         !-------------------------------------------------------------------!
232         !   Updating and limitation of sea ice properties after transport   !
233         !-------------------------------------------------------------------!
234         DO jj = 1, jpj
235            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
236            DO ji = 1, jpi
237               !
238               ! Recover mean values over the grid squares.
239               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
240               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
241               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
242               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
243               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
244               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
245               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
246
247               ! Recover in situ values.
248               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
249               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
250               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
251               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
252               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
253               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
254               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
255               zindb         = MAX( zindsn, zindic )
256               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
257               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
258               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
259               hicif(ji,jj)  = zindic * hicif(ji,jj)
260               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
261               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
262               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
263               zrtt          = 173.15 * rone 
264               ztsn          =          zignm   * tbif(ji,jj,1)  &
265                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
266               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
267               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
268 
269               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
270               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
271               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
272               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
273            END DO
274         END DO
275         !
276      ENDIF
277      !
278# if defined key_agrif
279      CALL agrif_trp_lim2      ! Fill boundaries of the fine grid
280# endif
281      !
282      CALL wrk_dealloc( jpi, jpj, zui_u , zvi_v , zsm, zs0ice, zs0sn , zs0a, zs0c0 , zs0c1 , zs0c2 , zs0st )
283      !
284   END SUBROUTINE lim_trp_2
285
286
287   SUBROUTINE lim_trp_init_2
288      !!-------------------------------------------------------------------
289      !!                  ***  ROUTINE lim_trp_init_2  ***
290      !!
291      !! ** Purpose :   initialization of ice advection parameters
292      !!
293      !! ** Method  :   Read the namicetrp namelist and check the parameter
294      !!              values called at the first timestep (nit000)
295      !!
296      !! ** input   :   Namelist namicetrp
297      !!-------------------------------------------------------------------
298      NAMELIST/namicetrp/ bound
299      !!-------------------------------------------------------------------
300      !
301      REWIND ( numnam_ice )      ! Read Namelist namicetrp
302      READ   ( numnam_ice  , namicetrp )
303      IF(lwp) THEN
304         WRITE(numout,*)
305         WRITE(numout,*) 'lim_trp_init_2 : Ice parameters for advection '
306         WRITE(numout,*) '~~~~~~~~~~~~~~'
307         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
308      ENDIF
309      !
310   END SUBROUTINE lim_trp_init_2
311
312#else
313   !!----------------------------------------------------------------------
314   !!   Default option         Empty Module                No sea-ice model
315   !!----------------------------------------------------------------------
316CONTAINS
317   SUBROUTINE lim_trp_2        ! Empty routine
318   END SUBROUTINE lim_trp_2
319#endif
320
321   !!======================================================================
322END MODULE limtrp_2
Note: See TracBrowser for help on using the repository browser.