New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 3318

Last change on this file since 3318 was 3318, checked in by gm, 12 years ago

Ediag branche: #927 split TRA/DYN trd computation

  • Property svn:keywords set to Id
File size: 11.9 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE trd_oce         ! ocean trend diagnostics
21   USE phycst          ! physical constants
22   USE in_out_manager  ! I/O manager
23   USE iom             ! I/O module
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmld_oce      ! ocean active mixed layer tracers trends variables
26   USE domvvl          ! variable volume
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   rst_opn    ! routine called by step module
32   PUBLIC   rst_write  ! routine called by step module
33   PUBLIC   rst_read   ! routine called by opa  module
34
35   LOGICAL, PUBLIC ::   lrst_oce =  .FALSE.   !: logical to control the oce restart write
36   INTEGER, PUBLIC ::   numror, numrow        !: logical unit for cean restart (read and write)
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ice output restart file name
62      !!----------------------------------------------------------------------
63      !
64      IF( kt == nit000 ) THEN   ! default definitions
65         lrst_oce = .FALSE.   
66         nitrst = nitend
67      ENDIF
68      IF( MOD( kt - 1, nstock ) == 0 ) THEN   
69         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
70         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
71         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
72      ENDIF
73      ! to get better performances with NetCDF format:
74      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
75      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
76      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
77         ! beware of the format used to write kt (default is i8.8, that should be large enough...)
78         IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
79         ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
80         ENDIF
81         ! create the file
82         clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
83         IF(lwp) THEN
84            WRITE(numout,*)
85            SELECT CASE ( jprstlib )
86            CASE ( jprstdimg )   ;   WRITE(numout,*) '             open ocean restart binary file: '//clname
87            CASE DEFAULT         ;   WRITE(numout,*) '             open ocean restart NetCDF file: '//clname
88            END SELECT
89            IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
90            IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
91            ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
92            ENDIF
93         ENDIF
94         !
95         CALL iom_open( clname, numrow, ldwrt = .TRUE., kiolib = jprstlib )
96         lrst_oce = .TRUE.
97      ENDIF
98      !
99   END SUBROUTINE rst_opn
100
101
102   SUBROUTINE rst_write( kt )
103      !!---------------------------------------------------------------------
104      !!                   ***  ROUTINE rstwrite  ***
105      !!                     
106      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
107      !!
108      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
109      !!              file, save fields which are necessary for restart
110      !!----------------------------------------------------------------------
111      INTEGER, INTENT(in) ::   kt   ! ocean time-step
112      !!----------------------------------------------------------------------
113
114                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
115                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
116
117                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
118                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
119                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
120                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
121                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
122                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
123                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
124      IF( lk_vvl )   CALL iom_rstput( kt, nitrst, numrow, 'fse3t_b', fse3t_b(:,:,:) )
125                     !
126                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
127                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
128                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
129                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
130                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
131                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
132                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
133                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
134#if defined key_zdfkpp
135                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
136#endif
137      IF( kt == nitrst ) THEN
138         CALL iom_close( numrow )     ! close the restart file (only at last time step)
139         IF( .NOT. ln_tra_mld )   lrst_oce = .FALSE.
140      ENDIF
141      !
142   END SUBROUTINE rst_write
143
144
145   SUBROUTINE rst_read
146      !!----------------------------------------------------------------------
147      !!                   ***  ROUTINE rst_read  ***
148      !!
149      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
150      !!
151      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
152      !!----------------------------------------------------------------------
153      REAL(wp) ::   zrdt, zrdttra1
154      INTEGER  ::   jk, jlibalt = jprstlib
155      LOGICAL  ::   llok
156      !!----------------------------------------------------------------------
157
158      IF(lwp) THEN                                             ! Contol prints
159         WRITE(numout,*)
160         SELECT CASE ( jprstlib )
161         CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
162         CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
163         END SELECT
164         IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
165         WRITE(numout,*) '~~~~~~~~'
166      ENDIF
167
168      IF ( jprstlib == jprstdimg ) THEN
169        ! eventually read netcdf file (monobloc)  for restarting on different number of processors
170        ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
171        INQUIRE( FILE = TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
172        IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
173      ENDIF
174      CALL iom_open( cn_ocerst_in, numror, kiolib = jlibalt )
175
176      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
177      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
178         CALL iom_get( numror, 'rdt', zrdt )
179         IF( zrdt /= rdt )   neuler = 0
180      ENDIF
181      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
182         CALL iom_get( numror, 'rdttra1', zrdttra1 )
183         IF( zrdttra1 /= rdttra(1) )   neuler = 0
184      ENDIF
185      !
186                     CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
187                     CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
188                     CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
189                     CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
190                     CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
191                     CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
192                     CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
193      IF( lk_vvl )   CALL iom_get( numror, jpdom_autoglo, 'fse3t_b', fse3t_b(:,:,:) )
194                     !
195                     CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
196                     CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
197                     CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
198                     CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
199                     CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
200                     CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
201                     CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
202                     CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
203#if defined key_zdfkpp
204      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
205                     CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
206      ELSE
207                     CALL eos( tsn, rhd )   ! compute rhd
208      ENDIF
209#endif
210      !
211      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
212         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
213         ub   (:,:,:)   = un   (:,:,:)
214         vb   (:,:,:)   = vn   (:,:,:)
215         rotb (:,:,:)   = rotn (:,:,:)
216         hdivb(:,:,:)   = hdivn(:,:,:)
217         sshb (:,:)     = sshn (:,:)
218         IF( lk_vvl ) THEN
219            DO jk = 1, jpk
220               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
221            END DO
222         ENDIF
223      ENDIF
224      !
225   END SUBROUTINE rst_read
226
227   !!=====================================================================
228END MODULE restart
Note: See TracBrowser for help on using the repository browser.