New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2012/dev_NOC_2012_rev3555/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2012/dev_NOC_2012_rev3555/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 3609

Last change on this file since 3609 was 3609, checked in by acc, 11 years ago

Branch dev_NOC_2012_r3555. #1006. Step 4: Merge in changes from 2012/dev_r3337_NOCS10_ICB (ICeBergs) branch

  • Property svn:keywords set to Id
File size: 23.5 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   sbc_init       : read namsbc namelist
18   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
19   !!----------------------------------------------------------------------
20   USE oce              ! ocean dynamics and tracers
21   USE dom_oce          ! ocean space and time domain
22   USE phycst           ! physical constants
23   USE sbc_oce          ! Surface boundary condition: ocean fields
24   USE sbc_ice          ! Surface boundary condition: ice fields
25   USE sbcdcy           ! surface boundary condition: diurnal cycle
26   USE sbcssm           ! surface boundary condition: sea-surface mean variables
27   USE sbcapr           ! surface boundary condition: atmospheric pressure
28   USE sbcana           ! surface boundary condition: analytical formulation
29   USE sbcflx           ! surface boundary condition: flux formulation
30   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
31   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
32   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
33   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
34   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
35   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
36   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
37   USE sbccpl           ! surface boundary condition: coupled florulation
38   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
39   USE sbcssr           ! surface boundary condition: sea surface restoring
40   USE sbcrnf           ! surface boundary condition: runoffs
41   USE sbcfwb           ! surface boundary condition: freshwater budget
42   USE closea           ! closed sea
43   USE bdy_par          ! for lk_bdy
44   USE bdyice_lim2      ! unstructured open boundary data  (bdy_ice_lim_2 routine)
45   USE icbstp           ! Icebergs!
46
47   USE prtctl           ! Print control                    (prt_ctl routine)
48   USE restart          ! ocean restart
49   USE iom              ! IOM library
50   USE in_out_manager   ! I/O manager
51   USE lib_mpp          ! MPP library
52   USE timing           ! Timing
53   USE sbcwave          ! Wave module
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc        ! routine called by step.F90
59   PUBLIC   sbc_init   ! routine called by opa.F90
60   
61   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
62     
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE sbc_init
73      !!---------------------------------------------------------------------
74      !!                    ***  ROUTINE sbc_init ***
75      !!
76      !! ** Purpose :   Initialisation of the ocean surface boundary computation
77      !!
78      !! ** Method  :   Read the namsbc namelist and set derived parameters
79      !!                Call init routines for all other SBC modules that have one
80      !!
81      !! ** Action  : - read namsbc parameters
82      !!              - nsbc: type of sbc
83      !!----------------------------------------------------------------------
84      INTEGER ::   icpt   ! local integer
85      !!
86      NAMELIST/namsbc/ nn_fsbc   , ln_ana , ln_flx  , ln_blk_clio, ln_blk_core, ln_cpl,   &
87         &             ln_blk_mfs, ln_apr_dyn, nn_ice , ln_dm2dc, ln_rnf, ln_ssr     , nn_fwb, ln_cdgw
88      !!----------------------------------------------------------------------
89
90      IF(lwp) THEN
91         WRITE(numout,*)
92         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
93         WRITE(numout,*) '~~~~~~~~ '
94      ENDIF
95
96      REWIND( numnam )           ! Read Namelist namsbc
97      READ  ( numnam, namsbc )
98
99      !                          ! overwrite namelist parameter using CPP key information
100      IF( Agrif_Root() ) THEN                ! AGRIF zoom
101        IF( lk_lim2 )   nn_ice      = 2
102        IF( lk_lim3 )   nn_ice      = 3
103        IF( lk_cice )   nn_ice      = 4
104      ENDIF
105      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
106          ln_ana      = .TRUE.   
107          nn_ice      =   0
108      ENDIF
109     
110      IF(lwp) THEN               ! Control print
111         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
112         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
113         WRITE(numout,*) '           Type of sbc : '
114         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
115         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
116         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
117         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
118         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
119         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
120         WRITE(numout,*) '           Misc. options of sbc : '
121         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
122         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
123         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
124         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
125         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
126         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
127         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
128      ENDIF
129
130      !                              ! allocate sbc arrays
131      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
132
133      !                          ! Checks:
134      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
135         ln_rnf_mouth  = .false.                     
136         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
137         nkrnf         = 0
138         rnf     (:,:) = 0.e0
139         rnfmsk  (:,:) = 0.e0
140         rnfmsk_z(:)   = 0.e0
141      ENDIF
142      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
143
144      !                                            ! restartability   
145      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
146          MOD( nstock             , nn_fsbc) /= 0 ) THEN
147         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
148            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
149         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
150      ENDIF
151      !
152      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
153         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
154      !
155      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
156         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
157      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
158         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
159      IF( nn_ice == 4 .AND. ( .NOT. ( cp_cfg == 'orca' ) .OR. lk_agrif ) )   &
160         &   CALL ctl_stop( 'CICE sea-ice model currently only available in a global ORCA configuration without AGRIF' )
161     
162      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
163
164      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
165         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
166     
167      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
168         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
169
170       !drag coefficient read from wave model definable only with mfs bulk formulae and core
171       IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )              &
172          &   CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
173     
174      !                          ! Choice of the Surface Boudary Condition (set nsbc)
175      icpt = 0
176      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
177      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
178      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
179      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
180      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
181      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
182      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
183      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
184      !
185      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
186         WRITE(numout,*)
187         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
188         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
189         WRITE(numout,*) '                     We stop'
190         nstop = nstop + 1
191      ENDIF
192      IF(lwp) THEN
193         WRITE(numout,*)
194         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
195         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
196         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
197         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
198         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
199         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
200         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
201         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
202      ENDIF
203
204      !!----------------------------------------------------------------------
205      !!   Other SBC modules to initialise come here
206      !!----------------------------------------------------------------------
207
208      CALL sbc_ssm_init
209
210      IF( nn_ice == 4 )   CALL cice_sbc_init (nsbc)
211      !
212      !!----------------------------------------------------------------------
213   END SUBROUTINE sbc_init
214
215
216   SUBROUTINE sbc( kt )
217      !!---------------------------------------------------------------------
218      !!                    ***  ROUTINE sbc  ***
219      !!             
220      !! ** Purpose :   provide at each time-step the ocean surface boundary
221      !!                condition (momentum, heat and freshwater fluxes)
222      !!
223      !! ** Method  :   blah blah  to be written ?????????
224      !!                CAUTION : never mask the surface stress field (tke sbc)
225      !!
226      !! ** Action  : - set the ocean surface boundary condition at before and now
227      !!                time step, i.e. 
228      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
229      !!                utau  , vtau  , qns  , qsr  , emp  , emps  , qrp  , erp
230      !!              - updte the ice fraction : fr_i
231      !!----------------------------------------------------------------------
232      INTEGER, INTENT(in) ::   kt       ! ocean time step
233      !!---------------------------------------------------------------------
234      !
235      IF( nn_timing == 1 )  CALL timing_start('sbc')
236      !
237      !                                            ! ---------------------------------------- !
238      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
239         !                                         ! ---------------------------------------- !
240         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
241         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
242         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
243         ! The 3D heat content due to qsr forcing is treated in traqsr
244         ! qsr_b (:,:) = qsr (:,:)
245         emp_b (:,:) = emp (:,:)
246         emps_b(:,:) = emps(:,:)
247      ENDIF
248      !                                            ! ---------------------------------------- !
249      !                                            !        forcing field computation         !
250      !                                            ! ---------------------------------------- !
251
252      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
253      !
254      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
255                                                         ! (caution called before sbc_ssm)
256      !
257      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
258      !                                                  ! averaged over nf_sbc time-step
259
260      IF (ln_cdgw) CALL sbc_wave( kt )
261                                                   !==  sbc formulation  ==!
262                                                           
263      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
264      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, emps)
265      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
266      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
267      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
268      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
269      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
270      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
271      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
272      CASE( -1 )                               
273                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
274                       CALL sbc_gyre    ( kt )                    !
275                       CALL sbc_flx     ( kt )                    !
276                       CALL sbc_blk_clio( kt )                    !
277                       CALL sbc_blk_core( kt )                    !
278                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
279      END SELECT
280
281      !                                            !==  Misc. Options  ==!
282     
283      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
284      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                  ! Ice-cover climatology ("Ice-if" model)
285         !                                                     
286      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )            ! LIM-2 ice model
287         IF( lk_bdy )      CALL bdy_ice_lim_2( kt )                  ! BDY boundary condition
288         !                                                     
289      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc )            ! LIM-3 ice model
290         !
291      CASE(  4 )   ;       CALL sbc_ice_cice ( kt, nsbc )            ! CICE ice model
292      END SELECT                                             
293
294      IF( ln_icebergs )    CALL icb_stp( kt )                   ! compute icebergs
295
296      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
297 
298      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
299
300      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
301
302      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
303      !                                                         ! (update freshwater fluxes)
304!RBbug do not understand why see ticket 667
305      CALL lbc_lnk( emp, 'T', 1. )
306      !
307      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
308         !                                             ! ---------------------------------------- !
309         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
310            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
311            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
312            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
313            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
314            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
315            ! The 3D heat content due to qsr forcing is treated in traqsr
316            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  )   ! before     solar heat flux (T-point)
317            CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b  )   ! before     freshwater flux (T-point)
318            CALL iom_get( numror, jpdom_autoglo, 'emps_b', emps_b )   ! before C/D freshwater flux (T-point)
319         ELSE                                                   !* no restart: set from nit000 values
320            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
321            utau_b(:,:) = utau(:,:) 
322            vtau_b(:,:) = vtau(:,:)
323            qns_b (:,:) = qns (:,:)
324            ! qsr_b (:,:) = qsr (:,:)
325            emp_b (:,:) = emp (:,:)
326            emps_b(:,:) = emps(:,:)
327         ENDIF
328      ENDIF
329      !                                                ! ---------------------------------------- !
330      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
331         !                                             ! ---------------------------------------- !
332         IF(lwp) WRITE(numout,*)
333         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
334            &                    'at it= ', kt,' date= ', ndastp
335         IF(lwp) WRITE(numout,*) '~~~~'
336         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
337         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
338         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
339         ! The 3D heat content due to qsr forcing is treated in traqsr
340         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
341         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
342         CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , emps )
343      ENDIF
344
345      !                                                ! ---------------------------------------- !
346      !                                                !        Outputs and control print         !
347      !                                                ! ---------------------------------------- !
348      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
349         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
350         CALL iom_put( "empsmr", emps - rnf )                   ! c/d water flux
351         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
352         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
353         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
354         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
355      ENDIF
356      !
357      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
358      !
359      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
360      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
361      CALL iom_put( "taum", taum )   ! wind stress module
362      CALL iom_put( "wspd", wndm )   ! wind speed  module
363      !
364      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
365         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
366         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
367         CALL prt_ctl(tab2d_1=(emps-rnf)       , clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 )
368         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
369         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
370         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
371         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
372         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
373         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
374            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
375      ENDIF
376
377      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
378      !
379      IF( nn_timing == 1 )  CALL timing_stop('sbc')
380      !
381   END SUBROUTINE sbc
382
383   SUBROUTINE sbc_final
384      !!---------------------------------------------------------------------
385      !!                    ***  ROUTINE sbc_final  ***
386      !!---------------------------------------------------------------------
387
388      !-----------------------------------------------------------------
389      ! Finalize CICE (if used)
390      !-----------------------------------------------------------------
391
392      IF( nn_ice == 4 )   CALL cice_sbc_final
393      !
394   END SUBROUTINE sbc_final
395
396   !!======================================================================
397END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.