New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 3318

Last change on this file since 3318 was 3318, checked in by gm, 12 years ago

Ediag branche: #927 split TRA/DYN trd computation
  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trd_oce         ! trends: ocean variables
19   USE trdtra          ! trends manager: tracers
20   USE in_out_manager  ! I/O manager
21   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
22   USE lib_mpp         ! distribued memory computing
23   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE wrk_nemo        ! Memory Allocation
27   USE timing          ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_muscl  ! routine called by step.F90
33
34   LOGICAL  :: l_trd       ! flag to compute trends
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, &
47      &                                        ptb, pta, kjpt )
48      !!----------------------------------------------------------------------
49      !!                    ***  ROUTINE tra_adv_muscl  ***
50      !!
51      !! ** Purpose :   Compute the now trend due to total advection of T and
52      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
53      !!      Conservation Laws) and add it to the general tracer trend.
54      !!
55      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
56      !!
57      !! ** Action  : - update (ta,sa) with the now advective tracer trends
58      !!              - save trends
59      !!
60      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
61      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
62      !!----------------------------------------------------------------------
63      USE oce     , ONLY:   zwx   => ua    , zwy   => va          ! (ua,va) used as workspace
64      !
65      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
66      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
67      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
69      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
70      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
73      !
74      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
75      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
76      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
77      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
78      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
79      !!----------------------------------------------------------------------
80      !
81      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl')
82      !
83      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
84      !
85
86      IF( kt == kit000 )  THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
89         IF(lwp) WRITE(numout,*) '~~~~~~~'
90         !
91         l_trd = .FALSE.
92         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
93      ENDIF
94
95      !                                                     ! ===========
96      DO jn = 1, kjpt                                       ! tracer loop
97         !                                                  ! ===========
98         ! I. Horizontal advective fluxes
99         ! ------------------------------
100         ! first guess of the slopes
101         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
102         ! interior values
103         DO jk = 1, jpkm1
104            DO jj = 1, jpjm1     
105               DO ji = 1, fs_jpim1   ! vector opt.
106                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
107                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
108               END DO
109           END DO
110         END DO
111         !
112         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
113         CALL lbc_lnk( zwy, 'V', -1. )
114         !                                             !-- Slopes of tracer
115         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
116         DO jk = 1, jpkm1                                     ! interior values
117            DO jj = 2, jpj
118               DO ji = fs_2, jpi   ! vector opt.
119                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
120                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
121                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
122                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
123               END DO
124            END DO
125         END DO
126         !
127         DO jk = 1, jpkm1                                     ! Slopes limitation
128            DO jj = 2, jpj
129               DO ji = fs_2, jpi   ! vector opt.
130                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
131                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
132                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
133                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
134                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
135                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
136               END DO
137           END DO
138         END DO             ! interior values
139
140         !                                             !-- MUSCL horizontal advective fluxes
141         DO jk = 1, jpkm1                                     ! interior values
142            zdt  = p2dt(jk)
143            DO jj = 2, jpjm1
144               DO ji = fs_2, fs_jpim1   ! vector opt.
145                  ! MUSCL fluxes
146                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
147                  zalpha = 0.5 - z0u
148                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
149                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
150                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
151                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
152                  !
153                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
154                  zalpha = 0.5 - z0v
155                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
156                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
157                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
158                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
159               END DO
160            END DO
161         END DO
162         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
163         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
164         !
165         ! Tracer flux divergence at t-point added to the general trend
166         DO jk = 1, jpkm1
167            DO jj = 2, jpjm1     
168               DO ji = fs_2, fs_jpim1   ! vector opt.
169                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
170                  ! horizontal advective trends
171                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
172                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
173                  ! add it to the general tracer trends
174                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
175               END DO
176           END DO
177         END DO       
178         !                                 ! trend diagnostics (contribution of upstream fluxes)
179         IF( l_trd )  THEN
180            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
181            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
182         END IF
183         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
184         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
185            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
186            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
187         ENDIF
188
189         ! II. Vertical advective fluxes
190         ! -----------------------------
191         !                                             !-- first guess of the slopes
192         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
193         DO jk = 2, jpkm1                                     ! interior values
194            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
195         END DO
196
197         !                                             !-- Slopes of tracer
198         zslpx(:,:,1) = 0.e0                                  ! surface values
199         DO jk = 2, jpkm1                                     ! interior value
200            DO jj = 1, jpj
201               DO ji = 1, jpi
202                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
203                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
204               END DO
205            END DO
206         END DO
207         !                                             !-- Slopes limitation
208         DO jk = 2, jpkm1                                     ! interior values
209            DO jj = 1, jpj
210               DO ji = 1, jpi
211                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
212                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
213                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
214               END DO
215            END DO
216         END DO
217         !                                             !-- vertical advective flux
218         !                                                    ! surface values  (bottom already set to zero)
219         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
220         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
221         ENDIF 
222         !
223         DO jk = 1, jpkm1                                     ! interior values
224            zdt  = p2dt(jk)
225            DO jj = 2, jpjm1     
226               DO ji = fs_2, fs_jpim1   ! vector opt.
227                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
228                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
229                  zalpha = 0.5 + z0w
230                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
231                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
232                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
233                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
234               END DO
235            END DO
236         END DO
237
238         ! Compute & add the vertical advective trend
239         DO jk = 1, jpkm1
240            DO jj = 2, jpjm1     
241               DO ji = fs_2, fs_jpim1   ! vector opt.
242                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
243                  ! vertical advective trends
244                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
245                  ! add it to the general tracer trends
246                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
247               END DO
248            END DO
249         END DO
250         !                                 ! Save the vertical advective trends for diagnostic
251         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
252         !
253      ENDDO
254      !
255      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
256      !
257      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl')
258      !
259   END SUBROUTINE tra_adv_muscl
260
261   !!======================================================================
262END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.