New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 3524

Last change on this file since 3524 was 3524, checked in by gm, 11 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. add USE lib_fortran when SIGN is used (TOP,OPA,LIM2&3) ; salt flux names start with sfx_ in LIM3
  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trdmod_oce     ! tracers trends
19   USE trdtra         ! tracers trends
20   USE in_out_manager ! I/O manager
21   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
22   USE trabbl         ! tracers: bottom boundary layer
23   USE lib_mpp        ! distribued memory computing
24   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
25   USE diaptr         ! poleward transport diagnostics
26   USE trc_oce        ! share passive tracers/Ocean variables
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_muscl  ! routine called by step.F90
35
36   LOGICAL  :: l_trd       ! flag to compute trends
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, &
49      &                                        ptb, pta, kjpt )
50      !!----------------------------------------------------------------------
51      !!                    ***  ROUTINE tra_adv_muscl  ***
52      !!
53      !! ** Purpose :   Compute the now trend due to total advection of T and
54      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
55      !!      Conservation Laws) and add it to the general tracer trend.
56      !!
57      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
58      !!
59      !! ** Action  : - update (ta,sa) with the now advective tracer trends
60      !!              - save trends
61      !!
62      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
63      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
64      !!----------------------------------------------------------------------
65      USE oce     , ONLY:   zwx   => ua    , zwy   => va          ! (ua,va) used as workspace
66      !
67      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
68      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
71      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
72      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
75      !
76      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
77      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
78      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
79      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl')
84      !
85      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
86      !
87
88      IF( kt == kit000 )  THEN
89         IF(lwp) WRITE(numout,*)
90         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
91         IF(lwp) WRITE(numout,*) '~~~~~~~'
92         !
93         l_trd = .FALSE.
94         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
95      ENDIF
96
97      !                                                     ! ===========
98      DO jn = 1, kjpt                                       ! tracer loop
99         !                                                  ! ===========
100         ! I. Horizontal advective fluxes
101         ! ------------------------------
102         ! first guess of the slopes
103         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
104         ! interior values
105         DO jk = 1, jpkm1
106            DO jj = 1, jpjm1     
107               DO ji = 1, fs_jpim1   ! vector opt.
108                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
109                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
110               END DO
111           END DO
112         END DO
113         !
114         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
115         CALL lbc_lnk( zwy, 'V', -1. )
116         !                                             !-- Slopes of tracer
117         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
118         DO jk = 1, jpkm1                                     ! interior values
119            DO jj = 2, jpj
120               DO ji = fs_2, jpi   ! vector opt.
121                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
122                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
123                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
124                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
125               END DO
126            END DO
127         END DO
128         !
129         DO jk = 1, jpkm1                                     ! Slopes limitation
130            DO jj = 2, jpj
131               DO ji = fs_2, jpi   ! vector opt.
132                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
133                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
134                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
135                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
136                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
137                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
138               END DO
139           END DO
140         END DO             ! interior values
141
142         !                                             !-- MUSCL horizontal advective fluxes
143         DO jk = 1, jpkm1                                     ! interior values
144            zdt  = p2dt(jk)
145            DO jj = 2, jpjm1
146               DO ji = fs_2, fs_jpim1   ! vector opt.
147                  ! MUSCL fluxes
148                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
149                  zalpha = 0.5 - z0u
150                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
151                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
152                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
153                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
154                  !
155                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
156                  zalpha = 0.5 - z0v
157                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
158                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
159                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
160                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
161               END DO
162            END DO
163         END DO
164         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
165         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
166         !
167         ! Tracer flux divergence at t-point added to the general trend
168         DO jk = 1, jpkm1
169            DO jj = 2, jpjm1     
170               DO ji = fs_2, fs_jpim1   ! vector opt.
171                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
172                  ! horizontal advective trends
173                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
174                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
175                  ! add it to the general tracer trends
176                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
177               END DO
178           END DO
179         END DO       
180         !                                 ! trend diagnostics (contribution of upstream fluxes)
181         IF( l_trd )  THEN
182            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
183            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
184         END IF
185         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
186         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
187            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
188            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
189         ENDIF
190
191         ! II. Vertical advective fluxes
192         ! -----------------------------
193         !                                             !-- first guess of the slopes
194         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
195         DO jk = 2, jpkm1                                     ! interior values
196            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
197         END DO
198
199         !                                             !-- Slopes of tracer
200         zslpx(:,:,1) = 0.e0                                  ! surface values
201         DO jk = 2, jpkm1                                     ! interior value
202            DO jj = 1, jpj
203               DO ji = 1, jpi
204                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
205                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
206               END DO
207            END DO
208         END DO
209         !                                             !-- Slopes limitation
210         DO jk = 2, jpkm1                                     ! interior values
211            DO jj = 1, jpj
212               DO ji = 1, jpi
213                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
214                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
215                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
216               END DO
217            END DO
218         END DO
219         !                                             !-- vertical advective flux
220         !                                                    ! surface values  (bottom already set to zero)
221         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
222         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
223         ENDIF 
224         !
225         DO jk = 1, jpkm1                                     ! interior values
226            zdt  = p2dt(jk)
227            DO jj = 2, jpjm1     
228               DO ji = fs_2, fs_jpim1   ! vector opt.
229                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
230                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
231                  zalpha = 0.5 + z0w
232                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
233                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
234                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
235                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
236               END DO
237            END DO
238         END DO
239
240         ! Compute & add the vertical advective trend
241         DO jk = 1, jpkm1
242            DO jj = 2, jpjm1     
243               DO ji = fs_2, fs_jpim1   ! vector opt.
244                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
245                  ! vertical advective trends
246                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
247                  ! add it to the general tracer trends
248                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
249               END DO
250            END DO
251         END DO
252         !                                 ! Save the vertical advective trends for diagnostic
253         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
254         !
255      ENDDO
256      !
257      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
258      !
259      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl')
260      !
261   END SUBROUTINE tra_adv_muscl
262
263   !!======================================================================
264END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.