New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/TOP_SRC/TRP/trcldf.F90 @ 3318

Last change on this file since 3318 was 3318, checked in by gm, 12 years ago

Ediag branche: #927 split TRA/DYN trd computation
  • Property svn:keywords set to Id
File size: 13.6 KB
Line 
1MODULE trcldf
2   !!======================================================================
3   !!                       ***  MODULE  trcldf  ***
4   !! Ocean Passive tracers : lateral diffusive trends
5   !!=====================================================================
6   !! History :  1.0  ! 2005-11  (G. Madec)  Original code
7   !!            3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_ldf     : update the tracer trend with the lateral diffusion
14   !!       ldf_ctl : initialization, namelist read, and parameters control
15   !!----------------------------------------------------------------------
16   USE oce_trc         ! ocean dynamics and active tracers
17   USE trc             ! ocean passive tracers variables
18   USE trcnam_trp      ! passive tracers transport namelist variables
19   USE ldftra_oce      ! lateral diffusion coefficient on tracers
20   USE ldfslp          ! ???
21   USE traldf_bilapg   ! lateral mixing            (tra_ldf_bilapg routine)
22   USE traldf_bilap    ! lateral mixing            (tra_ldf_bilap routine)
23   USE traldf_iso      ! lateral mixing            (tra_ldf_iso routine)
24   USE traldf_iso_grif ! lateral mixing          (tra_ldf_iso_grif routine)
25   USE traldf_lap      ! lateral mixing            (tra_ldf_lap routine)
26   USE trd_oce         ! trends: ocean variables
27   USE trdtra          ! trends: tracer manager
28   USE prtctl_trc      ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   trc_ldf    ! called by step.F90
34   !                                                 !!: ** lateral mixing namelist (nam_trcldf) **
35   REAL(wp) ::  rldf_rat    ! ratio between active and passive tracers diffusive coefficient
36   INTEGER  ::  nldf = 0   ! type of lateral diffusion used defined from ln_trcldf_... namlist logicals)
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE trc_ldf( kt )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_ldf  ***
51      !!
52      !! ** Purpose :   compute the lateral ocean tracer physics.
53      !!
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !!
57      INTEGER            :: jn
58      CHARACTER (len=22) :: charout
59      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrtrd
60      !!----------------------------------------------------------------------
61      !
62      IF( nn_timing == 1 )   CALL timing_start('trc_ldf')
63      !
64      IF( kt == nittrc000 )   CALL ldf_ctl          ! initialisation & control of options
65
66      rldf = rldf_rat
67
68      IF( l_trdtrc )  THEN
69         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrtrd )
70         ztrtrd(:,:,:,:)  = tra(:,:,:,:)
71      ENDIF
72
73      SELECT CASE ( nldf )                       ! compute lateral mixing trend and add it to the general trend
74      CASE ( 0 )   ;   CALL tra_ldf_lap   ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )  ! iso-level laplacian
75      CASE ( 1 )                                                                                            ! rotated laplacian
76                       IF( ln_traldf_grif ) THEN
77                          CALL tra_ldf_iso_grif( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
78                       ELSE
79                          CALL tra_ldf_iso     ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
80                       ENDIF
81      CASE ( 2 )   ;   CALL tra_ldf_bilap ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )  ! iso-level bilaplacian
82      CASE ( 3 )   ;   CALL tra_ldf_bilapg( kt, nittrc000, 'TRC',             trb, tra, jptra            )  ! s-coord. horizontal bilaplacian
83         !
84      CASE ( -1 )                                     ! esopa: test all possibility with control print
85         CALL tra_ldf_lap   ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )
86         WRITE(charout, FMT="('ldf0 ')") ;  CALL prt_ctl_trc_info(charout)
87                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
88         IF( ln_traldf_grif ) THEN
89            CALL tra_ldf_iso_grif( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
90         ELSE
91            CALL tra_ldf_iso     ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra, rn_ahtb_0 )
92         ENDIF
93         WRITE(charout, FMT="('ldf1 ')") ;  CALL prt_ctl_trc_info(charout)
94                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
95         CALL tra_ldf_bilap ( kt, nittrc000, 'TRC', gtru, gtrv, trb, tra, jptra            )
96         WRITE(charout, FMT="('ldf2 ')") ;  CALL prt_ctl_trc_info(charout)
97                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
98         CALL tra_ldf_bilapg( kt, nittrc000, 'TRC',             trb, tra, jptra            )
99         WRITE(charout, FMT="('ldf3 ')") ;  CALL prt_ctl_trc_info(charout)
100                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
101      END SELECT
102      !
103      IF( l_trdtrc )   THEN                      ! save the horizontal diffusive trends for further diagnostics
104        DO jn = 1, jptra
105           ztrtrd(:,:,:,jn) = tra(:,:,:,jn) - ztrtrd(:,:,:,jn)
106           CALL trd_tra( kt, 'TRC', jn, jptra_ldf, ztrtrd(:,:,:,jn) )
107        END DO
108        CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrtrd )
109      ENDIF
110      !                                          ! print mean trends (used for debugging)
111      IF( ln_ctl )   THEN
112         WRITE(charout, FMT="('ldf ')") ;  CALL prt_ctl_trc_info(charout)
113                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
114      ENDIF
115      !
116      IF( nn_timing == 1 )   CALL timing_stop('trc_ldf')
117      !
118   END SUBROUTINE trc_ldf
119
120
121   SUBROUTINE ldf_ctl
122      !!----------------------------------------------------------------------
123      !!                  ***  ROUTINE ldf_ctl  ***
124      !!
125      !! ** Purpose :   Choice of the operator for the lateral tracer diffusion
126      !!
127      !! ** Method  :   set nldf from the namtra_ldf logicals
128      !!      nldf == -2   No lateral diffusion
129      !!      nldf == -1   ESOPA test: ALL operators are used
130      !!      nldf ==  0   laplacian operator
131      !!      nldf ==  1   Rotated laplacian operator
132      !!      nldf ==  2   bilaplacian operator
133      !!      nldf ==  3   Rotated bilaplacian
134      !!----------------------------------------------------------------------
135      INTEGER ::   ioptio, ierr         ! temporary integers
136      !!----------------------------------------------------------------------
137
138      IF (ABS(rn_aht_0) < 2._wp*TINY(1.e0)) THEN
139         IF (ABS(rn_ahtrc_0) < 2._wp*TINY(1.e0)) THEN
140            rldf_rat = 1.0_wp
141         ELSE
142            CALL ctl_stop( 'STOP', 'ldf_ctl : cannot define rldf_rat, rn_aht_0==0, rn_ahtrc_0 /=0' )
143         END IF
144      ELSE
145         rldf_rat = rn_ahtrc_0 / rn_aht_0
146      END IF
147      !  Define the lateral mixing oparator for tracers
148      ! ===============================================
149
150      !                               ! control the input
151      ioptio = 0
152      IF( ln_trcldf_lap   )   ioptio = ioptio + 1
153      IF( ln_trcldf_bilap )   ioptio = ioptio + 1
154      IF( ioptio >  1 )   CALL ctl_stop( '          use ONE or NONE of the 2 lap/bilap operator type on tracer' )
155      IF( ioptio == 0 )   nldf = -2   ! No lateral diffusion
156      ioptio = 0
157      IF( ln_trcldf_level )   ioptio = ioptio + 1
158      IF( ln_trcldf_hor   )   ioptio = ioptio + 1
159      IF( ln_trcldf_iso   )   ioptio = ioptio + 1
160      IF( ioptio /= 1 )   CALL ctl_stop( '          use only ONE direction (level/hor/iso)' )
161
162      ! defined the type of lateral diffusion from ln_trcldf_... logicals
163      ! CAUTION : nldf = 1 is used in trazdf_imp, change it carefully
164      ierr = 0
165      IF( ln_trcldf_lap ) THEN       ! laplacian operator
166         IF ( ln_zco ) THEN                ! z-coordinate
167            IF ( ln_trcldf_level )   nldf = 0      ! iso-level  (no rotation)
168            IF ( ln_trcldf_hor   )   nldf = 0      ! horizontal (no rotation)
169            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
170         ENDIF
171         IF ( ln_zps ) THEN             ! z-coordinate
172            IF ( ln_trcldf_level )   ierr = 1      ! iso-level not allowed
173            IF ( ln_trcldf_hor   )   nldf = 0      ! horizontal (no rotation)
174            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
175         ENDIF
176         IF ( ln_sco ) THEN             ! z-coordinate
177            IF ( ln_trcldf_level )   nldf = 0      ! iso-level  (no rotation)
178            IF ( ln_trcldf_hor   )   nldf = 1      ! horizontal (   rotation)
179            IF ( ln_trcldf_iso   )   nldf = 1      ! isoneutral (   rotation)
180         ENDIF
181      ENDIF
182
183      IF( ln_trcldf_bilap ) THEN      ! bilaplacian operator
184         IF ( ln_zco ) THEN                ! z-coordinate
185            IF ( ln_trcldf_level )   nldf = 2      ! iso-level  (no rotation)
186            IF ( ln_trcldf_hor   )   nldf = 2      ! horizontal (no rotation)
187            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
188         ENDIF
189         IF ( ln_zps ) THEN             ! z-coordinate
190            IF ( ln_trcldf_level )   ierr = 1      ! iso-level not allowed
191            IF ( ln_trcldf_hor   )   nldf = 2      ! horizontal (no rotation)
192            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
193         ENDIF
194         IF ( ln_sco ) THEN             ! z-coordinate
195            IF ( ln_trcldf_level )   nldf = 2      ! iso-level  (no rotation)
196            IF ( ln_trcldf_hor   )   nldf = 3      ! horizontal (   rotation)
197            IF ( ln_trcldf_iso   )   ierr = 2      ! isoneutral (   rotation)
198         ENDIF
199      ENDIF
200
201      IF( ierr == 1 )   CALL ctl_stop( ' iso-level in z-coordinate - partial step, not allowed' )
202      IF( ierr == 2 )   CALL ctl_stop( ' isoneutral bilaplacian operator does not exist' )
203      IF( lk_traldf_eiv .AND. .NOT.ln_trcldf_iso )   &
204           CALL ctl_stop( '          eddy induced velocity on tracers',   &
205           &              ' the eddy induced velocity on tracers requires isopycnal laplacian diffusion' )
206      IF( nldf == 1 .OR. nldf == 3 ) THEN      ! rotation
207         IF( .NOT.lk_ldfslp )   CALL ctl_stop( '          the rotation of the diffusive tensor require key_ldfslp' )
208#if defined key_offline
209         l_traldf_rot = .TRUE.                 ! needed for trazdf_imp
210#endif
211      ENDIF
212
213      IF( lk_esopa ) THEN
214         IF(lwp) WRITE(numout,*) '          esopa control: use all lateral physics options'
215         nldf = -1
216      ENDIF
217
218      IF( .NOT. ln_trcldf_diff ) THEN
219         IF(lwp) WRITE(numout,*) '          No lateral diffusion on passive tracers'
220         nldf = -2
221      ENDIF
222
223      IF(lwp) THEN
224         WRITE(numout,*)
225         IF( nldf == -2 )   WRITE(numout,*) '          NO lateral diffusion'
226         IF( nldf == -1 )   WRITE(numout,*) '          ESOPA test All scheme used'
227         IF( nldf ==  0 )   WRITE(numout,*) '          laplacian operator'
228         IF( nldf ==  1 )   WRITE(numout,*) '          Rotated laplacian operator'
229         IF( nldf ==  2 )   WRITE(numout,*) '          bilaplacian operator'
230         IF( nldf ==  3 )   WRITE(numout,*) '          Rotated bilaplacian'
231      ENDIF
232
233      IF( ln_trcldf_bilap ) THEN
234         IF(lwp) WRITE(numout,*) '          biharmonic tracer diffusion'
235         IF( rn_ahtrc_0 > 0 .AND. .NOT. lk_esopa )   CALL ctl_stop( 'The horizontal diffusivity coef. rn_ahtrc_0 must be negative' )
236      ELSE
237         IF(lwp) WRITE(numout,*) '          harmonic tracer diffusion (default)'
238         IF( rn_ahtrc_0 < 0 .AND. .NOT. lk_esopa )   CALL ctl_stop('The horizontal diffusivity coef. rn_ahtrc_0 must be positive' )
239      ENDIF
240
241      ! ratio between active and passive tracers diffusive coef.
242      IF (ABS(rn_aht_0) < 2._wp*TINY(1.e0)) THEN
243         IF (ABS(rn_ahtrc_0) < 2._wp*TINY(1.e0)) THEN
244            rldf_rat = 1.0_wp
245         ELSE
246            CALL ctl_stop( 'STOP', 'ldf_ctl : cannot define rldf_rat, rn_aht_0==0, rn_ahtrc_0 /=0' )
247         END IF
248      ELSE
249         rldf_rat = rn_ahtrc_0 / rn_aht_0
250      END IF
251      IF( rldf_rat < 0 ) THEN
252         IF( .NOT.lk_offline ) THEN
253            CALL ctl_stop( 'Choose the same type of diffusive scheme both for active & passive tracers' )
254         ELSE
255            CALL ctl_stop( 'Change the sign of rn_aht_0 in namelist to -/+1' )
256         ENDIF
257      ENDIF
258      !
259   END SUBROUTINE ldf_ctl
260#else
261   !!----------------------------------------------------------------------
262   !!   Default option                                         Empty module
263   !!----------------------------------------------------------------------
264CONTAINS
265   SUBROUTINE trc_ldf( kt )
266      INTEGER, INTENT(in) :: kt
267      WRITE(*,*) 'trc_ldf: You should not have seen this print! error?', kt
268   END SUBROUTINE trc_ldf
269#endif
270   !!======================================================================
271END MODULE trcldf
Note: See TracBrowser for help on using the repository browser.