New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limrhg_2.F90 in branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/LIM_SRC_2/limrhg_2.F90 @ 3414

Last change on this file since 3414 was 3414, checked in by acc, 12 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. Stage 3 of 2012 development: First working version with (optionally) active embedding. Still some stability questions when running the LIM2-EVP, ORCA2 test-case with full embedding. Works with reduced (halved) timestep. Still investigating.
  • Property svn:keywords set to Id
File size: 35.3 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  1993-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  1994-12  (H. Goosse)
8   !!            2.0  !  2003-12  (C. Ethe, G. Madec)  F90, mpp
9   !!             -   !  2006-08  (G. Madec)  surface module, ice-stress at I-point
10   !!             -   !  2009-09  (G. Madec)  Huge verctor optimisation
11   !!            3.3  !  2009-05  (G.Garric, C. Bricaud) addition of the lim2_evp case
12   !!----------------------------------------------------------------------
13#if defined   key_lim2   &&   defined key_lim2_vp
14   !!----------------------------------------------------------------------
15   !!   'key_lim2'                AND                   LIM-2 sea-ice model
16   !!   'key_lim2_vp'                                       VP ice rheology
17   !!----------------------------------------------------------------------
18   !!   lim_rhg_2   : computes ice velocities
19   !!----------------------------------------------------------------------
20   USE par_oce        ! ocean parameter
21   USE dom_oce        ! ocean space and time domain
22   USE sbc_oce        ! surface boundary condition: ocean variables
23   USE sbc_ice        ! surface boundary condition: ice variables
24   USE dom_ice_2      ! LIM2: ice domain
25   USE phycst         ! physical constant
26   USE ice_2          ! LIM2: ice variables
27   USE lbclnk         ! lateral boundary condition - MPP exchanges
28   USE lib_mpp        ! MPP library
29   USE wrk_nemo       ! work arrays
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE oce, ONLY : snwice_mass, snwice_mass_b
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   lim_rhg_2         ! routine called by lim_dyn
38
39   REAL(wp) ::   rzero   = 0._wp   ! constant value: zero
40   REAL(wp) ::   rone    = 1._wp   !            and  one
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
52      !!-------------------------------------------------------------------
53      !!                 ***  SUBROUTINR lim_rhg_2  ***
54      !!
55      !! ** purpose :   determines the velocity field of sea ice by using
56      !!  atmospheric (wind stress) and oceanic (water stress and surface
57      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
58      !!  viscous-plastic law including shear strength and a bulk rheology.
59      !!
60      !! ** Action  : - compute u_ice, v_ice the sea-ice velocity defined
61      !!              at I-point
62      !!-------------------------------------------------------------------
63      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
64      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
65      !!
66      INTEGER ::   ji, jj              ! dummy loop indices
67      INTEGER ::   iter, jter          ! temporary integers
68      CHARACTER (len=50) ::   charout
69      REAL(wp) ::   ze11  , ze12  , ze22  , ze21               ! local scalars
70      REAL(wp) ::   zt11  , zt12  , zt21  , zt22               !   -      -
71      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22             !   -      -
72      REAL(wp) ::   zgphsx, ztagnx, zgsshx, zunw, zur, zusw    !   -      -
73      REAL(wp) ::   zgphsy, ztagny, zgsshy, zvnw, zvr          !   -      -
74      REAL(wp) ::   zresm,  za, zac, zmod
75      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
76      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
77      REAL(wp) ::   za1, zb1, zc1, zd1
78      REAL(wp) ::   za2, zb2, zc2, zd2, zden
79      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
80      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
81      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
82      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
83      REAL(wp) ::   zintb, zintn
84      REAL(wp), POINTER, DIMENSION(:,:) ::   zfrld, zmass, zcorl
85      REAL(wp), POINTER, DIMENSION(:,:) ::   za1ct, za2ct, zresr
86      REAL(wp), POINTER, DIMENSION(:,:) ::   zc1u, zc1v, zc2u, zc2v
87      REAL(wp), POINTER, DIMENSION(:,:) ::   zsang, zpice
88      REAL(wp), POINTER, DIMENSION(:,:) ::   zu0, zv0
89      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_n, zv_n
90      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_a, zv_a
91      REAL(wp), POINTER, DIMENSION(:,:) ::   zviszeta, zviseta
92      REAL(wp), POINTER, DIMENSION(:,:) ::   zzfrld, zztms
93      REAL(wp), POINTER, DIMENSION(:,:) ::   zi1, zi2, zmasst, zpresh
94      !!-------------------------------------------------------------------
95     
96      CALL wrk_alloc( jpi,jpj, zfrld, zmass, zcorl, za1ct, za2ct, zresr )
97      CALL wrk_alloc( jpi,jpj, zc1u , zc1v , zc2u , zc2v , zsang, zpice )
98      CALL wrk_alloc( jpi,jpj+2, zu0, zv0, zu_n, zv_n, zu_a, zv_a, zviszeta, zviseta, kjstart = 0 )
99      CALL wrk_alloc( jpi,jpj+2, zzfrld, zztms, zi1, zi2, zmasst, zpresh, kjstart = 0 )
100
101      !  Store initial velocities
102      !  ----------------
103      zztms(:,0    ) = 0._wp        ;   zzfrld(:,0    ) = 0._wp
104      zztms(:,jpj+1) = 0._wp        ;   zzfrld(:,jpj+1) = 0._wp
105      zu0  (:,0    ) = 0._wp        ;   zv0   (:,0    ) = 0._wp
106      zu0  (:,jpj+1) = 0._wp        ;   zv0   (:,jpj+1) = 0._wp
107      zztms(:,1:jpj) = tms  (:,:)   ;   zzfrld(:,1:jpj) = frld (:,:)
108      zu0  (:,1:jpj) = u_ice(:,:)   ;   zv0   (:,1:jpj) = v_ice(:,:)
109      zu_a (:, :   ) = zu0  (:,:)   ;   zv_a  (:, :   ) = zv0  (:,:)
110      zu_n (:, :   ) = zu0  (:,:)   ;   zv_n  (:, :   ) = zv0  (:,:)
111
112!i
113      zi1   (:,:) = 0._wp
114      zi2   (:,:) = 0._wp
115      zpresh(:,:) = 0._wp
116      zmasst(:,:) = 0._wp
117!i
118!!gm violant
119      zfrld(:,:) =0._wp
120      zcorl(:,:) =0._wp
121      zmass(:,:) =0._wp
122      za1ct(:,:) =0._wp
123      za2ct(:,:) =0._wp
124!!gm end
125
126      zviszeta(:,:) = 0._wp
127      zviseta (:,:) = 0._wp
128
129!i    zviszeta(:,0    ) = 0._wp    ;    zviseta(:,0    ) = 0._wp
130!i    zviszeta(:,jpj  ) = 0._wp    ;    zviseta(:,jpj  ) = 0._wp
131!i    zviszeta(:,jpj+1) = 0._wp    ;    zviseta(:,jpj+1) = 0._wp
132
133      IF( nn_ice_embd == 2 ) THEN             !== embedded sea ice: compute representative ice top surface ==!
134          !
135          ! average interpolation coeff as used in dynspg = (1/nn_fsbc) * {SUM[n/nn_fsbc], n=0,nn_fsbc-1}
136          !                                               = (1/nn_fsbc)^2 * {SUM[n], n=0,nn_fsbc-1}
137         zintn = REAL( nn_fsbc - 1 ) / REAL( nn_fsbc ) * 0.5_wp
138          !
139          ! average interpolation coeff as used in dynspg = (1/nn_fsbc) * {SUM[1-n/nn_fsbc], n=0,nn_fsbc-1}
140          !                                               = (1/nn_fsbc)^2 * (nn_fsbc^2 - {SUM[n], n=0,nn_fsbc-1})
141         zintb = REAL( nn_fsbc + 1 ) / REAL( nn_fsbc ) * 0.5_wp
142          !
143         zpice(:,:) = ssh_m(:,:) + (  zintn * snwice_mass(:,:) +  zintb * snwice_mass_b(:,:)  ) * r1_rau0
144          !
145         !
146      ELSE                                    !== non-embedded sea ice: use ocean surface for slope calculation ==!
147         zpice(:,:) = ssh_m(:,:)
148      ENDIF
149
150      ! Ice mass, ice strength, and wind stress at the center            |
151      ! of the grid squares.                                             |
152      !-------------------------------------------------------------------
153
154!CDIR NOVERRCHK
155      DO jj = k_j1 , k_jpj-1
156!CDIR NOVERRCHK
157         DO ji = 1 , jpi
158            ! only the sinus changes its sign with the hemisphere
159            zsang(ji,jj)  = SIGN( 1._wp, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
160            !
161            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
162            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
163!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
164            zi1(ji,jj)    = tms(ji,jj) * ( 1._wp - frld(ji,jj) )
165            zi2(ji,jj)    = tms(ji,jj) * ( 1._wp - frld(ji,jj) )
166         END DO
167      END DO
168
169
170      !---------------------------------------------------------------------------
171      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
172      !  Gradient of ice strenght.                                               |
173      !---------------------------------------------------------------------------
174         
175      DO jj = k_j1+1, k_jpj-1
176         DO ji = 2, jpi    ! NO vector opt.
177            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
178               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
179            zusw  = 1._wp / MAX( zstms, epsd )
180
181            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
182            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
183            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
184            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
185
186            ! Leads area.
187            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
188               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
189
190            ! Mass and coriolis coeff. at I-point
191            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
192               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
193            zcorl(ji,jj) = zmass(ji,jj) &
194               &           *( fcor(ji,jj  ) * wght(ji,jj,2,2) + fcor(ji-1,jj  )*wght(ji,jj,1,2)   &
195               &            + fcor(ji,jj-1) * wght(ji,jj,2,1) + fcor(ji-1,jj-1)*wght(ji,jj,1,1) ) * zusw
196
197            ! Wind stress.
198            ! always provide stress at I-point
199            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
200               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utau_ice(ji,jj)
201            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
202               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtau_ice(ji,jj)
203
204            ! Gradient of ice strength
205            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
206               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
207               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
208               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
209
210            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
211               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
212               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
213               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
214
215            ! Gradient of the sea surface height
216            zgsshx =  (   (zpice(ji  ,jj  ) - zpice(ji-1,jj  ))/e1u(ji-1,jj  )   &
217               &       +  (zpice(ji  ,jj-1) - zpice(ji-1,jj-1))/e1u(ji-1,jj-1)   ) * 0.5_wp
218            zgsshy =  (   (zpice(ji  ,jj  ) - zpice(ji  ,jj-1))/e2v(ji  ,jj-1)   &
219               &       +  (zpice(ji-1,jj  ) - zpice(ji-1,jj-1))/e2v(ji-1,jj-1)   ) * 0.5_wp
220
221            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
222            ! Terms that are independent of the ice velocity field.
223            za1ct(ji,jj) = ztagnx - zmass(ji,jj) * grav * zgsshx - zgphsx
224            za2ct(ji,jj) = ztagny - zmass(ji,jj) * grav * zgsshy - zgphsy
225         END DO
226      END DO
227
228
229      ! SOLUTION OF THE MOMENTUM EQUATION.
230      !------------------------------------------
231      !                                                   ! ==================== !
232      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
233         !                                                ! ==================== !       
234         zindu = MOD( iter , 2 )
235         zusdtp = ( zindu * 2._wp + ( 1._wp - zindu ) * 1._wp )  * REAL( nbiter ) / rdt_ice
236
237         ! Computation of free drift field for free slip boundary conditions.
238
239!CDIR NOVERRCHK
240         DO jj = k_j1, k_jpj-1
241!CDIR NOVERRCHK
242            DO ji = 1, fs_jpim1
243               !- Rate of strain tensor.
244               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
245                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
246               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
247                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
248               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
249                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
250               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
251                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
252
253               !- Rate of strain tensor.
254               zdgp = zt11 + zt22
255               zdgi = zt12 + zt21
256               ztrace2 = zdgp * zdgp 
257               zdeter  = zt11 * zt22 - 0.25_wp * zdgi * zdgi
258
259               !  Creep limit depends on the size of the grid.
260               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4._wp * zdeter ) * usecc2 ),  creepl)
261
262               !-  Computation of viscosities.
263               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
264               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
265            END DO
266         END DO
267
268         !-  Determination of zc1u, zc2u, zc1v and zc2v.
269         DO jj = k_j1+1, k_jpj-1
270            DO ji = 2, fs_jpim1   ! NO vector opt.
271               !* zc1u , zc2v
272               zvis11 = 2._wp * zviseta (ji-1,jj-1) + dm
273               zvis12 =         zviseta (ji-1,jj-1) + dm
274               zvis21 =         zviseta (ji-1,jj-1)
275               zvis22 =         zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
276               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
277               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
278               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
279               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
280               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
281
282               zvis11 = 2._wp * zviseta (ji,jj-1) + dm
283               zvis22 =         zviszeta(ji,jj-1) - zviseta(ji,jj-1)
284               zvis12 =         zviseta (ji,jj-1) + dm
285               zvis21 =         zviseta (ji,jj-1)
286               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
287               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
288               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
289               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
290               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
291
292               zvis11 = 2._wp * zviseta (ji-1,jj) + dm
293               zvis22 =         zviszeta(ji-1,jj) - zviseta(ji-1,jj)
294               zvis12 =         zviseta (ji-1,jj) + dm
295               zvis21 =         zviseta (ji-1,jj)
296               zdiag  = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
297               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
298               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
299               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
300               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
301
302               zvis11 = 2._wp * zviseta (ji,jj) + dm
303               zvis22 =         zviszeta(ji,jj) - zviseta(ji,jj)
304               zvis12 =         zviseta (ji,jj) + dm
305               zvis21 =         zviseta (ji,jj)
306               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
307               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
308               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
309               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
310               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
311
312               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
313                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
314                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
315                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
316                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
317                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
318                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
319                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
320
321               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
322                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
323                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
324                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
325                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
326                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
327                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
328                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
329
330               !* zc1v , zc2v.
331               zvis11 = 2._wp * zviseta (ji-1,jj-1) + dm
332               zvis22 =         zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
333               zvis12 =         zviseta (ji-1,jj-1) + dm
334               zvis21 =         zviseta (ji-1,jj-1)
335               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
336               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
337               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
338               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
339               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
340 
341               zvis11 = 2._wp * zviseta (ji,jj-1) + dm
342               zvis22 =         zviszeta(ji,jj-1) - zviseta(ji,jj-1)
343               zvis12 =         zviseta (ji,jj-1) + dm
344               zvis21 =         zviseta (ji,jj-1)
345               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
346               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
347               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
348               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
349               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
350
351               zvis11 = 2._wp * zviseta (ji-1,jj) + dm
352               zvis22 =         zviszeta(ji-1,jj) - zviseta(ji-1,jj)
353               zvis12 =         zviseta (ji-1,jj) + dm
354               zvis21 =         zviseta (ji-1,jj)
355               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
356               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
357               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
358               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
359               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
360
361               zvis11 = 2._wp * zviseta (ji,jj) + dm
362               zvis22 =         zviszeta(ji,jj) - zviseta(ji,jj)
363               zvis12 =         zviseta (ji,jj) + dm
364               zvis21 =         zviseta (ji,jj)
365               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
366               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
367               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
368               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
369               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
370
371               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
372                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
373                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
374                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
375                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
376                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
377                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
378                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
379
380               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
381                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
382                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
383                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
384                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
385                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
386                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
387                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
388            END DO
389         END DO
390
391         ! GAUSS-SEIDEL method
392         !                                                      ! ================ !
393iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
394            !                                                   ! ================ !
395!CDIR NOVERRCHK
396            DO jj = k_j1+1, k_jpj-1
397!CDIR NOVERRCHK
398               DO ji = 2, fs_jpim1   ! NO vector opt.
399                  !
400                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
401                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
402                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
403                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
404                  zvis11 = 2._wp * zviseta (ji,jj-1) + dm
405                  zvis22 =         zviszeta(ji,jj-1) - zviseta(ji,jj-1)
406                  zvis12 =         zviseta (ji,jj-1) + dm
407                  zvis21 =         zviseta (ji,jj-1)
408                  zdiag = zvis22 * ( ze11 + ze22 )
409                  zs11_21 =  zvis11 * ze11 + zdiag
410                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
411                  zs22_21 =  zvis11 * ze22 + zdiag
412                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
413
414                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
415                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
416                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
417                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
418                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
419                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
420                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
421                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
422                  zvis11 = 2._wp * zviseta (ji-1,jj) + dm
423                  zvis22 =         zviszeta(ji-1,jj) - zviseta(ji-1,jj)
424                  zvis12 =         zviseta (ji-1,jj) + dm
425                  zvis21 =         zviseta (ji-1,jj)
426                  zdiag = zvis22 * ( ze11 + ze22 )
427                  zs11_12 =  zvis11 * ze11 + zdiag
428                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
429                  zs22_12 =  zvis11 * ze22 + zdiag
430                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
431
432                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
433                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
434                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
435                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
436                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
437                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
438                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
439                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
440                  zvis11 = 2._wp * zviseta (ji,jj) + dm
441                  zvis22 =         zviszeta(ji,jj) - zviseta(ji,jj)
442                  zvis12 =         zviseta (ji,jj) + dm
443                  zvis21 =         zviseta (ji,jj)
444                  zdiag = zvis22 * ( ze11 + ze22 )
445                  zs11_22 =  zvis11 * ze11 + zdiag
446                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
447                  zs22_22 =  zvis11 * ze22 + zdiag
448                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
449
450            ! 2nd part
451                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
452                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
453                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
454                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
455                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
456                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
457                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
458                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
459                  zvis11 = 2._wp * zviseta (ji-1,jj-1) + dm
460                  zvis22 =         zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
461                  zvis12 =         zviseta (ji-1,jj-1) + dm
462                  zvis21 =         zviseta (ji-1,jj-1)
463                  zdiag = zvis22 * ( ze11 + ze22 )
464                  zs11_11 =  zvis11 * ze11 + zdiag
465                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
466                  zs22_11 =  zvis11 * ze22 + zdiag
467                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
468
469                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
470                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
471                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
472                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
473                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
474                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
475                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
476                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
477                  zvis11 = 2._wp * zviseta (ji,jj-1) + dm
478                  zvis22 =         zviszeta(ji,jj-1) - zviseta(ji,jj-1)
479                  zvis12 =         zviseta (ji,jj-1) + dm
480                  zvis21 =         zviseta (ji,jj-1)
481                  zdiag = zvis22 * ( ze11 + ze22 )
482                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
483                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
484                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
485                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
486
487                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
488                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
489                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
490                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
491                  zvis11 = 2._wp * zviseta (ji-1,jj) + dm
492                  zvis22 =         zviszeta(ji-1,jj) - zviseta(ji-1,jj)
493                  zvis12 =         zviseta (ji-1,jj) + dm
494                  zvis21 =         zviseta (ji-1,jj)
495                  zdiag = zvis22 * ( ze11 + ze22 )
496                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
497                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
498                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
499                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
500
501                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
502                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
503                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
504                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
505                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
506                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
507                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
508                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
509
510                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
511                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
512                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
513                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
514                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
515                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
516                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
517                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
518
519                  zur     = zu_a(ji,jj) - u_oce(ji,jj)
520                  zvr     = zv_a(ji,jj) - v_oce(ji,jj)
521!!!!
522                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1._wp - zfrld(ji,jj) )
523                  za      = rhoco * zmod
524!!!!
525!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1._wp - zfrld(ji,jj) )
526                  zac     = za * cangvg
527                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
528                  zmassdt = zusdtp * zmass(ji,jj)
529                  zcorlal = ( 1._wp - alpha ) * zcorl(ji,jj)
530
531                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
532                     &        + za * ( cangvg * u_oce(ji,jj) - zsang(ji,jj) * v_oce(ji,jj) )
533                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
534                     &        + za * ( cangvg * v_oce(ji,jj) + zsang(ji,jj) * u_oce(ji,jj) )
535                  zb1    = zmassdt + zac - zc1u(ji,jj)
536                  zb2    = zmpzas        - zc2u(ji,jj)
537                  zc1    = zmpzas        + zc1v(ji,jj)
538                  zc2    = zmassdt + zac - zc2v(ji,jj)
539                  zdeter = zc1 * zb2 + zc2 * zb1
540                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
541                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
542                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
543                  zmask  = ( 1._wp - MAX( rzero, SIGN( rone , 1._wp - zmass(ji,jj) ) ) ) * tmu(ji,jj)
544
545                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
546                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
547               END DO
548            END DO
549
550            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
551            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
552
553            ! Test of Convergence
554            DO jj = k_j1+1 , k_jpj-1
555               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
556            END DO
557            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
558!!!! this should be faster on scalar processor
559!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
560!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
561!!!!
562            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
563
564            DO jj = k_j1, k_jpj
565               zu_a(:,jj) = zu_n(:,jj)
566               zv_a(:,jj) = zv_n(:,jj)
567            END DO
568
569            IF( zresm <= resl )   EXIT   iflag
570
571            !                                                   ! ================ !
572         END DO    iflag                                        !  end Relaxation  !
573         !                                                      ! ================ !
574
575         IF( zindu == 0 ) THEN      ! even iteration
576            DO jj = k_j1 , k_jpj-1
577               zu0(:,jj) = zu_a(:,jj)
578               zv0(:,jj) = zv_a(:,jj)
579            END DO
580         ENDIF
581         !                                                ! ==================== !
582      END DO                                              !  end loop over iter  !
583      !                                                   ! ==================== !
584
585      u_ice(:,:) = zu_a(:,1:jpj)
586      v_ice(:,:) = zv_a(:,1:jpj)
587
588      IF(ln_ctl) THEN
589         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
590         CALL prt_ctl_info(charout)
591         CALL prt_ctl(tab2d_1=u_ice, clinfo1=' lim_rhg  : u_ice :', tab2d_2=v_ice, clinfo2=' v_ice :')
592      ENDIF
593
594      CALL wrk_dealloc( jpi,jpj, zfrld, zmass, zcorl, za1ct, za2ct, zresr )
595      CALL wrk_dealloc( jpi,jpj, zc1u , zc1v , zc2u , zc2v , zsang, zpice )
596      CALL wrk_dealloc( jpi,jpj+2, zu0, zv0, zu_n, zv_n, zu_a, zv_a, zviszeta, zviseta, kjstart = 0 )
597      CALL wrk_dealloc( jpi,jpj+2, zzfrld, zztms, zi1, zi2, zmasst, zpresh, kjstart = 0 )
598
599   END SUBROUTINE lim_rhg_2
600
601#else
602   !!----------------------------------------------------------------------
603   !!   Default option        Dummy module      NO VP & LIM-2 sea-ice model
604   !!----------------------------------------------------------------------
605CONTAINS
606   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
607      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
608   END SUBROUTINE lim_rhg_2
609#endif
610
611   !!==============================================================================
612END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.