New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 3666

Last change on this file since 3666 was 3666, checked in by cetlod, 11 years ago

commit the changes resulting for the merged branches, see ticket #1025
  • Property svn:keywords set to Id
File size: 10.6 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  05-11  (G. Madec)  Original code
7   !!            3.0  !  10-06  (C. Ethe)   Adapted to passive tracers
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_adv      : compute ocean tracer advection trend
14   !!   trc_adv_ctl  : control the different options of advection scheme
15   !!----------------------------------------------------------------------
16   USE oce_trc         ! ocean dynamics and active tracers
17   USE trc             ! ocean passive tracers variables
18   USE trcnam_trp      ! passive tracers transport namelist variables
19   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
20   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
21   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
22   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
23   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
24   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
25   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
26   USE ldftra_oce      ! lateral diffusion coefficient on tracers
27   USE prtctl_trc      ! Print control
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   trc_adv          ! routine called by step module
33   PUBLIC   trc_adv_alloc    ! routine called by nemogcm module
34
35   INTEGER ::   nadv   ! choice of the type of advection scheme
36   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt  ! vertical profile time-step, = 2 rdttra
37   !                                                    ! except at nitrrc000 (=rdttra) if neuler=0
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   INTEGER FUNCTION trc_adv_alloc()
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE trc_adv_alloc  ***
52      !!----------------------------------------------------------------------
53
54      ALLOCATE( r2dt(jpk), STAT=trc_adv_alloc )
55
56      IF( trc_adv_alloc /= 0 ) CALL ctl_warn('trc_adv_alloc : failed to allocate array.')
57
58   END FUNCTION trc_adv_alloc
59
60
61   SUBROUTINE trc_adv( kt )
62      !!----------------------------------------------------------------------
63      !!                  ***  ROUTINE trc_adv  ***
64      !!
65      !! ** Purpose :   compute the ocean tracer advection trend.
66      !!
67      !! ** Method  : - Update the tracer with the advection term following nadv
68      !!----------------------------------------------------------------------
69      !!
70      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
71      !
72      INTEGER ::   jk 
73      CHARACTER (len=22) ::   charout
74      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('trc_adv')
78      !
79      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
80      !
81
82      IF( kt == nittrc000 )   CALL trc_adv_ctl          ! initialisation & control of options
83
84      IF( ln_top_euler) THEN
85         r2dt(:) =  rdttrc(:)              ! = rdttrc (use Euler time stepping)
86      ELSE
87         IF( neuler == 0 .AND. kt == nittrc000 ) THEN     ! at nittrc000
88            r2dt(:) =  rdttrc(:)           ! = rdttrc (restarting with Euler time stepping)
89         ELSEIF( kt <= nittrc000 + 1 ) THEN          ! at nittrc000 or nittrc000+1
90            r2dt(:) = 2. * rdttrc(:)       ! = 2 rdttrc (leapfrog)
91         ENDIF
92      ENDIF
93
94      !                                                   ! effective transport
95      DO jk = 1, jpkm1
96         !                                                ! eulerian transport only
97         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)
98         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
99         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
100         !
101      END DO
102      zwn(:,:,jpk) = 0.e0                                 ! no transport trough the bottom
103
104      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &  ! add the eiv transport (if necessary)
105         &              CALL tra_adv_eiv( kt, nittrc000, zun, zvn, zwn, 'TRC' )
106      !
107      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
108      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )   !  2nd order centered
109      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  TVD
110      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )   !  MUSCL
111      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  MUSCL2
112      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  UBS
113      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  QUICKEST
114      !
115      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
116         CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )         
117         WRITE(charout, FMT="('adv1')")  ; CALL prt_ctl_trc_info(charout)
118                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
119         CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
120         WRITE(charout, FMT="('adv2')")  ; CALL prt_ctl_trc_info(charout)
121                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
122         CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )         
123         WRITE(charout, FMT="('adv3')")  ; CALL prt_ctl_trc_info(charout)
124                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
125         CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
126         WRITE(charout, FMT="('adv4')")  ; CALL prt_ctl_trc_info(charout)
127                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
128         CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
129         WRITE(charout, FMT="('adv5')")  ; CALL prt_ctl_trc_info(charout)
130                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
131         CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
132         WRITE(charout, FMT="('adv6')")  ; CALL prt_ctl_trc_info(charout)
133                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
134         !
135      END SELECT
136
137      !                                              ! print mean trends (used for debugging)
138      IF( ln_ctl )   THEN
139         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
140                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
141      END IF
142      !
143      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
144      !
145      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
146      !
147   END SUBROUTINE trc_adv
148
149
150   SUBROUTINE trc_adv_ctl
151      !!---------------------------------------------------------------------
152      !!                  ***  ROUTINE trc_adv_ctl  ***
153      !!               
154      !! ** Purpose : Control the consistency between namelist options for
155      !!              passive tracer advection schemes and set nadv
156      !!----------------------------------------------------------------------
157      INTEGER ::   ioptio
158      !!----------------------------------------------------------------------
159
160      ioptio = 0                      ! Parameter control
161      IF( ln_trcadv_cen2   )   ioptio = ioptio + 1
162      IF( ln_trcadv_tvd    )   ioptio = ioptio + 1
163      IF( ln_trcadv_muscl  )   ioptio = ioptio + 1
164      IF( ln_trcadv_muscl2 )   ioptio = ioptio + 1
165      IF( ln_trcadv_ubs    )   ioptio = ioptio + 1
166      IF( ln_trcadv_qck    )   ioptio = ioptio + 1
167      IF( lk_esopa         )   ioptio =          1
168
169      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
170
171      !                              ! Set nadv
172      IF( ln_trcadv_cen2   )   nadv =  1
173      IF( ln_trcadv_tvd    )   nadv =  2
174      IF( ln_trcadv_muscl  )   nadv =  3
175      IF( ln_trcadv_muscl2 )   nadv =  4
176      IF( ln_trcadv_ubs    )   nadv =  5
177      IF( ln_trcadv_qck    )   nadv =  6
178      IF( lk_esopa         )   nadv = -1
179
180      IF(lwp) THEN                   ! Print the choice
181         WRITE(numout,*)
182         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
183         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
184         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
185         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
186         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
187         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
188         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
189      ENDIF
190      !
191   END SUBROUTINE trc_adv_ctl
192   
193#else
194   !!----------------------------------------------------------------------
195   !!   Default option                                         Empty module
196   !!----------------------------------------------------------------------
197CONTAINS
198   SUBROUTINE trc_adv( kt )
199      INTEGER, INTENT(in) :: kt
200      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
201   END SUBROUTINE trc_adv
202#endif
203
204  !!======================================================================
205END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.