New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2012/dev_r3342_MERCATOR7_SST/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2012/dev_r3342_MERCATOR7_SST/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 3572

Last change on this file since 3572 was 3572, checked in by cbricaud, 11 years ago

merge dev_r3342_MERCATOR7_SST with trunk: rev3342 to rev3555.
  • Property svn:keywords set to Id
File size: 52.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dyn_hpg        ! routine called by step module
46   PUBLIC   dyn_hpg_init   ! routine called by opa module
47
48   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
49   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
50   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
51   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
52   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
53   LOGICAL , PUBLIC ::   ln_hpg_prj    = .FALSE.   !: s-coordinate (Pressure Jacobian scheme)
54   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
55
56   INTEGER  ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!   
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - Save the trend (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
83      !
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
86         ztrdu(:,:,:) = ua(:,:,:) 
87         ztrdv(:,:,:) = va(:,:,:) 
88      ENDIF     
89      !
90      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
95      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
96      END SELECT
97      !
98      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
99         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
101         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
102         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
103      ENDIF         
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
109      !
110   END SUBROUTINE dyn_hpg
111
112
113   SUBROUTINE dyn_hpg_init
114      !!----------------------------------------------------------------------
115      !!                 ***  ROUTINE dyn_hpg_init  ***
116      !!
117      !! ** Purpose :   initializations for the hydrostatic pressure gradient
118      !!              computation and consistency control
119      !!
120      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
121      !!      with the type of vertical coordinate used (zco, zps, sco)
122      !!----------------------------------------------------------------------
123      INTEGER ::   ioptio = 0      ! temporary integer
124      !!
125      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
126         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
127      !!----------------------------------------------------------------------
128      !
129      REWIND( numnam )               ! Read Namelist namdyn_hpg
130      READ  ( numnam, namdyn_hpg )
131      !
132      IF(lwp) THEN                   ! Control print
133         WRITE(numout,*)
134         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
135         WRITE(numout,*) '~~~~~~~~~~~~'
136         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
137         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
138         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
139         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
140         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
141         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
142         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
143      ENDIF
144      !
145      IF( ln_hpg_djc )   &
146         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
147                           & currently disabled (bugs under investigation). Please select &
148                           & either  ln_hpg_sco or  ln_hpg_prj instead')
149      !
150      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
151         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
152                           & the standard jacobian formulation hpg_sco or &
153                           & the pressure jacobian formulation hpg_prj')
154      !
155      !                               ! Set nhpg from ln_hpg_... flags
156      IF( ln_hpg_zco )   nhpg = 0
157      IF( ln_hpg_zps )   nhpg = 1
158      IF( ln_hpg_sco )   nhpg = 2
159      IF( ln_hpg_djc )   nhpg = 3
160      IF( ln_hpg_prj )   nhpg = 4
161      !
162      !                               ! Consistency check
163      ioptio = 0 
164      IF( ln_hpg_zco )   ioptio = ioptio + 1
165      IF( ln_hpg_zps )   ioptio = ioptio + 1
166      IF( ln_hpg_sco )   ioptio = ioptio + 1
167      IF( ln_hpg_djc )   ioptio = ioptio + 1
168      IF( ln_hpg_prj )   ioptio = ioptio + 1
169      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
170      !
171   END SUBROUTINE dyn_hpg_init
172
173
174   SUBROUTINE hpg_zco( kt )
175      !!---------------------------------------------------------------------
176      !!                  ***  ROUTINE hpg_zco  ***
177      !!
178      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
179      !!      The now hydrostatic pressure gradient at a given level, jk,
180      !!      is computed by taking the vertical integral of the in-situ
181      !!      density gradient along the model level from the suface to that
182      !!      level:    zhpi = grav .....
183      !!                zhpj = grav .....
184      !!      add it to the general momentum trend (ua,va).
185      !!            ua = ua - 1/e1u * zhpi
186      !!            va = va - 1/e2v * zhpj
187      !!
188      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
189      !!----------------------------------------------------------------------
190      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
191      !!
192      INTEGER  ::   ji, jj, jk       ! dummy loop indices
193      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
194      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
195      !!----------------------------------------------------------------------
196      ! 
197      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
198      !
199      IF( kt == nit000 ) THEN
200         IF(lwp) WRITE(numout,*)
201         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
202         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
203      ENDIF
204     
205      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
206
207      ! Surface value
208      DO jj = 2, jpjm1
209         DO ji = fs_2, fs_jpim1   ! vector opt.
210            zcoef1 = zcoef0 * fse3w(ji,jj,1)
211            ! hydrostatic pressure gradient
212            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
213            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
214            ! add to the general momentum trend
215            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
216            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
217         END DO
218      END DO
219
220      !
221      ! interior value (2=<jk=<jpkm1)
222      DO jk = 2, jpkm1
223         DO jj = 2, jpjm1
224            DO ji = fs_2, fs_jpim1   ! vector opt.
225               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
226               ! hydrostatic pressure gradient
227               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
228                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
229                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
230
231               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
232                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
233                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
234               ! add to the general momentum trend
235               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
236               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
237            END DO
238         END DO
239      END DO
240      !
241      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
242      !
243   END SUBROUTINE hpg_zco
244
245
246   SUBROUTINE hpg_zps( kt )
247      !!---------------------------------------------------------------------
248      !!                 ***  ROUTINE hpg_zps  ***
249      !!                   
250      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
251      !!
252      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
253      !!----------------------------------------------------------------------
254      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
255      !!
256      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
257      INTEGER  ::   iku, ikv                         ! temporary integers
258      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
259      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
260      !!----------------------------------------------------------------------
261      !
262      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
263      !
264      IF( kt == nit000 ) THEN
265         IF(lwp) WRITE(numout,*)
266         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
267         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
268      ENDIF
269
270
271      ! Local constant initialization
272      zcoef0 = - grav * 0.5_wp
273
274      !  Surface value (also valid in partial step case)
275      DO jj = 2, jpjm1
276         DO ji = fs_2, fs_jpim1   ! vector opt.
277            zcoef1 = zcoef0 * fse3w(ji,jj,1)
278            ! hydrostatic pressure gradient
279            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
280            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
281            ! add to the general momentum trend
282            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
283            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
284         END DO
285      END DO
286
287
288      ! interior value (2=<jk=<jpkm1)
289      DO jk = 2, jpkm1
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1   ! vector opt.
292               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
293               ! hydrostatic pressure gradient
294               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
295                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
296                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
297
298               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
299                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
300                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
301               ! add to the general momentum trend
302               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
303               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
304            END DO
305         END DO
306      END DO
307
308
309      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
310# if defined key_vectopt_loop
311         jj = 1
312         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
313# else
314      DO jj = 2, jpjm1
315         DO ji = 2, jpim1
316# endif
317            iku = mbku(ji,jj)
318            ikv = mbkv(ji,jj)
319            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
320            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
321            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
322               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
323               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
324                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
325               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
326            ENDIF
327            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
328               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
329               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
330                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
331               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
332            ENDIF
333# if ! defined key_vectopt_loop
334         END DO
335# endif
336      END DO
337      !
338      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
339      !
340   END SUBROUTINE hpg_zps
341
342
343   SUBROUTINE hpg_sco( kt )
344      !!---------------------------------------------------------------------
345      !!                  ***  ROUTINE hpg_sco  ***
346      !!
347      !! ** Method  :   s-coordinate case. Jacobian scheme.
348      !!      The now hydrostatic pressure gradient at a given level, jk,
349      !!      is computed by taking the vertical integral of the in-situ
350      !!      density gradient along the model level from the suface to that
351      !!      level. s-coordinates (ln_sco): a corrective term is added
352      !!      to the horizontal pressure gradient :
353      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
354      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
355      !!      add it to the general momentum trend (ua,va).
356      !!         ua = ua - 1/e1u * zhpi
357      !!         va = va - 1/e2v * zhpj
358      !!
359      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
360      !!----------------------------------------------------------------------
361      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
362      !!
363      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
364      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
365      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
366      !!----------------------------------------------------------------------
367      !
368      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
369      !
370      IF( kt == nit000 ) THEN
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
373         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
374      ENDIF
375
376      ! Local constant initialization
377      zcoef0 = - grav * 0.5_wp
378      ! To use density and not density anomaly
379      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
380      ELSE                 ;     znad = 0._wp         ! Fixed volume
381      ENDIF
382
383      ! Surface value
384      DO jj = 2, jpjm1
385         DO ji = fs_2, fs_jpim1   ! vector opt.   
386            ! hydrostatic pressure gradient along s-surfaces
387            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
388               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
389            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
390               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
391            ! s-coordinate pressure gradient correction
392            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
393               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
394            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
395               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
396            ! add to the general momentum trend
397            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
398            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
399         END DO 
400      END DO   
401           
402      ! interior value (2=<jk=<jpkm1)
403      DO jk = 2, jpkm1                                 
404         DO jj = 2, jpjm1     
405            DO ji = fs_2, fs_jpim1   ! vector opt.     
406               ! hydrostatic pressure gradient along s-surfaces
407               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
408                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
409                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
410               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
411                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
412                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
413               ! s-coordinate pressure gradient correction
414               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
415                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
416               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
417                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
418               ! add to the general momentum trend
419               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
420               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
421            END DO
422         END DO
423      END DO
424      !
425      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
426      !
427   END SUBROUTINE hpg_sco
428
429   SUBROUTINE hpg_djc( kt )
430      !!---------------------------------------------------------------------
431      !!                  ***  ROUTINE hpg_djc  ***
432      !!
433      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
434      !!
435      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
436      !!----------------------------------------------------------------------
437      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
438      !!
439      INTEGER  ::   ji, jj, jk          ! dummy loop indices
440      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
441      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
442      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
443      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
444      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
445      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
446      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
447      !!----------------------------------------------------------------------
448      !
449      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
450      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
451      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        ) 
452      !
453
454      IF( kt == nit000 ) THEN
455         IF(lwp) WRITE(numout,*)
456         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
457         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
458      ENDIF
459
460      ! Local constant initialization
461      zcoef0 = - grav * 0.5_wp
462      z1_10  = 1._wp / 10._wp
463      z1_12  = 1._wp / 12._wp
464
465      !----------------------------------------------------------------------------------------
466      !  compute and store in provisional arrays elementary vertical and horizontal differences
467      !----------------------------------------------------------------------------------------
468
469!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
470
471      DO jk = 2, jpkm1
472         DO jj = 2, jpjm1
473            DO ji = fs_2, fs_jpim1   ! vector opt.
474               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
475               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
476               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
477               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
478               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
479               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
480            END DO
481         END DO
482      END DO
483
484      !-------------------------------------------------------------------------
485      ! compute harmonic averages using eq. 5.18
486      !-------------------------------------------------------------------------
487      zep = 1.e-15
488
489!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
490!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
491
492      DO jk = 2, jpkm1
493         DO jj = 2, jpjm1
494            DO ji = fs_2, fs_jpim1   ! vector opt.
495               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
496
497               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
498               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
499 
500               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
501               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
502
503               IF( cffw > zep) THEN
504                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
505                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
506               ELSE
507                  drhow(ji,jj,jk) = 0._wp
508               ENDIF
509
510               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
511                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
512
513               IF( cffu > zep ) THEN
514                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
515                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
516               ELSE
517                  drhou(ji,jj,jk ) = 0._wp
518               ENDIF
519
520               IF( cffx > zep ) THEN
521                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
522                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
523               ELSE
524                  dzu(ji,jj,jk) = 0._wp
525               ENDIF
526
527               IF( cffv > zep ) THEN
528                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
529                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
530               ELSE
531                  drhov(ji,jj,jk) = 0._wp
532               ENDIF
533
534               IF( cffy > zep ) THEN
535                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
536                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
537               ELSE
538                  dzv(ji,jj,jk) = 0._wp
539               ENDIF
540
541            END DO
542         END DO
543      END DO
544
545      !----------------------------------------------------------------------------------
546      ! apply boundary conditions at top and bottom using 5.36-5.37
547      !----------------------------------------------------------------------------------
548      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
549      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
550      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
551
552      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
553      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
554      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
555
556
557      !--------------------------------------------------------------
558      ! Upper half of top-most grid box, compute and store
559      !-------------------------------------------------------------
560
561!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
562!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
563
564      DO jj = 2, jpjm1
565         DO ji = fs_2, fs_jpim1   ! vector opt.
566            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
567               &                   * (  rhd(ji,jj,1)                                    &
568               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
569               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
570               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
571         END DO
572      END DO
573
574!!bug gm    : here also, simplification is possible
575!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
576
577      DO jk = 2, jpkm1
578         DO jj = 2, jpjm1
579            DO ji = fs_2, fs_jpim1   ! vector opt.
580
581               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
582                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
583                  &            - grav * z1_10 * (                                                                     &
584                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
585                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
586                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
587                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
588                  &                             )
589
590               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
591                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
592                  &            - grav* z1_10 * (                                                                      &
593                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
594                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
595                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
596                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
597                  &                            )
598
599               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
600                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
601                  &            - grav* z1_10 * (                                                                      &
602                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
603                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
604                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
605                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
606                  &                            )
607
608            END DO
609         END DO
610      END DO
611      CALL lbc_lnk(rho_k,'W',1.)
612      CALL lbc_lnk(rho_i,'U',1.)
613      CALL lbc_lnk(rho_j,'V',1.)
614
615
616      ! ---------------
617      !  Surface value
618      ! ---------------
619      DO jj = 2, jpjm1
620         DO ji = fs_2, fs_jpim1   ! vector opt.
621            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
622            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
623            ! add to the general momentum trend
624            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
625            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
626         END DO
627      END DO
628
629      ! ----------------
630      !  interior value   (2=<jk=<jpkm1)
631      ! ----------------
632      DO jk = 2, jpkm1
633         DO jj = 2, jpjm1 
634            DO ji = fs_2, fs_jpim1   ! vector opt.
635               ! hydrostatic pressure gradient along s-surfaces
636               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
637                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
638                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
639               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
640                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
641                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
642               ! add to the general momentum trend
643               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
644               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
645            END DO
646         END DO
647      END DO
648      !
649      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
650      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
651      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        ) 
652      !
653   END SUBROUTINE hpg_djc
654
655
656   SUBROUTINE hpg_prj( kt )
657      !!---------------------------------------------------------------------
658      !!                  ***  ROUTINE hpg_prj  ***
659      !!
660      !! ** Method  :   s-coordinate case.
661      !!      A Pressure-Jacobian horizontal pressure gradient method
662      !!      based on the constrained cubic-spline interpolation for
663      !!      all vertical coordinate systems
664      !!
665      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
666      !!             - Save the trend (l_trddyn=T)
667      !!
668      !!----------------------------------------------------------------------
669      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
670      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
671      !!
672      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
673      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
674      !!
675      !! The local variables for the correction term
676      INTEGER  :: jk1, jis, jid, jjs, jjd
677      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
678      REAL(wp) :: zrhdt1 
679      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
680      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh 
681      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
682      !!----------------------------------------------------------------------
683      !
684      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
685      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh ) 
686      !
687      IF( kt == nit000 ) THEN
688         IF(lwp) WRITE(numout,*)
689         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
690         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
691      ENDIF
692
693      !!----------------------------------------------------------------------
694      ! Local constant initialization
695      zcoef0 = - grav 
696      znad = 0.0_wp
697      IF( lk_vvl ) znad = 1._wp
698
699      ! Clean 3-D work arrays
700      zhpi(:,:,:) = 0._wp
701      zrhh(:,:,:) = rhd(:,:,:)
702     
703      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
704      DO jj = 1, jpj
705        DO ji = 1, jpi   
706          jk = mbathy(ji,jj)
707          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
708          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
709          ELSE IF(jk < jpkm1) THEN
710             DO jkk = jk+1, jpk
711                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
712                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
713             END DO
714          ENDIF
715        END DO
716      END DO
717
718      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
719      DO jj = 1, jpj;   DO ji = 1, jpi
720          zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
721      END DO        ;   END DO
722
723      DO jk = 2, jpk;   DO jj = 1, jpj;   DO ji = 1, jpi
724          zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
725      END DO        ;   END DO        ;   END DO
726
727      fsp(:,:,:) = zrhh(:,:,:)
728      xsp(:,:,:) = zdept(:,:,:)
729
730      ! Construct the vertical density profile with the
731      ! constrained cubic spline interpolation
732      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
733      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)     
734
735      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
736      DO jj = 2, jpj
737        DO ji = 2, jpi 
738          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
739                                         bsp(ji,jj,1),   csp(ji,jj,1), &
740                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
741
742          ! assuming linear profile across the top half surface layer
743          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1 
744        END DO
745      END DO
746
747      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
748      DO jk = 2, jpkm1                                 
749        DO jj = 2, jpj     
750          DO ji = 2, jpi
751            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
752                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
753                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
754                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
755          END DO
756        END DO
757      END DO
758
759      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
760      DO jj = 2, jpjm1     
761        DO ji = 2, jpim1 
762          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshu_n(ji,jj) * znad)
763          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshv_n(ji,jj) * znad)
764        END DO
765      END DO
766
767      DO jk = 2, jpkm1                                 
768        DO jj = 2, jpjm1     
769          DO ji = 2, jpim1 
770            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
771            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
772          END DO
773        END DO
774      END DO
775               
776      DO jk = 1, jpkm1                                 
777        DO jj = 2, jpjm1     
778          DO ji = 2, jpim1 
779            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
780            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
781          END DO
782        END DO
783      END DO
784
785      DO jk = 1, jpkm1
786        DO jj = 2, jpjm1
787          DO ji = 2, jpim1
788            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
789            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
790            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
791            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
792          END DO
793        END DO
794      END DO
795
796
797      DO jk = 1, jpkm1                                 
798        DO jj = 2, jpjm1     
799          DO ji = 2, jpim1 
800            zpwes = 0._wp; zpwed = 0._wp
801            zpnss = 0._wp; zpnsd = 0._wp
802            zuijk = zu(ji,jj,jk)
803            zvijk = zv(ji,jj,jk)
804
805            !!!!!     for u equation
806            IF( jk <= mbku(ji,jj) ) THEN
807               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
808                 jis = ji + 1; jid = ji
809               ELSE
810                 jis = ji;     jid = ji +1
811               ENDIF
812
813               ! integrate the pressure on the shallow side
814               jk1 = jk 
815               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
816                 IF( jk1 == mbku(ji,jj) ) THEN
817                   zuijk = -zdept(jis,jj,jk1)
818                   EXIT
819                 ENDIF
820                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
821                 zpwes = zpwes +                                    & 
822                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
823                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
824                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
825                 jk1 = jk1 + 1
826               END DO
827           
828               ! integrate the pressure on the deep side
829               jk1 = jk 
830               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
831                 IF( jk1 == 1 ) THEN
832                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
833                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
834                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
835                                                     dsp(jid,jj,1)) * zdeps
836                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
837                   EXIT
838                 ENDIF
839                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
840                 zpwed = zpwed +                                        & 
841                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
842                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
843                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
844                 jk1 = jk1 - 1
845               END DO
846           
847               ! update the momentum trends in u direction
848
849               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
850               IF( lk_vvl ) THEN
851                 zdpdx2 = zcoef0 / e1u(ji,jj) * & 
852                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) ) 
853                ELSE
854                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed) 
855               ENDIF
856
857               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
858               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
859            ENDIF
860 
861            !!!!!     for v equation
862            IF( jk <= mbkv(ji,jj) ) THEN
863               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
864                 jjs = jj + 1; jjd = jj
865               ELSE
866                 jjs = jj    ; jjd = jj + 1
867               ENDIF
868
869               ! integrate the pressure on the shallow side
870               jk1 = jk 
871               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
872                 IF( jk1 == mbkv(ji,jj) ) THEN
873                   zvijk = -zdept(ji,jjs,jk1)
874                   EXIT
875                 ENDIF
876                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
877                 zpnss = zpnss +                                      & 
878                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
879                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
880                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
881                 jk1 = jk1 + 1
882               END DO
883           
884               ! integrate the pressure on the deep side
885               jk1 = jk 
886               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
887                 IF( jk1 == 1 ) THEN
888                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
889                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
890                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
891                                                     dsp(ji,jjd,1) ) * zdeps
892                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
893                   EXIT
894                 ENDIF
895                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
896                 zpnsd = zpnsd +                                        & 
897                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
898                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
899                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
900                 jk1 = jk1 - 1
901               END DO
902           
903
904               ! update the momentum trends in v direction
905
906               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
907               IF( lk_vvl ) THEN
908                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
909                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) ) 
910               ELSE
911                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd ) 
912               ENDIF
913
914               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
915               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
916            ENDIF
917
918                   
919           END DO
920        END DO
921      END DO
922      !
923      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
924      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh ) 
925      !
926   END SUBROUTINE hpg_prj
927
928   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
929      !!----------------------------------------------------------------------
930      !!                 ***  ROUTINE cspline  ***
931      !!       
932      !! ** Purpose :   constrained cubic spline interpolation
933      !!         
934      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
935      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
936      !!
937      !!----------------------------------------------------------------------
938      IMPLICIT NONE
939      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
940      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
941                                                                    ! the interpoated function
942      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
943                                                                    ! 2: Linear
944
945      ! Local Variables     
946      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
947      INTEGER  ::   jpi, jpj, jpkm1
948      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
949      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
950      REAL(wp) ::   zdf(size(fsp,3))
951      !!----------------------------------------------------------------------
952
953      jpi   = size(fsp,1)
954      jpj   = size(fsp,2)
955      jpkm1 = size(fsp,3) - 1
956
957     
958      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
959         DO ji = 1, jpi
960            DO jj = 1, jpj
961           !!Fritsch&Butland's method, 1984 (preferred, but more computation)             
962           !    DO jk = 2, jpkm1-1
963           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1) 
964           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
965           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
966           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
967           !
968           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
969           !     
970           !       IF(zdf1 * zdf2 <= 0._wp) THEN
971           !           zdf(jk) = 0._wp
972           !       ELSE
973           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
974           !       ENDIF
975           !    END DO
976           
977           !!Simply geometric average
978               DO jk = 2, jpkm1-1
979                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
980                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
981           
982                  IF(zdf1 * zdf2 <= 0._wp) THEN
983                     zdf(jk) = 0._wp
984                  ELSE
985                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
986                  ENDIF
987               END DO
988           
989               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
990                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
991               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
992                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
993                          & 0.5_wp * zdf(jpkm1 - 1)
994   
995               DO jk = 1, jpkm1 - 1
996                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
997                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
998                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
999                 zddf1  = -2._wp * ztmp1 + ztmp2 
1000                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1001                 zddf2  =  2._wp * ztmp1 - ztmp2 
1002     
1003                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1004                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1005                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - & 
1006                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1007                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1008                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1009                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1010                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1011                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1012               END DO
1013            END DO
1014         END DO
1015 
1016      ELSE IF (polynomial_type == 2) THEN     ! Linear
1017         DO ji = 1, jpi
1018            DO jj = 1, jpj
1019               DO jk = 1, jpkm1-1
1020                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1021                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1022   
1023                  dsp(ji,jj,jk) = 0._wp
1024                  csp(ji,jj,jk) = 0._wp
1025                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1026                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1027               END DO
1028            END DO
1029         END DO
1030
1031      ELSE
1032           CALL ctl_stop( 'invalid polynomial type in cspline' )
1033      ENDIF
1034
1035     
1036   END SUBROUTINE cspline
1037
1038
1039   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f) 
1040      !!----------------------------------------------------------------------
1041      !!                 ***  ROUTINE interp1  ***
1042      !!       
1043      !! ** Purpose :   1-d linear interpolation
1044      !!         
1045      !! ** Method  : 
1046      !!                interpolation is straight forward
1047      !!                extrapolation is also permitted (no value limit)
1048      !!
1049      !!----------------------------------------------------------------------
1050      IMPLICIT NONE
1051      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr   
1052      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1053      REAL(wp)             ::  zdeltx
1054      !!----------------------------------------------------------------------
1055
1056      zdeltx = xr - xl
1057      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1058        f = 0.5_wp * (fl + fr)
1059      ELSE
1060        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1061      ENDIF
1062     
1063   END FUNCTION interp1
1064
1065   FUNCTION interp2(x, a, b, c, d)  RESULT(f) 
1066      !!----------------------------------------------------------------------
1067      !!                 ***  ROUTINE interp1  ***
1068      !!       
1069      !! ** Purpose :   1-d constrained cubic spline interpolation
1070      !!         
1071      !! ** Method  :  cubic spline interpolation
1072      !!
1073      !!----------------------------------------------------------------------
1074      IMPLICIT NONE
1075      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1076      REAL(wp)             ::  f ! value from the interpolation
1077      !!----------------------------------------------------------------------
1078
1079      f = a + x* ( b + x * ( c + d * x ) ) 
1080
1081   END FUNCTION interp2
1082
1083
1084   FUNCTION interp3(x, a, b, c, d)  RESULT(f) 
1085      !!----------------------------------------------------------------------
1086      !!                 ***  ROUTINE interp1  ***
1087      !!       
1088      !! ** Purpose :   Calculate the first order of deriavtive of
1089      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1090      !!         
1091      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1092      !!
1093      !!----------------------------------------------------------------------
1094      IMPLICIT NONE
1095      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1096      REAL(wp)             ::  f ! value from the interpolation
1097      !!----------------------------------------------------------------------
1098
1099      f = b + x * ( 2._wp * c + 3._wp * d * x)
1100
1101   END FUNCTION interp3
1102
1103   
1104   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f) 
1105      !!----------------------------------------------------------------------
1106      !!                 ***  ROUTINE interp1  ***
1107      !!       
1108      !! ** Purpose :   1-d constrained cubic spline integration
1109      !!         
1110      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1111      !!
1112      !!----------------------------------------------------------------------
1113      IMPLICIT NONE
1114      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d   
1115      REAL(wp)             ::  za1, za2, za3     
1116      REAL(wp)             ::  f                   ! integration result
1117      !!----------------------------------------------------------------------
1118
1119      za1 = 0.5_wp * b 
1120      za2 = c / 3.0_wp 
1121      za3 = 0.25_wp * d 
1122
1123      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1124         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1125
1126   END FUNCTION integ_spline
1127
1128
1129   !!======================================================================
1130END MODULE dynhpg
1131
Note: See TracBrowser for help on using the repository browser.