| 1 | MODULE limsbc_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc_2 *** |
|---|
| 4 | !! LIM-2 : updates the fluxes at the ocean surface with ice-ocean fluxes |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : LIM ! 2000-01 (H. Goosse) Original code |
|---|
| 7 | !! 1.0 ! 2002-07 (C. Ethe, G. Madec) re-writing F90 |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) surface module |
|---|
| 9 | !! 3.3 ! 2009-05 (G. Garric, C. Bricaud) addition of the lim2_evp case |
|---|
| 10 | !! - ! 2010-11 (G. Madec) ice-ocean stress computed at each ocean time-step |
|---|
| 11 | !! 3.3.1 ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 12 | !! 3.5 ! 2012-11 ((G. Madec, Y. Aksenov, A. Coward) salt and heat fluxes associated with e-p |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_lim2 |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! lim_sbc_alloc_2 : allocate the limsbc arrays |
|---|
| 19 | !! lim_sbc_init : initialisation |
|---|
| 20 | !! lim_sbc_flx_2 : update mass, heat and salt fluxes at the ocean surface |
|---|
| 21 | !! lim_sbc_tau_2 : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | USE par_oce ! ocean parameters |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE dom_oce ! ocean domain |
|---|
| 26 | USE dom_ice_2 ! LIM-2: ice domain |
|---|
| 27 | USE ice_2 ! LIM-2: ice variables |
|---|
| 28 | USE sbc_ice ! surface boundary condition: ice |
|---|
| 29 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 30 | USE sbccpl |
|---|
| 31 | |
|---|
| 32 | USE albedo ! albedo parameters |
|---|
| 33 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 34 | USE lib_mpp ! MPP library |
|---|
| 35 | USE wrk_nemo ! work arrays |
|---|
| 36 | USE in_out_manager ! I/O manager |
|---|
| 37 | USE diaar5, ONLY : lk_diaar5 |
|---|
| 38 | USE iom ! I/O library |
|---|
| 39 | USE prtctl ! Print control |
|---|
| 40 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | PRIVATE |
|---|
| 44 | |
|---|
| 45 | PUBLIC lim_sbc_init_2 ! called by ice_init_2 |
|---|
| 46 | PUBLIC lim_sbc_flx_2 ! called by sbc_ice_lim_2 |
|---|
| 47 | PUBLIC lim_sbc_tau_2 ! called by sbc_ice_lim_2 |
|---|
| 48 | |
|---|
| 49 | REAL(wp) :: r1_rdtice ! = 1. / rdt_ice |
|---|
| 50 | REAL(wp) :: epsi16 = 1.e-16_wp ! constant values |
|---|
| 51 | REAL(wp) :: rzero = 0._wp ! - - |
|---|
| 52 | REAL(wp) :: rone = 1._wp ! - - |
|---|
| 53 | ! |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0, sice_0 ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean relative velocity [m/s] |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id$ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION lim_sbc_alloc_2() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE lim_sbc_alloc_2 *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc_2) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc_2 ) |
|---|
| 75 | IF( lim_sbc_alloc_2 /= 0 ) CALL ctl_warn('lim_sbc_alloc_2: failed to allocate arrays.') |
|---|
| 76 | ! |
|---|
| 77 | END FUNCTION lim_sbc_alloc_2 |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx_2( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_2 *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update surface ocean boundary condition over areas |
|---|
| 85 | !! that are at least partially covered by sea-ice |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
|---|
| 88 | !! fluxes at the ice-ocean interface. |
|---|
| 89 | !! - Update the fluxes provided to the ocean |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux : solar |
|---|
| 92 | !! - qns : sea heat flux : non solar (including heat content of the mass flux) |
|---|
| 93 | !! - emp : freshwater budget: mass flux |
|---|
| 94 | !! - emps : freshwater budget: salt flux due to Freezing/Melting |
|---|
| 95 | !! - utau : sea surface i-stress (ocean referential) |
|---|
| 96 | !! - vtau : sea surface j-stress (ocean referential) |
|---|
| 97 | !! - fr_i : ice fraction |
|---|
| 98 | !! - tn_ice : sea-ice surface temperature |
|---|
| 99 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 100 | !! |
|---|
| 101 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 102 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 103 | !!--------------------------------------------------------------------- |
|---|
| 104 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 105 | !! |
|---|
| 106 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 107 | INTEGER :: ii0, ii1, ij0, ij1 ! local integers |
|---|
| 108 | INTEGER :: ifvt, i1mfr, idfr, iflt ! - - |
|---|
| 109 | INTEGER :: ial, iadv, ifral, ifrdv ! - - |
|---|
| 110 | REAL(wp) :: zqsr, zqns, zfmm ! local scalars |
|---|
| 111 | REAL(wp) :: zinda, zfsalt, zemp ! - - |
|---|
| 112 | REAL(wp) :: zemp_snw, zqhc, zcd ! - - |
|---|
| 113 | REAL(wp) :: zswitch ! - - |
|---|
| 114 | REAL(wp), POINTER, DIMENSION(:,:) :: zqnsoce ! 2D workspace |
|---|
| 115 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalbp ! 2D/3D workspace |
|---|
| 116 | !!--------------------------------------------------------------------- |
|---|
| 117 | |
|---|
| 118 | CALL wrk_alloc( jpi, jpj, zqnsoce ) |
|---|
| 119 | CALL wrk_alloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 120 | |
|---|
| 121 | zswitch = 1 ! Default standard levitating sea-ice (salt exchanges only) |
|---|
| 122 | !!gm ice embedment |
|---|
| 123 | ! SELECT CASE( nn_ice_embd ) ! levitating/embedded sea-ice option (not yet activated) |
|---|
| 124 | ! CASE( 0 ) ; zswitch = 1 ! standard levitating sea-ice : salt exchange only |
|---|
| 125 | ! CASE( 1, 2 ) ; zswitch = 0 ! other levitating sea-ice or embedded sea-ice : salt and volume fluxes |
|---|
| 126 | ! END SELECT ! |
|---|
| 127 | !!gm end embedment |
|---|
| 128 | !------------------------------------------! |
|---|
| 129 | ! heat flux at the ocean surface ! |
|---|
| 130 | !------------------------------------------! |
|---|
| 131 | |
|---|
| 132 | zqnsoce(:,:) = qns(:,:) |
|---|
| 133 | DO jj = 1, jpj |
|---|
| 134 | DO ji = 1, jpi |
|---|
| 135 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 136 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
|---|
| 137 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
|---|
| 138 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
|---|
| 139 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 140 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 141 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 142 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 143 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 144 | |
|---|
| 145 | !!$ attempt to explain the tricky flags set above.... |
|---|
| 146 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice adv, but before ice thermo) |
|---|
| 147 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice thermo) |
|---|
| 148 | !!$ |
|---|
| 149 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = 1. if there was snow and ice before the ice thermo. which has been completely melted (possibly overmelted) |
|---|
| 150 | !!$ ELSE ; ifvt = 0. ! |
|---|
| 151 | !!$ ENDIF |
|---|
| 152 | !!$ |
|---|
| 153 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases due to ice thermodynamics |
|---|
| 154 | !!$ ELSE ; idfr = 1. |
|---|
| 155 | !!$ ENDIF |
|---|
| 156 | !!$ |
|---|
| 157 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous time and ice-free ocean currently |
|---|
| 158 | !!$ |
|---|
| 159 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 160 | !!$ = i1mfr if ifvt = 1 i.e. |
|---|
| 161 | !!$ = idfr if ifvt = 0 |
|---|
| 162 | !!$! snow no ice ice ice or nothing lead fraction increases |
|---|
| 163 | !!$! at previous now at previous |
|---|
| 164 | !!$! -> ice area increases ??? -> ice area decreases ??? |
|---|
| 165 | !!$ |
|---|
| 166 | !!$ iadv = ( 1 - i1mfr ) * zinda |
|---|
| 167 | !!$! pure ocean ice at |
|---|
| 168 | !!$! at current previous |
|---|
| 169 | !!$! -> = 1. if ice disapear between previous and current |
|---|
| 170 | !!$ |
|---|
| 171 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 172 | !!$! ice at ??? |
|---|
| 173 | !!$! current |
|---|
| 174 | !!$! -> ??? |
|---|
| 175 | !!$ |
|---|
| 176 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 177 | !!$! ice disapear |
|---|
| 178 | !!$ |
|---|
| 179 | !!$ |
|---|
| 180 | |
|---|
| 181 | ! computation the solar flux at ocean surface |
|---|
| 182 | #if defined key_coupled |
|---|
| 183 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 184 | #else |
|---|
| 185 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 186 | #endif |
|---|
| 187 | ! computation the non solar heat flux at ocean surface |
|---|
| 188 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
|---|
| 189 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
|---|
| 190 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
|---|
| 191 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice |
|---|
| 192 | |
|---|
| 193 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! store residual heat flux (to put into the ocean at the next time-step) |
|---|
| 194 | zqhc = ( rdq_snw(ji,jj) + rdq_ice(ji,jj) ) * r1_rdtice ! heat flux due to snow & ice heat content exchange |
|---|
| 195 | ! |
|---|
| 196 | qsr (ji,jj) = zqsr ! solar heat flux |
|---|
| 197 | qns (ji,jj) = zqns - fdtcn(ji,jj) + zqhc ! non solar heat flux |
|---|
| 198 | ! !------------------------------------------! |
|---|
| 199 | ! ! mass flux at the ocean surface ! |
|---|
| 200 | ! !------------------------------------------! |
|---|
| 201 | ! |
|---|
| 202 | ! mass flux at the ocean-atmosphere interface (open ocean fraction = leads area) |
|---|
| 203 | #if defined key_coupled |
|---|
| 204 | ! ! coupled mode: |
|---|
| 205 | zemp = + emp_tot(ji,jj) & ! net mass flux over the grid cell (ice+ocean area) |
|---|
| 206 | & - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) ! minus the mass flux intercepted by sea-ice |
|---|
| 207 | #else |
|---|
| 208 | ! ! forced mode: |
|---|
| 209 | zemp = + emp(ji,jj) * frld(ji,jj) & ! mass flux over open ocean fraction |
|---|
| 210 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precip. over ice reaches directly the ocean |
|---|
| 211 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) ! snow is intercepted by sea-ice (previous frld) |
|---|
| 212 | #endif |
|---|
| 213 | ! |
|---|
| 214 | ! mass flux at the ocean/ice interface (sea ice fraction) |
|---|
| 215 | zemp_snw = rdm_snw(ji,jj) * r1_rdtice ! snow melting = pure water that enters the ocean |
|---|
| 216 | zfmm = rdm_ice(ji,jj) * r1_rdtice ! Freezing minus Melting (F-M) |
|---|
| 217 | |
|---|
| 218 | ! salt flux at the ice/ocean interface (sea ice fraction) [PSU*kg/m2/s] |
|---|
| 219 | zfsalt = - sice_0(ji,jj) * zfmm ! F-M salt exchange |
|---|
| 220 | zcd = soce_0(ji,jj) * zfmm ! concentration/dilution term due to F-M |
|---|
| 221 | ! |
|---|
| 222 | ! salt flux only : add concentration dilution term in salt flux and no F-M term in volume flux |
|---|
| 223 | ! salt and mass fluxes : non concentartion dilution term in salt flux and add F-M term in volume flux |
|---|
| 224 | emps(ji,jj) = zfsalt + zswitch * zcd ! salt flux (+ C/D if no ice/ocean mass exchange) |
|---|
| 225 | emp (ji,jj) = zemp + zemp_snw + ( 1.- zswitch) * zfmm ! mass flux (- F/M mass flux if no ice/ocean mass exchange) |
|---|
| 226 | ! |
|---|
| 227 | END DO |
|---|
| 228 | END DO |
|---|
| 229 | |
|---|
| 230 | CALL iom_put( 'hflx_ice_cea', - fdtcn(:,:) ) |
|---|
| 231 | CALL iom_put( 'qns_io_cea', qns(:,:) - zqnsoce(:,:) * pfrld(:,:) ) |
|---|
| 232 | CALL iom_put( 'qsr_io_cea', fstric(:,:) * (1.e0 - pfrld(:,:)) ) |
|---|
| 233 | |
|---|
| 234 | IF( lk_diaar5 ) THEN ! AR5 diagnostics |
|---|
| 235 | CALL iom_put( 'isnwmlt_cea' , rdm_snw(:,:) * r1_rdtice ) |
|---|
| 236 | CALL iom_put( 'fsal_virt_cea', soce_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
|---|
| 237 | CALL iom_put( 'fsal_real_cea', - sice_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
|---|
| 238 | ENDIF |
|---|
| 239 | |
|---|
| 240 | !-----------------------------------------------! |
|---|
| 241 | ! Coupling variables ! |
|---|
| 242 | !-----------------------------------------------! |
|---|
| 243 | |
|---|
| 244 | #if defined key_coupled |
|---|
| 245 | tn_ice(:,:,1) = sist(:,:) ! sea-ice surface temperature |
|---|
| 246 | ht_i(:,:,1) = hicif(:,:) |
|---|
| 247 | ht_s(:,:,1) = hsnif(:,:) |
|---|
| 248 | a_i(:,:,1) = fr_i(:,:) |
|---|
| 249 | ! ! Computation of snow/ice and ocean albedo |
|---|
| 250 | CALL albedo_ice( tn_ice, ht_i, ht_s, zalbp, zalb ) |
|---|
| 251 | alb_ice(:,:,1) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
|---|
| 252 | CALL iom_put( "icealb_cea", alb_ice(:,:,1) * fr_i(:,:) ) ! ice albedo |
|---|
| 253 | #endif |
|---|
| 254 | |
|---|
| 255 | IF(ln_ctl) THEN ! control print |
|---|
| 256 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
|---|
| 257 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps , clinfo2=' emps : ') |
|---|
| 258 | CALL prt_ctl(tab2d_1=utau , clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 259 | & tab2d_2=vtau , clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 260 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice(:,:,1), clinfo2=' tn_ice : ') |
|---|
| 261 | ENDIF |
|---|
| 262 | ! |
|---|
| 263 | CALL wrk_dealloc( jpi, jpj, zqnsoce ) |
|---|
| 264 | CALL wrk_dealloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 265 | ! |
|---|
| 266 | END SUBROUTINE lim_sbc_flx_2 |
|---|
| 267 | |
|---|
| 268 | |
|---|
| 269 | SUBROUTINE lim_sbc_tau_2( kt , pu_oce, pv_oce ) |
|---|
| 270 | !!------------------------------------------------------------------- |
|---|
| 271 | !! *** ROUTINE lim_sbc_tau_2 *** |
|---|
| 272 | !! |
|---|
| 273 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 274 | !! |
|---|
| 275 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 276 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 277 | !! at T-point (C-grid) or I-point (B-grid) |
|---|
| 278 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 279 | !! - update the modulus of stress at ocean surface |
|---|
| 280 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 281 | !! * at each ocean time step (each kt): |
|---|
| 282 | !! compute linearized ice-ocean stresses as |
|---|
| 283 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 284 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 285 | !! |
|---|
| 286 | !! NB: - the averaging operator used depends on the ice dynamics grid (cp_ice_msh='I' or 'C') |
|---|
| 287 | !! - ice-ocean rotation angle only allowed in cp_ice_msh='I' case |
|---|
| 288 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 289 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 290 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximation... |
|---|
| 291 | !! |
|---|
| 292 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 293 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 294 | !!--------------------------------------------------------------------- |
|---|
| 295 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 296 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 297 | !! |
|---|
| 298 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 299 | REAL(wp) :: zfrldu, zat_u, zu_i, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 300 | REAL(wp) :: zfrldv, zat_v, zv_i, zvtau_ice, zv_t, zmodi ! - - |
|---|
| 301 | REAL(wp) :: zsang, zumt ! - - |
|---|
| 302 | REAL(wp), POINTER, DIMENSION(:,:) :: ztio_u, ztio_v ! ocean stress below sea-ice |
|---|
| 303 | !!--------------------------------------------------------------------- |
|---|
| 304 | ! |
|---|
| 305 | CALL wrk_alloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 306 | ! |
|---|
| 307 | SELECT CASE( cp_ice_msh ) |
|---|
| 308 | ! !-----------------------! |
|---|
| 309 | CASE( 'I' ) ! B-grid ice dynamics ! I-point (i.e. F-point with sea-ice indexation) |
|---|
| 310 | ! !--=--------------------! |
|---|
| 311 | ! |
|---|
| 312 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 313 | !CDIR NOVERRCHK |
|---|
| 314 | DO jj = 1, jpj !* modulus of ice-ocean relative velocity at I-point |
|---|
| 315 | !CDIR NOVERRCHK |
|---|
| 316 | DO ji = 1, jpi |
|---|
| 317 | zu_i = u_ice(ji,jj) - u_oce(ji,jj) ! ice-ocean relative velocity at I-point |
|---|
| 318 | zv_i = v_ice(ji,jj) - v_oce(ji,jj) |
|---|
| 319 | tmod_io(ji,jj) = SQRT( zu_i * zu_i + zv_i * zv_i ) ! modulus of this velocity (at I-point) |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | !CDIR NOVERRCHK |
|---|
| 323 | DO jj = 1, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 324 | !CDIR NOVERRCHK |
|---|
| 325 | DO ji = 1, jpim1 ! NO vector opt. |
|---|
| 326 | ! ! modulus of U_ice-U_oce at T-point |
|---|
| 327 | zumt = 0.25_wp * ( tmod_io(ji+1,jj) + tmod_io(ji ,jj ) & |
|---|
| 328 | & + tmod_io(ji,jj+1) + tmod_io(ji+1,jj+1) ) |
|---|
| 329 | ! ! update the modulus of stress at ocean surface |
|---|
| 330 | taum(ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zumt * zumt |
|---|
| 331 | END DO |
|---|
| 332 | END DO |
|---|
| 333 | CALL lbc_lnk( taum, 'T', 1. ) |
|---|
| 334 | ! |
|---|
| 335 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 336 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 337 | ! |
|---|
| 338 | ENDIF |
|---|
| 339 | ! |
|---|
| 340 | ! !== at each ocean time-step ==! |
|---|
| 341 | ! |
|---|
| 342 | ! !* ice/ocean stress WITH a ice-ocean rotation angle at I-point |
|---|
| 343 | DO jj = 2, jpj |
|---|
| 344 | zsang = SIGN( 1._wp, gphif(1,jj) ) * sangvg ! change the cosine angle sign in the SH |
|---|
| 345 | DO ji = 2, jpi ! NO vect. opt. possible |
|---|
| 346 | ! ... ice-ocean relative velocity at I-point using instantaneous surface ocean current at u- & v-pts |
|---|
| 347 | zu_i = u_ice(ji,jj) - 0.5_wp * ( pu_oce(ji-1,jj ) + pu_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 348 | zv_i = v_ice(ji,jj) - 0.5_wp * ( pv_oce(ji ,jj-1) + pv_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 349 | ! ... components of stress with a ice-ocean rotation angle |
|---|
| 350 | zmodi = rhoco * tmod_io(ji,jj) |
|---|
| 351 | ztio_u(ji,jj) = zmodi * ( cangvg * zu_i - zsang * zv_i ) |
|---|
| 352 | ztio_v(ji,jj) = zmodi * ( cangvg * zv_i + zsang * zu_i ) |
|---|
| 353 | END DO |
|---|
| 354 | END DO |
|---|
| 355 | ! !* surface ocean stresses at u- and v-points |
|---|
| 356 | DO jj = 2, jpjm1 |
|---|
| 357 | DO ji = 2, jpim1 ! NO vector opt. |
|---|
| 358 | ! ! ice-ocean stress at U and V-points (from I-point values) |
|---|
| 359 | zutau_ice = 0.5_wp * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
|---|
| 360 | zvtau_ice = 0.5_wp * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
|---|
| 361 | ! ! open-ocean (lead) fraction at U- & V-points (from T-point values) |
|---|
| 362 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 363 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 364 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 365 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 366 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 370 | ! |
|---|
| 371 | ! |
|---|
| 372 | ! !-----------------------! |
|---|
| 373 | CASE( 'C' ) ! C-grid ice dynamics ! U & V-points (same as in the ocean) |
|---|
| 374 | ! !--=--------------------! |
|---|
| 375 | ! |
|---|
| 376 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 377 | !CDIR NOVERRCHK |
|---|
| 378 | DO jj = 2, jpjm1 !* modulus of the ice-ocean velocity at T-point |
|---|
| 379 | !CDIR NOVERRCHK |
|---|
| 380 | DO ji = fs_2, fs_jpim1 |
|---|
| 381 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) ! 2*(U_ice-U_oce) at T-point |
|---|
| 382 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 383 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) ! |U_ice-U_oce|^2 |
|---|
| 384 | ! ! update the modulus of stress at ocean surface |
|---|
| 385 | taum (ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zmodt |
|---|
| 386 | tmod_io(ji,jj) = SQRT( zmodt ) * rhoco ! rhoco*|Uice-Uoce| |
|---|
| 387 | END DO |
|---|
| 388 | END DO |
|---|
| 389 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 390 | ! |
|---|
| 391 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 392 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 393 | ! |
|---|
| 394 | ENDIF |
|---|
| 395 | ! |
|---|
| 396 | ! !== at each ocean time-step ==! |
|---|
| 397 | ! |
|---|
| 398 | DO jj = 2, jpjm1 !* ice stress over ocean WITHOUT a ice-ocean rotation angle |
|---|
| 399 | DO ji = fs_2, fs_jpim1 |
|---|
| 400 | ! ! ocean area at u- & v-points |
|---|
| 401 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 402 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 403 | ! ! quadratic drag formulation without rotation |
|---|
| 404 | ! ! using instantaneous surface ocean current |
|---|
| 405 | zutau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 406 | zvtau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 407 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 408 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 409 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 410 | END DO |
|---|
| 411 | END DO |
|---|
| 412 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 413 | ! |
|---|
| 414 | END SELECT |
|---|
| 415 | |
|---|
| 416 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 417 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 418 | ! |
|---|
| 419 | CALL wrk_dealloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 420 | ! |
|---|
| 421 | END SUBROUTINE lim_sbc_tau_2 |
|---|
| 422 | |
|---|
| 423 | |
|---|
| 424 | SUBROUTINE lim_sbc_init_2 |
|---|
| 425 | !!------------------------------------------------------------------- |
|---|
| 426 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 427 | !! |
|---|
| 428 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 429 | !! the temporal evolution of key variables |
|---|
| 430 | !! |
|---|
| 431 | !! ** input : Namelist namicedia |
|---|
| 432 | !!------------------------------------------------------------------- |
|---|
| 433 | ! |
|---|
| 434 | IF(lwp) WRITE(numout,*) |
|---|
| 435 | IF(lwp) WRITE(numout,*) 'lim_sbc_init_2 : LIM-2 sea-ice - surface boundary condition' |
|---|
| 436 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ ' |
|---|
| 437 | |
|---|
| 438 | ! ! allocate lim_sbc arrays |
|---|
| 439 | IF( lim_sbc_alloc_2() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_flx_2 : unable to allocate arrays' ) |
|---|
| 440 | ! |
|---|
| 441 | r1_rdtice = 1._wp / rdt_ice |
|---|
| 442 | ! |
|---|
| 443 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 444 | sice_0(:,:) = sice |
|---|
| 445 | ! |
|---|
| 446 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 447 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 448 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 449 | soce_0(:,:) = 4._wp |
|---|
| 450 | sice_0(:,:) = 2._wp |
|---|
| 451 | END WHERE |
|---|
| 452 | ENDIF |
|---|
| 453 | ! |
|---|
| 454 | END SUBROUTINE lim_sbc_init_2 |
|---|
| 455 | |
|---|
| 456 | #else |
|---|
| 457 | !!---------------------------------------------------------------------- |
|---|
| 458 | !! Default option Empty module NO LIM 2.0 sea-ice model |
|---|
| 459 | !!---------------------------------------------------------------------- |
|---|
| 460 | #endif |
|---|
| 461 | |
|---|
| 462 | !!====================================================================== |
|---|
| 463 | END MODULE limsbc_2 |
|---|
