New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 3490

Last change on this file since 3490 was 3490, checked in by cbricaud, 11 years ago

add Jerome Chanut 's modications for BDY, Mercator_1 2012 task

  • Property svn:keywords set to Id
File size: 16.1 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!----------------------------------------------------------------------
27
28   !!----------------------------------------------------------------------
29   !!   stp             : OPA system time-stepping
30   !!----------------------------------------------------------------------
31   USE step_oce         ! time stepping definition modules
32#if defined key_top
33   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
34#endif
35#if defined key_agrif
36   USE agrif_opa_sponge ! Momemtum and tracers sponges
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   stp   ! called by opa.F90
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54#if defined key_agrif
55   SUBROUTINE stp( )
56      INTEGER             ::   kstp   ! ocean time-step index
57#else
58   SUBROUTINE stp( kstp )
59      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
60#endif
61      !!----------------------------------------------------------------------
62      !!                     ***  ROUTINE stp  ***
63      !!                     
64      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
65      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
66      !!              - Tme stepping  of TRC (passive tracer eqs.)
67      !!
68      !! ** Method  : -1- Update forcings and data 
69      !!              -2- Update ocean physics
70      !!              -3- Compute the t and s trends
71      !!              -4- Update t and s
72      !!              -5- Compute the momentum trends
73      !!              -6- Update the horizontal velocity
74      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
75      !!              -8- Outputs and diagnostics
76      !!----------------------------------------------------------------------
77      INTEGER ::   jk       ! dummy loop indice
78      INTEGER ::   indic    ! error indicator if < 0
79      !! ---------------------------------------------------------------------
80
81#if defined key_agrif
82      kstp = nit000 + Agrif_Nb_Step()
83!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
84!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
85# if defined key_iomput
86      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
87# endif   
88#endif   
89                             indic = 0                ! reset to no error condition
90      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
91                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
92
93      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
94      ! Update data, open boundaries, surface boundary condition (including sea-ice)
95      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
96                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
97      IF( lk_tide.AND.(kstp /= nit000 ))   CALL tide_init ( kstp )
98      IF( lk_tide    )   CALL sbc_tide( kstp )
99      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
100      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
101      IF( lk_bdy     )   CALL bdy_dta( kstp, time_offset=+1 ) ! update dynamic and tracer data at open boundaries
102
103      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
104      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
105      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
106                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
107
108      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
109      ! Ocean physics update                (ua, va, tsa used as workspace)
110      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
111                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
112                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
113      !
114      !  VERTICAL PHYSICS   
115                         CALL zdf_bfr( kstp )         ! bottom friction
116                         
117      !                                               ! Vertical eddy viscosity and diffusivity coefficients
118      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
119      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
120      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
121      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
122      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
123         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
124         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
125         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
126      ENDIF
127      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
128         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
129      ENDIF
130      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
131
132      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
133
134      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
135         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
136         
137                         CALL zdf_mxl( kstp )         ! mixed layer depth
138
139                                                      ! write TKE or GLS information in the restart file
140      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
141      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
142      !
143      !  LATERAL  PHYSICS
144      !
145      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
146                         CALL eos( tsb, rhd )                ! before in situ density
147         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
148            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
149         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
150                         CALL ldf_slp_grif( kstp )
151         ELSE
152                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
153         ENDIF
154      ENDIF
155#if defined key_traldf_c2d
156      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
157#endif
158
159      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
160      ! diagnostics and outputs             (ua, va, tsa used as workspace)
161      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
162      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
163      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
164      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
165      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
166      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
167      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
168      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
169                         CALL dia_wri( kstp )         ! ocean model: outputs
170
171#if defined key_top
172      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
173      ! Passive Tracer Model
174      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
175                         CALL trc_stp( kstp )         ! time-stepping
176#endif
177
178      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
179      ! Active tracers                              (ua, va used as workspace)
180      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
181                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
182
183      IF(  ln_asmiau .AND. &
184         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
185                             CALL tra_sbc    ( kstp )       ! surface boundary condition
186      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
187      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
188      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
189      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
190      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
191                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
192      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
193                             CALL tra_ldf    ( kstp )       ! lateral mixing
194#if defined key_agrif
195      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
196#endif
197                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
198
199      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
200         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
201                             CALL tra_nxt( kstp )                ! tracer fields at next time step
202                             CALL eos    ( tsa, rhd, rhop )      ! Time-filtered in situ density for hpg computation
203         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
204            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
205         
206      ELSE                                                  ! centered hpg  (eos then time stepping)
207                             CALL eos    ( tsn, rhd, rhop )      ! now in situ density for hpg computation
208         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
209            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
210         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
211                             CALL tra_nxt( kstp )                ! tracer fields at next time step
212      ENDIF 
213
214      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
215      ! Dynamics                                    (tsa used as workspace)
216      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
217                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
218                               va(:,:,:) = 0.e0
219
220      IF(  ln_asmiau .AND. &
221         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
222      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
223      IF( lk_bdy           )   CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
224                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
225                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
226                               CALL dyn_ldf( kstp )         ! lateral mixing
227      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
228#if defined key_agrif
229      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
230#endif
231                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
232                               CALL dyn_bfr( kstp )         ! bottom friction   
233                               CALL dyn_zdf( kstp )         ! vertical diffusion
234                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
235                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
236
237                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
238
239      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
240      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
241
242      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
243      ! Control and restarts
244      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
245                               CALL stp_ctl( kstp, indic )
246      IF( indic < 0        )   THEN
247                               CALL ctl_stop( 'step: indic < 0' )
248                               CALL dia_wri_state( 'output.abort', kstp )
249      ENDIF
250      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
251      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
252      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
253
254      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
255      ! Trends                              (ua, va, tsa used as workspace)
256      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
257      IF( nstop == 0 ) THEN                         
258         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
259         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
260         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
261         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
262      ENDIF
263
264      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
265      ! Coupled mode
266      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
267      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
268      !
269      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
270      !
271   END SUBROUTINE stp
272
273   !!======================================================================
274END MODULE step
Note: See TracBrowser for help on using the repository browser.