| 1 | MODULE daymod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE daymod *** |
|---|
| 4 | !! Ocean : calendar |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 1994-09 (M. Pontaud M. Imbard) Original code |
|---|
| 7 | !! ! 1997-03 (O. Marti) |
|---|
| 8 | !! ! 1997-05 (G. Madec) |
|---|
| 9 | !! ! 1997-08 (M. Imbard) |
|---|
| 10 | !! NEMO 1.0 ! 2003-09 (G. Madec) F90 + nyear, nmonth, nday |
|---|
| 11 | !! ! 2004-01 (A.M. Treguier) new calculation based on adatrj |
|---|
| 12 | !! ! 2006-08 (G. Madec) surface module major update |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! day : calendar |
|---|
| 17 | !! |
|---|
| 18 | !! ------------------------------- |
|---|
| 19 | !! ----------- WARNING ----------- |
|---|
| 20 | !! |
|---|
| 21 | !! we suppose that the time step is deviding the number of second of in a day |
|---|
| 22 | !! ---> MOD( rday, rdttra(1) ) == 0 |
|---|
| 23 | !! |
|---|
| 24 | !! ----------- WARNING ----------- |
|---|
| 25 | !! ------------------------------- |
|---|
| 26 | !! |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE dom_oce ! ocean space and time domain |
|---|
| 29 | USE phycst ! physical constants |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE iom ! |
|---|
| 32 | USE ioipsl, ONLY : ymds2ju ! for calendar |
|---|
| 33 | USE prtctl ! Print control |
|---|
| 34 | USE trc_oce, ONLY : lk_offline ! offline flag |
|---|
| 35 | USE timing ! Timing |
|---|
| 36 | USE restart ! restart |
|---|
| 37 | |
|---|
| 38 | IMPLICIT NONE |
|---|
| 39 | PRIVATE |
|---|
| 40 | |
|---|
| 41 | PUBLIC day ! called by step.F90 |
|---|
| 42 | PUBLIC day_init ! called by istate.F90 |
|---|
| 43 | |
|---|
| 44 | INTEGER :: nsecd, nsecd05, ndt, ndt05 |
|---|
| 45 | |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 48 | !! $Id$ |
|---|
| 49 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | CONTAINS |
|---|
| 52 | |
|---|
| 53 | SUBROUTINE day_init |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE day_init *** |
|---|
| 56 | !! |
|---|
| 57 | !! ** Purpose : Initialization of the calendar values to their values 1 time step before nit000 |
|---|
| 58 | !! because day will be called at the beginning of step |
|---|
| 59 | !! |
|---|
| 60 | !! ** Action : - nyear : current year |
|---|
| 61 | !! - nmonth : current month of the year nyear |
|---|
| 62 | !! - nday : current day of the month nmonth |
|---|
| 63 | !! - nday_year : current day of the year nyear |
|---|
| 64 | !! - nsec_year : current time step counted in second since 00h jan 1st of the current year |
|---|
| 65 | !! - nsec_month : current time step counted in second since 00h 1st day of the current month |
|---|
| 66 | !! - nsec_day : current time step counted in second since 00h of the current day |
|---|
| 67 | !! - nsec1jan000 : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year |
|---|
| 68 | !! - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | INTEGER :: inbday, idweek |
|---|
| 71 | REAL(wp) :: zjul |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | ! |
|---|
| 74 | ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0 |
|---|
| 75 | IF( MOD( rday , rdttra(1) ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 76 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 77 | IF( MOD( rdttra(1), 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 78 | nsecd = NINT(rday ) |
|---|
| 79 | nsecd05 = NINT(0.5 * rday ) |
|---|
| 80 | ndt = NINT( rdttra(1)) |
|---|
| 81 | ndt05 = NINT(0.5 * rdttra(1)) |
|---|
| 82 | |
|---|
| 83 | IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' ) |
|---|
| 84 | |
|---|
| 85 | ! set the calandar from ndastp (read in restart file and namelist) |
|---|
| 86 | |
|---|
| 87 | nyear = ndastp / 10000 |
|---|
| 88 | nmonth = ( ndastp - (nyear * 10000) ) / 100 |
|---|
| 89 | nday = ndastp - (nyear * 10000) - ( nmonth * 100 ) |
|---|
| 90 | |
|---|
| 91 | CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday ) ! we assume that we start run at 00:00 |
|---|
| 92 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 93 | fjulday = fjulday + 1. ! move back to the day at nit000 (and not at nit000 - 1) |
|---|
| 94 | |
|---|
| 95 | nsec1jan000 = 0 |
|---|
| 96 | CALL day_mth |
|---|
| 97 | |
|---|
| 98 | IF ( nday == 0 ) THEN ! for ex if ndastp = ndate0 - 1 |
|---|
| 99 | nmonth = nmonth - 1 |
|---|
| 100 | nday = nmonth_len(nmonth) |
|---|
| 101 | ENDIF |
|---|
| 102 | IF ( nmonth == 0 ) THEN ! go at the end of previous year |
|---|
| 103 | nmonth = 12 |
|---|
| 104 | nyear = nyear - 1 |
|---|
| 105 | nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0) |
|---|
| 106 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 107 | ENDIF |
|---|
| 108 | |
|---|
| 109 | ! day since january 1st |
|---|
| 110 | nday_year = nday + SUM( nmonth_len(1:nmonth - 1) ) |
|---|
| 111 | |
|---|
| 112 | !compute number of days between last monday and today |
|---|
| 113 | CALL ymds2ju( 1900, 01, 01, 0.0, zjul ) ! compute julian day value of 01.01.1900 (our reference that was a Monday) |
|---|
| 114 | inbday = NINT(fjulday - zjul) ! compute nb day between 01.01.1900 and current day |
|---|
| 115 | idweek = MOD(inbday, 7) ! compute nb day between last monday and current day |
|---|
| 116 | |
|---|
| 117 | ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step |
|---|
| 118 | nsec_year = nday_year * nsecd - ndt05 ! 1 time step before the middle of the first time step |
|---|
| 119 | nsec_month = nday * nsecd - ndt05 ! because day will be called at the beginning of step |
|---|
| 120 | nsec_week = idweek * nsecd - ndt05 |
|---|
| 121 | nsec_day = nsecd - ndt05 |
|---|
| 122 | |
|---|
| 123 | ! control print |
|---|
| 124 | IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i6)')' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ', & |
|---|
| 125 | & nyear, '/', nmonth, '/', nday, ' nsec_day:', nsec_day, ' nsec_week:', nsec_week |
|---|
| 126 | |
|---|
| 127 | ! Up to now, calendar parameters are related to the end of previous run (nit000-1) |
|---|
| 128 | ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init |
|---|
| 129 | CALL day( nit000 ) |
|---|
| 130 | ! |
|---|
| 131 | END SUBROUTINE day_init |
|---|
| 132 | |
|---|
| 133 | |
|---|
| 134 | SUBROUTINE day_mth |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | !! *** ROUTINE day_init *** |
|---|
| 137 | !! |
|---|
| 138 | !! ** Purpose : calendar values related to the months |
|---|
| 139 | !! |
|---|
| 140 | !! ** Action : - nmonth_len : length in days of the months of the current year |
|---|
| 141 | !! - nyear_len : length in days of the previous/current year |
|---|
| 142 | !! - nmonth_half : second since the beginning of the year and the halft of the months |
|---|
| 143 | !! - nmonth_end : second since the beginning of the year and the end of the months |
|---|
| 144 | !!---------------------------------------------------------------------- |
|---|
| 145 | INTEGER :: jm ! dummy loop indice |
|---|
| 146 | !!---------------------------------------------------------------------- |
|---|
| 147 | |
|---|
| 148 | ! length of the month of the current year (from nleapy, read in namelist) |
|---|
| 149 | IF ( nleapy < 2 ) THEN |
|---|
| 150 | nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /) |
|---|
| 151 | nyear_len(:) = 365 |
|---|
| 152 | IF ( nleapy == 1 ) THEN ! we are using calandar with leap years |
|---|
| 153 | IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN |
|---|
| 154 | nyear_len(0) = 366 |
|---|
| 155 | ENDIF |
|---|
| 156 | IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN |
|---|
| 157 | nmonth_len(2) = 29 |
|---|
| 158 | nyear_len(1) = 366 |
|---|
| 159 | ENDIF |
|---|
| 160 | ENDIF |
|---|
| 161 | ELSE |
|---|
| 162 | nmonth_len(:) = nleapy ! all months with nleapy days per year |
|---|
| 163 | nyear_len(:) = 12 * nleapy |
|---|
| 164 | ENDIF |
|---|
| 165 | |
|---|
| 166 | ! half month in second since the begining of the year: |
|---|
| 167 | ! time since Jan 1st 0 1 2 ... 11 12 13 |
|---|
| 168 | ! ---------*--|--*--|--*--| ... |--*--|--*--|--*--|-------------------------------------- |
|---|
| 169 | ! <---> <---> <---> ... <---> <---> <---> |
|---|
| 170 | ! month number 0 1 2 ... 11 12 13 |
|---|
| 171 | ! |
|---|
| 172 | ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) ) |
|---|
| 173 | nmonth_half(0) = - nsecd05 * nmonth_len(0) |
|---|
| 174 | DO jm = 1, 13 |
|---|
| 175 | nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) ) |
|---|
| 176 | END DO |
|---|
| 177 | |
|---|
| 178 | nmonth_end(0) = 0 |
|---|
| 179 | DO jm = 1, 13 |
|---|
| 180 | nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm) |
|---|
| 181 | END DO |
|---|
| 182 | ! |
|---|
| 183 | END SUBROUTINE |
|---|
| 184 | |
|---|
| 185 | |
|---|
| 186 | SUBROUTINE day( kt ) |
|---|
| 187 | !!---------------------------------------------------------------------- |
|---|
| 188 | !! *** ROUTINE day *** |
|---|
| 189 | !! |
|---|
| 190 | !! ** Purpose : Compute the date with a day iteration IF necessary. |
|---|
| 191 | !! |
|---|
| 192 | !! ** Method : - ??? |
|---|
| 193 | !! |
|---|
| 194 | !! ** Action : - nyear : current year |
|---|
| 195 | !! - nmonth : current month of the year nyear |
|---|
| 196 | !! - nday : current day of the month nmonth |
|---|
| 197 | !! - nday_year : current day of the year nyear |
|---|
| 198 | !! - ndastp : = nyear*10000 + nmonth*100 + nday |
|---|
| 199 | !! - adatrj : date in days since the beginning of the run |
|---|
| 200 | !! - nsec_year : current time of the year (in second since 00h, jan 1st) |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | INTEGER, INTENT(in) :: kt ! ocean time-step indices |
|---|
| 203 | ! |
|---|
| 204 | CHARACTER (len=25) :: charout |
|---|
| 205 | REAL(wp) :: zprec ! fraction of day corresponding to 0.1 second |
|---|
| 206 | !!---------------------------------------------------------------------- |
|---|
| 207 | ! |
|---|
| 208 | IF( nn_timing == 1 ) CALL timing_start('day') |
|---|
| 209 | ! |
|---|
| 210 | zprec = 0.1 / rday |
|---|
| 211 | ! ! New time-step |
|---|
| 212 | nsec_year = nsec_year + ndt |
|---|
| 213 | nsec_month = nsec_month + ndt |
|---|
| 214 | nsec_week = nsec_week + ndt |
|---|
| 215 | nsec_day = nsec_day + ndt |
|---|
| 216 | adatrj = adatrj + rdttra(1) / rday |
|---|
| 217 | fjulday = fjulday + rdttra(1) / rday |
|---|
| 218 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 219 | IF( ABS(adatrj - REAL(NINT(adatrj ),wp)) < zprec ) adatrj = REAL(NINT(adatrj ),wp) ! avoid truncation error |
|---|
| 220 | |
|---|
| 221 | IF( nsec_day > nsecd ) THEN ! New day |
|---|
| 222 | ! |
|---|
| 223 | nday = nday + 1 |
|---|
| 224 | nday_year = nday_year + 1 |
|---|
| 225 | nsec_day = ndt05 |
|---|
| 226 | ! |
|---|
| 227 | IF( nday == nmonth_len(nmonth) + 1 ) THEN ! New month |
|---|
| 228 | nday = 1 |
|---|
| 229 | nmonth = nmonth + 1 |
|---|
| 230 | nsec_month = ndt05 |
|---|
| 231 | IF( nmonth == 13 ) THEN ! New year |
|---|
| 232 | nyear = nyear + 1 |
|---|
| 233 | nmonth = 1 |
|---|
| 234 | nday_year = 1 |
|---|
| 235 | nsec_year = ndt05 |
|---|
| 236 | nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1) |
|---|
| 237 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 238 | ENDIF |
|---|
| 239 | ENDIF |
|---|
| 240 | ! |
|---|
| 241 | ndastp = nyear * 10000 + nmonth * 100 + nday ! New date |
|---|
| 242 | ! |
|---|
| 243 | !compute first day of the year in julian days |
|---|
| 244 | CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear ) |
|---|
| 245 | ! |
|---|
| 246 | IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt, & |
|---|
| 247 | & ' New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, ' nday_year = ', nday_year |
|---|
| 248 | IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') ' nsec_year = ', nsec_year, & |
|---|
| 249 | & ' nsec_month = ', nsec_month, ' nsec_day = ', nsec_day, ' nsec_week = ', nsec_week |
|---|
| 250 | ENDIF |
|---|
| 251 | |
|---|
| 252 | IF( nsec_week > 7*nsecd ) nsec_week = ndt05 ! New week |
|---|
| 253 | |
|---|
| 254 | IF(ln_ctl) THEN |
|---|
| 255 | WRITE(charout,FMT="('kt =', I4,' d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear |
|---|
| 256 | CALL prt_ctl_info(charout) |
|---|
| 257 | ENDIF |
|---|
| 258 | |
|---|
| 259 | IF( .NOT. lk_offline ) CALL rst_opn( kt ) ! Open the restart file if needed and control lrst_oce |
|---|
| 260 | IF( lrst_oce ) CALL day_rst( kt, 'WRITE' ) ! write day restart information |
|---|
| 261 | ! |
|---|
| 262 | IF( nn_timing == 1 ) CALL timing_stop('day') |
|---|
| 263 | ! |
|---|
| 264 | END SUBROUTINE day |
|---|
| 265 | |
|---|
| 266 | |
|---|
| 267 | SUBROUTINE day_rst( kt, cdrw ) |
|---|
| 268 | !!--------------------------------------------------------------------- |
|---|
| 269 | !! *** ROUTINE ts_rst *** |
|---|
| 270 | !! |
|---|
| 271 | !! ** Purpose : Read or write calendar in restart file: |
|---|
| 272 | !! |
|---|
| 273 | !! WRITE(READ) mode: |
|---|
| 274 | !! kt : number of time step since the begining of the experiment at the |
|---|
| 275 | !! end of the current(previous) run |
|---|
| 276 | !! adatrj(0) : number of elapsed days since the begining of the experiment at the |
|---|
| 277 | !! end of the current(previous) run (REAL -> keep fractions of day) |
|---|
| 278 | !! ndastp : date at the end of the current(previous) run (coded as yyyymmdd integer) |
|---|
| 279 | !! |
|---|
| 280 | !! According to namelist parameter nrstdt, |
|---|
| 281 | !! nrstdt = 0 no control on the date (nit000 is arbitrary). |
|---|
| 282 | !! nrstdt = 1 we verify that nit000 is equal to the last |
|---|
| 283 | !! time step of previous run + 1. |
|---|
| 284 | !! In both those options, the exact duration of the experiment |
|---|
| 285 | !! since the beginning (cumulated duration of all previous restart runs) |
|---|
| 286 | !! is not stored in the restart and is assumed to be (nit000-1)*rdt. |
|---|
| 287 | !! This is valid is the time step has remained constant. |
|---|
| 288 | !! |
|---|
| 289 | !! nrstdt = 2 the duration of the experiment in days (adatrj) |
|---|
| 290 | !! has been stored in the restart file. |
|---|
| 291 | !!---------------------------------------------------------------------- |
|---|
| 292 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 293 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
|---|
| 294 | ! |
|---|
| 295 | REAL(wp) :: zkt, zndastp |
|---|
| 296 | !!---------------------------------------------------------------------- |
|---|
| 297 | |
|---|
| 298 | IF( TRIM(cdrw) == 'READ' ) THEN |
|---|
| 299 | |
|---|
| 300 | IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 301 | ! Get Calendar informations |
|---|
| 302 | CALL iom_get( numror, 'kt', zkt ) ! last time-step of previous run |
|---|
| 303 | IF(lwp) THEN |
|---|
| 304 | WRITE(numout,*) ' *** Info read in restart : ' |
|---|
| 305 | WRITE(numout,*) ' previous time-step : ', NINT( zkt ) |
|---|
| 306 | WRITE(numout,*) ' *** restart option' |
|---|
| 307 | SELECT CASE ( nrstdt ) |
|---|
| 308 | CASE ( 0 ) ; WRITE(numout,*) ' nrstdt = 0 : no control of nit000' |
|---|
| 309 | CASE ( 1 ) ; WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)' |
|---|
| 310 | CASE ( 2 ) ; WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart' |
|---|
| 311 | END SELECT |
|---|
| 312 | WRITE(numout,*) |
|---|
| 313 | ENDIF |
|---|
| 314 | ! Control of date |
|---|
| 315 | IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 ) & |
|---|
| 316 | & CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart', & |
|---|
| 317 | & ' verify the restart file or rerun with nrstdt = 0 (namelist)' ) |
|---|
| 318 | ! define ndastp and adatrj |
|---|
| 319 | IF ( nrstdt == 2 ) THEN |
|---|
| 320 | ! read the parameters correspondting to nit000 - 1 (last time step of previous run) |
|---|
| 321 | CALL iom_get( numror, 'ndastp', zndastp ) |
|---|
| 322 | ndastp = NINT( zndastp ) |
|---|
| 323 | CALL iom_get( numror, 'adatrj', adatrj ) |
|---|
| 324 | ELSE |
|---|
| 325 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 326 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 327 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 328 | ! note this is wrong if time step has changed during run |
|---|
| 329 | ENDIF |
|---|
| 330 | ELSE |
|---|
| 331 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 332 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 333 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 334 | ENDIF |
|---|
| 335 | IF( ABS(adatrj - REAL(NINT(adatrj),wp)) < 0.1 / rday ) adatrj = REAL(NINT(adatrj),wp) ! avoid truncation error |
|---|
| 336 | ! |
|---|
| 337 | IF(lwp) THEN |
|---|
| 338 | WRITE(numout,*) ' *** Info used values : ' |
|---|
| 339 | WRITE(numout,*) ' date ndastp : ', ndastp |
|---|
| 340 | WRITE(numout,*) ' number of elapsed days since the begining of run : ', adatrj |
|---|
| 341 | WRITE(numout,*) |
|---|
| 342 | ENDIF |
|---|
| 343 | ! |
|---|
| 344 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN |
|---|
| 345 | ! |
|---|
| 346 | IF( kt == nitrst ) THEN |
|---|
| 347 | IF(lwp) WRITE(numout,*) |
|---|
| 348 | IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file kt =', kt |
|---|
| 349 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 350 | ENDIF |
|---|
| 351 | ! calendar control |
|---|
| 352 | CALL iom_rstput( kt, nitrst, numrow, 'kt' , REAL( kt , wp) ) ! time-step |
|---|
| 353 | CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) ) ! date |
|---|
| 354 | CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj ) ! number of elapsed days since |
|---|
| 355 | ! ! the begining of the run [s] |
|---|
| 356 | ENDIF |
|---|
| 357 | ! |
|---|
| 358 | END SUBROUTINE day_rst |
|---|
| 359 | |
|---|
| 360 | !!====================================================================== |
|---|
| 361 | END MODULE daymod |
|---|
