| 1 | MODULE icbthm |
|---|
| 2 | |
|---|
| 3 | !!====================================================================== |
|---|
| 4 | !! *** MODULE icbthm *** |
|---|
| 5 | !! Icebergs: thermodynamics routines for icebergs |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 3.3.1 ! 2010-01 (Martin&Adcroft) Original code |
|---|
| 8 | !! - ! 2011-03 (Madec) Part conversion to NEMO form |
|---|
| 9 | !! - ! Removal of mapping from another grid |
|---|
| 10 | !! - ! 2011-04 (Alderson) Split into separate modules |
|---|
| 11 | !! - ! 2011-05 (Alderson) Use tmask instead of tmask_i |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! icb_thm : initialise |
|---|
| 15 | !! reference for equations - M = Martin + Adcroft, OM 34, 2010 |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE par_oce ! NEMO parameters |
|---|
| 18 | USE dom_oce ! NEMO domain |
|---|
| 19 | USE in_out_manager ! NEMO IO routines, numout in particular |
|---|
| 20 | USE lib_mpp ! NEMO MPI routines, ctl_stop in particular |
|---|
| 21 | USE phycst ! NEMO physical constants |
|---|
| 22 | USE sbc_oce |
|---|
| 23 | |
|---|
| 24 | USE icb_oce ! define iceberg arrays |
|---|
| 25 | USE icbutl ! iceberg utility routines |
|---|
| 26 | USE icbdia ! iceberg budget routines |
|---|
| 27 | |
|---|
| 28 | IMPLICIT NONE |
|---|
| 29 | PRIVATE |
|---|
| 30 | |
|---|
| 31 | PUBLIC icb_thm ! routine called in icbstp.F90 module |
|---|
| 32 | |
|---|
| 33 | CONTAINS |
|---|
| 34 | |
|---|
| 35 | SUBROUTINE icb_thm( kt ) |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! *** ROUTINE icb_thm *** |
|---|
| 38 | !! |
|---|
| 39 | !! ** Purpose : compute the iceberg thermodynamics. |
|---|
| 40 | !! |
|---|
| 41 | !! ** Method : - See Martin & Adcroft, Ocean Modelling 34, 2010 |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | INTEGER, INTENT(in) :: kt ! timestep number, just passed to icb_utl_print_berg |
|---|
| 44 | ! |
|---|
| 45 | INTEGER :: ii, ij |
|---|
| 46 | REAL(wp) :: zM, zT, zW, zL, zSST, zVol, zLn, zWn, zTn, znVol, zIC, zDn |
|---|
| 47 | REAL(wp) :: zMv, zMe, zMb, zmelt, zdvo, zdva, zdM, zSs, zdMe, zdMb, zdMv |
|---|
| 48 | REAL(wp) :: zMnew, zMnew1, zMnew2, zheat |
|---|
| 49 | REAL(wp) :: zMbits, znMbits, zdMbitsE, zdMbitsM, zLbits, zAbits, zMbb |
|---|
| 50 | REAL(wp) :: zxi, zyj, zff, z1_rday, z1_e1e2, zdt, z1_dt, z1_dt_e1e2 |
|---|
| 51 | TYPE(iceberg), POINTER :: this, next |
|---|
| 52 | TYPE(point) , POINTER :: pt |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | ! |
|---|
| 55 | z1_rday = 1._wp / rday |
|---|
| 56 | |
|---|
| 57 | ! we're either going to ignore berg fresh water melt flux and associated heat |
|---|
| 58 | ! or we pass it into the ocean, so at this point we set them both to zero, |
|---|
| 59 | ! accumulate the contributions to them from each iceberg in the while loop following |
|---|
| 60 | ! and then pass them (or not) to the ocean |
|---|
| 61 | ! |
|---|
| 62 | berg_grid%floating_melt(:,:) = 0._wp |
|---|
| 63 | berg_grid%calving_hflx(:,:) = 0._wp |
|---|
| 64 | |
|---|
| 65 | this => first_berg |
|---|
| 66 | DO WHILE( associated(this) ) |
|---|
| 67 | ! |
|---|
| 68 | pt => this%current_point |
|---|
| 69 | nknberg = this%number(1) |
|---|
| 70 | CALL icb_utl_interp( pt%xi, pt%e1, pt%uo, pt%ui, pt%ua, pt%ssh_x, & |
|---|
| 71 | & pt%yj, pt%e2, pt%vo, pt%vi, pt%va, pt%ssh_y, & |
|---|
| 72 | & pt%sst, pt%cn, pt%hi, zff ) |
|---|
| 73 | ! |
|---|
| 74 | zSST = pt%sst |
|---|
| 75 | zIC = MIN( 1._wp, pt%cn + rn_sicn_shift ) ! Shift sea-ice concentration !!gm ??? |
|---|
| 76 | zM = pt%mass |
|---|
| 77 | zT = pt%thickness ! total thickness |
|---|
| 78 | ! D = (rn_rho_bergs/pp_rho_seawater)*zT ! draught (keel depth) |
|---|
| 79 | ! F = zT - D ! freeboard |
|---|
| 80 | zW = pt%width |
|---|
| 81 | zL = pt%length |
|---|
| 82 | zxi = pt%xi ! position in (i,j) referential |
|---|
| 83 | zyj = pt%yj |
|---|
| 84 | ii = INT( zxi + 0.5 ) ! T-cell of the berg |
|---|
| 85 | ii = mi1( ii ) |
|---|
| 86 | ij = INT( zyj + 0.5 ) |
|---|
| 87 | ij = mj1( ij ) |
|---|
| 88 | zVol = zT * zW * zL |
|---|
| 89 | zdt = berg_dt ; z1_dt = 1._wp / zdt |
|---|
| 90 | |
|---|
| 91 | ! Environment |
|---|
| 92 | zdvo = SQRT( (pt%uvel-pt%uo)**2 + (pt%vvel-pt%vo)**2 ) |
|---|
| 93 | zdva = SQRT( (pt%ua -pt%uo)**2 + (pt%va -pt%vo)**2 ) |
|---|
| 94 | zSs = 1.5 * SQRT( zdva ) + 0.1 * zdva ! Sea state (eqn M.A9) |
|---|
| 95 | |
|---|
| 96 | ! Melt rates in m/s (i.e. division by rday) |
|---|
| 97 | zMv = MAX( 7.62e-3*zSST+1.29e-3*(zSST**2) , 0._wp ) * z1_rday ! Buoyant convection at sides (eqn M.A10) |
|---|
| 98 | zMb = MAX( 0.58*(zdvo**0.8)*(zSST+4.0)/(zL**0.2) , 0._wp ) * z1_rday ! Basal turbulent melting (eqn M.A7 ) |
|---|
| 99 | zMe = MAX( 1./12.*(zSST+2.)*zSs*(1+cos(rpi*(zIC**3))) , 0._wp ) * z1_rday ! Wave erosion (eqn M.A8 ) |
|---|
| 100 | |
|---|
| 101 | IF( ln_operator_splitting ) THEN ! Operator split update of volume/mass |
|---|
| 102 | zTn = MAX( zT - zMb*zdt , 0._wp ) ! new total thickness (m) |
|---|
| 103 | znVol = zTn * zW * zL ! new volume (m^3) |
|---|
| 104 | zMnew1 = (znVol/zVol) * zM ! new mass (kg) |
|---|
| 105 | zdMb = zM - zMnew1 ! mass lost to basal melting (>0) (kg) |
|---|
| 106 | ! |
|---|
| 107 | zLn = MAX( zL - zMv*zdt , 0._wp ) ! new length (m) |
|---|
| 108 | zWn = MAX( zW - zMv*zdt , 0._wp ) ! new width (m) |
|---|
| 109 | znVol = zTn * zWn * zLn ! new volume (m^3) |
|---|
| 110 | zMnew2 = (znVol/zVol) * zM ! new mass (kg) |
|---|
| 111 | zdMv = zMnew1 - zMnew2 ! mass lost to buoyant convection (>0) (kg) |
|---|
| 112 | ! |
|---|
| 113 | zLn = MAX( zLn - zMe*zdt , 0._wp ) ! new length (m) |
|---|
| 114 | zWn = MAX( zWn - zMe*zdt , 0._wp ) ! new width (m) |
|---|
| 115 | znVol = zTn * zWn * zLn ! new volume (m^3) |
|---|
| 116 | zMnew = ( znVol / zVol ) * zM ! new mass (kg) |
|---|
| 117 | zdMe = zMnew2 - zMnew ! mass lost to erosion (>0) (kg) |
|---|
| 118 | zdM = zM - zMnew ! mass lost to all erosion and melting (>0) (kg) |
|---|
| 119 | ! |
|---|
| 120 | ELSE ! Update dimensions of berg |
|---|
| 121 | zLn = MAX( zL -(zMv+zMe)*zdt ,0._wp ) ! (m) |
|---|
| 122 | zWn = MAX( zW -(zMv+zMe)*zdt ,0._wp ) ! (m) |
|---|
| 123 | zTn = MAX( zT - zMb *zdt ,0._wp ) ! (m) |
|---|
| 124 | ! Update volume and mass of berg |
|---|
| 125 | znVol = zTn*zWn*zLn ! (m^3) |
|---|
| 126 | zMnew = (znVol/zVol)*zM ! (kg) |
|---|
| 127 | zdM = zM - zMnew ! (kg) |
|---|
| 128 | zdMb = (zM/zVol) * (zW* zL ) *zMb*zdt ! approx. mass loss to basal melting (kg) |
|---|
| 129 | zdMe = (zM/zVol) * (zT*(zW+zL)) *zMe*zdt ! approx. mass lost to erosion (kg) |
|---|
| 130 | zdMv = (zM/zVol) * (zT*(zW+zL)) *zMv*zdt ! approx. mass loss to buoyant convection (kg) |
|---|
| 131 | ENDIF |
|---|
| 132 | |
|---|
| 133 | IF( rn_bits_erosion_fraction > 0._wp ) THEN ! Bergy bits |
|---|
| 134 | ! |
|---|
| 135 | zMbits = pt%mass_of_bits ! mass of bergy bits (kg) |
|---|
| 136 | zdMbitsE = rn_bits_erosion_fraction * zdMe ! change in mass of bits (kg) |
|---|
| 137 | znMbits = zMbits + zdMbitsE ! add new bergy bits to mass (kg) |
|---|
| 138 | zLbits = MIN( zL, zW, zT, 40._wp ) ! assume bergy bits are smallest dimension or 40 meters |
|---|
| 139 | zAbits = ( zMbits / rn_rho_bergs ) / zLbits ! Effective bottom area (assuming T=Lbits) |
|---|
| 140 | zMbb = MAX( 0.58*(zdvo**0.8)*(zSST+2.0)/(zLbits**0.2), 0.) * z1_rday ! Basal turbulent melting (for bits) |
|---|
| 141 | zMbb = rn_rho_bergs * zAbits * zMbb ! in kg/s |
|---|
| 142 | zdMbitsM = MIN( zMbb*zdt , znMbits ) ! bergy bits mass lost to melting (kg) |
|---|
| 143 | znMbits = znMbits-zdMbitsM ! remove mass lost to bergy bits melt |
|---|
| 144 | IF( zMnew == 0._wp ) THEN ! if parent berg has completely melted then |
|---|
| 145 | zdMbitsM = zdMbitsM + znMbits ! instantly melt all the bergy bits |
|---|
| 146 | znMbits = 0._wp |
|---|
| 147 | ENDIF |
|---|
| 148 | ELSE ! No bergy bits |
|---|
| 149 | zAbits = 0._wp |
|---|
| 150 | zdMbitsE = 0._wp |
|---|
| 151 | zdMbitsM = 0._wp |
|---|
| 152 | znMbits = pt%mass_of_bits ! retain previous value incase non-zero |
|---|
| 153 | ENDIF |
|---|
| 154 | |
|---|
| 155 | ! use tmask rather than tmask_i when dealing with icebergs |
|---|
| 156 | IF( tmask(ii,ij,1) /= 0._wp ) THEN ! Add melting to the grid and field diagnostics |
|---|
| 157 | z1_e1e2 = 1._wp / e1e2t(ii,ij) * this%mass_scaling |
|---|
| 158 | z1_dt_e1e2 = z1_dt * z1_e1e2 |
|---|
| 159 | zmelt = ( zdM - ( zdMbitsE - zdMbitsM ) ) * z1_dt ! kg/s |
|---|
| 160 | berg_grid%floating_melt(ii,ij) = berg_grid%floating_melt(ii,ij) + zmelt * z1_e1e2 ! kg/m2/s |
|---|
| 161 | zheat = zmelt * pt%heat_density ! kg/s x J/kg = J/s |
|---|
| 162 | berg_grid%calving_hflx (ii,ij) = berg_grid%calving_hflx (ii,ij) + zheat * z1_e1e2 ! W/m2 |
|---|
| 163 | CALL icb_dia_melt( ii, ij, zMnew, zheat, this%mass_scaling, & |
|---|
| 164 | & zdM, zdMbitsE, zdMbitsM, zdMb, zdMe, & |
|---|
| 165 | & zdMv, z1_dt_e1e2 ) |
|---|
| 166 | ELSE |
|---|
| 167 | WRITE(numout,*) 'icb_thm: berg ',this%number(:),' appears to have grounded at ',narea,ii,ij |
|---|
| 168 | CALL icb_utl_print_berg( this, kt ) |
|---|
| 169 | WRITE(numout,*) 'msk=',tmask(ii,ij,1), e1e2t(ii,ij) |
|---|
| 170 | CALL ctl_stop('icb_thm', 'berg appears to have grounded!') |
|---|
| 171 | ENDIF |
|---|
| 172 | |
|---|
| 173 | ! Rolling |
|---|
| 174 | zDn = ( rn_rho_bergs / pp_rho_seawater ) * zTn ! draught (keel depth) |
|---|
| 175 | IF( zDn > 0._wp .AND. MAX(zWn,zLn) < SQRT( 0.92*(zDn**2) + 58.32*zDn ) ) THEN |
|---|
| 176 | zT = zTn |
|---|
| 177 | zTn = zWn |
|---|
| 178 | zWn = zT |
|---|
| 179 | endif |
|---|
| 180 | |
|---|
| 181 | ! Store the new state of iceberg (with L>W) |
|---|
| 182 | pt%mass = zMnew |
|---|
| 183 | pt%mass_of_bits = znMbits |
|---|
| 184 | pt%thickness = zTn |
|---|
| 185 | pt%width = min(zWn,zLn) |
|---|
| 186 | pt%length = max(zWn,zLn) |
|---|
| 187 | |
|---|
| 188 | next=>this%next |
|---|
| 189 | |
|---|
| 190 | !!gm add a test to avoid over melting ? |
|---|
| 191 | |
|---|
| 192 | IF( zMnew <= 0._wp ) THEN ! Delete the berg if completely melted |
|---|
| 193 | CALL icb_utl_delete( first_berg, this ) |
|---|
| 194 | ! |
|---|
| 195 | ELSE ! Diagnose mass distribution on grid |
|---|
| 196 | z1_e1e2 = 1._wp / e1e2t(ii,ij) * this%mass_scaling |
|---|
| 197 | CALL icb_dia_size( ii, ij, zWn, zLn, zAbits, & |
|---|
| 198 | & this%mass_scaling, zMnew, znMbits, z1_e1e2) |
|---|
| 199 | ENDIF |
|---|
| 200 | ! |
|---|
| 201 | this=>next |
|---|
| 202 | ! |
|---|
| 203 | END DO |
|---|
| 204 | |
|---|
| 205 | ! now use melt and associated heat flux in ocean (or not) |
|---|
| 206 | ! |
|---|
| 207 | IF(.NOT. ln_passive_mode ) THEN |
|---|
| 208 | emp (:,:) = emp (:,:) - berg_grid%floating_melt(:,:) |
|---|
| 209 | !! qns (:,:) = qns (:,:) + berg_grid%calving_hflx (:,:) !!gm heat flux not yet properly coded ==>> need it, SOLVE that! |
|---|
| 210 | ENDIF |
|---|
| 211 | ! |
|---|
| 212 | END SUBROUTINE icb_thm |
|---|
| 213 | |
|---|
| 214 | !!====================================================================== |
|---|
| 215 | END MODULE icbthm |
|---|
