| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 43 | USE closea ! closed sea |
|---|
| 44 | USE bdy_par ! for lk_bdy |
|---|
| 45 | USE bdyice_lim2 ! unstructured open boundary data (bdy_ice_lim_2 routine) |
|---|
| 46 | USE icbstp ! Icebergs! |
|---|
| 47 | |
|---|
| 48 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 49 | USE iom ! IOM library |
|---|
| 50 | USE in_out_manager ! I/O manager |
|---|
| 51 | USE lib_mpp ! MPP library |
|---|
| 52 | USE timing ! Timing |
|---|
| 53 | USE sbcwave ! Wave module |
|---|
| 54 | |
|---|
| 55 | IMPLICIT NONE |
|---|
| 56 | PRIVATE |
|---|
| 57 | |
|---|
| 58 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 59 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 60 | |
|---|
| 61 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 62 | |
|---|
| 63 | !! * Substitutions |
|---|
| 64 | # include "domzgr_substitute.h90" |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 67 | !! $Id$ |
|---|
| 68 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | CONTAINS |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE sbc_init |
|---|
| 73 | !!--------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE sbc_init *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 77 | !! |
|---|
| 78 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 79 | !! Call init routines for all other SBC modules that have one |
|---|
| 80 | !! |
|---|
| 81 | !! ** Action : - read namsbc parameters |
|---|
| 82 | !! - nsbc: type of sbc |
|---|
| 83 | !!---------------------------------------------------------------------- |
|---|
| 84 | INTEGER :: icpt ! local integer |
|---|
| 85 | !! |
|---|
| 86 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl, & |
|---|
| 87 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 88 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | |
|---|
| 91 | IF(lwp) THEN |
|---|
| 92 | WRITE(numout,*) |
|---|
| 93 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 94 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 95 | ENDIF |
|---|
| 96 | |
|---|
| 97 | call flush(numout) |
|---|
| 98 | REWIND( numnam ) ! Read Namelist namsbc |
|---|
| 99 | READ ( numnam, namsbc ) |
|---|
| 100 | call flush(numout) |
|---|
| 101 | |
|---|
| 102 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 103 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 104 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 105 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 106 | IF( lk_cice ) nn_ice = 4 |
|---|
| 107 | ENDIF |
|---|
| 108 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 109 | ln_ana = .TRUE. |
|---|
| 110 | nn_ice = 0 |
|---|
| 111 | ENDIF |
|---|
| 112 | |
|---|
| 113 | IF(lwp) THEN ! Control print |
|---|
| 114 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 115 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 116 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 117 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 118 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 119 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 120 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 121 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 122 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 123 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 124 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 125 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 126 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 127 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 128 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 129 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 130 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 131 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 132 | ENDIF |
|---|
| 133 | |
|---|
| 134 | ! ! allocate sbc arrays |
|---|
| 135 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 136 | |
|---|
| 137 | ! ! Checks: |
|---|
| 138 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 139 | ln_rnf_mouth = .false. |
|---|
| 140 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 141 | nkrnf = 0 |
|---|
| 142 | rnf (:,:) = 0.0_wp |
|---|
| 143 | rnfmsk (:,:) = 0.0_wp |
|---|
| 144 | rnfmsk_z(:) = 0.0_wp |
|---|
| 145 | ENDIF |
|---|
| 146 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 147 | |
|---|
| 148 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 149 | ! only if sea-ice is present |
|---|
| 150 | |
|---|
| 151 | ! ! restartability |
|---|
| 152 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 153 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 154 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 155 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 156 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 157 | ENDIF |
|---|
| 158 | ! |
|---|
| 159 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 160 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 161 | ! |
|---|
| 162 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 163 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 164 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 165 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 166 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 167 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 168 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 169 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 2 or 3' ) |
|---|
| 170 | |
|---|
| 171 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 172 | |
|---|
| 173 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 174 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 175 | |
|---|
| 176 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 177 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 178 | |
|---|
| 179 | IF ( ln_wave ) THEN |
|---|
| 180 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 181 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 182 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 183 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 184 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 185 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 186 | ENDIF |
|---|
| 187 | ELSE |
|---|
| 188 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 189 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 190 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 191 | ENDIF |
|---|
| 192 | |
|---|
| 193 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 194 | icpt = 0 |
|---|
| 195 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 196 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 197 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 198 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 199 | IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 200 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 201 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 202 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 203 | ! |
|---|
| 204 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 205 | WRITE(numout,*) |
|---|
| 206 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 207 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 208 | WRITE(numout,*) ' We stop' |
|---|
| 209 | nstop = nstop + 1 |
|---|
| 210 | ENDIF |
|---|
| 211 | IF(lwp) THEN |
|---|
| 212 | WRITE(numout,*) |
|---|
| 213 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 214 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 215 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 216 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 217 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 218 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 219 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 220 | IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 221 | ENDIF |
|---|
| 222 | |
|---|
| 223 | !!---------------------------------------------------------------------- |
|---|
| 224 | !! Other SBC modules to initialise come here |
|---|
| 225 | !!---------------------------------------------------------------------- |
|---|
| 226 | |
|---|
| 227 | CALL sbc_ssm_init |
|---|
| 228 | |
|---|
| 229 | IF( nn_ice == 4 ) CALL cice_sbc_init (nsbc) |
|---|
| 230 | ! |
|---|
| 231 | !!---------------------------------------------------------------------- |
|---|
| 232 | END SUBROUTINE sbc_init |
|---|
| 233 | |
|---|
| 234 | |
|---|
| 235 | SUBROUTINE sbc( kt ) |
|---|
| 236 | !!--------------------------------------------------------------------- |
|---|
| 237 | !! *** ROUTINE sbc *** |
|---|
| 238 | !! |
|---|
| 239 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 240 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 241 | !! |
|---|
| 242 | !! ** Method : blah blah to be written ????????? |
|---|
| 243 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 244 | !! |
|---|
| 245 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 246 | !! time step, i.e. |
|---|
| 247 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 248 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 249 | !! - updte the ice fraction : fr_i |
|---|
| 250 | !!---------------------------------------------------------------------- |
|---|
| 251 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 252 | !!--------------------------------------------------------------------- |
|---|
| 253 | ! |
|---|
| 254 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 255 | ! |
|---|
| 256 | ! ! ---------------------------------------- ! |
|---|
| 257 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 258 | ! ! ---------------------------------------- ! |
|---|
| 259 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 260 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 261 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 262 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 263 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 264 | emp_b(:,:) = emp(:,:) |
|---|
| 265 | sfx_b(:,:) = sfx(:,:) |
|---|
| 266 | ENDIF |
|---|
| 267 | ! ! ---------------------------------------- ! |
|---|
| 268 | ! ! forcing field computation ! |
|---|
| 269 | ! ! ---------------------------------------- ! |
|---|
| 270 | |
|---|
| 271 | CALL iom_setkt( kt + nn_fsbc - 1 ) ! in sbc, iom_put is called every nn_fsbc time step |
|---|
| 272 | ! |
|---|
| 273 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 274 | ! (caution called before sbc_ssm) |
|---|
| 275 | ! |
|---|
| 276 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 277 | ! ! averaged over nf_sbc time-step |
|---|
| 278 | |
|---|
| 279 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 280 | !== sbc formulation ==! |
|---|
| 281 | |
|---|
| 282 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 283 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 284 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 285 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 286 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 287 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 288 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 289 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 290 | CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 291 | CASE( -1 ) |
|---|
| 292 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 293 | CALL sbc_gyre ( kt ) ! |
|---|
| 294 | CALL sbc_flx ( kt ) ! |
|---|
| 295 | CALL sbc_blk_clio( kt ) ! |
|---|
| 296 | CALL sbc_blk_core( kt ) ! |
|---|
| 297 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 298 | END SELECT |
|---|
| 299 | |
|---|
| 300 | ! !== Misc. Options ==! |
|---|
| 301 | |
|---|
| 302 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 303 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 304 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 305 | IF( lk_bdy ) CALL bdy_ice_lim_2( kt ) ! BDY boundary condition |
|---|
| 306 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 307 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 308 | END SELECT |
|---|
| 309 | |
|---|
| 310 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 311 | |
|---|
| 312 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 313 | |
|---|
| 314 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 315 | |
|---|
| 316 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 317 | |
|---|
| 318 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 319 | ! ! (update freshwater fluxes) |
|---|
| 320 | !RBbug do not understand why see ticket 667 |
|---|
| 321 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 322 | ! |
|---|
| 323 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 324 | ! ! ---------------------------------------- ! |
|---|
| 325 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 326 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 327 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 328 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 329 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 330 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 331 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 332 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 333 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 334 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 335 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 336 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 337 | ELSE |
|---|
| 338 | sfx_b (:,:) = sfx(:,:) |
|---|
| 339 | ENDIF |
|---|
| 340 | ELSE !* no restart: set from nit000 values |
|---|
| 341 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 342 | utau_b(:,:) = utau(:,:) |
|---|
| 343 | vtau_b(:,:) = vtau(:,:) |
|---|
| 344 | qns_b (:,:) = qns (:,:) |
|---|
| 345 | emp_b (:,:) = emp(:,:) |
|---|
| 346 | sfx_b (:,:) = sfx(:,:) |
|---|
| 347 | ENDIF |
|---|
| 348 | ENDIF |
|---|
| 349 | ! ! ---------------------------------------- ! |
|---|
| 350 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 351 | ! ! ---------------------------------------- ! |
|---|
| 352 | IF(lwp) WRITE(numout,*) |
|---|
| 353 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 354 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 355 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 356 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 357 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 358 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 359 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 360 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 361 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 362 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 363 | ENDIF |
|---|
| 364 | |
|---|
| 365 | ! ! ---------------------------------------- ! |
|---|
| 366 | ! ! Outputs and control print ! |
|---|
| 367 | ! ! ---------------------------------------- ! |
|---|
| 368 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 369 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 370 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 371 | ! (includes virtual salt flux beneath ice |
|---|
| 372 | ! in linear free surface case) |
|---|
| 373 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 374 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 375 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 376 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 377 | ENDIF |
|---|
| 378 | ! |
|---|
| 379 | CALL iom_setkt( kt ) ! iom_put outside of sbc is called at every time step |
|---|
| 380 | ! |
|---|
| 381 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 382 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 383 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 384 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 385 | ! |
|---|
| 386 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 387 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 388 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 389 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 390 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 391 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 392 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 393 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 394 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 395 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 396 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 397 | ENDIF |
|---|
| 398 | |
|---|
| 399 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 400 | ! |
|---|
| 401 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 402 | ! |
|---|
| 403 | END SUBROUTINE sbc |
|---|
| 404 | |
|---|
| 405 | SUBROUTINE sbc_final |
|---|
| 406 | !!--------------------------------------------------------------------- |
|---|
| 407 | !! *** ROUTINE sbc_final *** |
|---|
| 408 | !!--------------------------------------------------------------------- |
|---|
| 409 | |
|---|
| 410 | !----------------------------------------------------------------- |
|---|
| 411 | ! Finalize CICE (if used) |
|---|
| 412 | !----------------------------------------------------------------- |
|---|
| 413 | |
|---|
| 414 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 415 | ! |
|---|
| 416 | END SUBROUTINE sbc_final |
|---|
| 417 | |
|---|
| 418 | !!====================================================================== |
|---|
| 419 | END MODULE sbcmod |
|---|
