New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step_c1d.F90 in branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC/C1D – NEMO

source: branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC/C1D/step_c1d.F90 @ 3680

Last change on this file since 3680 was 3680, checked in by rblod, 11 years ago

First commit of the final branch for 2012 (future nemo_3_5), see ticket #1028
File size: 8.8 KB
Line 
1MODULE step_c1d
2   !!======================================================================
3   !!                       ***  MODULE step_c1d  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping - c1d case
5   !!======================================================================
6   !! History :   2.0  !  2004-04  (C. Ethe)  adapted from step.F90 for C1D
7   !!             3.0  !  2008-04  (G. Madec)  redo the adaptation to include SBC
8   !!----------------------------------------------------------------------
9#if defined key_c1d
10   !!----------------------------------------------------------------------
11   !!   'key_c1d'                                       1D Configuration
12   !!---------------------------------------------------------------------- 
13   !!   stp_c1d        : NEMO system time-stepping in c1d case
14   !!----------------------------------------------------------------------
15   USE step_oce         ! time stepping definition modules
16#if defined key_top
17   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
18#endif
19   USE dyncor_c1d      ! Coriolis term (c1d case)         (dyn_cor_1d     )
20   USE dynnxt_c1d      ! time-stepping                    (dyn_nxt routine)
21   USE restart         ! restart
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC stp_c1d      ! called by opa.F90
27
28   !! * Substitutions
29#  include "domzgr_substitute.h90"
30#  include "zdfddm_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/C1D 3.3 , NEMO Consortium (2010)
33   !! $Id: step_c1d.F90 2382 2010-11-13 13:08:12Z gm $
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE stp_c1d( kstp )
39      !!----------------------------------------------------------------------
40      !!                     ***  ROUTINE stp_c1d  ***
41      !!                     
42      !! ** Purpose :  - Time stepping of SBC including LIM (dynamic and thermodynamic eqs.)
43      !!               - Time stepping of OPA (momentum and active tracer eqs.)
44      !!               - Time stepping of TOP (passive tracer eqs.)
45      !!
46      !! ** Method  : -1- Update forcings and data 
47      !!              -2- Update vertical ocean physics
48      !!              -3- Compute the t and s trends
49      !!              -4- Update t and s
50      !!              -5- Compute the momentum trends
51      !!              -6- Update the horizontal velocity
52      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
53      !!              -8- Outputs and diagnostics
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
56      INTEGER ::   jk       ! dummy loop indice
57      INTEGER ::   indic    ! error indicator if < 0
58      !! ---------------------------------------------------------------------
59
60                             indic = 0                ! reset to no error condition
61      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
62                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
63
64      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
65      ! Update data, open boundaries, surface boundary condition (including sea-ice)
66      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
67                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
68
69      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
70      ! Ocean physics update                (ua, va, ta, sa used as workspace)
71      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
72                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
73                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
74      !  VERTICAL PHYSICS   
75                         CALL zdf_bfr( kstp )         ! bottom friction
76      !                                               ! Vertical eddy viscosity and diffusivity coefficients
77      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
78      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
79      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
80      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
81      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
82         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
83         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
84         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
85      ENDIF
86
87      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
88         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:)   ;   END DO
89      ENDIF
90      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
91
92      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
93
94      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
95         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
96         
97                         CALL zdf_mxl( kstp )         ! mixed layer depth
98
99                                                      ! write tke information in the restart file
100      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
101                                                      ! write gls information in the restart file
102      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
103
104      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
105      ! diagnostics and outputs             (ua, va, ta, sa used as workspace)
106      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
107                         CALL dia_wri( kstp )       ! ocean model: outputs
108
109#if defined key_top
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111      ! Passive Tracer Model
112      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
113                         CALL trc_stp( kstp )            ! time-stepping
114#endif
115
116      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
117      ! Active tracers                              (ua, va used as workspace)
118      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
119                             tsa(:,:,:,:) = 0.e0                ! set tracer trends to zero
120
121                             CALL tra_sbc    ( kstp )        ! surface boundary condition
122      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )        ! penetrative solar radiation qsr
123      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )        ! KPP non-local tracer fluxes
124                             CALL tra_zdf    ( kstp )        ! vertical mixing
125                             CALL tra_nxt    ( kstp )        ! tracer fields at next time step
126      IF( ln_zdfnpc      )   CALL tra_npc    ( kstp )        ! applied non penetrative convective adjustment on (t,s)
127                             CALL eos( tsb, rhd, rhop )      ! now (swap=before) in situ density for dynhpg module
128
129      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
130      ! Dynamics                                    (ta, sa used as workspace)
131      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
132                               ua(:,:,:) = 0.e0               ! set dynamics trends to zero
133                               va(:,:,:) = 0.e0
134
135                               CALL dyn_cor_c1d( kstp )       ! vorticity term including Coriolis
136                               CALL dyn_zdf    ( kstp )       ! vertical diffusion
137                               CALL dyn_nxt_c1d( kstp )       ! lateral velocity at next time step
138
139      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
140      ! Control and restarts
141      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
142                                 CALL stp_ctl( kstp, indic )
143      IF( kstp == nit000     )   CALL iom_close( numror )             ! close input  ocean restart file
144      IF( lrst_oce           )   CALL rst_write  ( kstp )             ! write output ocean restart file
145      !
146   END SUBROUTINE stp_c1d
147
148#else
149   !!----------------------------------------------------------------------
150   !!   Default key                                            NO 1D Config
151   !!----------------------------------------------------------------------
152CONTAINS
153   SUBROUTINE stp_c1d ( kt )      ! dummy routine
154      WRITE(*,*) 'stp_c1d: You should not have seen this print! error?', kt
155   END SUBROUTINE stp_c1d
156#endif
157
158   !!======================================================================
159END MODULE step_c1d
Note: See TracBrowser for help on using the repository browser.