New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 3524

Last change on this file since 3524 was 3524, checked in by gm, 11 years ago

Branch: dev_r3385_NOCS04_HAMF; #665. add USE lib_fortran when SIGN is used (TOP,OPA,LIM2&3) ; salt flux names start with sfx_ in LIM3

  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trdmod_oce     ! tracers trends
25   USE trdtra         ! tracers trends
26   USE in_out_manager ! I/O manager
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE lib_mpp        ! MPP library
29   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
30   USE diaptr         ! poleward transport diagnostics
31   USE trc_oce        ! share passive tracers/Ocean variables
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL ::   l_trd   ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
54      &                                       ptb, ptn, pta, kjpt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_adv_tvd  ***
57      !!
58      !! **  Purpose :   Compute the now trend due to total advection of
59      !!       tracers and add it to the general trend of tracer equations
60      !!
61      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
62      !!       corrected flux (monotonic correction)
63      !!       note: - this advection scheme needs a leap-frog time scheme
64      !!
65      !! ** Action : - update (pta) with the now advective tracer trends
66      !!             - save the trends
67      !!----------------------------------------------------------------------
68      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
69      !
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
75      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
78      !
79      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
80      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
81      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
82      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
85      !!----------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
88      !
89      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
90      !
91      IF( kt == kit000 )  THEN
92         IF(lwp) WRITE(numout,*)
93         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
94         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
95         !
96         l_trd = .FALSE.
97         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
98      ENDIF
99      !
100      IF( l_trd )  THEN
101         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
102         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
103      ENDIF
104      !
105      zwi(:,:,:) = 0.e0
106      !
107      !                                                          ! ===========
108      DO jn = 1, kjpt                                            ! tracer loop
109         !                                                       ! ===========
110         ! 1. Bottom value : flux set to zero
111         ! ----------------------------------
112         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
113         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
114
115         ! 2. upstream advection with initial mass fluxes & intermediate update
116         ! --------------------------------------------------------------------
117         ! upstream tracer flux in the i and j direction
118         DO jk = 1, jpkm1
119            DO jj = 1, jpjm1
120               DO ji = 1, fs_jpim1   ! vector opt.
121                  ! upstream scheme
122                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
123                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
124                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
125                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
126                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
127                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
128               END DO
129            END DO
130         END DO
131
132         ! upstream tracer flux in the k direction
133         ! Surface value
134         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
135         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
136         ENDIF
137         ! Interior value
138         DO jk = 2, jpkm1
139            DO jj = 1, jpj
140               DO ji = 1, jpi
141                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
142                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
143                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
144               END DO
145            END DO
146         END DO
147
148         ! total advective trend
149         DO jk = 1, jpkm1
150            z2dtt = p2dt(jk)
151            DO jj = 2, jpjm1
152               DO ji = fs_2, fs_jpim1   ! vector opt.
153                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
154                  ! total intermediate advective trends
155                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
156                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
157                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
158                  ! update and guess with monotonic sheme
159                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
160                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
161               END DO
162            END DO
163         END DO
164         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
165         CALL lbc_lnk( zwi, 'T', 1. ) 
166
167         !                                 ! trend diagnostics (contribution of upstream fluxes)
168         IF( l_trd )  THEN 
169            ! store intermediate advective trends
170            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
171         END IF
172         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
173         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
174           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
175           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
176         ENDIF
177
178         ! 3. antidiffusive flux : high order minus low order
179         ! --------------------------------------------------
180         ! antidiffusive flux on i and j
181         DO jk = 1, jpkm1
182            DO jj = 1, jpjm1
183               DO ji = 1, fs_jpim1   ! vector opt.
184                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
185                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
186               END DO
187            END DO
188         END DO
189     
190         ! antidiffusive flux on k
191         zwz(:,:,1) = 0.e0         ! Surface value
192         !
193         DO jk = 2, jpkm1          ! Interior value
194            DO jj = 1, jpj
195               DO ji = 1, jpi
196                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
197               END DO
198            END DO
199         END DO
200         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
201         CALL lbc_lnk( zwz, 'W',  1. )
202
203         ! 4. monotonicity algorithm
204         ! -------------------------
205         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
206
207
208         ! 5. final trend with corrected fluxes
209         ! ------------------------------------
210         DO jk = 1, jpkm1
211            DO jj = 2, jpjm1
212               DO ji = fs_2, fs_jpim1   ! vector opt. 
213                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
214                  ! total advective trends
215                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
216                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
217                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
218                  ! add them to the general tracer trends
219                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
220               END DO
221            END DO
222         END DO
223
224         !                                 ! trend diagnostics (contribution of upstream fluxes)
225         IF( l_trd )  THEN
226            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
227            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
228            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
229           
230            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
231            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
232            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
233         END IF
234         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
235         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
236           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
237           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
238         ENDIF
239         !
240      END DO
241      !
242                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
243      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
244      !
245      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
246      !
247   END SUBROUTINE tra_adv_tvd
248
249
250   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
251      !!---------------------------------------------------------------------
252      !!                    ***  ROUTINE nonosc  ***
253      !!     
254      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
255      !!       scheme and the before field by a nonoscillatory algorithm
256      !!
257      !! **  Method  :   ... ???
258      !!       warning : pbef and paft must be masked, but the boundaries
259      !!       conditions on the fluxes are not necessary zalezak (1979)
260      !!       drange (1995) multi-dimensional forward-in-time and upstream-
261      !!       in-space based differencing for fluid
262      !!----------------------------------------------------------------------
263      !
264      !!----------------------------------------------------------------------
265      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
266      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
267      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
268      !
269      INTEGER ::   ji, jj, jk   ! dummy loop indices
270      INTEGER ::   ikm1         ! local integer
271      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
272      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
273      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
274      !!----------------------------------------------------------------------
275      !
276      IF( nn_timing == 1 )  CALL timing_start('nonosc')
277      !
278      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
279      !
280
281      zbig  = 1.e+40_wp
282      zrtrn = 1.e-15_wp
283      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
284
285
286      ! Search local extrema
287      ! --------------------
288      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
289      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
290         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
291      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
292         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
293
294      DO jk = 1, jpkm1
295         ikm1 = MAX(jk-1,1)
296         z2dtt = p2dt(jk)
297         DO jj = 2, jpjm1
298            DO ji = fs_2, fs_jpim1   ! vector opt.
299
300               ! search maximum in neighbourhood
301               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
302                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
303                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
304                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
305
306               ! search minimum in neighbourhood
307               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
308                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
309                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
310                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
311
312               ! positive part of the flux
313               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
314                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
315                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
316
317               ! negative part of the flux
318               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
319                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
320                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
321
322               ! up & down beta terms
323               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
324               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
325               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
326            END DO
327         END DO
328      END DO
329      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
330
331      ! 3. monotonic flux in the i & j direction (paa & pbb)
332      ! ----------------------------------------
333      DO jk = 1, jpkm1
334         DO jj = 2, jpjm1
335            DO ji = fs_2, fs_jpim1   ! vector opt.
336               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
337               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
338               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
339               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
340
341               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
342               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
343               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
344               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
345
346      ! monotonic flux in the k direction, i.e. pcc
347      ! -------------------------------------------
348               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
349               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
350               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
351               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
352            END DO
353         END DO
354      END DO
355      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
356      !
357      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
358      !
359      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
360      !
361   END SUBROUTINE nonosc
362
363   !!======================================================================
364END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.