New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2012/dev_r3438_LOCEAN15_PISLOB/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2012/dev_r3438_LOCEAN15_PISLOB/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 3496

Last change on this file since 3496 was 3496, checked in by cetlod, 12 years ago

branch:2012/dev_r3438_LOCEAN15_PISLOB: minor changes in PISCES log files, see ticket #972
File size: 18.6 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: ryyss                    !: number of seconds per year
36   REAL(wp) :: r1_ryyss                 !: inverse of ryyss
37   REAL(wp) :: rmtss                    !: number of seconds per month
38   REAL(wp) :: r1_rday                  !: inverse of rday
39
40   INTEGER ::  numnit 
41
42
43   !!* Substitution
44#  include "top_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Header:$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_sed( kt, jnt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_sed  ***
55      !!
56      !! ** Purpose :   Compute loss of organic matter in the sediments. This
57      !!              is by no way a sediment model. The loss is simply
58      !!              computed to balance the inout from rivers and dust
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      !
63      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
64      INTEGER  ::   ji, jj, jk, ikt
65#if ! defined key_sed
66      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
67      REAL(wp) ::   zrivalk, zrivsil, zrivno3
68#endif
69      REAL(wp) ::  zwflux, zfminus, zfplus
70      REAL(wp) ::  zlim, zfact, zfactcal
71      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit
72      REAL(wp) ::  zsiloss, zcaloss, zwsbio3, zwsbio4, zwscal, zdep, zwstpoc
73      REAL(wp) ::  ztrfer, ztrpo4, zwdust
74!!Ch 
75      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot, znitrfix
76!!Ch 
77      CHARACTER (len=25) :: charout
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep
81      !!---------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
84      !
85      IF( kt == nit000 .AND. jnt == 1 )  THEN
86         ryyss    = nyear_len(1) * rday    ! number of seconds per year and per month
87         rmtss    = ryyss / raamo
88         r1_rday  = 1. / rday
89         r1_ryyss = 1. / ryyss
90         IF(lwp) CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
91      ENDIF
92      !
93      ! Allocate temporary workspace
94      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 )
95      CALL wrk_alloc( jpi, jpj, jpk, znitrpot )
96      zdenit2d(:,:) = 0.e0
97
98      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
99      ! ----------------------------------------------------
100      IF( ln_ironice ) THEN 
101         !                                             
102         CALL wrk_alloc( jpi, jpj, zironice )
103         !                                             
104         DO jj = 1, jpj
105            DO ji = 1, jpi
106               zdep    = rfact2 / fse3t(ji,jj,1)
107               zwflux  = ( emps(ji,jj) - emp(ji,jj) ) &
108               &        * tsn(ji,jj,1,jp_sal) / ( tsn(ji,jj,1,jp_sal) - 6.0 ) / 1000.
109               zfminus = MIN( 0., -zwflux ) * trn(ji,jj,1,jpfer) * zdep
110               zfplus  = MAX( 0., -zwflux ) * 10E-9 * zdep
111               zironice(ji,jj) =  zfplus + zfminus
112            END DO
113         END DO
114         !
115         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) 
116         !                                             
117         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
118            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
119         CALL wrk_dealloc( jpi, jpj, zironice )
120         !                                             
121      ENDIF
122
123      ! Add the external input of nutrients from dust deposition
124      ! ----------------------------------------------------------
125      IF( ln_dust ) THEN
126         !                                             
127         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
128         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
129         !                                              ! Iron and Si deposition at the surface
130         IF( ln_solub ) THEN
131            zirondep(:,:,1) = solub(:,:) * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
132         ELSE
133            zirondep(:,:,1) = dustsolub  * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
134         ENDIF
135         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 28.1  * rmtss )
136         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 31.   * rmtss )
137         !                                              ! Iron solubilization of particles in the water column
138         zwdust = 0.005 / ( wdust * 55.85 * 30.42 ) / ( 45. * rday ) 
139         DO jk = 2, jpkm1
140            zirondep(:,:,jk) = dust(:,:) * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 1000. )
141         END DO
142         !                                              ! Iron solubilization of particles in the water column
143         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
144         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
145         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
146         !                                             
147         IF( ln_diatrc ) THEN
148            zfact = 1.e+3 * rfact2r
149            IF( lk_iomput .AND. jnt == nrdttrc ) THEN
150               CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
151               CALL iom_put( "pdust"  , dust(:,:) / ( wdust * 30.42 * 0.035 )  * tmask(:,:,1) ) ! dust concentration at surface
152            ELSE
153               trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1)
154            ENDIF
155         ENDIF
156         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
157         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
158         !                                             
159      ENDIF
160     
161      ! Add the external input of nutrients from river
162      ! ----------------------------------------------------------
163      IF( ln_river ) THEN
164         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
165         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
166         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
167         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
168         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
169         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
170      ENDIF
171     
172      ! Add the external input of nutrients from nitrogen deposition
173      ! ----------------------------------------------------------
174      IF( ln_ndepo ) THEN
175         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
176         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
177      ENDIF
178
179      ! Add the external input of iron from sediment mobilization
180      ! ------------------------------------------------------
181      IF( ln_ironsed ) THEN
182         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
183         !
184         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
185            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
186      ENDIF
187
188      ! Add the external input of iron from hydrothermal vents
189      ! ------------------------------------------------------
190      IF( ln_hydrofe ) THEN
191         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
192         !
193         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
194            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
195      ENDIF
196
197#if ! defined key_sed
198      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
199      ! -------------------------------------------------------
200      DO jj = 1, jpj
201         DO ji = 1, jpi
202           IF( tmask(ji,jj,1) == 1 ) THEN
203              ikt = mbkt(ji,jj)
204# if defined key_kriest
205              zflx =    trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt)    * 1E3 * 1E6 / 1E4
206# else
207              zflx = (  trn(ji,jj,ikt,jpgoc) * wsbio4(ji,jj,ikt)   &
208                &     + trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) )  * 1E3 * 1E6 / 1E4
209#endif
210              zflx  = LOG10( MAX( 1E-3, zflx ) )
211              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
212              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
213              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
214              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
215              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
216              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
217           ENDIF
218         END DO
219      END DO 
220      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
221      ! First, the total loss is computed.
222      ! The factor for calcite comes from the alkalinity effect
223      ! -------------------------------------------------------------
224      DO jj = 1, jpj
225         DO ji = 1, jpi
226            ikt = mbkt(ji,jj) 
227# if defined key_kriest
228            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * wscal (ji,jj,ikt)
229            zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt)
230# else
231            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * wsbio4(ji,jj,ikt)
232            zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * wsbio4(ji,jj,ikt) + trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) 
233# endif
234            ! For calcite, burial efficiency is made a function of saturation
235            zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
236            zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
237            zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * wscal (ji,jj,ikt) * 2.e0 * zfactcal
238         END DO
239      END DO
240      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
241      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
242      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
243#endif
244
245      ! THEN this loss is scaled at each bottom grid cell for
246      ! equilibrating the total budget of silica in the ocean.
247      ! Thus, the amount of silica lost in the sediments equal
248      ! the supply at the surface (dust+rivers)
249      ! ------------------------------------------------------
250#if ! defined key_sed
251      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / zsumsedsi
252      zrivno3 =  1._wp - ( rivdininput * r1_ryyss ) / zsumsedpo4
253#endif
254
255      DO jj = 1, jpj
256         DO ji = 1, jpi
257            ikt  = mbkt(ji,jj)
258            zdep = xstep / fse3t(ji,jj,ikt)
259            zwsbio4 = wsbio4(ji,jj,ikt) * zdep
260            zwscal  = wscal (ji,jj,ikt) * zdep
261# if defined key_kriest
262            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsbio4
263# else
264            zsiloss = trn(ji,jj,ikt,jpgsi) * zwscal
265# endif
266            zcaloss = trn(ji,jj,ikt,jpcal) * zwscal
267            !
268            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
269            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
270#if ! defined key_sed
271            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
272            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
273            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
274            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / zsumsedcal 
275            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
276            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
277#endif
278         END DO
279      END DO
280
281      DO jj = 1, jpj
282         DO ji = 1, jpi
283            ikt     = mbkt(ji,jj)
284            zdep    = xstep / fse3t(ji,jj,ikt)
285            zwsbio4 = wsbio4(ji,jj,ikt) * zdep
286            zwsbio3 = wsbio3(ji,jj,ikt) * zdep
287# if ! defined key_kriest
288            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zwsbio4
289            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zwsbio3
290            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zwsbio4
291            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zwsbio3
292            zwstpoc =  trn(ji,jj,ikt,jpgoc) * zwsbio4 + trn(ji,jj,ikt,jppoc) * zwsbio3 
293# else
294            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zwsbio4
295            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zwsbio3
296            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zwsbio3
297            zwstpoc = trn(ji,jj,ikt,jppoc) * zwsbio3 
298# endif
299
300#if ! defined key_sed
301            zpdenit  = MIN( ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
302            z1pdenit = zwstpoc * zrivno3 - zpdenit
303            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit
304            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit
305            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit
306            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * zpdenit
307            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * ( 1. + rdenit ) * zpdenit
308            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit
309            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
310#endif
311         END DO
312      END DO
313
314      ! Nitrogen fixation process
315      !-----------------------------------
316      DO jk = 1, jpkm1
317         DO jj = 1, jpj
318            DO ji = 1, jpi
319               !                                       ! Potential nitrogen fixation dependant on temperature and iron
320               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
321               IF( zlim <= 0.2 )   zlim = 0.01
322#if defined key_degrad
323               zfact = zlim * rfact2 * facvol(ji,jj,jk)
324#else
325               zfact = zlim * rfact2
326#endif
327               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
328               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
329               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
330                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) )
331            END DO
332         END DO
333      END DO
334 
335      ! The total gain from nitrogen fixation is scaled to balance the loss by denitrification
336      ! -------------------------------------------------------------
337      zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
338      zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
339      znitrpottot  = glob_sum ( znitrpot(:,:,:)                        * cvol(:,:,:) )
340      IF( kt == nitend .AND. jnt == nrdttrc ) THEN
341         zfact = 1.e+3 * rfact2r * rno3 * 365. * 86400. * 14. / 1e12
342         IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact
343      ENDIF
344
345      ! Nitrogen change due to nitrogen fixation
346      ! ----------------------------------------
347      DO jk = 1, jpkm1
348         DO jj = 1, jpj
349            DO ji = 1, jpi
350               zfact = znitrpot(ji,jj,jk) * nitrfix
351               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
352               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
353               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
354               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + 30. / 46. * zfact
355           END DO
356         END DO
357      END DO
358      !
359      IF( ln_diatrc ) THEN
360         zfact = 1.e+3 * rfact2r
361         IF( lk_iomput .AND. jnt == nrdttrc ) THEN
362            CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
363            CALL iom_put( "Sdenit", zwork4(:,:)               * rno3 * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
364         ELSE
365            trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1)
366         ENDIF
367      ENDIF
368      !
369      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
370         WRITE(charout, fmt="('sed ')")
371         CALL prt_ctl_trc_info(charout)
372         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
373      ENDIF
374      !
375      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 )
376      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot )
377      !
378      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
379      !
380 9100  FORMAT(i8,3f10.5)
381      !
382   END SUBROUTINE p4z_sed
383
384#else
385   !!======================================================================
386   !!  Dummy module :                                   No PISCES bio-model
387   !!======================================================================
388CONTAINS
389   SUBROUTINE p4z_sed                         ! Empty routine
390   END SUBROUTINE p4z_sed
391#endif 
392
393   !!======================================================================
394END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.